chiark / gitweb /
Makefile: drop utils.scad from AUTOINCS
[reprap-play.git] / sewing-table.scad.m4
1 // -*- C -*-
2
3 include <funcs.scad>
4 include <commitid.scad>
5
6 ply_th = 18;
7 ply_hole_dia = 15;
8 ply_edge_min = 10;
9
10 tile_th = 3;
11 post_dia = 8;
12
13 post_shorter = 1;
14
15 screw_dia = 2.2;
16 screw_big_dia = 3.6;
17 screw_big_len = 4.0;
18
19 round_edge_rad = 2.0;
20
21 round_cnr_rad = 10;
22
23 interlock_dia = 10;
24 interlock_fine = 0.66;
25
26 interlock_fine_slope = 1.0;
27 interlock_fine_lenslop = 1.0;
28
29 demo_slop = 0.1;
30
31 // cutout
32
33 machine_rear_to_front = 85;
34
35 machine_rear_profile = [
36                         [ -  0,  -0.00 ],
37                         [ -  2,  -0.10 ],
38                         [ -  4,  -0.20 ],
39                         [ -  5,  -0.30 ],
40                         [ -  6,  -0.40 ],
41                         [ -  7,  -0.50 ],
42                         [ -  8,  -0.75 ],
43                         [ - 10,  -1.50 ],
44                         [ - 12,  -2.25 ],
45                         [ - 14,  -3.25 ],
46                         [ - 16,  -4.25 ],
47                         [ - 18,  -5.75 ],
48                         [ - 20,  -8.00 ]
49                         ];
50
51 machine_front_profile =  [
52                           [  128,  -3.70,  ],
53                           [  124,  -2.90,  ],
54                           [  120,  -2.45,  ],
55                           [  116,  -2.10,  ],
56                           [  112,  -1.80,  ],
57                           [  108,  -1.55,  ],
58                           [  104,  -1.25,  ],
59                           [  100,  -1.00,  ],
60                           [   96,  -0.80,  ],
61                           [   92,  -0.65,  ],
62                           [   88,  -0.55,  ],
63                           [   84,  -0.50,  ]
64                           ];
65
66 cutout_l_end_y_front_slop = 0.5;
67 cutout_l_end_y_rear_slop = 0.5;
68 cutout_l_end_x_slop = 0.25;
69
70 cutout_l_end_x = 22;
71 cutout_l_end_y = machine_rear_to_front;
72 cutout_l_end_curve = 1;
73 cutout_l_end_y_total = cutout_l_end_y
74   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
75
76 tile02_tr = [-250, 0];
77 tile01_tr = [  0, 0];
78
79 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
80 cutout_tile11_x = cutout_l_end_x + cutout_l_end_curve;
81 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
82
83 // front and rear curves
84
85 rearedge_len = 170;
86
87 rearcurve_strt_len = 52;
88
89 rearcurve_z_slop = 0.75;
90
91 rearcurve_avoid_y = 35;
92
93 rearcurve_double_inrad = 26.10 + 8.04;
94
95 reartablet_z = 2.54;
96 reartablet_x = 5 + 1;
97 reartablet_y = 8;
98
99 frontcurve_side_skew = 3.5 / 72;
100 frontcurve_avoid_y = 70;
101 frontcurve_z_slop = 0.75;
102
103 // calculated
104
105 TEST = false;
106
107 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
108
109 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
110
111 hole_slop = (ply_hole_dia - post_dia)/2;
112 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
113
114 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
115          tile_hard_edge_hole_dist));
116
117 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
118          tile_hard_edge_hole_dist + round_edge_rad));
119
120 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
121 thehd_tr = thehd;
122 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
123 thehd_bl = -thehd_tr;
124 thehd_br = -thehd_tl;
125
126 tablet_z_slop = rearcurve_z_slop;
127
128 interlock_rad = interlock_dia/2;
129 interlock_negative_rad = interlock_rad + 0.125;
130
131 interlock_sq_adj = 0.2; // arbitrary
132
133 first_front = machine_front_profile[len(machine_front_profile)-1];
134
135 m4_define(`POST_TCROSSSZ',
136           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
137
138 module Post(){
139   mirror([0,0,1]) {
140     difference(){
141       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
142       translate([0,0, tile_th]) {
143         cylinder(r= screw_big_dia/2, h= screw_big_len);
144         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
145       }
146     }
147     if (TEST) {
148       translate([0,0, tile_th/2]) {
149         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
150         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
151       }
152     }
153   }
154 }
155
156 module Posts(posts) {
157   for (p= posts) {
158     translate(concat(p, [0]))
159       Post();
160   }
161 }
162
163 module TileBase(botleft, topright){
164   size = topright - botleft;
165   botleft_post = botleft + thehd_tr;
166   topright_post = topright + thehd_bl;
167   difference(){
168     mirror([0,0,1])
169       translate(concat(botleft, [0]))
170       cube(concat(size, [tile_th]));
171     if (!TEST) {
172       cidsz = topright_post-botleft_post
173         + [-post_dia,-post_dia]
174         + [0, thehd[1]];
175       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
176       echo("CID",cidsz,cidszr);
177       translate( concat(botleft_post, [ -tile_th ])
178                  + 0.5 * [ post_dia, post_dia, 0 ]
179                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
180         Commitid_BestCount_M(cidszr);
181     }
182     if (TEST) {
183       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
184       cidsz = [ thehd[0], size[1] - 2*crossoff ];
185       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
186       translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
187         Commitid_BestCount(cidszr);
188       difference(){
189         mirror([0,0,1]) {
190           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
191             cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
192           translate(concat(botleft_post, [-1]))
193             cube(concat(topright_post-botleft_post, [tile_th+2]));
194         }
195         shufflesz = max(test_edge, tile_hard_edge_hole_dist)*2;
196         hull(){ // poor man's minkowski
197           for (xs=[-1,1]) for (ys=[-1,1]) for (zs=[-1,1]) {
198             translate([xs,ys,zs] * shufflesz)
199               Machine();
200           }
201         }
202       }
203     }
204   }
205 }
206
207 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
208 m4_define(`INREFFRAME',`
209   length_vec = ($2) - ($1);
210   length = dist2d([0,0], length_vec);
211   length_uvec = length_vec / length;
212   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
213   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
214         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
215         [ 0,              0,              1,            0, ],
216         [ 0,              0,              0,            1, ] ];
217   $3
218   multmatrix(m)
219 ')
220
221 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
222 m4_dnl    INREFFRAME_EDGE { body; }
223 m4_define(`INREFFRAME_EDGE',`
224   translate([0,0, -round_edge_rad])
225 ')
226
227 module RoundEdge(left_cnr, right_cnr) {
228   INREFFRAME(left_cnr, right_cnr)
229     INREFFRAME_EDGE {
230     difference(){
231       rotate([0,90,0])
232         cylinder(r= round_edge_rad, h= length, $fn=50);
233       translate([-1, 0, -20])
234         cube([length+2, 20, 20]);
235     }
236   }
237 }
238
239 module RoundCornerCut(ci) {
240   // ci should be [this_cnr, right_cnr]
241   // where right_cnr is to the right (ie, anticlockwise)
242   this_cnr = ci[0];
243   right_cnr = ci[1];
244   offr= round_cnr_rad - round_edge_rad;
245   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
246     difference(){
247       cube(offr*2 - 0.1, center=true);
248       translate([offr, offr, 0])
249         cylinder(center=true, h=20, r= offr);
250     }
251   }
252 }
253
254 module RoundCornerAdd(ci) {
255   this_cnr = ci[0];
256   right_cnr = ci[1];
257   bigr = round_cnr_rad - round_edge_rad;
258   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
259     intersection(){
260       cube(bigr*2 + 0.1, center=true);
261       translate([bigr, bigr, 0])
262         rotate_extrude(convexity=10, $fn=50)
263         translate([bigr, 0])
264         difference(){
265           circle(r= round_edge_rad, $fn=50);
266           mirror([1,1])
267             square([20,20]);
268         }
269     }
270   }
271 }
272
273 module InterlockLobePlan(negative) {
274   r = negative ? interlock_negative_rad : interlock_rad;
275   ymir = negative ? 0 : 1;
276
277   dx = sqrt(3) * r;
278   $fn= 80;
279   translate([thehd[0], 0]){
280     mirror([0,ymir]){
281       circle(r=r);
282       difference(){
283         translate([-dx, -0.1])
284           square([ dx*2, r/2 + 0.1 ]);
285         for (xi = [-1, 1]) {
286           translate([ xi*dx, r ])
287             circle(r=r);
288         }
289       }
290     }
291   }
292 }
293
294 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
295   for (lobei = [ 0 : nlobes-1 ]) {
296     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
297     translate([lobex, 0, 0]) {
298       InterlockLobePlan(negative);
299     }
300   }
301
302   if (dosquare) {
303     iadj = 0;
304     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
305     mirror([0, negative])
306       translate([slotshorter, iadj])
307       square([length - slotshorter*2, interlock_fine + iadj*2]);
308   }
309 }
310
311 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
312   plusth = negative * 1.0;
313   protr = interlock_fine + interlock_sq_adj;
314
315   z2 = -tile_th/2;
316   z1 = -tile_th/2 - protr / interlock_fine_slope;
317   z3 = -tile_th/2 + protr / interlock_fine_slope;
318
319   negsign = negative ? -1 : +1;
320   yprotr = negsign * protr;
321
322   INREFFRAME(left_cnr, right_cnr) {
323     for (vsect = [ // zs0            zs1      ys0,            ys1
324                   [ -tile_th-plusth, plusth,  0,              0],
325                   [ z1,              z2,      0, yprotr],
326                   [ z2,              z3,      yprotr, 0],
327                   ]) {
328       zs0 = vsect[0];
329       zs1 = vsect[1];
330       zsd = zs1-zs0;
331       ys0 = vsect[2];
332       ys1 = vsect[3];
333       ysd = ys1-ys0;
334       sl = ysd/zsd;
335       m = [ [ 1,0,   0,    0 ],
336             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
337             [ 0,0,   1,  zs0 ],
338             [ 0,0,   0,    1 ] ];
339       multmatrix(m)
340         linear_extrude(height=zsd, convexity=10)
341         InterlockEdgePlan(negative, nlobes, length, !!ysd);
342     }
343   }
344 }
345
346 function TestPiece_holes2corners(holes) =
347   [ holes[0] + thehd_bl,
348     holes[1] + thehd_br,
349     holes[1] + thehd_tr,
350     holes[0] + thehd_tl ];
351
352 module TestPiece1(){ ////toplevel
353   holes = [ [-100, 0],
354             [   0, 0]
355             ];
356   corners = TestPiece_holes2corners(holes);
357   rcs = [corners[0], corners[1]];
358   difference(){
359     union(){
360       TileBase(corners[0], corners[2]);
361       Posts(holes);
362       RoundEdge(corners[0], corners[1]);
363       RoundEdge(corners[3], corners[0]);
364     }
365     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
366     RoundCornerCut(rcs);
367   }
368   RoundCornerAdd(rcs);
369 }
370
371 module TestPiece2(){ ////toplevel
372   holes = [ [   0, 0],
373             [  50, 0]
374             ];
375   corners = TestPiece_holes2corners(holes);
376   TileBase(corners[0], corners[2]);
377   Posts(holes);
378   RoundEdge(corners[0], corners[1]);
379   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
380 }
381
382 module TestDemo(){ ////toplevel
383   translate([ -thehd[0], 0 ])
384     color("blue")
385     TestPiece1();
386   translate([ +thehd[0] + demo_slop, 0 ])
387     TestPiece2();
388 }
389
390 module Machine_Arm(){
391   ysz = cutout_l_end_y_total;
392   // assume the round end is arc of a circle
393   chordlen = dist2d([0,0], [ cutout_l_end_y, cutout_l_end_curve ]);
394   endrad = cutout_l_end_y / cutout_l_end_curve * chordlen;
395   
396   translate([0,0,-30]) linear_extrude(height=60) {
397     translate(tile01_tr + [0, (-cutout_tile01_y + cutout_tile11_y)/2]) {
398       intersection(){
399         translate([-50, -ysz/2])
400           square([400, ysz]);
401         translate([ endrad - cutout_tile11_x - cutout_l_end_x_slop, 0 ])
402           circle(r=endrad, $fa=0.01,$fd=5);
403       }
404     }
405   }
406 }
407
408 module Machine_Profile(){
409   first_rear = machine_rear_profile[0];
410   below_point = 0.5 * ( first_rear + first_front ) + [ 0, -10 ];
411   pol = concat( machine_rear_profile,
412                 [ below_point ],
413                 machine_front_profile);
414   skew_angle = atan2( first_front[1] - first_rear[1],
415                       first_front[0] - first_rear[0] );
416   echo(below_point, pol, skew_angle);
417   hull(){
418     for (z=[0,-40]) {
419       translate([0,z]) {
420         //scale([1,5])
421         rotate([0,0, -skew_angle ]){
422           //translate( - first_front )
423           polygon(pol);
424         }
425       }
426     }
427   }
428 }
429
430 module Machine_NewRearProfile(){
431   // figures copied out of xfig edit boxes
432   // best not to edit the posbox size if poss - just move it
433   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
434   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
435   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
436   scaleline_mm = 12+5+10+5+3;
437   sh = -[abs(posbox[0]), abs(posbox[1])];
438   rot = atan2(-sideline[0], sideline[1]);
439   sc = scaleline_mm / scaleline;
440   echo("SH",sh,rot,sc);
441   scale(sc) rotate(rot) translate(sh){
442     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
443   }
444 }
445
446 module Machine_NewRearCurve(){
447   slant = atan2(4,210-10);
448   echo("SL",slant);
449   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
450     translate([ rearcurve_double_inrad,
451                 0,
452                 -rearcurve_double_inrad + 10 ]){
453       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
454         hull(){
455           Machine_NewRearProfile();
456           translate([0,-100]) Machine_NewRearProfile();
457         }
458       }
459     }
460     rotate([0,90,0]) rotate([90,0,0]) {
461       intersection(){
462         rotate_extrude(convexity=10, $fn=64)
463           rotate(90)
464           translate([ 0, -rearcurve_double_inrad ])
465           Machine_NewRearProfile();
466         translate([0,0,-500])
467           cube([500,500,1000]);
468       }
469     }
470     translate([1,0,-rearcurve_double_inrad])
471       rotate([0,-90,0]) rotate([0,0,-90])
472       linear_extrude(height= rearcurve_strt_len + 1)
473       Machine_NewRearProfile();
474   }
475 }
476
477 module Machine_RearProfile(){ ////toplevel
478   intersection(){
479     Machine_Profile();
480     translate([ -200 + machine_rear_to_front/2, -100 ]) {
481       square([200,200]);
482     }
483   }
484 }
485
486 module Machine_FrontProfile(){
487   intersection(){
488     Machine_Profile();
489     translate([ machine_rear_to_front/2, -100 ]) {
490       square([200,200]);
491     }
492   }
493 }
494
495 module Machine_Curves(){ ////toplevel
496   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
497               cutout_tile11_y,
498               0 ]){
499     //%cube([20,20,20]);
500     translate([ -reartablet_x,
501                 -1,
502                 -reartablet_z + tablet_z_slop])
503       mirror([0,0,1])
504       cube([ reartablet_x+1,
505              reartablet_y+1,
506              20 ]);
507   }
508   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
509               cutout_tile11_y,
510               frontcurve_z_slop ]){
511     translate([ 0, -first_front[0] , 0 ])
512       multmatrix([[1, -frontcurve_side_skew, 0, 0],
513                   [0,  1,   0, 0],
514                   [0,  0,   1, 0],
515                   [0,  0,   0, 1]])
516       translate([ 0, first_front[0] , 0 ])
517       mirror([1,0,0]){
518       rotate([0,-90,0])rotate([0,0,-90]){
519         linear_extrude(height= 200)
520           Machine_FrontProfile();
521       }
522     }
523     translate([ rearcurve_strt_len,
524                 0,
525                 rearcurve_z_slop ]){
526       Machine_NewRearCurve();
527     }
528   }
529 }
530
531 module Machine(){ ////toplevel
532   Machine_Arm();
533   Machine_Curves();
534 }
535
536 function Rectangle_corners(c0, sz) =
537   // returns the corners of a rectangle from c0 to c0+sz
538   // if sz is positive, the corners are anticlockwise starting with c0
539   [ c0 + [ 0,     0     ],
540     c0 + [ sz[0], 0     ],
541     c0 + [ sz[0], sz[1] ],
542     c0 + [ 0,     sz[1] ] ];
543
544 function Rectangle_corners2posts(c) =
545   [ c[0] + thehd_tr,
546     c[1] + thehd_tl,
547     c[2] + thehd_bl,
548     c[3] + thehd_br ];
549
550 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
551
552 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
553
554 m4_dnl   R_EDGE(c,ix)
555 m4_dnl        c is from Rectangle_corners and
556 m4_dnl        ix is a corner number
557 m4_dnl    expands to two comma-separated corners:
558 m4_dnl    that denoted by ix, and the next one anticlockwise
559 m4_define(`R_EDGE',`$1[$2],$1[(($2)+1)%4]')
560
561 module FitTest_general(c0,sz, dobrace=false){
562   c = Rectangle_corners(c0, sz);
563   brace = [7,7,9];
564   difference(){
565     union(){
566       Rectangle_TileBase(c);
567       if (dobrace) {
568         translate(concat(c0, [-brace[2] + 0.1])){
569           difference(){
570             cube(concat(sz,[brace[2]]) - [5,0,0]);
571             translate(brace + [0,0, -25])
572               cube(concat(sz, [50]) - brace*2 + [10,0,0]);
573           }
574         }
575       }
576       RoundEdge(R_EDGE(c,1));
577     }
578     Machine();
579   }
580 }
581
582 module FitTest_Entire(){ ////toplevel
583   FitTest_general([-40,-80], [275,180], dobrace=true);
584 }
585
586 module FitTest_RearCurve(){ ////toplevel
587   FitTest_general([110,0], [170,100]);
588 }
589
590 module FitTest_FrontCurve(){ ////toplevel
591   FitTest_general([110,-80], [170,80]);
592 }
593
594 module Tile02(){ ////toplevel
595   sz = [100,170];
596   c0 = tile02_tr + -sz;
597   c = Rectangle_corners(c0, sz);
598   posts = Rectangle_corners2posts(c);
599   rcs = [R_EDGE(c,0)];
600   difference(){
601     union(){
602       Rectangle_TileBase(c);
603       Posts(posts);
604       RoundEdge(R_EDGE(c,0));
605       RoundEdge(R_EDGE(c,3));
606       InterlockEdge(R_EDGE(c,2), 0);
607     }
608     InterlockEdge(R_EDGE(c,1), 1);
609     RoundCornerCut(rcs);
610   }
611   RoundCornerAdd(rcs);
612 }
613
614 module Tile12(){ ////toplevel
615   sz = [100,250];
616   c0 = tile02_tr + [-sz[0], 0];
617   c = Rectangle_corners(c0, sz);
618   posts = Rectangle_corners2posts(c);
619   rcs = [R_EDGE(c,3)];
620   difference(){
621     union(){
622       Rectangle_TileBase(c);
623       Posts(posts);
624       RoundEdge(R_EDGE(c,2));
625       RoundEdge(R_EDGE(c,3));
626     }
627     InterlockEdge(R_EDGE(c,0), 1);
628     InterlockEdge(R_EDGE(c,1), 1);
629     RoundCornerCut(rcs);
630   }
631   RoundCornerAdd(rcs);
632 }
633
634 tile_01_11_cnr = tile01_tr + [-cutout_tile11_x, 0];
635 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
636 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
637
638 module Tile11(){ ////toplevel
639   sz = [250,250];
640   c0 = tile01_tr + [-sz[0],0];
641   c = Rectangle_corners(c0, sz);
642   cnr_posts = Rectangle_corners2posts(c);
643   posts = concat(
644                  Posts_interpolate_one(cnr_posts[0],
645                                        cnr_posts[1] - [cutout_tile11_x, 0]),
646                  [ cnr_posts[1] + [0, cutout_tile11_y],
647                    cnr_posts[2],
648                    cnr_posts[3]
649                    ]);
650   difference(){
651     union(){
652       Rectangle_TileBase(c);
653       Posts(posts);
654       RoundEdge(R_EDGE(c,2));
655       InterlockEdge(R_EDGE(c,3));
656     }
657     InterlockEdge(c[0], tile_01_11_cnr, 1);
658     InterlockEdge(tile_11_10_cnr, c[2], 1);
659     Machine();
660   }
661 }    
662
663 module Tile01(){ ////toplevel
664   sz = [250,170];
665   c0 = tile01_tr + -sz;
666   c = Rectangle_corners(c0, sz);
667   cnr_posts = Rectangle_corners2posts(c);
668   posts = concat(
669                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
670                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
671                  Posts_interpolate_one(cnr_posts[2] - [cutout_tile11_x, 0],
672                                        cnr_posts[3])
673                  );
674   difference(){
675     union(){
676       Rectangle_TileBase(c);
677       Posts(posts);
678       RoundEdge(R_EDGE(c,0));
679       InterlockEdge(tile_01_11_cnr, c[3]);
680       InterlockEdge(R_EDGE(c,3));
681     }
682     InterlockEdge(c[1], tile_01_00_cnr, 1);
683     Machine();
684   }
685 }    
686
687 module Tile10(){ ////toplevel
688   sz = [250,250];
689   c0 = tile01_tr + [0,0];
690   c = Rectangle_corners(c0, sz);
691   cnr_posts = Rectangle_corners2posts(c);
692   cty = cutout_tile11_y;
693   rcy = cty + rearcurve_avoid_y;
694   posts = [ cnr_posts[0] + [ 0,                             cty ],
695             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
696             cnr_posts[1] + [ 0,                             rcy ],
697             cnr_posts[2],
698             cnr_posts[3] ];
699   rcs = [R_EDGE(c,2)];
700   difference(){
701     union(){
702       Rectangle_TileBase(c);
703       Posts(posts);
704       RoundEdge(R_EDGE(c,1));
705       RoundEdge(R_EDGE(c,2));
706       InterlockEdge(c[3], tile_11_10_cnr);
707     }
708     RoundCornerCut(rcs);
709     Machine();
710   }
711   RoundCornerAdd(rcs);
712 }
713
714 module Tile00(){ ////toplevel
715   sz = [250,170];
716   c0 = tile01_tr + [0,-sz[1]];
717   c = Rectangle_corners(c0, sz);
718   cnr_posts = Rectangle_corners2posts(c);
719   cty = cutout_tile01_y;
720   rcy = cty + frontcurve_avoid_y;
721   posts = [ cnr_posts[0],
722             cnr_posts[1],
723             cnr_posts[2] + [ 0,                             -rcy ],
724             cnr_posts[2] + [ -sz[0] + rearedge_len - cutout_l_end_x, -cty ],
725             cnr_posts[3] + [ 0,                             -cty ]
726             ];
727   rcs = [R_EDGE(c,1)];
728   difference(){
729     union(){
730       Rectangle_TileBase(c);
731       Posts(posts);
732       RoundEdge(R_EDGE(c,0));
733       RoundEdge(R_EDGE(c,1));
734       InterlockEdge(tile_01_00_cnr, c[0]);
735     }
736     RoundCornerCut(rcs);
737     Machine();
738   }
739   RoundCornerAdd(rcs);
740 }
741
742 module Demo(){ ////toplevel
743   translate(demo_slop*[-2,1]) color("blue") Tile12();
744   translate(demo_slop*[-2,0]) color("red")  Tile02();
745   translate(demo_slop*[-2,1]) color("orange") Tile11();
746   translate(demo_slop*[-2,0]) color("purple") Tile01();
747   translate(demo_slop*[-3,1]) color("blue")   Tile10();
748   translate(demo_slop*[-3,0]) color("red")    Tile00();
749   %Machine();
750 }
751   
752 //TestPiece1();
753 //TestPiece2();
754 //Demo();
755
756 //Machine_Profile();
757 //Machine_NewRearProfile();
758 //Machine_NewRearCurve();
759 //Machine_Curves();
760 //Machine();
761 //FitTest();