poster-tube-lid.scad

   1 // -*- C -*-
   2
   3 coarse = false;
   4
   5 main_dia = 71.2 + 0.50 - 2.26;
   6 top_thick_middle = 4;
   7 top_thick_by_oring = 3.0;
   8 top_middle_dr = 11;
   9
  10 main_cnr = 6.0;
  11
  12 min_wall = 3;
  13
  14 rivet_posn = 6.0 + 0.30;
  15 rivet_thick = 1.67;
  16 rivet_width = 4.15 + 1.0;
  17 rivet_tall = 5.51 + 1.49;
  18
  19 over_rivet_wall = 1.0;
  20 side_rivet_gap = 1.5;
  21 inside_rivet_gap = 1.5;
  22
  23 bayo_interf = 0.30;
  24 bayo_behind = 3.5;
  25 bayo_interf_width = 2.0;
  26 bayo_interf_slope = 0.5;
  27
  28 oring_thick = 5.0;
  29 oring_bore = 62.0;
  30
  31 oring_upper_embed_angle = 80;
  32 oring_compress = 0.1; // proportion
  33 oring_compress_more = 0.2;
  34
  35 oring_rm_beside = 8;
  36 oring_rm_scale = 2.0;
  37 oring_rm_angle = 20;
  38
  39 side_taper = 1.0;
  40
  41 bayo_gap = 6.0;
  42
  43 bayo_entry = bayo_behind/3;
  44
  45 bayo_slice_size = coarse ? 5 : 1;
  46
  47 brace_hole_width = 1.0;
  48 brace_above_below = 1.2;
  49 brace_end_shorter = 0.3;
  50
  51 jig_thick = 1.4;
  52 jig_hole_dia = 3.0;
  53 jig_rim = 5;
  54 jig_mark = 5;
  55
  56 strap_hoop_thick = 6;
  57 strap_hoop_inside = 10;
  58 strap_hoop_strlen = 10;
  59 strap_hoop_elevation = 45;
  60
  61 sm_inner_circum = 218 - 1.90 - 1.00 - 0.50;
  62 sm_main_thick = 2.0;
  63 sm_main_width = 20;
  64
  65 sm_bolt_dia = 3.5 + 0.1;
  66 sm_bolt_shaft = 21.9;
  67 sm_bolt_head_dia = 6.94 + 1.0;
  68 sm_bolt_head_thick = 2.14;
  69 sm_bolt_nut_width = 5.89 + 0.25;
  70 sm_bolt_nut_thick = 3.68;
  71 sm_bolt_tighten_allow = 2.0;
  72
  73 sm_bolt_y_clear = 0.75;
  74 sm_bolt_y_over = 0.5;
  75
  76 sm_closure_cnr = 3.0;
  77
  78 catch_stem_h = 3;
  79 catch_stem_len = 50;
  80 catch_stem_th = 3;
  81
  82 catch_knob_dia = 6;
  83 catch_knob_above_gap = 8;
  84 catch_pin_height = 7;
  85
  86 catch_stem_below_gap = 1.0;
  87 catch_stem_beside_gap = 2.0;
  88 catch_pin_gap = 0.5;
  89
  90 // calculated
  91
  92 TAU = PI*2;
  93
  94 bayo_entry_x = bayo_entry;
  95 bayo_entry_z = bayo_entry;
  96 bayo_inramp_x = bayo_entry;
  97 bayo_inramp_z = bayo_entry;
  98
  99 oring_mid_dia = oring_bore + oring_thick;
 100 oring_outer_dia = oring_mid_dia + oring_thick;
 101
 102 oring_oblate = (1 - oring_compress);
 103
 104 oring_y_rad = oring_thick/2 * oring_oblate;
 105 oring_x_rad = oring_thick/2 / oring_oblate;
 106
 107 by_oring_z = oring_y_rad * (1 + cos(oring_upper_embed_angle));
 108
 109 side_height = rivet_posn + bayo_behind + rivet_thick/2;
 110 side_thick = rivet_tall + over_rivet_wall;
 111
 112 top_z = top_thick_by_oring + oring_y_rad + by_oring_z;
 113
 114 middle_bot_z = top_z - top_thick_middle;
 115
 116 bayo_entry = bayo_behind / 3.0;
 117 bayo_top_z = bayo_behind + bayo_gap;
 118
 119 rivet_entry_width = rivet_width + side_rivet_gap;
 120
 121 jig_mark_rad = jig_mark + main_dia/2 + jig_thick;
 122
 123 handling_dia = oring_bore + oring_thick*2 + min_wall*2;
 124 handling_angle = 45;
 125
 126 sm_inner_rad = (sm_inner_circum + sm_bolt_tighten_allow/2) / TAU;
 127 sm_outer_rad = sm_inner_rad + sm_main_thick;
 128
 129 smc_pos = [ 0, sm_inner_rad, 0 ];
 130
 131 smc_bolt_nut_dia = sm_bolt_nut_width / cos(30);
 132 smc_bolt_nut_eff_thick = sm_bolt_nut_thick + sm_bolt_tighten_allow;
 133
 134 smc_bolt_y = sm_bolt_dia/2 + sm_bolt_y_clear;
 135 smc_max_y = smc_bolt_y + sm_bolt_y_over
 136   + max(sm_bolt_head_dia/2, smc_bolt_nut_dia/2);
 137 smc_cnr_c_x = sm_bolt_shaft/2 - sm_closure_cnr
 138   + sm_bolt_head_thick/2 + smc_bolt_nut_eff_thick/2;
 139
 140 catch_cr = catch_knob_dia/2 + catch_stem_beside_gap;
 141 catch_strap_width = sm_main_width;
 142 catch_stem_end_h = catch_stem_h;
 143 catch_pin_width = rivet_entry_width - catch_pin_gap;
 144
 145 cppy6 = -catch_strap_width/2;
 146 cppB = [ catch_pin_width/2,
 147          cppy6
 148          + catch_stem_below_gap
 149          + catch_pin_height
 150          + catch_knob_dia/2 ];
 151 cpp0 = [ 0,
 152          cppB[1]
 153          + catch_knob_dia
 154          + catch_knob_above_gap ];
 155 cpp1 = cpp0 + [0,1] * catch_pin_height;
 156 cpp2 = cpp1 + [1,0] * catch_pin_width;
 157 cpp4 = cpp0 + [0,-1] * catch_stem_end_h;
 158 cpp3 = [ cpp2[0], cpp4[1] ];
 159 cpp5 = [ cpp0[0] - catch_stem_len,
 160          -catch_stem_h ];
 161 cpp6 = [ cpp5[0], catch_cr ];
 162 cpp7 = cppB + [1,-1] * catch_knob_dia/2
 163             + [ catch_stem_beside_gap, -catch_stem_below_gap ]
 164             + [ 0, -catch_pin_height ]
 165             + [-1,1] * catch_cr;
 166 cpp11 = cpp7 + [1,0] * catch_cr;
 167 cpp10 = [ cpp11[0], 0 - catch_cr ];
 168 cpp8 = cpp10 + [1,0] * catch_cr;
 169 cpp9 = cpp8 + [0,1] * catch_cr;
 170 cppC = cpp8 + [1,1] * catch_cr;
 171 cppA = [ cpp5[0] - catch_cr, 0 ];
 172 cppD = cppC + [0,-1] * catch_strap_width;
 173 cppE = [ cppA[0], cppD[1] ];
 174
 175 $fs= coarse ? 2.5 : 0.5;
 176 $fa= coarse ? 5 : 1;
 177
 178 include <poster-tube-lid-parametric.scad>
 179
 180 // bayonet definition
 181
 182 bayo_a = [ bayo_entry_x, 0 ];
 183 bayo_p = [ 0, bayo_entry_z ];
 184 bayo_n = [ 0, bayo_behind-bayo_inramp_z ];
 185 bayo_m = [ bayo_inramp_x, bayo_behind ];
 186 bayo_l = bayo_m + bayo_interf * [ 1/bayo_interf_slope,  1 ];
 187 bayo_k = bayo_l + [ bayo_interf_width, 0 ];
 188 bayo_j = bayo_k + bayo_interf * [ 1/bayo_interf_slope, -1 ];
 189 bayo_i = bayo_j + [ rivet_width + inside_rivet_gap, 0 ];
 190 bayo_h = [ bayo_i[0], bayo_behind + bayo_gap + bayo_interf ];
 191 bayo_g = [ bayo_m[0] - rivet_width, bayo_h[1] ];
 192
 193 bayo_e = [-bayo_p[0], bayo_p[1]] - [rivet_entry_width,0];
 194 bayo_d = [-bayo_a[0], bayo_a[1]] - [rivet_entry_width,0];
 195 bayo_c = bayo_d + [0,-5];
 196 bayo_b = bayo_a + [0,-5];
 197
 198 bayo_f = [ bayo_e[0], bayo_g[1] + (bayo_e[0] - bayo_g[0]) ];
 199
 200 bayo_polygon = [ bayo_a,
 201                  bayo_b,
 202                  bayo_c,
 203                  bayo_d,
 204                  bayo_e,
 205                  bayo_f,
 206                  bayo_g,
 207                  bayo_h,
 208                  bayo_i,
 209                  bayo_j,
 210                  bayo_k,
 211                  bayo_l,
 212                  bayo_m,
 213                  bayo_n,
 214                  bayo_p ];
 215
 216 echo(bayo_polygon);
 217
 218 module MainProfile(){
 219   main_cnr_pos = [ side_thick, top_z ] - [1,1]*main_cnr;
 220   difference(){
 221     union(){
 222       translate(main_cnr_pos){
 223         intersection(){
 224           difference(){
 225             circle(r = main_cnr);
 226             circle(r = main_cnr * 0.5);
 227           }
 228           square([10,10]);
 229         }
 230       }
 231       polygon([[ -top_middle_dr,        middle_bot_z      ],
 232                [ -top_middle_dr,        top_z             ],
 233                [ main_cnr_pos[0],       top_z             ],
 234                [ side_thick,            main_cnr_pos[1]   ],
 235                [ side_thick,            -side_height      ],
 236                [ side_taper,            -side_height      ],
 237                [ 0,                     -rivet_posn       ],
 238                [ 0,                     by_oring_z        ],
 239                [ -oring_x_rad,          by_oring_z        ],
 240                ],
 241               convexity=10);
 242     }
 243     translate([ oring_mid_dia/2 - main_dia/2, 0 ])
 244       hull(){
 245       translate([ 0, oring_y_rad ])
 246         scale([ 1/oring_oblate * (oring_compress_more+1) , oring_oblate ])
 247         circle(oring_thick/2);
 248       translate([ 0, oring_y_rad*2 - oring_thick/2 ])
 249         circle(oring_thick/2);
 250     }
 251   }
 252 }
 253
 254 module StrapHoopProfile(){
 255   circle(r = strap_hoop_thick/2);
 256 }
 257
 258 module StrapHoop(){ ////toplevel
 259   bigrad = strap_hoop_inside/2 + strap_hoop_thick/2;
 260   extralen = strap_hoop_thick * 5;
 261
 262   intersection(){
 263     rotate([strap_hoop_elevation, 0,0]){
 264       for (x= [ -1, +1 ] * bigrad) {
 265         translate([x, -extralen, 0])
 266           rotate([-90,0,0])
 267           linear_extrude(height= extralen + strap_hoop_strlen + 0.1,
 268                          convexity=10)
 269           StrapHoopProfile();
 270       }
 271       translate([0, strap_hoop_strlen, 0]){
 272         intersection(){
 273           rotate_extrude(convexity=10)
 274             translate([bigrad, 0,0])
 275             StrapHoopProfile();
 276           translate([0,50,0])
 277             cube([100,100,100], center=true);
 278         }
 279       }
 280     }
 281     translate([0, 50, 0])
 282       cube(100, center=true);
 283   }
 284 }
 285
 286 module RotateProjectSlice(offset, slice_size, nom_rad, real_rad){
 287   // nom_rad > real_rad
 288   rotate([0,0, atan2(offset, nom_rad) ]){
 289     intersection(){
 290       translate([-offset, -10, 0])
 291         rotate([90,0,0])
 292         linear_extrude(height= nom_rad*2)
 293         children(0);
 294       translate([0,0, -25])
 295         cylinder(h=50, r= real_rad);
 296       translate([0,0, -25])
 297         linear_extrude(height= 50)
 298         polygon([ [ 0,0 ],
 299                   [ -slice_size, -real_rad*2 ],
 300                   [ +slice_size, -real_rad*2 ] ]);
 301     }
 302   }
 303 }
 304
 305 module RotateProject(x_min, x_max, slice_size, nom_rad, real_rad){
 306   offs = [ for (i=[ x_min :
 307                     slice_size :
 308                     x_max + slice_size ]) i ];
 309   echo (offs);
 310   for (off=offs)
 311     RotateProjectSlice(off, slice_size, nom_rad, real_rad)
 312     children(0);
 313 }
 314
 315 module BayonetCutout(){
 316   RotateProject(bayo_c[0], bayo_i[0], bayo_slice_size,
 317                 main_dia/2 + side_thick,
 318                 main_dia/2 + rivet_tall)
 319     translate([-0.5 * (bayo_a[0] + bayo_d[0]), 0])
 320     polygon(bayo_polygon, convexity=10);
 321 }
 322
 323 module ProfilesDemo(){ ////toplevel
 324   translate([-10,0]) MainProfile();
 325   translate([+10, -side_height]) polygon(bayo_polygon, convexity=10);
 326 }
 327
 328 module LimitForHandling(){ ////toplevel
 329   hull() for (r=[0,180])
 330     rotate([0,0,r]) {
 331       for (rs=[-1,+1]) {
 332         for (xd=[0,1]) {
 333           rotate([0,0, rs * handling_angle/2]) {
 334             translate([rs * xd * main_dia/2 * tan(handling_angle/2),
 335                        main_dia/2 + side_thick - main_cnr,
 336                        top_z - main_cnr]) {
 337               mirror([0,0,1])
 338                 cylinder(r= main_cnr, h=50);
 339               sphere(main_cnr);
 340             }
 341           }
 342         }
 343       }
 344     }
 345   hull() rotate_extrude(){
 346     translate([ handling_dia/2 - main_cnr, top_z - main_cnr ]) {
 347       circle(r = main_cnr);
 348       mirror([0,1]) square([ main_cnr, 50 ]);
 349     }
 350   }
 351   //cylinder(r= handling_dia/2, h=20);
 352 }
 353
 354 module Cover(){ ////toplevel
 355   render() difference(){
 356     intersection(){
 357       union(){
 358         rotate_extrude(convexity=10)
 359           translate([main_dia/2, 0])
 360           MainProfile();
 361         translate([0,0, middle_bot_z])
 362           cylinder(h= top_thick_middle, r = main_dia/2 - top_middle_dr + 1);
 363       }
 364       LimitForHandling();
 365     }
 366     for (r=[0,180]){
 367       rotate([0,0, r])
 368         translate([0,0, -side_height])
 369         BayonetCutout();
 370       rotate([0,0, r + asin((-oring_rm_beside) / (main_dia/2))])
 371         translate([0,
 372                    oring_mid_dia/2 + oring_thick/4 * oring_rm_scale,
 373                    oring_y_rad * 1.5])
 374         rotate([-oring_rm_angle, 0, 0])
 375         mirror([0,0,1])
 376         cylinder(r = oring_thick/4 * oring_rm_scale, h=20);
 377     }
 378     for (r=[0 : 60 : 179]) {
 379       rotate([0,0, r]) {
 380         height = top_thick_middle - brace_above_below*2;
 381         translate([0,0, middle_bot_z + brace_above_below + height/2 ])
 382         cube(center=true, [ oring_bore - brace_end_shorter,
 383                             brace_hole_width, height ]);
 384       }
 385     }
 386   }
 387   for (r=[0,180])
 388     rotate([0,0,r])
 389       translate([-implheadcup_large_dia * .5 - implheadcup_thick/2,
 390                  -implheadcup_large_dia * .0,
 391                  middle_bot_z + 0.1])
 392       ImplHeadCup();
 393 //  translate(strap_hoop_thick * [-0.5, 0, +1])
 394 //    translate([handling_dia/2, 0, -side_height])
 395 //    rotate([0,180,0]) rotate([0,0,90])
 396 //    StrapHoop();
 397 }
 398
 399 module SavingHole(){
 400   translate([0,0, -10])
 401     cylinder(r= main_dia/2 - jig_rim, h=20);
 402 }
 403
 404 module Jig(){ ////toplevel
 405   difference(){
 406     union(){
 407       translate([0,0, -side_height]){
 408         cylinder(r= main_dia/2 + jig_thick, h= side_height + jig_thick);
 409       }
 410       translate([-jig_mark_rad, 0, jig_thick - jig_mark])
 411         cube([jig_mark_rad*2, jig_mark, jig_mark]);
 412     }
 413     translate([0,0, -side_height-1])
 414       cylinder(r= main_dia/2, h= side_height + 1);
 415     SavingHole();
 416     translate([0,0, -rivet_posn])
 417       rotate([90, 0,0])
 418       translate([0,0, -100])
 419       cylinder(r= jig_hole_dia/2, h = 200);
 420   }
 421 }
 422
 423 module CoverTest2(){ ////toplevel
 424   difference(){
 425     Cover();
 426     SavingHole();
 427   }
 428 }
 429
 430 module CoverTest1(){ ////toplevel
 431   difference(){
 432     CoverTest2();
 433     difference(){
 434       for (r= [ 40, 147 ]){
 435         rotate([0,0, r]){
 436           translate([0,0, -10]) {
 437             cube([ main_dia*3, main_dia * .53, 18], center=true);
 438           }
 439         }
 440       }
 441 //      translate([ 50, 0, 0 ])
 442 //      cube([ 100,
 443 //             strap_hoop_inside + strap_hoop_thick*2 + 1,
 444 //             100 ],
 445 //           center=true);
 446     }
 447   }
 448 }
 449
 450 module ImplHeadCupTest(){ ////toplevel
 451   for (r=[0,180])
 452     rotate([0,0,r])
 453       translate([-17,0,0])
 454       ImplHeadCup();
 455 }
 456
 457 module StrapMountBolt(l_delta){ ///toplevel
 458   // positioned relative to smc_pos
 459   translate([(smc_bolt_nut_eff_thick - sm_bolt_head_thick)/2,
 460              smc_bolt_y,
 461              sm_main_width/2]){
 462     translate([ -sm_bolt_shaft/2-1, 0,0 ]){
 463       rotate([0,90,0]) cylinder(r= sm_bolt_dia/2, h= sm_bolt_shaft+2);
 464     }
 465     translate([ -sm_bolt_shaft/2, 0,0 ])
 466       rotate([0,-90,0])
 467       cylinder($fn=6, r=smc_bolt_nut_dia/2,
 468                h=smc_bolt_nut_eff_thick + l_delta);
 469     translate([ sm_bolt_shaft/2, 0,0 ])
 470       rotate([0,90,0])
 471       cylinder(r=sm_bolt_head_dia/2, h=sm_bolt_head_thick + l_delta);
 472   }
 473 }
 474
 475 module StrapMountProtrusion(half_x, max_y, cnr){
 476   translate(smc_pos){
 477     linear_extrude(height=sm_main_width, convexity=10){
 478       hull(){
 479         for (m = [0,1]) mirror([m,0,0]) {
 480           translate([-(half_x - cnr), max_y - cnr])
 481             circle(r=cnr);
 482           translate([-half_x, -sm_inner_rad])
 483             square([1,1]);
 484         }
 485       }
 486     }
 487   }
 488 }
 489
 490 module StrapMount(){ ////toplevel
 491   difference(){
 492     union(){
 493       cylinder(r=sm_outer_rad, h=sm_main_width);
 494       StrapMountProtrusion(smc_cnr_c_x + sm_closure_cnr,
 495                            smc_max_y,
 496                            sm_closure_cnr);
 497       rotate([0,0,180]){
 498         StrapMountProtrusion(strap_hoop_inside/2 + strap_hoop_thick,
 499                              strap_hoop_thick,
 500                              sm_closure_cnr);
 501         translate(smc_pos +
 502                   [0,0, sm_main_width] +
 503                   strap_hoop_thick * [ 0, 0.5, -1.0 ])
 504           StrapHoop();
 505       }
 506     }
 507     translate([0,0,-1])
 508       cylinder(r=sm_inner_rad, h=sm_main_width+2);
 509     translate(smc_pos)
 510       StrapMountBolt(10);
 511     translate(smc_pos)
 512       cube([ sm_bolt_tighten_allow, 40,100 ], center=true);
 513   }
 514 }
 515
 516 module CatchCoreProfile(){ ////toplevel
 517   hull(){
 518     translate(cppB) circle(r= catch_knob_dia/2);
 519     polygon([cpp4,
 520              cppB,
 521              cpp3]);
 522   }
 523   translate(cpp8) circle(catch_cr);
 524   difference(){
 525     polygon([ cpp4,
 526               cppB,
 527               cpp3,
 528               cpp2,
 529               cpp1,
 530               cpp0,
 531               cppA,
 532               cppE,
 533               cppD,
 534               cppC,
 535               cpp9,
 536               cpp10,
 537               cpp11,
 538               cpp7,
 539               cpp5,
 540               ], convexity=10);
 541     hull(){
 542       translate(cpp7) circle(r= catch_cr);
 543       polygon([ cpp7,
 544                 cpp5,
 545                 cpp11 ]);
 546     }
 547     hull(){
 548       translate(cpp6) circle(catch_cr);
 549       polygon([ cppA,
 550                 cpp0,
 551                 cpp1 ]);
 552     }
 553   }
 554 }
 555
 556 //ProfilesDemo();
 557 //BayonetCutout();
 558 //MainProfile();
 559 //Cover();
 560 //Jig();
 561 //CoverTest();