pawn.scad

   1 // -*- C -*-
   2
   3 // shape parameters
   4
   5 r1 =  3;
   6 r2 =  4; a2 = 27;
   7 r3 = r2;
   8 r4 =  4; a4 = 20;
   9 r5 = 35;
  10 h6 =  5; a6 = 5;
  11
  12 // coordinates
  13
  14                                 z1 =  0;
  15 h2 = r2 * sin(a2);              z2 = z1 - h2;
  16 h3 = r3 * sin(a2);              z3 = z2 - h3;
  17 h4 = r4 * sin(a4);              z4 = z3 - h4;
  18
  19 zc5 = z4 - r5 * sin(a4);
  20 z5 = zc5 + r5 * sin(a6);        z6 = z5 - h6;
  21
  22 x1 =  0 - r1;
  23 x2 = x1 + r2 * (1-cos(a2));
  24 x3 = x2 + r3 * (1-cos(a2));
  25 x4 = x3 - r4 * (1-cos(a4));
  26
  27 xc5 = x4 + r5 * cos(a4);
  28 x5 = xc5 - r5 * cos(a6);
  29
  30 x6 = x5 - h6 * tan(a6);
  31
  32 htotal = r1 - z6;
  33 echo("height", htotal);
  34
  35 $fa=1;
  36 $fs=0.1;
  37
  38 module SegmentBasisSquare(zmin, zmax, xmin){
  39   translate([xmin, zmin-0.01]) square([-xmin+0.01, zmax-zmin+0.02]);
  40 }
  41 module ConvexSegment(xc, zc, r, zmin, zmax){
  42   intersection(){
  43     translate([xc,zc]) circle(r=r);
  44     SegmentBasisSquare(zmin,zmax,-50);
  45   }
  46 }
  47 module ConcaveSegment(xc, zc, r, zmin, zmax){
  48   difference(){
  49     SegmentBasisSquare(zmin,zmax, xc);
  50     translate([xc,zc]) circle(r=r);
  51   }
  52 }
  53
  54 module PawnTemplate(){
  55   ConvexSegment(  x1 + r1,  z1,   r1, z1, 50);
  56   ConvexSegment(  x1 + r2,  z1,   r2, z2, z1);
  57   ConcaveSegment( x3 - r3,  z3,   r3, z3, z2);
  58   ConcaveSegment( x3 - r4,  z3,   r4, z4, z3);
  59   ConvexSegment(  xc5,      zc5,  r5, z5, z4);
  60   polygon([[x6, z6],
  61            [x5, z5+0.01],
  62            [0.01, z5],
  63            [0.01, z6]]);
  64 }
  65
  66 module Pawn(h=htotal){
  67   scale(h/htotal) {
  68     rotate_extrude($fn=100){
  69       assign($fn=undef){
  70         PawnTemplate();
  71       }
  72     }
  73   }
  74 }
  75
  76 Pawn(h=20);