filamentspool.scad

   1 // -*- C -*-
   2
   3 // filamentspool.scad
   4 // 3D design for filament spools to hold coils as supplied by Faberdashery
   5 //
   6
   7 //
   8 // Copyright 2012,2013,2016 Ian Jackson
   9 //
  10 // This work is free software: you can redistribute it and/or modify
  11 // it under the terms of the GNU General Public License as published by
  12 // the Free Software Foundation, either version 3 of the License, or
  13 // (at your option) any later version.
  14 //
  15 // This work is distributed in the hope that it will be useful,
  16 // but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 // GNU General Public License for more details.
  19 //
  20 // You should have received a copy of the GNU General Public License
  21 // along with this work.  If not, see <http://www.gnu.org/licenses/>
  22 //
  23
  24 //
  25 // Each spool is a hub with 3 or 4 arms.  Each arm has a cup for
  26 // holding the filament.  The effective diameter can be adjusted by
  27 // setting the cup into a different seat in the arm.  The cups are
  28 // held on with simple clips, so the filement coil can easily be
  29 // removed and replaced.
  30 //
  31 // This file (and its includes) can generate:
  32 //
  33 // ===== Heavy duty 4-armed spool for 3mm x 100m coil =====
  34 //
  35 // A heavy duty 4-armed spool suitable for holding a 100m
  36 // Faberdashery coil on the spool arm of a Lulzbot TAZ-5.
  37 //
  38 //     Set
  39 //           fdia=2.85
  40 //           lightduty=false
  41 //     And print following parts
  42 //            Hub
  43 //            ArmEnd x 4
  44 //            FilamentCup x 4  (or FilamentCupPair x 2)
  45 //            CupSecuringClip x 4
  46 //
  47 //     You will also need  4 x M4 machine screws and nuts.
  48 //
  49 //     This is the default.
  50 //
  51 // ===== Light duty 3-armed spool for 3mm x <=30m coil =====
  52 //
  53 // A light duty 3-armed spool suitable for up to around 30m
  54 // of Faberdashery 2.85mm PLA.
  55 //
  56 //     Set
  57 //           fdia=2.85
  58 //           lightduty=true
  59 //     (or look in filamentspool-lt.scad).
  60 //
  61 //     And print following parts
  62 //           Hub
  63 //           ArmEnd x 3
  64 //           FilamentCup x 3  (or FilamentCup + FilamentCupPair)
  65 //           CupSecuringClip x 3
  66 //           TowerDoveClipPin x 6
  67 //
  68 //     When assembling, insert one TowerDoveClipPin from each side,
  69 //     joining each ArmEnd to the Hub with two TowerDoveClipPins.
  70 //     Modest force with pliers is good to seat them properly.
  71 //
  72 //     (note that the light duty and heavy duty CupSecuringClips
  73 //      are slightly different)
  74 //
  75 // ===== Notes regarding both the above spools =====
  76 //
  77 // When mounting either spool on the TAZ-5 spool arm, put the `pointy'
  78 // end of the hub towards the printer - ie, put put the spool on
  79 // `backwards'.  This ensures that the spool's arms will clear the
  80 // printer framework.
  81 //
  82 // For the above, I generally used the Cura `Standard' PLA profile.
  83 //
  84 // ===== TAZ-5 feed tube adjustment kit =====
  85 //
  86 // With a TAZ-5 I recommend using this kit to improve the feed
  87 // reliability:
  88 //
  89 //       Set
  90 //           fdia=2.85
  91 //     And print following parts
  92 //           FilamentGuideSpacer (ideally, at `high detail')
  93 //           FilamentGuideArmPrint (optional; `high detail' or `standard')
  94 //
  95 //     And possibly also
  96 //           t-nut_jig_0.2.stl
  97 //     from Aleph Objects - look here:
  98 //           http://download.lulzbot.com/TAZ/accessories/tool_heads/version_2/Dual_Extruder_v2/production_parts/stl/
  99 //
 100 // The spacer clips onto the filament guide tube holder arm, on the
 101 // inside, with the pointy flanged end towards the filament guide
 102 // tube.  It stops the filament guide tube angle (and so the
 103 // filament's natural pickup location) changing as the print head moves.
 104 //
 105 // The FilamentGuideArm[Print] is a replacement for the arm supplied
 106 // with your TAZ-5.  It's longer, so that the filament pickup point is
 107 // closer to the middle of the coil.  Use the t-nut_jig to stop the
 108 // T-nuts in the aluminium channel from annoyingly sliding down to the
 109 // bottom while you swap out the arm.
 110 //
 111 // (Faberdashery coils, and therefore both the above spools, have a
 112 // larger diameter than the flat-walled spools often supplied by other
 113 // vendors.  And the spools above have individual arms rather than a
 114 // continuous disc.  If the filament `unhooks' from the arm, it can
 115 // pull taught around the hub and stop feeding properly.)
 116 //
 117 // ===== Spool storage arm, for mounting on walls =====
 118 //
 119 // A storage arm suitable for screwing to walls, bookshelves,
 120 // etc. (requires non-countersunk M4 screws); will hold two heavy duty
 121 // spools each with a 100m coil.
 122 //
 123 //     Set
 124 //           fdia=2.85
 125 //           lightduty=false
 126 //     (or look in filamentspool-sm.scad).
 127 //
 128 //     And print one of these, according to taste
 129 //            StorageArmLeft
 130 //            StorageArmRight
 131 //
 132 //     NB that the `light duty' version of this is shorter and
 133 //     will only take two `light duty' spools.
 134 //
 135 // For the above, I used the Cura `High detail' PLA profile because
 136 // I wanted it pretty, but the `Standard' profile should do fine.
 137 //
 138 // ===== Spools for 1.75mm filament =====
 139 //
 140 // Spool (in many parts) for handing 1.75mm filament, printable
 141 // on, and with parts for mounting on, a Reprappro Huxley.
 142
 143
 144 fdia=2.85; // or 1.75
 145 lightduty=false; // or true
 146
 147
 148 slop=0.5;
 149 bigslop=slop*2;
 150
 151 function selsz(sm,lt,lg) = fdia < 2 ? sm : lightduty ? lt : lg;
 152 function usedove() = selsz(true,true,false);
 153
 154 num_arms = selsz(3,3,4);
 155
 156 channelslop=selsz(slop,0.75,slop);
 157
 158 exteffrad = 70;
 159 hubeffrad = selsz(30, 82, 40);
 160 hubbigrad = selsz(20, 38, 38);
 161 hublwidth = selsz(3, 2.5, 4);
 162 hubstemwidth = 2;
 163 hublthick = 10;
 164 hubaxlerad = selsz(5, 28/2, 28/2);
 165 totalheightfromtower = 240;
 166 axletowerfudgebend = 0;
 167 axleaxlefudgebend = 3;
 168 axlepadlen = 1.0;
 169
 170 armend_length = 120;
 171
 172 prongthick=selsz(5,4,5);
 173 prongwidth=selsz(5,4,5);
 174 prongribwidth=3;
 175 prongribheight=selsz(0,0,4);
 176 ratchetstep=15;
 177 ratchettooth=3;
 178 ratchettoothheight=5;
 179 ratchettoothsmoothr=1;
 180 ratchettoothslope=0.75;
 181 overlap=0.5;
 182 cupwidth=selsz(40,25,50);
 183 cupheight=selsz(55,25,55);
 184
 185 cupstrong_dx=selsz(0,0,-10);
 186
 187 propxshift = -6;
 188
 189 doveclipheight = 10;
 190
 191 teethh=3;
 192 teethgapx=4+fdia;
 193
 194 prongstalkxwidth=3;
 195
 196 stalklength=selsz(35,25,55);
 197 overclipcupgap=5;
 198 overclipdepth=15;
 199 overcliproundr=2.0;
 200 overclipthick=1.0;
 201 overclipcupnextgap=selsz(20,15,20);
 202
 203 hubaxlelen = selsz(25, 62.5, 77.5);
 204 echo(hubaxlelen);
 205
 206 overclipsmaller=-2.5;
 207 overclipbigger=0.0;
 208
 209 wingspoke=2.5;
 210 wingsize=6;
 211 wingthick=3;
 212
 213 armendwallthick=selsz(2.5, 1.8, 2.5);
 214 armendbasethick=selsz(1.2, 1.2, 1.2);
 215
 216 numbers_relief = 0.7;
 217 numbers_tick_len = 8;
 218 numbers_tick_width = 0.75;
 219 numbers_tick_linespc = 1.0;
 220 numbers_height_allow = 8;
 221
 222 axlehorizoffset = 12.5;
 223 axlevertheight = 100;
 224 towercliph = 16;
 225 towerclipcount = 3;
 226 towerpillarw = 5;
 227
 228 axlepinrad = 2;
 229 axlepintabrad = 5;
 230
 231 washerthick = 1.2;
 232 washerthinthick = 0.8;
 233 washerverythinthick = 0.4;
 234 washerrad = hubaxlerad + 7.5;
 235 frictionwasherarmwidth = 3;
 236 frictionwasherextrapush = 1.0;
 237
 238 ratchetpawl=ratchetstep-ratchettooth-bigslop*2;
 239
 240 nondove_armhole_x = 32;
 241 nondove_armhole_hole = 4 + 0.8;
 242 nondove_armhole_support = 7;
 243 nondove_armhole_wall = 3.2;
 244 nondove_armhole_slop = 0.5;
 245 nondove_armhole_slop_x = 0.5;
 246
 247 nondove_armbase = nondove_armhole_x + nondove_armhole_hole/2 +
 248   nondove_armhole_support;
 249 echo(nondove_armbase);
 250
 251 include <doveclip.scad>
 252 include <cliphook.scad>
 253 include <filamentteeth.scad>
 254 include <axlepin.scad>
 255 include <commitid.scad>
 256
 257 hub_clip_baseextend = (hubeffrad - DoveClip_depth()
 258                        - hubbigrad + hublwidth);
 259
 260 real_exteffrad = selsz(exteffrad + hub_clip_baseextend,
 261                        hubeffrad + DoveClip_depth(),
 262                        hubeffrad + nondove_armbase);
 263
 264 channelwidth = prongthick + channelslop;
 265 channeldepth = prongwidth + ratchettoothheight;
 266 totalwidth = armendwallthick*2 + channelwidth;
 267 totalheight = channeldepth + armendbasethick;
 268 stalkwidth = prongwidth + prongstalkxwidth;
 269
 270 tau = PI*2;
 271
 272 module ArmEnd(length=armend_length){ ////toplevel
 273   if (usedove()) {
 274     translate([ratchettoothsmoothr, channelwidth/2, -armendbasethick]) {
 275       rotate([0,0,-90])
 276         DoveClipPairBase(h=doveclipheight);
 277     }
 278   } else {
 279     difference(){
 280       translate([1, -armendwallthick, -armendbasethick])
 281         mirror([1,0,0])
 282         cube([nondove_armbase+1, totalwidth, totalheight]);
 283       translate([-nondove_armbase + nondove_armhole_x,
 284                  -armendwallthick + totalwidth/2,
 285                  -armendbasethick -1])
 286         cylinder(r= nondove_armhole_hole/2, h=totalheight+2, $fn=10);
 287       translate([-nondove_armbase, -armendwallthick, -armendbasethick])
 288         rotate([90,0,0])
 289         Commitid_BestCount([nondove_armbase, totalwidth]);
 290     }
 291   }
 292
 293   for (otherside=[0,1]) {
 294     for (circum = [300:100:1500]) {
 295       assign(rad = circum / tau)
 296         assign(fn = str("filamentspool-number-n",circum,".dxf"))
 297         assign(rotateoffset = [0, totalwidth/2, 0])
 298         assign(xlen = rad - real_exteffrad) {
 299         if (xlen >= numbers_tick_width/2
 300             + (otherside ? numbers_height_allow : 0) &&
 301             xlen <= length - (otherside ? 0 : numbers_height_allow))
 302           translate([xlen, -armendwallthick,
 303                      -armendbasethick + (totalheight - numbers_tick_len)/2])
 304           translate(rotateoffset)
 305           rotate([0,0, otherside*180])
 306           translate(-rotateoffset){
 307             translate([-numbers_tick_width/2, -1, 0])
 308               cube([numbers_tick_width, numbers_relief+1, numbers_tick_len]);
 309             translate([numbers_tick_width/2 + numbers_tick_linespc,
 310                        1,
 311                        numbers_tick_len])
 312               rotate([90,0,0])
 313               rotate([0,0,-90])
 314               linear_extrude(height= numbers_relief+1)
 315               //    scale(templatescale)
 316               import(file=fn, convexity=100);
 317           }
 318       }
 319     }
 320   }
 321
 322   difference(){
 323     translate([0, -armendwallthick, -armendbasethick])
 324       cube([length, totalwidth, totalheight]);
 325     translate([-1, 0, 0])
 326       cube([length+1 - ratchettooth, channelwidth, channeldepth+1]);
 327     translate([-1, 0, ratchettoothheight])
 328       cube([length+2, channelwidth, channeldepth+1]);
 329   }
 330   for (dx = [0 : ratchetstep : length - ratchetstep]) translate([dx,0,0]) {
 331     translate([ratchettoothsmoothr+0.5, armendwallthick/2, 0]) minkowski(){
 332       rotate([90,0,0])
 333         cylinder($fn=20, r=ratchettoothsmoothr, h=armendwallthick);
 334       multmatrix([      [       1, 0, ratchettoothslope, 0      ],
 335                         [       0,      1,      0,      0       ],
 336                         [       0,      0,      1,      0       ],
 337                         [       0,      0,      0,      1       ]])
 338         cube([ratchettooth - ratchettoothsmoothr*2,
 339               channelwidth, ratchettoothheight - ratchettoothsmoothr]);
 340     }
 341   }
 342 }
 343
 344 module FilamentCupHandle(){
 345   pawlusewidth = ratchetpawl-ratchettoothsmoothr*2;
 346   mirror([0,1,0]) {
 347     cube([stalklength, stalkwidth, prongthick]);
 348     translate([stalklength, stalkwidth/2, 0])
 349       cylinder(r=stalkwidth/2, h=prongthick, $fn=20);
 350     translate([ratchettoothsmoothr, stalkwidth, 0]) {
 351       minkowski(){
 352         cylinder($fn=20,r=ratchettoothsmoothr, h=1);
 353         multmatrix([    [       1, -ratchettoothslope, 0, 0     ],
 354                         [       0,      1,      0,      0       ],
 355                         [       0,      0,      1,      0       ],
 356                         [       0,      0,      0,      1       ]])
 357           cube([pawlusewidth,
 358                 ratchettoothheight - ratchettoothsmoothr,
 359                 prongthick - 1]);
 360       }
 361     }
 362   }
 363 }
 364
 365 module FilamentCupCup(){
 366   for (my=[0,1]) mirror([0,my,0]) {
 367     translate([0, cupwidth/2, 0])
 368       cube([cupheight + prongwidth, prongwidth, prongthick]);
 369   }
 370 }
 371
 372 module FilamentCup() { ////toplevel
 373   FilamentCupHandle();
 374
 375   gapy = prongwidth;
 376   dy = cupwidth/2 + gapy + overclipcupgap;
 377   baselen = dy+cupwidth/2;
 378
 379   translate([0, dy, 0])
 380     FilamentCupCup();
 381   cube([prongwidth, baselen+1, prongthick]);
 382
 383   translate([cupstrong_dx, prongwidth, 0]) {
 384     cube([prongwidth, baselen-prongwidth, prongthick]);
 385     for (y = [0, .33, .67, 1])
 386       translate([0, (baselen - prongwidth) * y, 0])
 387         cube([-cupstrong_dx + 1, prongwidth, prongthick]);
 388   }
 389   if (cupstrong_dx != 0) {
 390     rotate([0,0,45])
 391       translate([-prongwidth*.55, -prongwidth*2.1, 0])
 392       cube([prongwidth*(2.65), prongwidth*4.2, prongthick]);
 393   }
 394
 395   translate([0, -0.2, 0])
 396     cube([prongribwidth, baselen, prongthick + prongribheight]);
 397
 398   if (prongribheight > 0) {
 399     translate([-prongwidth, baselen, 0])
 400       cube([cupheight/2, prongwidth + prongribheight, prongribwidth]);
 401   }
 402
 403   midrad = cupwidth/2 + prongwidth/2;
 404
 405   propshift = stalklength - overclipdepth - prongthick + propxshift;
 406   proptaken = propshift;
 407   echo(midrad, propshift, proptaken);
 408
 409   translate([propshift, -1, 0]) {
 410     // something is wrong with the y calculation
 411     cube([prongwidth,
 412           gapy+2,
 413           prongthick]);
 414   }
 415   for (y = [overclipcupgap, overclipcupgap+overclipcupnextgap]) {
 416     translate([cupstrong_dx, y + prongwidth, 0])
 417       rotate([0,0, 102 + fdia])
 418       FilamentTeeth(fdia=fdia, h=teethh);
 419   }
 420   for (x = [-0.3, -1.3]) {
 421     translate([cupheight + overclipcupnextgap*x, baselen + prongwidth, 0])
 422       rotate([0,0, 12 + fdia])
 423       FilamentTeeth(fdia=fdia, h=teethh);
 424   }
 425 }
 426
 427 module CupSecuringClipSolid(w,d,h1,h2){
 428   rotate([0,-90,0]) translate([0,-h1/2,-w/2]) linear_extrude(height=w) {
 429     polygon(points=[[0,0], [d,0], [d,h2], [0,h1]]);
 430   }
 431 }
 432
 433 module CupSecuringClipSolidSmooth(xrad=0, xdepth=0){
 434   hbase = totalheight + prongstalkxwidth - overcliproundr*2;
 435   minkowski(){
 436     CupSecuringClipSolid(w=totalwidth,
 437                          d=overclipdepth + xdepth,
 438                          h1=hbase - overclipsmaller,
 439                          h2=hbase + overclipbigger);
 440     cylinder($fn=20, h=0.01, r=overcliproundr+xrad);
 441   }
 442 }
 443
 444 module CupSecuringClip(){ ////toplevel
 445   wingswidth = wingspoke*2 + overclipthick*2 + overcliproundr*2 + totalwidth;
 446   difference(){
 447     union(){
 448       CupSecuringClipSolidSmooth(xrad=overclipthick, xdepth=0);
 449       translate([-wingswidth/2, -wingsize/2, 0])
 450         cube([wingswidth, wingsize, wingthick]);
 451       translate([-wingsize/2, -wingswidth/2, 0])
 452         cube([wingsize, wingswidth, wingthick]);
 453     }
 454     translate([0,0,-0.1])
 455       CupSecuringClipSolidSmooth(xrad=0, xdepth=0.2);
 456   }
 457 }
 458
 459 module ArmDoveClipPin(){ ////toplevel
 460   DoveClipPin(h=doveclipheight);
 461 }
 462
 463 module TowerDoveClipPin(){ ////toplevel
 464   DoveClipPin(h=towercliph/2);
 465 }
 466
 467 module Hub(){ ////toplevel
 468   axlerad = hubaxlerad + slop;
 469   xmin = axlerad+hublwidth/2;
 470   xmax = hubbigrad-hublwidth/2;
 471   hole = hubeffrad - hubbigrad - DoveClip_depth() - hublwidth*2;
 472   holewidth = DoveClipPairSane_width() - hubstemwidth*2;
 473   nondove_allwidth = nondove_armhole_wall*2 + totalwidth;
 474   difference(){
 475     union(){
 476       difference(){
 477         cylinder($fn=60, h=hublthick, r=hubbigrad);
 478         translate([0,0,-1])
 479           cylinder($fn=30, h=hublthick+2, r=(hubbigrad-hublwidth));
 480       }
 481       cylinder(h=hubaxlelen, r=axlerad+hublwidth);
 482       for (ang=[0 : 360/num_arms : 359])
 483         rotate([0,0,ang]) {
 484           if (usedove()){
 485             difference() {
 486               translate([hubeffrad,0,0])
 487                 DoveClipPairSane(h=doveclipheight,
 488                                  baseextend = hub_clip_baseextend);
 489               if (hole>hublwidth && holewidth > 2) {
 490                 translate([hubbigrad + hublwidth, -holewidth/2, -1])
 491                   cube([hole, holewidth, hublthick+2]);
 492               }
 493             }
 494           } else {
 495             difference(){
 496               translate([0,
 497                          -nondove_allwidth/2,
 498                          0])
 499                 cube([hubeffrad + nondove_armhole_x
 500                       + nondove_armhole_hole/2 + nondove_armhole_support,
 501                       nondove_allwidth,
 502                       nondove_armhole_wall + totalheight]);
 503               translate([hubeffrad - nondove_armhole_slop_x,
 504                          -nondove_allwidth/2
 505                          + nondove_armhole_wall - nondove_armhole_slop,
 506                          nondove_armhole_wall])
 507                 cube([nondove_armhole_x + 50,
 508                       totalwidth + nondove_armhole_slop*2,
 509                       totalheight + 1]);
 510               translate([hubeffrad + nondove_armhole_x, 0, -20])
 511                 cylinder(r= nondove_armhole_hole/2, h=50, $fn=10);
 512             }
 513           }
 514         }
 515       for (ang = [0 : 180/num_arms : 359])
 516         rotate([0,0,ang]) rotate([90,0,0]) {
 517           translate([0,0,-hublwidth/2])
 518             linear_extrude(height=hublwidth)
 519             polygon([[xmin,0.05], [xmax,0.05],
 520                      [xmax,hublthick-0.2], [xmin, hubaxlelen-0.2]]);
 521         }
 522     }
 523     translate([0,0,-1]) cylinder($fn=60, h=hubaxlelen+2, r=axlerad);
 524
 525     rotate([0,0, selsz(0,0,45)])
 526       translate([axlerad+hublwidth,
 527                  -hublwidth/2,
 528                  0])
 529       rotate([90,0,0])
 530       Commitid_BestCount([(hubbigrad-hublwidth) - (axlerad+hublwidth),
 531                           hublthick +
 532                           hublwidth/2 * hubaxlelen/(hubbigrad-axlerad),
 533                           ]);
 534   }
 535 }
 536
 537 module ArmExtender(){ ////toplevel
 538   DoveClipExtender(length=exteffrad-hubeffrad,
 539                    ha=doveclipheight,
 540                    hb=doveclipheight);
 541 }
 542
 543 module FsAxlePin(){ ////toplevel
 544   AxlePin(hubaxlerad, washerrad*2, axlepinrad, axlepintabrad, slop);
 545 }
 546
 547 module Axle(){ ////toplevel
 548   pillarswidth = DoveClipPairSane_width(towerclipcount);
 549
 550   rotate([0,0, -( axleaxlefudgebend + atan(slop/hubaxlelen) ) ])
 551   translate([-axlehorizoffset, -axlevertheight, 0]) {
 552     rotate([0,0,-axletowerfudgebend])
 553     rotate([0,0,-90])
 554       DoveClipPairSane(h=towercliph, count=towerclipcount, baseextend=3);
 555     translate([0, DoveClip_depth(), 0])
 556     rotate([0,0,90])
 557       ExtenderPillars(axlevertheight - DoveClip_depth(),
 558                       pillarswidth, towercliph,
 559                       pillarw=towerpillarw);
 560   }
 561
 562   axleclearlen = hubaxlelen + slop*4 + washerthick*2 + axlepadlen;
 563   axlerad = hubaxlerad-slop;
 564   bump = axlerad * 0.2;
 565   shift = axlerad-bump;
 566   joinbelowallow = 3;
 567
 568   intersection(){
 569     translate([0, 0, shift]) {
 570       difference() {
 571         union(){
 572           translate([-1, 0, 0])
 573             rotate([0,90,0])
 574             cylinder($fn=60,
 575                      r = axlerad,
 576                      h = 1 + axleclearlen + axlepinrad*2 + 2);
 577           mirror([1,0,0]) rotate([0,90,0])
 578             cylinder(r = axlerad*1.75, h = 3);
 579           intersection(){
 580             mirror([1,0,0])
 581               translate([axlehorizoffset - pillarswidth/2, 0, 0])
 582               rotate([0,90,0])
 583               cylinder($fn=60,
 584                        r = towercliph - shift,
 585                        h = pillarswidth);
 586             translate([-50, -joinbelowallow, -50])
 587               cube([100, joinbelowallow+50, 100]);
 588           }
 589         }
 590         rotate([90,0,0])
 591         translate([axleclearlen + axlepinrad/2, 0, -25])
 592           cylinder(r = axlepinrad + slop, h=50);
 593       }
 594     }
 595     translate([-50,-50,0]) cube([100,100,100]);
 596   }
 597 }
 598
 599 module washer(thick){
 600   Washer(hubaxlerad, washerrad, thick, slop);
 601 }
 602
 603 module AxleWasher(){ ////toplevel
 604   washer(thick=washerthick);
 605 }
 606
 607 module AxleThinWasher(){ ////toplevel
 608   washer(thick=washerthinthick);
 609 }
 610
 611 module AxleVeryThinWasher(){ ////toplevel
 612   washer(thick=washerverythinthick);
 613 }
 614
 615 module AxleFrictionWasher(){ ////toplevel
 616   difference(){
 617     cylinder(h=washerthick, r=washerrad);
 618     translate([0,0,-1]) cylinder(h=washerthick+2, r=hubaxlerad+slop);
 619   }
 620   frarmr = hubbigrad;
 621   frarmw = frictionwasherarmwidth;
 622   frarmpawlr = hublwidth;
 623   frarmpawlpush = slop*4 + frictionwasherextrapush;
 624   for (ang=[0,180]) rotate([0,0,ang]) {
 625     translate([washerrad-1, -frarmw/2, 0])
 626       cube([frarmr - washerrad + 1, frarmw, washerthick]);
 627     intersection(){
 628       translate([frarmr - frarmpawlr, -50, 0])
 629         cube([frarmpawlr, 100, 50]);
 630       rotate([0,90,0])
 631         cylinder(h = 50, r = frarmpawlpush, $fn=36);
 632     }
 633   }
 634 }
 635
 636 module TowerExtender(){ ////toplevel
 637   l = totalheightfromtower - axlevertheight;
 638   echo("TowerExtender",l);
 639   DoveClipExtender(length = l,
 640                    ha = towercliph, hb = towercliph,
 641                    counta = towerclipcount, countb = towerclipcount,
 642                    pillarw = towerpillarw);
 643 }
 644
 645 module FilamentCupPair(){ ////toplevel
 646   FilamentCup();
 647   translate([cupheight + prongthick*3,
 648              cupwidth/2*1.7,
 649              0])
 650     rotate([0,0,180]) FilamentCup();
 651 }
 652
 653 //----- storarm -----
 654
 655 storarm_hooklen = 8;
 656 storarm_hookheight = 5;
 657 storarm_thick = 10;
 658 storarm_axleslop = 4;
 659
 660 storarm_base_w = 30;
 661 storarm_base_h = 100;
 662 storarm_base_d = 15;
 663 storarm_base_mind = 2;
 664
 665 storarm_cope_hubaxle_mk1 = true;
 666
 667 storarm_screw_hole = 4;
 668 storarm_screw_hole_slop = 0.5;
 669 storarm_besides_hole = 4;
 670
 671 storarm_under_hole = 5;
 672 storarm_screw_hole_head = 8.8;
 673 storarm_screw_hole_head_slop = 1.5;
 674
 675 // calculated
 676
 677 storarm_axlerad = hubaxlerad - storarm_axleslop;
 678 storarm_mainlen = hubaxlelen*2 + storarm_axleslop
 679   + (storarm_cope_hubaxle_mk1 ? 10 : 0);
 680 storarm_totlen = storarm_mainlen + storarm_hooklen;
 681
 682 storarm_mid_off_y = storarm_axlerad;
 683
 684 storarm_base_off_y = storarm_mid_off_y + storarm_base_h/2;
 685
 686 module StorageArmDiagPartSide(xmin, xmax){
 687   xsz = xmax-xmin;
 688   yuse = storarm_thick/2;
 689
 690   intersection(){
 691     translate([xmin-1, -storarm_axlerad, storarm_thick/2])
 692       rotate([0,90,0])
 693       cylinder(r=storarm_axlerad, h=xsz+2, $fn=60);
 694     translate([xmin, -yuse, 0])
 695       cube([xsz, yuse, storarm_thick]);
 696   }
 697 }
 698
 699 module StorageArmDiagPart(xmin, xmax, shear, adjbot){
 700   hull(){
 701     StorageArmDiagPartSide(xmin,xmax);
 702
 703     multmatrix([[1,0,0,0],
 704                 [shear,1,0,0],
 705                 [0,0,1,0],
 706                 [0,0,0,1]])
 707       translate([0, -storarm_axlerad*2 + adjbot, 0])
 708       mirror([0,1,0])
 709       StorageArmDiagPartSide(xmin,xmax);
 710   }
 711 }
 712
 713 module StorageArmBaseTemplate(){
 714   square([storarm_base_w, storarm_base_h]);
 715 }
 716
 717 module StorageArmAtMountingHoles(){
 718   bes = storarm_besides_hole + storarm_screw_hole;
 719
 720   x0 = bes;
 721   x1 = storarm_base_w-bes;
 722   y1 = storarm_base_h - bes;
 723   y0 = bes;
 724
 725   for (pos=[ [x0, y1],
 726              [x1, y1],
 727              [x1, y0] ]) {
 728     rotate([0,90,0])
 729       translate([pos[0] - storarm_base_w,
 730                  pos[1] - storarm_base_off_y, -storarm_base_d])
 731       children();
 732   }
 733 }
 734
 735 module StorageArmRight(){ ////toplevel
 736   shear = storarm_hookheight / (storarm_mainlen/2);
 737
 738   StorageArmDiagPart(-1, storarm_mainlen/2+1, shear, 0);
 739   StorageArmDiagPart(storarm_mainlen/2-1, storarm_mainlen+1, shear/2,
 740                      storarm_hookheight/2);
 741
 742   translate([0, storarm_hookheight, 0])
 743     StorageArmDiagPart(storarm_mainlen, storarm_totlen,
 744                        shear/2, -storarm_hookheight/2);
 745
 746   difference(){
 747     union(){
 748       hull(){
 749         translate([-storarm_base_d, -storarm_base_off_y, storarm_base_w])
 750           rotate([0,90,0])
 751           linear_extrude(height=storarm_base_mind)
 752           StorageArmBaseTemplate();
 753         StorageArmDiagPart(-1, 0, shear, 0);
 754       }
 755       StorageArmAtMountingHoles(){
 756         cylinder(r= storarm_screw_hole_head/2,
 757                  h=10);
 758       }
 759     }
 760     StorageArmAtMountingHoles(){
 761       translate([0,0,-1])
 762         cylinder(r= (storarm_screw_hole + storarm_screw_hole_slop)/2 ,
 763                  h=20);
 764       translate([0,0,storarm_under_hole])
 765         cylinder(r= (storarm_screw_hole_head + storarm_screw_hole_head_slop)/2,
 766                  h=20);
 767     }
 768   }
 769 }
 770
 771 module StorageArmLeft(){ ////toplevel
 772   mirror([1,0,0]) StorageArmRight();
 773 }
 774
 775 module StorArmHoleTest(){ ////toplevel
 776   sz = storarm_screw_hole_head + storarm_besides_hole*2;
 777   intersection(){
 778     StorageArmRight();
 779     translate([-50, -storarm_base_off_y, -1])
 780       cube([100, sz, sz+1]);
 781   }
 782 }
 783
 784
 785 //----- filament guide spacer -----
 786
 787 guide_armdia = 15.0;
 788 guide_armwidth = 10.2;
 789 guide_armcorelen = 25.0;
 790 guide_clipcirclethick = 10.0;
 791
 792 guidefilclip_outerdia = 22.8;
 793
 794 guidespacer_armslop = 0.75;
 795 guidespacer_armlenslop = 1.05;
 796
 797 guidespacer_prongprotrude = 4;
 798 guidespacer_thick = 1.6;
 799
 800 // calculated
 801
 802 guidespacer_armdia = guide_armdia + guidespacer_armslop;
 803 guidespacer_armwidth = guide_armwidth + guidespacer_armslop;
 804 guidespacer_len = guide_armcorelen - guide_clipcirclethick
 805   + guidespacer_armlenslop;
 806
 807 guidespacer_wingheight = (guidefilclip_outerdia - guidespacer_armdia)/2;
 808
 809 module FilamentGuideArmTemplate(extra=0){
 810   intersection(){
 811     circle(r= (guidespacer_armdia/2) + extra);
 812     square(center=true, [guidespacer_armwidth+extra*2,
 813                          guidespacer_armdia + extra*2 + 10]);
 814   }
 815 }
 816
 817 module FilamentGuideSpacerInnerTemplate(){
 818   FilamentGuideArmTemplate();
 819   translate([0, -guidespacer_armdia/2])
 820     square(center=true, [guidespacer_armwidth - guidespacer_prongprotrude,
 821                          guidespacer_armdia]);
 822 }
 823
 824 module FilamentGuideSpacer(){ ////toplevel
 825   difference(){
 826     union(){
 827       linear_extrude(height= guidespacer_len)
 828         FilamentGuideArmTemplate(extra= guidespacer_thick);
 829       for (angle=[26, 60]) {
 830         for (m=[0,1]) {
 831           mirror([m,0,0]) {
 832             rotate([0,0,angle]) {
 833               hull(){
 834                 for (t=[[0, guidespacer_wingheight],
 835                         [guidespacer_len-1, -guidespacer_wingheight]])
 836                   translate([0,0, t[0] + 0.5])
 837                     cube([guidespacer_thick, guidespacer_armdia + t[1]*2,
 838                       1],
 839                          center=true);
 840               }
 841             }
 842           }
 843         }
 844       }
 845     }
 846     translate([0,0,-1])
 847       linear_extrude(height= guidespacer_len+5)
 848       FilamentGuideSpacerInnerTemplate();
 849   }
 850 }
 851
 852
 853 //----- replacement filament guide arm for TAZ-5 -----
 854
 855 guidearm_armslop = 0.25;
 856 guidearm_armlenslop = 0.25;
 857
 858 guidearm_hookprotr = 3;
 859 guidearm_hookprotrflat = 1;
 860 guidearm_hookslope = 0.3;
 861
 862 guidearm_totallen = 60;
 863
 864 guidearm_screwplatesz = 12;
 865 guidearm_screwplateth = 4;
 866 guidearm_screwplatewd = 15;
 867 guidearm_screwhole = 5 + 0.5;
 868
 869 guidearm_bendlen = 40;
 870 guidearm_bendslot = 4.5;
 871
 872 guidearm_stopthick = 4;
 873 guidearm_protrslop = 1.0;
 874
 875 // calculated
 876
 877 guidearm_armdia = guide_armdia - guidearm_armslop;
 878 guidearm_armwidth = guide_armwidth - guidearm_armslop;
 879 guidearm_armcorelen = guide_armcorelen + guidearm_armlenslop;
 880
 881 guidearm_base_z0 = -(guidearm_totallen - guidearm_armcorelen);
 882
 883 guidearm_realbendlen = min(guidearm_bendlen,
 884                            guidearm_totallen - guidearm_screwplateth - 0.1);
 885 guidearm_slopelen = guidearm_hookprotr/guidearm_hookslope;
 886
 887 module FilamentGuideArmStop(h){
 888   for (ts=[-1,+1]) {
 889     translate([ts * guidearm_hookprotr, 0,0])
 890       cylinder(r=guidearm_armdia/2, h, $fn=80);
 891   }
 892 }
 893
 894 module FilamentGuideArmShaftPositive(){
 895   r = guidearm_armdia/2;
 896
 897   translate([0,0, guidearm_base_z0+1])
 898     cylinder(r=r, h= guidearm_totallen, $fn=80);
 899   translate([0,0, guidearm_armcorelen]){
 900     hull(){
 901       FilamentGuideArmStop(guidearm_hookprotrflat);
 902       translate([0,0, guidearm_slopelen])
 903         cylinder(r=r, h=guidearm_hookprotrflat, $fn=80);
 904     }
 905   }
 906   mirror([0,0,1])
 907     FilamentGuideArmStop(guidearm_stopthick);
 908 }
 909
 910 module FilamentGuideArmBase(){
 911   translate([0,
 912              (guidearm_screwplatewd - guidearm_armwidth)/2,
 913              guidearm_base_z0]){
 914     difference(){
 915       translate([0,0, guidearm_screwplateth/2])
 916         cube(center=true,
 917              [guidearm_armdia + guidearm_screwplatesz*2,
 918               guidearm_screwplatewd,
 919               guidearm_screwplateth]);
 920       for (ts=[-1,+1]) {
 921         translate([ts * (guidearm_armdia/2 + guidearm_screwplatesz/2),
 922                    0,
 923                    -20])
 924           cylinder(r= guidearm_screwhole/2, h=40, $fn=20);
 925       }
 926     }
 927   }
 928 }
 929
 930 module FilamentGuideArm(){ ///toplevel
 931   intersection(){
 932     difference(){
 933       FilamentGuideArmShaftPositive();
 934       translate([-guidearm_bendslot/2,
 935                  -50,
 936                  -guidearm_realbendlen + guidearm_armcorelen])
 937         cube([guidearm_bendslot,
 938               100,
 939               guidearm_realbendlen + 100]);
 940       hull(){
 941         for (zx=[ [ 0, guidearm_bendslot ],
 942                   [ guidearm_armcorelen + guidearm_slopelen,
 943                     guidearm_hookprotr*2 + guidearm_protrslop ]
 944                   ]) {
 945           translate([-zx[1]/2, -50, zx[0]])
 946           cube([zx[1], 100, 1]);
 947         }
 948       }
 949     }
 950     cube(center=true,
 951          [guidearm_armdia*2,
 952           guidearm_armwidth,
 953           guidearm_totallen*3]);
 954   }
 955   FilamentGuideArmBase();
 956 }
 957
 958 module FilamentGuideArmPrint(){ ////toplevel
 959   rotate([90,0,0])
 960     FilamentGuideArm();
 961 }
 962
 963 module Demo(){ ////toplevel
 964   translate([-real_exteffrad,-20,0]) Hub();
 965   ArmEnd();
 966   translate([ratchettooth*2, 30, 0]) FilamentCup();
 967   if (selsz(true,false,false)) {
 968     translate([-exteffrad + hubeffrad - hub_clip_baseextend, -10, 0])
 969       ArmExtender();
 970   }
 971 }
 972
 973 //ArmEnd();
 974 //FilamentCup();
 975 //FilamentCupPair();
 976 //CupSecuringClip();
 977 //Hub();
 978 //ArmExtender();
 979 //Axle();
 980 //AxleWasher();
 981 //AxlePin();
 982 //AxleFrictionWasher();
 983 //StorageArmLeft();
 984 //StorArmHoleTest();
 985 //FilamentGuideSpacer();
 986 //FilamentGuideArm();
 987 //FilamentGuideArmPrint();
 988 //Demo();