filamentspool.scad

   1 // -*- C -*-
   2
   3 fdia=1.75;
   4
   5 slop=0.5;
   6 bigslop=slop*2;
   7
   8 exteffrad = 70;
   9 hubeffrad = 30;
  10 hubbigrad = 20;
  11 hublwidth = 3;
  12 hubstemwidth = 2;
  13 hublthick = 10;
  14 hubaxlelen = 25;
  15 hubaxlerad = 5;
  16 totalheightfromtower = 240;
  17 axletowerfudgebend = 0;
  18 axleaxlefudgebend = 3;
  19 axlepadlen = 1.0;
  20
  21 prongthick=5;
  22 prongwidth=5;
  23 ratchetstep=15;
  24 ratchettooth=3;
  25 ratchettoothheight=5;
  26 ratchettoothsmoothr=1;
  27 ratchettoothslope=0.75;
  28 overlap=0.5;
  29 cupwidth=40;
  30 cupheight=55;
  31
  32 propxshift = 0;
  33
  34 doveclipheight = 10;
  35
  36 teethh=3;
  37 teethgapx=4+fdia;
  38
  39 prongstalkxwidth=3;
  40
  41 stalklength=35;
  42 overclipcupgap=5;
  43 overclipdepth=15;
  44 overcliproundr=2.0;
  45 overclipthick=0.5;
  46 overclipcupnextgap=20;
  47
  48 overclipsmaller=-2.5;
  49 overclipbigger=0.0;
  50
  51 wingspoke=3;
  52 wingsize=6;
  53 wingthick=3;
  54
  55 armendwallthick=2.5;
  56 armendbasethick=1.2;
  57
  58 axlehorizoffset = 12.5;
  59 axlevertheight = 100;
  60 towercliph = 16;
  61 towerclipcount = 3;
  62 towerpillarw = 5;
  63
  64 axlepinrad = 2;
  65 axlepintabrad = 5;
  66
  67 washerthick = 1.2;
  68 washerthinthick = 0.8;
  69 washerverythinthick = 0.4;
  70 washerrad = hubaxlerad + 7.5;
  71 frictionwasherarmwidth = 3;
  72 frictionwasherextrapush = 1.0;
  73
  74 ratchetpawl=ratchetstep-ratchettooth-bigslop*2;
  75
  76 include <doveclip.scad>
  77 include <cliphook.scad>
  78 include <filamentteeth.scad>
  79 include <axlepin.scad>
  80
  81 channelwidth = prongthick + slop;
  82 channeldepth = prongwidth + ratchettoothheight;
  83 totalwidth = armendwallthick*2 + channelwidth;
  84 totalheight = channeldepth + armendbasethick;
  85 stalkwidth = prongwidth + prongstalkxwidth;
  86
  87 module ArmEnd(length=120){ ////toplevel
  88   translate([ratchettoothsmoothr, channelwidth/2, -armendbasethick]) {
  89     rotate([0,0,-90])
  90       DoveClipPairBase(h=doveclipheight);
  91   }
  92
  93   difference(){
  94     translate([0, -armendwallthick, -armendbasethick])
  95       cube([length, totalwidth, totalheight]);
  96     translate([-1, 0, 0])
  97       cube([length+1 - ratchettooth, channelwidth, channeldepth+1]);
  98     translate([-1, 0, ratchettoothheight])
  99       cube([length+2, channelwidth, channeldepth+1]);
 100   }
 101   for (dx = [0 : ratchetstep : length - ratchetstep]) translate([dx,0,0]) {
 102     translate([ratchettoothsmoothr+0.5, armendwallthick/2, 0]) minkowski(){
 103       rotate([90,0,0])
 104         cylinder($fn=20, r=ratchettoothsmoothr, h=armendwallthick);
 105       multmatrix([      [       1, 0, ratchettoothslope, 0      ],
 106                         [       0,      1,      0,      0       ],
 107                         [       0,      0,      1,      0       ],
 108                         [       0,      0,      0,      1       ]])
 109         cube([ratchettooth - ratchettoothsmoothr*2,
 110               channelwidth, ratchettoothheight - ratchettoothsmoothr]);
 111     }
 112   }
 113 }
 114
 115 module FilamentCupHandle(){
 116   pawlusewidth = ratchetpawl-ratchettoothsmoothr*2;
 117   mirror([0,1,0]) {
 118     cube([stalklength, stalkwidth, prongthick]);
 119     translate([stalklength, stalkwidth/2, 0])
 120       cylinder(r=stalkwidth/2, h=prongthick, $fn=20);
 121     translate([ratchettoothsmoothr, stalkwidth, 0]) {
 122       minkowski(){
 123         cylinder($fn=20,r=ratchettoothsmoothr, h=1);
 124         multmatrix([    [       1, -ratchettoothslope, 0, 0     ],
 125                         [       0,      1,      0,      0       ],
 126                         [       0,      0,      1,      0       ],
 127                         [       0,      0,      0,      1       ]])
 128           cube([pawlusewidth,
 129                 ratchettoothheight - ratchettoothsmoothr,
 130                 prongthick - 1]);
 131       }
 132     }
 133   }
 134 }
 135
 136 module FilamentCupCup(){
 137   for (my=[0,1]) mirror([0,my,0]) {
 138     translate([0,cupwidth/2,0])
 139       cube([cupheight + prongwidth, prongwidth, prongthick]);
 140   }
 141 }
 142
 143 module FilamentCup() { ////toplevel
 144   FilamentCupHandle();
 145
 146   gapy = prongwidth;
 147   dy = cupwidth/2 + gapy + overclipcupgap;
 148
 149   translate([0, dy, 0])
 150     FilamentCupCup();
 151   translate([0, -1, 0]);
 152   cube([prongwidth, dy+1+cupwidth/2, prongthick]);
 153
 154   midrad = cupwidth/2 + prongwidth/2;
 155
 156   propshift = stalklength - overclipdepth - prongthick + propxshift;
 157   proptaken = propshift;
 158   echo(midrad, propshift, proptaken);
 159
 160   translate([propshift, -1, 0]) {
 161     // something is wrong with the y calculation
 162     cube([prongwidth,
 163           overclipdepth - prongwidth/2,
 164           prongthick]);
 165   }
 166   for (y = [overclipcupgap, overclipcupgap+overclipcupnextgap]) {
 167     translate([0, y, 0])
 168       rotate([0,0, 102 + fdia])
 169       FilamentTeeth(fdia=fdia, h=teethh);
 170   }
 171 }
 172
 173 module CupSecuringClipSolid(w,d,h1,h2){
 174   rotate([0,-90,0]) translate([0,-h1/2,-w/2]) linear_extrude(height=w) {
 175     polygon(points=[[0,0], [d,0], [d,h2], [0,h1]]);
 176   }
 177 }
 178
 179 module CupSecuringClipSolidSmooth(xrad=0, xdepth=0){
 180   hbase = totalheight + prongstalkxwidth - overcliproundr*2;
 181   minkowski(){
 182     CupSecuringClipSolid(w=totalwidth,
 183                          d=overclipdepth + xdepth,
 184                          h1=hbase - overclipsmaller,
 185                          h2=hbase + overclipbigger);
 186     cylinder($fn=20, h=0.01, r=overcliproundr+xrad);
 187   }
 188 }
 189
 190 module CupSecuringClip(){ ////toplevel
 191   wingswidth = wingspoke*2 + overclipthick*2 + overcliproundr*2 + totalwidth;
 192   difference(){
 193     union(){
 194       CupSecuringClipSolidSmooth(xrad=overclipthick, xdepth=0);
 195       translate([-wingswidth/2, -wingsize/2, 0])
 196         cube([wingswidth, wingsize, wingthick]);
 197     }
 198     translate([0,0,-0.1])
 199       CupSecuringClipSolidSmooth(xrad=0, xdepth=0.2);
 200   }
 201 }
 202
 203 module ArmDoveClipPin(){ ////toplevel
 204   DoveClipPin(h=doveclipheight);
 205 }
 206
 207 module TowerDoveClipPin(){ ////toplevel
 208   DoveClipPin(h=towercliph/2);
 209 }
 210
 211 module Hub(){ ////toplevel
 212   difference(){
 213     cylinder($fn=60, h=hublthick, r=hubbigrad);
 214     translate([0,0,-1])
 215       cylinder($fn=30, h=hublthick+2, r=(hubbigrad-hublwidth));
 216   }
 217   axlerad = hubaxlerad + slop;
 218   difference(){
 219     cylinder(h=hubaxlelen, r=axlerad+hublwidth);
 220     translate([0,0,-1]) cylinder($fn=60, h=hubaxlelen+2, r=axlerad);
 221   }
 222   hole = hubeffrad - hubbigrad - DoveClip_depth() - hublwidth*2;
 223   holewidth = DoveClipPairSane_width() - hubstemwidth*2;
 224   for (ang=[0,120,240])
 225     rotate([0,0,ang]) {
 226       difference() {
 227         translate([hubeffrad,0,0])
 228           DoveClipPairSane(h=doveclipheight,
 229                            baseextend = (hubeffrad - DoveClip_depth()
 230                                          - hubbigrad + hublwidth));
 231         if (hole>hublwidth && holewidth > 2) {
 232           translate([hubbigrad + hublwidth, -holewidth/2, -1])
 233             cube([hole, holewidth, hublthick+2]);
 234         }
 235       }
 236     }
 237   xmin = axlerad+hublwidth/2;
 238   xmax = hubbigrad-hublwidth/2;
 239   for (ang = [0 : 60 : 359])
 240     rotate([0,0,ang]) rotate([90,0,0]) {
 241       translate([0,0,-hublwidth/2])
 242         linear_extrude(height=hublwidth)
 243         polygon([[xmin,0.05], [xmax,0.05],
 244                  [xmax,hublthick-0.2], [xmin, hubaxlelen-0.2]]);
 245     }
 246 }
 247
 248 module ArmExtender(){ ////toplevel
 249   DoveClipExtender(length=exteffrad-hubeffrad,
 250                    ha=doveclipheight,
 251                    hb=doveclipheight);
 252 }
 253
 254 module FsAxlePin(){ ////toplevel
 255   AxlePin(hubaxlerad, washerrad*2, axlepinrad, axlepintabrad, slop);
 256 }
 257
 258 module Axle(){ ////toplevel
 259   pillarswidth = DoveClipPairSane_width(towerclipcount);
 260
 261   rotate([0,0, -( axleaxlefudgebend + atan(slop/hubaxlelen) ) ])
 262   translate([-axlehorizoffset, -axlevertheight, 0]) {
 263     rotate([0,0,-axletowerfudgebend])
 264     rotate([0,0,-90])
 265       DoveClipPairSane(h=towercliph, count=towerclipcount, baseextend=3);
 266     translate([0, DoveClip_depth(), 0])
 267     rotate([0,0,90])
 268       ExtenderPillars(axlevertheight - DoveClip_depth(),
 269                       pillarswidth, towercliph,
 270                       pillarw=towerpillarw);
 271   }
 272
 273   axleclearlen = hubaxlelen + slop*4 + washerthick*2 + axlepadlen;
 274   axlerad = hubaxlerad-slop;
 275   bump = axlerad * 0.2;
 276   shift = axlerad-bump;
 277   joinbelowallow = 3;
 278
 279   intersection(){
 280     translate([0, 0, shift]) {
 281       difference() {
 282         union(){
 283           translate([-1, 0, 0])
 284             rotate([0,90,0])
 285             cylinder($fn=60,
 286                      r = axlerad,
 287                      h = 1 + axleclearlen + axlepinrad*2 + 2);
 288           mirror([1,0,0]) rotate([0,90,0])
 289             cylinder(r = axlerad*1.75, h = 3);
 290           intersection(){
 291             mirror([1,0,0])
 292               translate([axlehorizoffset - pillarswidth/2, 0, 0])
 293               rotate([0,90,0])
 294               cylinder($fn=60,
 295                        r = towercliph - shift,
 296                        h = pillarswidth);
 297             translate([-50, -joinbelowallow, -50])
 298               cube([100, joinbelowallow+50, 100]);
 299           }
 300         }
 301         rotate([90,0,0])
 302         translate([axleclearlen + axlepinrad/2, 0, -25])
 303           cylinder(r = axlepinrad + slop, h=50);
 304       }
 305     }
 306     translate([-50,-50,0]) cube([100,100,100]);
 307   }
 308 }
 309
 310 module washer(thick){
 311   Washer(hubaxlerad, washerrad, thick, slop);
 312 }
 313
 314 module AxleWasher(){ ////toplevel
 315   washer(thick=washerthick);
 316 }
 317
 318 module AxleThinWasher(){ ////toplevel
 319   washer(thick=washerthinthick);
 320 }
 321
 322 module AxleVeryThinWasher(){ ////toplevel
 323   washer(thick=washerverythinthick);
 324 }
 325
 326 module AxleFrictionWasher(){ ////toplevel
 327   difference(){
 328     cylinder(h=washerthick, r=washerrad);
 329     translate([0,0,-1]) cylinder(h=washerthick+2, r=hubaxlerad+slop);
 330   }
 331   frarmr = hubbigrad;
 332   frarmw = frictionwasherarmwidth;
 333   frarmpawlr = hublwidth;
 334   frarmpawlpush = slop*4 + frictionwasherextrapush;
 335   for (ang=[0,180]) rotate([0,0,ang]) {
 336     translate([washerrad-1, -frarmw/2, 0])
 337       cube([frarmr - washerrad + 1, frarmw, washerthick]);
 338     intersection(){
 339       translate([frarmr - frarmpawlr, -50, 0])
 340         cube([frarmpawlr, 100, 50]);
 341       rotate([0,90,0])
 342         cylinder(h = 50, r = frarmpawlpush, $fn=36);
 343     }
 344   }
 345 }
 346
 347 module TowerExtender(){ ////toplevel
 348   l = totalheightfromtower - axlevertheight;
 349   echo("TowerExtender",l);
 350   DoveClipExtender(length = l,
 351                    ha = towercliph, hb = towercliph,
 352                    counta = towerclipcount, countb = towerclipcount,
 353                    pillarw = towerpillarw);
 354 }
 355
 356 module FilamentCupPair(){ ////toplevel
 357   FilamentCup();
 358   translate([cupheight + prongthick*3,
 359              cupwidth/2*1.7,
 360              0])
 361     rotate([0,0,180]) FilamentCup();
 362 }
 363
 364 //ArmEnd();
 365 //FilamentCup();
 366 FilamentCupPair();
 367 //CupSecuringClip();
 368 //Hub();
 369 //ArmExtender();
 370 //Axle();
 371 //AxleWasher();
 372 //AxlePin();
 373 //AxleFrictionWasher();