fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172
 173 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 174 rearspeaker_size   = [  3.76,  7.36 ];
 175
 176 microusb_above = 3.27 - 0.25;
 177 microusb_below = 0.0;
 178 microusb_width = 16.12 + 1.25;
 179
 180 case_th_bottom = 2.5;
 181 case_th_lid = 3.0;
 182 case_th_side = 2.3;
 183 case_th_lip = 1.2;
 184
 185 lid_screen_gap_extra = .66;
 186
 187 case_struts_count = 6;
 188 case_struts_solid_below = 1.00;
 189 case_struts_solid_above = 0.75;
 190 case_struts_width = 0.10;
 191
 192 keeper_th_z = 0.75;
 193 keeper_th_x = 0.75;
 194 keeper_inner_width = 2.75;
 195 keeper_inner_height = 2.75;
 196 keeper_slant_slope = 2; // larger means steeper
 197
 198 keeper_gap_z_top = 0.25;
 199 keeper_gap_z_bot = 0.75;
 200 keeper_gap_x     = 0.25;
 201 keeper_gap_x_holes = 0.75;
 202
 203 keeper_side = 0; // 0 = lhs; 1 = rhs
 204
 205 case_lip = 1.25;
 206
 207 lid_gap_x = 0.25;
 208 lid_gap_z = 0.25;
 209 lid_lip = 1.75;
 210 lid_edgepart_width = 5.0;
 211 lid_buttoncover_thick = 1.3;
 212
 213 catch_slop = 0.50;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // properties of the hinge fasteners
 219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 220 hingescrew_shaft_len = 12;
 221 hingescrew_fasteners_extra_thick = 0.40;
 222 // ^ amount of thread protruding if everything was completely nominal
 223 //   and we are using two nuts
 224 hingescrew_nut_access_dia = 4.72 + 0.50;
 225 // ^ washer is 4.72 dia
 226 //   also, want to get pliers or tiny spanner in to do up locknut
 227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 228 hingescrew_nut_thick = 1.93;
 229 hingescrew_head_th = 1.38 + 0.75;
 230 hingescrew_head_dia = 3.92;
 231
 232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 233
 234 lever_cover_th = 0.75;
 235 hingemount_th = 2.5;
 236 hingemount_wd = 4.8725;
 237
 238 $fa = 5;
 239 $fs = 0.1;
 240
 241 button_l_fudge = 4.4;
 242 buttonishleg_default_l_is_fudge = 10;
 243
 244 hinge_base_slope = 1.5; // bigger is steeper
 245
 246 strut_min_at_end = 1.5;
 247
 248 hinge_x_gap = 0.125;
 249 hinge_x_postscrew_gap = 0.75;
 250 hinge_x_arms_gap = 0.35;
 251 hinge_r_arms_gap = 0.55;
 252
 253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 254
 255 catch_len = 7.5;
 256 catch_width = 15;
 257 catch_thickness = 1.0;
 258 catch_side_gap = 0.75; // each side
 259
 260 catch_depth = 0.75;
 261 catch_height = 0.35;
 262 catch_finger_height = 1.5;
 263 catch_finger_depth = 2.5;
 264
 265 catch_topcurve_r = 5.0;
 266
 267 prop_recess_under = 0.50;
 268 prop_recess_slop = 0.200; // each side
 269 prop_end_dia = 0.5;
 270 prop_main_th = 3;
 271 prop_taper_len = 6;
 272 prop_main_width = 4;
 273 prop_side_gap = 0.75; // each side
 274 prop_lidrecess_behind = 0.75;
 275 prop_caserecess_behind = 0.75;
 276 prop_caserecess_taper = 0.45; // one side only
 277 prop_prop_gap = 0.5;
 278 prop_prong_heel_slope = 0.5;
 279
 280 lid_fold_clearance_antislop = 0.5;
 281
 282 // ---------- calculated ----------
 283
 284 phone_width =  (phone + bumper*2)[0];
 285 phone_height = (phone + bumper*2)[1];
 286
 287 inside_br = [phone_width, -phone_height];
 288
 289 prop_prong_h = prop_main_th;
 290
 291 //echo(camera_pos_tl + bumper,
 292 //     camera_pos_br + bumper);
 293
 294 // ----- could be changed -----
 295 lid_buttoncover_gap = lid_gap_x;
 296 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 297
 298 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 299
 300 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 301
 302 //prop_nose_len = case_th_lid - prop_recess_under;
 303 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 304 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 305
 306
 307 //lid_lip_overlap_width xxx bad name = ;
 308 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 309
 310 epp0 = [0,0];
 311 epp1 = [0, -phone_edge_thick];
 312 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 313 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 314 epp3 = epp2i + [10, 0];
 315 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 316 epp4 = epp5 + [-1,0] * case_th_side;
 317
 318 kppe = [0,0];
 319 kppd = kppe + [1,0] * keeper_inner_width;
 320 kppc = kppd + [0,1] * keeper_th_z;
 321 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 322 kppf = kppe - [0,1] * keeper_inner_height;
 323 kppa = [ kppb[0], kppf[1] ];
 324
 325 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 326 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 327
 328 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 329 // exact x posn not very important; must extend past end of keeper
 330
 331 lpp15 = [ lpp14[0],
 332           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 333           + lid_screen_gap_extra ];
 334 // ^ beam theory says to maximise force before contact,
 335 //   the gap below the `beam' (the lid) must be 1/3
 336 //   the thickness (ie the lid thickness) if the beam
 337 //   is solid, or 1/2 if it has a top and bottom only.
 338 //   ours is mostly solid.
 339
 340 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 341              case_th_lip);
 342
 343 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 344 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 345
 346 case_bottom_z = epp2o[1] - case_th_bottom;
 347
 348 // button profile
 349 bppM = epp4 + [0,5];
 350 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 351 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 352 bppS = [ epp1[0], bppR[1] ];
 353 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 354 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 355 bppO = [ bppN[0], bppP[1] ];
 356 bppL = lpp10 + [5,0];
 357 bppK = [ bppL[0], bppN[1] ];
 358 bppJ = [ bppN[0], bppL[1] ];
 359 bppU = [ bppJ[0], lpp12[1] ];
 360 bppV = lpp11;
 361 bppW = lpp10;
 362
 363 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 364
 365 // notification led aperture
 366
 367 nla_r0 = led_aperture/2;
 368 nla_r1 = nla_r0 + led_window_ledge;
 369 nla_r2 = nla_r1 + multicolour_gap;
 370 nla_t =
 371   led_window_style >= 3 ? initial_layer_thick :
 372   led_window_style >= 2 ? led_window_ledge : 0;
 373
 374
 375 // hinge plan
 376 hp_rn = hingescrew_nut_access_dia/2;
 377 hp_r2_min = hp_rn + lever_cover_th;
 378 hp_rs = hingescrew_shaft_dia/2;
 379 hp_r1_min = hp_rs + hingemount_th;
 380
 381 hp_r1 = max(hp_r1_min, hp_r2_min);
 382 hp_r2 = hp_r1;
 383
 384 hppU = lpp13;
 385 hppS = epp2o + [0,-1] * case_th_bottom;
 386 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 387
 388 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 389          0.5 * (hppU + hppS)[1] ];
 390 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 391 hppB = hppT + [0,-1] * hp_k;
 392
 393 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 394 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 395 hppE = [ hppE_x, hppE_y ];
 396
 397 // hinge elevation x coords
 398
 399 hex20 = max(epp2o[0],
 400             phone_cnr_rad,
 401             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 402 hex21 = hex20 + hingemount_wd;
 403 hex22 = hex21 + hinge_x_gap;
 404 hex27 = hex20 + hingescrew_shaft_len;
 405 hex24 = hex27 + hinge_x_postscrew_gap;
 406 hex23 = hex27 - (hingescrew_nut_thick*2
 407                  + hingescrew_fasteners_extra_thick);
 408 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 409
 410 echo(hex20, hex21, hex22, hex23, hex24);
 411 //  6, 10.8725, 10.9975, 13.74, 18.75
 412 module chk(act,exp) {
 413   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 414   else echo("ok", act);
 415 }
 416 chk(hex20, 6);
 417 chk(hex21, 10.8725);
 418 chk(hex22, 10.9975);
 419 chk(hex23, 13.74);
 420 chk(hex24, 18.75);
 421
 422 lid_fold_clearance_skew =
 423   (lpp10[1] - hppB[1]) /
 424   (lpp10[0] - hppB[0]);
 425
 426 echo("SK",lid_fold_clearance_skew);
 427
 428 // catch
 429
 430 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 431 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 432 cppB = [ epp0[0], cppA[1] ];
 433 cppP = [ epp4[0], cppJ[1] ];
 434
 435 cppS = cppJ + [0,-1] * catch_len;
 436 cppD = [ cppA[0], cppS[1] + catch_slop ];
 437 cppC = [ cppB[0], cppD[1] ];
 438 cppT = cppS + [1,0] * catch_depth;
 439 cppU = cppT + [0,-1] * catch_height;
 440 cppV = [ cppS[0], cppU[1] - catch_depth ];
 441
 442 cppR = 0.5*(cppP + cppJ);
 443
 444 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 445 cppQ = [ cppR[0],
 446          cppV[1] - (catch_finger_height - cp_rQ) ];
 447 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 448
 449 // lanyard
 450
 451 ly_r = lanyard_half_dia / 2;
 452 ly_rc = ly_r * 2;
 453
 454 // prop recess in case
 455
 456 prop_x_pos = phone_width/2;
 457
 458 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 459
 460 prc_r1 = prop_end_dia/2;
 461 prc_r3 = prc_r1 + prop_recess_slop;
 462
 463 prcp2 = [ epp4[0] + prop_buildout_less,
 464           case_bottom_z ];
 465
 466 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 467
 468 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 469           epp2i[1] - prc_r3 - prop_recess_under];
 470
 471 // prop recess in lid
 472
 473 prl_r10 = prop_end_dia/2;
 474 prl_r10o = prl_r10 + prop_recess_slop;
 475
 476 prlp10 = lpp10 + [1,1] * prl_r10o
 477   + [1,0] * prop_lidrecess_behind
 478   + [0,1] * prop_recess_under;
 479
 480 // prop
 481
 482 $prpp10 = [0,0];
 483 $prpp11 = [0, prop_taper_len];
 484
 485 $prp_r10 = prl_r10;
 486
 487 // ---------- modules ----------
 488
 489 module AdhocMultiprintFrame(phase, z0, zs) {
 490   // from z0 to z0 + zs*layer
 491   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 492   xextra = extra + -epp4[0];
 493   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 494   yextra = extra + -epp4[0];
 495   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 496   p0 = [ xrange[0], yrange[0] ];
 497   p1 = [ xrange[1], yrange[1] ];
 498   echo(p0, p1);
 499   translate([0,0, z0])
 500     mirror([0,0, zs<0 ? 1 : 0])
 501     linear_extrude(height= initial_layer_thick)
 502     difference(){
 503       rectfromto(p0 - [1,1] * initial_layer_width,
 504                  p1 + [1,1] * initial_layer_width);
 505       rectfromto(p0, p1);
 506     }
 507 }
 508
 509 module KeeperProfile(slant=0){
 510   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 511   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 512 }
 513
 514 module EdgeProfile(){
 515   difference(){
 516     hull(){
 517       translate(epp3) square(case_th_bottom*2, center=true);
 518       circleat(epp2o, r=case_th_bottom);
 519       circleat(epp1, r=case_th_side);
 520       rectfromto(epp0, epp4);
 521     }
 522     polygon([ epp5 + [0,10],
 523               epp1,
 524               epp2i,
 525               epp3 + [10,0] ]);
 526   }
 527 }
 528
 529 module LanyardLanyardProfile(entry=false){
 530   hull(){
 531     for (xs=[-1,+1] * (entry ? 2 : 1))
 532       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 533         circle(r= lanyard_half_dia/2);
 534   }
 535 }
 536
 537 module LanyardCurveChannelProfile(){
 538   translate([0, -ly_r])
 539     LanyardLanyardProfile();
 540 }
 541
 542 module LanyardEntryChannelProfile(){
 543   translate([0, -ly_r])
 544     LanyardLanyardProfile(true);
 545 }
 546
 547 module LanyardMainChannelProfile(){
 548   LanyardCurveChannelProfile();
 549   difference(){
 550     square(center=true, ly_r * [6, 2]);
 551     for (xs=[-1,+1])
 552       translate(ly_r * [3 * xs, -1])
 553         circle(r = ly_r);
 554   }
 555 }
 556
 557 module LanyardEntry(){
 558   q_z = -(ly_rc + ly_r);
 559   d_x = -ly_rc;
 560
 561   translate([d_x, 0, q_z]) {
 562     intersection(){
 563       rotate([90,0,0])
 564         rotate_extrude(convexity=10)
 565         rotate(90)
 566         translate([0, -q_z])
 567         LanyardCurveChannelProfile();
 568       translate([0,-10,0])
 569         cube([20,20,20]);
 570     }
 571   }
 572 }
 573
 574 module LanyardCutout(){
 575   LanyardEntry();
 576 }
 577
 578 module LidEdgeProfile(){
 579   polygon([ lpp10,
 580             lpp11,
 581             lpp12,
 582             lpp13,
 583             lpp13 + [10, 0],
 584             lpp15 + [10, 0],
 585             lpp15,
 586             lpp14,
 587             ]);
 588   intersection(){
 589     circleat(lpp12, r=lp_r12);
 590     rectfromto( lpp12 + [-10,   0],
 591                 lpp12 + [+10, +10] );
 592   }
 593 }
 594
 595 module LidEdgeFoldClearanceProfile(){
 596   translate([-lid_fold_clearance_antislop, 0])
 597     polygon([ lpp10,
 598               lpp11,
 599               lpp11 + [-20,  0],
 600               lpp11 + [-20, 20],
 601               lpp11 + [+20, 20],
 602               lpp10 + [+20,  0] ]);
 603 }
 604
 605 module ButtonCoverProfile(){
 606   intersection(){
 607     polygon(concat([ bppM, bppP, bppO, bppJ ],
 608                    (enable_support && !$button_suppress_over_keeper
 609                     ? [ bppU, bppV, bppW ] : []),
 610                    [ bppL, bppK ]));
 611     hull(){
 612       EdgeProfile();
 613       LidEdgeProfile();
 614     }
 615   }
 616 }
 617
 618 module ButtonPlan(l, deep, cut){
 619   epsilon =
 620     (cut  ? 0 : lid_buttoncover_gap);
 621
 622   delta =
 623     (deep ? lid_buttoncover_overlap : 0);
 624
 625   C = [0,0]; // by definition
 626   T = [ 0, epp4[1] ];
 627   G = T + [0,10];
 628
 629   B0 = C + [0,-1] * button_cutout_depth;
 630   B1 = B0 + [0,1] * epsilon;
 631
 632   r0 = 0.5 * (T[1] - B0[1]);
 633   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 634   H = A + [0,-1] * delta;
 635
 636   D = A + [-2,0] * r0;
 637   F = D + [0,10];
 638
 639   E0 = 0.5 * (D + A);
 640   E1 = E0 + [1,0] * epsilon;
 641
 642   I0 = [ E0[0], H[1] ];
 643   I1 = [ E1[0], H[1] ];
 644
 645   hull(){
 646     for (m=[0,1]) mirror([m,0])
 647       circleat(H, r0 - epsilon);
 648   }
 649   for (m=[0,1]) mirror([m,0]) {
 650     difference(){
 651       polygon([ E1,
 652                 I1,
 653                 H,
 654                 B1,
 655                 G,
 656                 F,
 657                 D
 658                 ]);
 659       circleat(D, r0 + epsilon);
 660     }
 661   }
 662 }
 663
 664 module CatchCatchProfile(){
 665   hull(){
 666     for (c=[ cppR, cppQ ])
 667       circleat(c, cp_rQ);
 668   }
 669   hull(){
 670     circleat(lpp12, lp_r12);
 671     circleat(lpp12 + [5,0], lp_r12);
 672     rectfromto(cppP, cppP + [5,0.1]);
 673   }
 674   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 675 }
 676
 677 module CatchCutProfile(){
 678   polygon([ cppB,
 679             cppA,
 680             cppD,
 681             cppF,
 682             cppF + [0,-10],
 683             cppF + [-10,-10],
 684             lpp12 + [-10,0],
 685             lpp12 + [10,0]
 686             ]);
 687 }
 688
 689 module Flip_rhs(yn=[0,1]) {
 690   for ($rhsflip=yn) {
 691     translate([phone_width/2, 0, 0])
 692       mirror([$rhsflip,0,0])
 693       translate([-phone_width/2, 0, 0])
 694       children();
 695   }
 696 }
 697
 698 module Flip_bot(yn=[0,1]) {
 699   for ($botflip=yn) {
 700     translate([0, -phone_height/2, 0])
 701       mirror([0, $botflip, 0])
 702       translate([0, phone_height/2, 0])
 703       children();
 704   }
 705 }
 706
 707 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 708   // sides
 709   Flip_rhs(){
 710     translate([0, -phone_cnr_rad, 0])
 711       rotate([90,0,0])
 712       linear_extrude(height = phone_height - phone_cnr_rad*2)
 713       children(0);
 714   }
 715   // corners
 716   Flip_rhs() Flip_bot() {
 717     translate([+1,-1] * phone_cnr_rad)
 718       intersection(){
 719         rotate_extrude()
 720           intersection(){
 721             mirror([1,0,0])
 722               translate([-1,0] * phone_cnr_rad)
 723               children(0);
 724             rectfromto([0,-20],[10,20]);
 725           }
 726         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 727           cube([10,10,40]);
 728       }
 729   }
 730   // top and bottom
 731   Flip_bot(){
 732     translate([ phone_width - phone_cnr_rad, 0,0 ])
 733       rotate([90,0,-90])
 734       linear_extrude(height = phone_width - phone_cnr_rad*2)
 735       children(0);
 736   }
 737   // fill
 738   translate([0,0, fill_zstart])
 739     mirror([0,0, fill_downwards])
 740     linear_extrude(height = fill_th)
 741     rectfromto([+1,-1] * phone_cnr_rad,
 742                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 743 }
 744
 745 module CaseAperture(pos, dia, $fn) {
 746   theta = 180/$fn;
 747   translate([ pos[0] + bumper[0],
 748               -epp2i[0],
 749               -pos[1] ])
 750     rotate([-90, theta, 0])
 751     cylinder(r = dia/2 / cos(theta),
 752              h = 60);
 753 }
 754
 755 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 756   // y_ref_sign:
 757   //   +1  measured from top    of actual phone to top    of button
 758   //   -1  measured from bottom of actual phone to bottom of button
 759   //    0  y is centre of button in coordinate system
 760   $button_l= l;
 761   $button_suppress_over_keeper= suppress_over_keeper;
 762   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 763           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 764           y;
 765   //echo(eff_y);
 766   translate([0, eff_y, 0])
 767     children();
 768 }
 769
 770 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 771   $button_leg_only = true;
 772   SideButton(y, y_ref_sign, l) children();
 773 }
 774
 775 module Buttons(){
 776   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 777   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 778   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 779   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 780 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 781 }
 782
 783 module Struts(x_start, z_min, th){
 784   // if th is negative, starts at z_min and works towards -ve z
 785   // and object should then be printed other way up
 786   for (i= [1 : 1 : case_struts_count]) {
 787     translate([0,
 788                0,
 789                z_min])
 790       mirror([0,0, th<0 ? 1 : 0])
 791       translate([0,
 792                  -phone_height * i / (case_struts_count+1),
 793                  case_struts_solid_below])
 794       linear_extrude(height= abs(th)
 795                      -(case_struts_solid_below+case_struts_solid_above))
 796       rectfromto([               x_start, -0.5 * case_struts_width ],
 797                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 798   }
 799 }
 800
 801 module OrdinaryRearAperture(rhs,bot, pos){
 802   Flip_rhs(rhs) Flip_bot(bot)
 803     linextr(-20, 20)
 804     mirror([0,1])
 805     translate(pos + bumper)
 806     children();
 807 }
 808
 809 module MicroUSB(){
 810   Flip_bot(1){
 811     rotate([90,0,0])
 812       mirror([0,0,1])
 813       linextr(-epp2i[0], 60)
 814       translate([0.5 * phone_width, 0, 0])
 815       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 816                  [+microusb_width/2, epp0[1] + -microusb_above]);
 817   }
 818 }
 819
 820 module OrdinaryRearApertures(){
 821   // rear speaker
 822   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 823     rectfromto(-rearspeaker_gap,
 824                rearspeaker_size + rearspeaker_gap);
 825
 826   // finger hole to remove phone
 827   if (len(fingerpushhole_dias))
 828     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 829                                 phone[1]/2 ])
 830     scale(fingerpushhole_dias)
 831     circle(r= 0.5 );
 832 }
 833
 834 module RearCameraAperture(){
 835   Flip_rhs(1)
 836     mirror([0, 0, 1])
 837     linear_extrude(height = 20)
 838     mirror([0, 1, 0])
 839     translate(bumper)
 840     rectfromto(camera_pos_tl, camera_pos_br);
 841 }
 842
 843 module HingeLidProfile(){
 844   hull(){
 845     circleat(hppT, hp_r1);
 846     circleat(lpp12, lp_r12);
 847     polygon([lpp10,
 848              lpp13 + [2,0],
 849              lpp12,
 850              hppT]);
 851   }
 852 }
 853
 854 module HingeBaseProfile(){
 855   difference(){
 856     hull(){
 857       circleat(hppB, hp_r1);
 858       circleat(hppE, hp_r1);
 859       circleat(epp2o, case_th_bottom);
 860       circleat(hppB + [10,0], hp_r1);
 861     }
 862     polygon([epp5, epp1, epp2i, epp3, bppL]);
 863   }
 864 }
 865
 866 module HingeLeverOuterProfile(){
 867   hull(){
 868     circleat(hppT, hp_r2);
 869     circleat(hppB, hp_r2);
 870   }
 871 }
 872
 873 module HingeLeverInnerProfile(){
 874   for (s = [-1,+1]) {
 875     c = s > 0 ? hppT : hppB;
 876     translate(c)
 877       mirror([0,0,s>0])
 878       rotate(s<0 ? -40 : 0)
 879       hull()
 880       for (x=[-20,20])
 881         for (y=[0, s * 10])
 882           translate([x,y])
 883             circle(hp_rn);
 884   }
 885 }
 886
 887 module HingeLeverNutProfile(){
 888   for (c= [hppB, hppT]) {
 889     translate(c)
 890       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 891   }
 892 }
 893
 894 module Flip_hinge(doflip=1){
 895   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 896   translate(hinge_origin)
 897     rotate([doflip*180,0,0])
 898     translate(-hinge_origin)
 899     children();
 900 }
 901
 902 module HingePortion(x0,x1){
 903   Flip_rhs() Flip_bot(1)
 904     translate([x0,0,0])
 905     mirror([1,0,0])
 906     rotate([90,0,-90])
 907     linear_extrude(height=x1-x0)
 908     children();
 909 }
 910
 911 module CatchPortion(xwidth, ztop){
 912   width = catch_width + xwidth;
 913   w = width + catch_topcurve_r*2 + 1;
 914   translate([phone_width/2, 0,0]){
 915     difference(){
 916       rotate([90,0,-90])
 917         linextr(-w/2, w/2)
 918         children(0);
 919       translate([0, 50, 0])
 920         rotate([90,0,0])
 921         linear_extrude(height=100){
 922         for (m=[0,1]) mirror([m,0,0]) {
 923           hull(){
 924             translate([w/2, ztop - catch_topcurve_r])
 925               circle(catch_topcurve_r);
 926             translate([w/2, -50])
 927               square(catch_topcurve_r*2, center=true);
 928           }
 929         }
 930       }
 931     }
 932   }
 933 }
 934
 935 module CaseBase(){
 936   AroundEdges(epp3[1], case_th_bottom, 1)
 937     EdgeProfile();
 938 }
 939
 940 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 941
 942 module PropProfileAssignments(gamma){
 943   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 944   x = prop_x(gamma);
 945   p = phone_height + prlp10[0] - hppB[0];
 946   b = p + x;
 947
 948   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 949   a = q + x;
 950   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 951   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 952
 953   $prp_theta = 90 - $prp_alpha;
 954   beta = 180 - $prp_alpha - gamma;
 955   psi = 90 - beta;
 956
 957   //echo("abc", a,b,c);
 958
 959   v1 = [ [ cos(psi), -sin(psi) ],    // x
 960          [ sin(psi),  cos(psi) ] ];  // y
 961
 962   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 963
 964   $prp_r1 = prc_r1;
 965   $prp_r11 = prop_main_th/2;
 966
 967   $prpp1 = $prpp7 + [1,0] *
 968     // this is approximate, but will do
 969     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 970   $prpp3 = $prpp1 +
 971     v1[0] * -$prp_r1 +
 972     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 973   $prpp12 = $prpp3 + v1[0] *
 974     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 975   $prp_r8 = prop_main_th;
 976   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 977   $prp_r5 = $prp_r8;
 978   $prpp5 = [ $prpp12[0] - $prp_r5,
 979             $prpp3[1] - prop_prong_h + $prp_r5 ];
 980   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 981          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 982   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 983   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 984
 985   children();
 986 }
 987
 988 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 989   PropProfileAssignments(gamma){
 990
 991     //#circleat($prpp3,1);
 992     //#circleat($prpp12,1);
 993
 994     if (!cut) {
 995       hull(){
 996         translate($prpp8)
 997           intersection(){
 998             circle($prp_r8);
 999             polygon([[-20,-0], [20,20], [0,0]]);
1000           }
1001         rectfromto($prpp6, $prpp9);
1002         translate($prpp5) intersection(){
1003           circle($prp_r5);
1004           polygon([[-10,-10], [0,0], [10,0]]);
1005         }
1006         rectfromto($prpp12 + [0,-0.1], $prpp3);
1007       }
1008       hull(){
1009         circleat($prpp1, $prp_r1);
1010         rectfromto($prpp12 + [0,-0.1], $prpp3);
1011       }
1012     }
1013     // main shaft
1014     rotate([0,0, rot*-$prp_theta]){
1015       hull(){
1016         extra = cut ? prop_recess_slop : 0;
1017         rectfromto($prpp6, $prpp9);
1018         circleat($prpp11, $prp_r11 + extra);
1019         circleat($prpp10, $prp_r10 + extra);
1020       }
1021     }
1022   }
1023 }
1024
1025 module PropAggregateProfile(){
1026   for (angle = prop_angles)
1027     PropProfile(angle, 0,0);
1028 }
1029
1030 module Prop(){ ////toplevel
1031   hw = prop_main_width/2;
1032   linextr(-hw, +hw)
1033     PropAggregateProfile();
1034 }
1035
1036 module Case(){ ////toplevel
1037   difference(){
1038     union(){
1039       CaseBase();
1040
1041       // ledge (fixed keeper)
1042       Flip_rhs(1-keeper_side) intersection(){
1043         rotate([90, 0, 0])
1044           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1045           KeeperProfile(1);
1046
1047         // outline of the whole case, to stop it protruding
1048         translate([0,0, -25])
1049           linear_extrude(height = 50)
1050           hull()
1051           Flip_bot()
1052           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1053       }
1054
1055       // hinge
1056       HingePortion(hex20, hex21) HingeBaseProfile();
1057
1058       // buildout for prop recess
1059       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1060         linextr(case_bottom_z, epp2i[1])
1061         hull() {
1062           for (dxs = [-1,+1])
1063             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1064                        -epp2o[0] ],
1065                      r = epp2o[0] - prcp2[0]);
1066         }
1067     }
1068
1069     // slot for keeper
1070     Flip_rhs(keeper_side)
1071       translate([0, -phone_cnr_rad, 0])
1072       rotate([90, 0, 0])
1073       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1074       minkowski(){
1075         KeeperProfile();
1076         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1077                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1078       }
1079
1080     // front camera
1081     RearCameraAperture();
1082
1083     // struts (invisible, because they're buried in the case)
1084     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1085
1086     Buttons(){
1087       mirror([1,0,0])
1088         rotate([90,0,90]) {
1089           if (!($button_leg_only && enable_support))
1090           intersection(){
1091             translate([0,0,-10])
1092               linear_extrude(height= 20)
1093               ButtonPlan($button_l, 0,1);
1094             if ($button_leg_only)
1095               rotate([-90,90,0])
1096                 translate([phone_width/2, -400, kppe[1]])
1097                 mirror([1-abs($rhsflip - keeper_side),0,0])
1098                 cube([400, 800, 50]);
1099             if (enable_support && !$button_suppress_over_keeper)
1100               rotate([-90,90,0])
1101               translate([-400, -400, kppd[1]])
1102                 mirror([0,0,1])
1103                 cube([800,800,100]);
1104           }
1105           translate([0,0, -bppR[0]])
1106             linear_extrude(height= 20)
1107             ButtonPlan($button_l, 1,1);
1108         }
1109
1110     }
1111
1112     // apertures along top edge
1113     CaseAperture(jack_pos, jack_dia, 8);
1114     Flip_rhs(1)
1115       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1116
1117     OrdinaryRearApertures();
1118
1119     MicroUSB();
1120
1121     // gaps for the lid's hinge arms
1122     HingePortion(hex20 - hinge_x_arms_gap,
1123                  hex21 + hinge_x_arms_gap)
1124       minkowski(){
1125         HingeLidProfile();
1126         circle(r= hinge_r_arms_gap, $fn= 8);
1127       }
1128
1129     // screw holes in the hinge arms
1130     HingeScrews();
1131
1132     // catch striker
1133     CatchPortion(catch_side_gap*2, epp4[1])
1134       CatchCutProfile();
1135
1136     // prop recess
1137     Flip_rhs(1)
1138       translate([prop_x_pos,0,0])
1139       mirror([0,1,0])
1140       rotate([90,0,90])
1141       linextr(-prop_recess_hw, +prop_recess_hw)
1142       hull(){
1143         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1144           circleat(prcp1 + 20*d,
1145                    prc_r3);
1146       }
1147   }
1148 }
1149
1150 module LidAdhocMultiprintFrame(phase){
1151   if (led_window_style >= 3) {
1152     AdhocMultiprintFrame(phase, lpp13[1], -1);
1153   }
1154 }
1155
1156 module LidAroundEdges(){
1157   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1158     children();
1159 }
1160
1161 module Lid(){ ////toplevel
1162   skew_centre = [0, lpp11[0], lpp11[1]];
1163   difference(){
1164     union(){
1165       intersection(){
1166         LidAroundEdges()
1167           LidEdgeProfile();
1168
1169         translate(skew_centre)
1170           multmatrix([[ 1, 0, 0, 0 ],
1171                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1172                       [ 0, 0, 1, 0 ],
1173                       [ 0, 0, 0, 1 ]])
1174           translate(-skew_centre)
1175           LidAroundEdges()
1176           LidEdgeFoldClearanceProfile();
1177       }
1178
1179       // button covers
1180       Buttons(){
1181         intersection(){
1182           rotate([90,0,90])
1183             translate([0,0,-10])
1184             linear_extrude(height= 20)
1185             ButtonPlan($button_l, 1,0);
1186           rotate([90,0,0])
1187              translate([0,0,-100])
1188             linear_extrude(height= 200)
1189             ButtonCoverProfile();
1190         }
1191       }
1192
1193       // hinge arms
1194       HingePortion(hex20, hex21) {
1195         LidEdgeProfile();
1196         HingeLidProfile();
1197       }
1198
1199       // catch
1200       CatchPortion(0, lpp12[1])
1201         CatchCatchProfile();
1202     }
1203     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1204
1205     // screw holes in the hinge arms
1206     HingeScrews();
1207
1208     // prop recess
1209     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1210       mirror([0,1,0])
1211       rotate([90,0,90])
1212       linextr(-prop_recess_hw, +prop_recess_hw)
1213       hull()
1214       for (pa = prop_angles)
1215         PropProfile(pa, 1,1);
1216
1217     // notification led aperture
1218     if (led_window_style)
1219       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1220         translate([0,0,-10])
1221           cylinder(r=nla_r0, h=20);
1222         if (led_window_style >= 2)
1223           translate([0,0, -nla_t])
1224             cylinder(r=nla_r2, height=20);
1225       }
1226
1227     }
1228
1229   LidAdhocMultiprintFrame(1);
1230 }
1231
1232 module HingeLever(){ ////toplevel
1233   difference() {
1234     // outer body, positive
1235     HingePortion(hex22, hex22 + phone_width/2)
1236       HingeLeverOuterProfile();
1237
1238     // space for the screws
1239     HingePortion(hex26, hex24)
1240       HingeLeverInnerProfile();
1241
1242     // recesses for the nuts
1243     HingePortion(hex23, hex26+1)
1244       HingeLeverNutProfile();
1245
1246     // bores for the screws
1247     HingeScrews();
1248
1249     // space for the charging cable
1250     MicroUSB();
1251     Flip_hinge() MicroUSB();
1252   }
1253 }
1254
1255 module LidWindow(){ ////toplevel
1256   translate([led_pos[0], -led_pos[1], lpp13[1]])
1257     mirror([0,0,1])
1258     cylinder(r= nla_r1, h=nla_t);
1259   LidAdhocMultiprintFrame(0);
1260 }
1261
1262 module LidWindowPrint(){ ////toplevel
1263   rotate([0,180,0])
1264     LidWindow();
1265 }
1266
1267 module DemoLidWindowSelect(){
1268   translate([led_pos[0], led_pos[1], -100]) {
1269     translate([0, -30, 0]) cube([400, 400, 200]);
1270   }
1271 }
1272
1273 module DemoLidWindow(){ ////toplevel
1274   %Lid();
1275   LidWindow();
1276   translate([0,40,0]){
1277     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1278     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1279   }
1280 }
1281
1282 module HingeLeverPrint(){ ////toplevel
1283   rotate([-90,0,0])
1284     translate([-phone_width/2, phone_height, 0])
1285     HingeLever();
1286 }
1287
1288 module TestSelectLength(){
1289   translate([-30, -200, -20])
1290     cube([30 + 15, 250, 40]);
1291 }
1292
1293 module TestLength(){ ////toplevel
1294   intersection(){
1295     Case();
1296     TestSelectLength();
1297   }
1298 }
1299
1300 module TestLengthRight(){ ////toplevel
1301   intersection(){
1302     Case();
1303     Flip_rhs(1)
1304       TestSelectLength();
1305   }
1306 }
1307
1308 module TestSelectWidth(){
1309   translate([-30, -(phone_height - 25), -20])
1310     mirror([0, 1, 0])
1311     cube([200, 50, 40]);
1312 }
1313
1314 module TestWidth(){ ////toplevel
1315   intersection(){
1316     Case();
1317     TestSelectWidth();
1318   }
1319 }
1320
1321 module TestLidWidthPrint(){ ////toplevel
1322   rotate([0,180.0]) intersection(){
1323     Lid();
1324     TestSelectWidth();
1325   }
1326 }
1327
1328 module TestSelectRearAperture(){
1329   minkowski(){
1330     union() children();
1331     translate([20, 0,0])
1332       cube([42, 2, 1], center=true);
1333   }
1334 }
1335
1336 module TestSelectCamera(){
1337   minkowski(){
1338     TestSelectRearAperture()
1339       RearCameraAperture();
1340     cube([0.1, 50, 0.1]);
1341   }
1342 }
1343
1344 module TestSelectOrdinaryRearApertures(){
1345   TestSelectRearAperture()
1346     OrdinaryRearApertures();
1347 }
1348
1349 module TestCamera(){ ////toplevel
1350   intersection(){
1351     Case();
1352     TestSelectCamera();
1353   }
1354 }
1355
1356 module TestLidByCamera(){ ////toplevel
1357   intersection(){
1358     Lid();
1359     TestSelectCamera();
1360   }
1361 }
1362
1363 module TestLidByCameraPrint(){ ////toplevel
1364   rotate([180,0,0]) TestLidByCamera();
1365 }
1366
1367 module DemoByCamera(){ ////toplevel
1368   color("blue") TestLidByCamera();
1369   color("red")  TestCamera();
1370 }
1371
1372 module OneKeeper(){ ////toplevel
1373   translate([0, -phone_cnr_rad, 0])
1374     rotate([90, 0, 0])
1375     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1376     KeeperProfile();
1377 }
1378
1379 module OneKeeperPrint(){ ////toplevel
1380   rotate([0,180,0])
1381     OneKeeper();
1382 }
1383
1384 module LidPrint(){ ////toplevel
1385   rotate([0,180,0])
1386     Lid();
1387 }
1388
1389 module TestSelectFrame(){
1390   include = [1,-1] * (epp2i[0] + 4);
1391
1392   difference(){
1393     cube(1000, center=true);
1394     translate([0,0, -100])
1395       linear_extrude(height=200)
1396       rectfromto(include,  inside_br - include);
1397   }
1398 }
1399
1400 module TestSelectLidFrame(){
1401   TestSelectFrame();
1402   translate([led_pos[0], -led_pos[1], -50])
1403     cylinder(r= nla_r2+3, h=100);
1404 }
1405
1406 module TestFrameCase(){ ////toplevel
1407   intersection(){
1408     Case();
1409     union(){
1410       TestSelectFrame();
1411       TestSelectCamera();
1412       TestSelectOrdinaryRearApertures();
1413     }
1414   }
1415 }
1416
1417 module TestSelectTopApertures(){
1418   translate([-100, -35, -100])
1419     cube([400, 100, 200]);
1420   LidAdhocMultiprintFrame(0);
1421   LidAdhocMultiprintFrame(1);
1422 }
1423
1424 module TestTopApertures(){ ////toplevel
1425   intersection(){
1426     Case();
1427     TestSelectFrame();
1428     TestSelectTopApertures();
1429   }
1430 }
1431
1432 module TestLidTopAperturesPrint(){ ////toplevel
1433   rotate([0,180,0]) intersection(){
1434     Lid();
1435     TestSelectLidFrame();
1436     TestSelectTopApertures();
1437   }
1438 }
1439
1440 module TestLidWindowTopAperturesPrint(){ ////toplevel
1441   rotate([0,180,0]) intersection(){
1442     LidWindow();
1443     TestSelectTopApertures();
1444   }
1445 }
1446
1447 module TestFrameLidPrint(){ ////toplevel
1448   rotate([0,180,0]) intersection(){
1449     Lid();
1450     TestSelectLidFrame();
1451   }
1452 }
1453
1454 module ButtonPlanForDemo(z, deep, cut){
1455   translate([0,0,z])
1456     ButtonPlan(8, deep, cut);
1457 }
1458
1459 module HingeScrews(){
1460   Flip_rhs() Flip_bot(1){
1461     for (c= [ hppT, hppB ])
1462       translate([ hex20,
1463                   -c[0],
1464                   c[1] ]){
1465         rotate([0,90,0])
1466           translate([0,0,-.2])
1467           cylinder( r= hingescrew_shaft_dia/2,
1468                     h = hingescrew_shaft_len+0.2 );
1469         rotate([0,-90,0])
1470           translate([0,0,+.1])
1471           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1472       }
1473   }
1474 }
1475
1476 module DemoPropAngleSelect(c){
1477   color(c) difference(){
1478     union(){ children(); }
1479     translate([ prop_x_pos, -400, -200 ])
1480       cube([ 400,800,400 ]);
1481   }
1482 }
1483
1484 module DemoPropAngle(ang){
1485   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1486   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1487
1488   translate(hL)
1489     rotate([ang/2,0,0])
1490     translate(-hL)
1491     translate(hC)
1492     rotate([ang/2,0,0])
1493     translate(-hC) {
1494       DemoPropAngleSelect("red") Case();
1495
1496       color("orange")
1497         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1498         PropProfileAssignments(ang) {
1499           echo($prpp1);
1500           rotate([-$prp_theta, 0, 0])
1501           translate([0, $prpp1[0], -$prpp1[1]])
1502           rotate([90,0,-90])
1503           Prop();
1504         }
1505     }
1506
1507   translate([0,0, -hp_k*2])
1508     DemoPropAngleSelect("blue")
1509     Lid();
1510 }
1511
1512 module DemoPropAngles(){ ////toplevel
1513   for (i=[0 : len(prop_angles)-1])
1514     translate(i * [0, -100, 100])
1515     DemoPropAngle(prop_angles[i]);
1516 }
1517
1518 module DemoHingeAngle(ang1,ang2){
1519   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1520   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1521
1522   translate(hL)
1523     rotate([ang2,0,0])
1524     translate(-hL)
1525     translate(hC)
1526     rotate([ang1,0,0])
1527     translate(-hC) {
1528       color("red") Lid();
1529     }
1530
1531   color("blue") intersection(){
1532     Case();
1533     union(){
1534       translate([bppJ[0], -400, -200])
1535         mirror([1,0,0])
1536         cube([400, 800, 400]);
1537       translate([10, -400, -200])
1538         cube([10, 800, 400]);
1539     }
1540   }
1541 }
1542
1543 module DemoHingeAngles(){ ////toplevel
1544   angles = [ 0, 4, 8, 12 ];
1545   echo("angles",angles);
1546   for (i=[0 : len(angles)-1]) {
1547     translate(i * [0, 0, 30]) {
1548       DemoHingeAngle(0,angles[i]);
1549       translate([0, 200, 0])
1550         DemoHingeAngle(angles[i],0);
1551     }
1552   }
1553 }
1554
1555 module DemoSelectAdhocLeftRight(right=0) {
1556   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1557     mirror([1-right, 0,0])
1558     cube([400, 800, 200]);
1559 }
1560
1561 module DemoLeft(){ ////toplevel
1562   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1563   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1564 }
1565
1566 module DemoFrame(){ ////toplevel
1567   color("red") TestFrameCase();
1568   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1569   color("black") HingeScrews();
1570   %HingeLever();
1571 }
1572
1573 module DemoLanyardEntry(){ ////toplevel
1574   LanyardEntry();
1575 }
1576
1577 module DemoHingedFrame(){ ///toplevel
1578   color("red") TestFrameCase();
1579   translate([0,0, -2*hp_k])
1580   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1581
1582   Flip_hinge(){
1583     color("orange") HingeLever();
1584     color("black") HingeScrews();
1585   }
1586 }
1587
1588 module DemoHinge(){ ////toplevel
1589   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1590     DemoFrame();
1591     translate([0,0, -hp_k*3])
1592       DemoHingedFrame();
1593   }
1594 }
1595
1596 module DemoProfiles(){ ////toplevel
1597   LidEdgeProfile();
1598   %EdgeProfile();
1599   KeeperProfile();
1600   translate([0,0,-1]) color("black") KeeperProfile(1);
1601   color("purple") translate(epp2i)
1602     rotate(atan2vector(epp2i - epp1)) {
1603     translate(lanyard_half_dia * 0.5 * [-3,-1])
1604       LanyardLanyardProfile();
1605     translate(lanyard_half_dia * 0.5 * [-3,+1])
1606       translate([0,-1] * case_th_side)
1607       LanyardLanyardProfile(true);
1608   }
1609
1610   translate([0,20]) {
1611     LanyardMainChannelProfile();
1612     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1613     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1614   }
1615
1616   translate([20,0]) {
1617     LidEdgeProfile();
1618     %EdgeProfile();
1619
1620     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1621
1622     color("blue") ButtonCoverProfile();
1623     color("red") {
1624       rectfromto(bppQ, demopoint_QR);
1625       rectfromto(bppR, demopoint_QR);
1626     }
1627   }
1628
1629   translate([-20,0]) {
1630     color("black") ButtonPlanForDemo(-2, 0,1);
1631     color("red" )  ButtonPlanForDemo(-4, 1,1);
1632     color("blue")  ButtonPlanForDemo(-6, 1,0);
1633   }
1634
1635   translate([0, -30]) {
1636     %LidEdgeProfile();
1637     %EdgeProfile();
1638     color("blue") HingeLidProfile();
1639     color("red")  HingeBaseProfile();
1640     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1641   }
1642
1643   for (f=[0,1]) {
1644     translate([-30, -60 + 30*f]) {
1645       translate([0,0,-4]) EdgeProfile();
1646       %translate([0,0,-10]) HingeBaseProfile();
1647       translate([0,-2] * f * hp_k) {
1648         translate([0,0,-4]) LidEdgeProfile();
1649         %translate([0,0,-10]) %HingeLidProfile();
1650       }
1651       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1652         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1653         translate([0,0,0]) color("red") difference(){
1654           HingeLeverOuterProfile();
1655           HingeLeverInnerProfile();
1656         }
1657         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1658       }
1659     }
1660   }
1661
1662   translate([20,-30]) {
1663     %EdgeProfile();
1664     %LidEdgeProfile();
1665     //translate([0,0,1]) CatchCutProfile();
1666     color("blue") CatchCatchProfile();
1667     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1668   }
1669
1670   translate([40,-30]) {
1671     difference(){
1672       LidEdgeProfile();
1673       translate(prlp10)
1674         PropProfile(10, 1, 0);
1675     }
1676     translate(prlp10)
1677       PropProfile(15, 0);
1678   }
1679   translate([60,-30]) {
1680     PropAggregateProfile();
1681   }
1682 }
1683
1684 //EdgeProfile();
1685 //KeeperProfile();
1686 //CaseBase();
1687 //%Case();
1688 //Keeper();
1689 //LidEdgeProfile();
1690 //KeeperProfile();
1691 //DemoProfiles();
1692 //PropRecess();