fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172 lanyard_entry_rel_breadth = 2;
 173 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 174 rearspeaker_size   = [  3.76,  7.36 ];
 175
 176 microusb_above = 3.27 - 0.25;
 177 microusb_below = 0.0;
 178 microusb_width = 16.12 + 1.25;
 179
 180 case_th_bottom = 2.5;
 181 case_th_lid = 3.0;
 182 case_th_side = 2.3;
 183 case_th_lip = 1.2;
 184
 185 lid_screen_gap_extra = .66;
 186
 187 case_struts_count = 6;
 188 case_struts_solid_below = 1.00;
 189 case_struts_solid_above = 0.75;
 190 case_struts_width = 0.10;
 191
 192 keeper_th_z = 0.75;
 193 keeper_th_x = 0.75;
 194 keeper_inner_width = 2.75;
 195 keeper_inner_height = 2.75;
 196 keeper_slant_slope = 2; // larger means steeper
 197
 198 keeper_gap_z_top = 0.25;
 199 keeper_gap_z_bot = 0.75;
 200 keeper_gap_x     = 0.25;
 201 keeper_gap_x_holes = 0.75;
 202
 203 keeper_side = 0; // 0 = lhs; 1 = rhs
 204
 205 case_lip = 1.25;
 206
 207 lid_gap_x = 0.25;
 208 lid_gap_z = 0.25;
 209 lid_lip = 1.75;
 210 lid_edgepart_width = 5.0;
 211 lid_buttoncover_thick = 1.3;
 212
 213 catch_slop = 0.50;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // properties of the hinge fasteners
 219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 220 hingescrew_shaft_len = 12;
 221 hingescrew_fasteners_extra_thick = 0.40;
 222 // ^ amount of thread protruding if everything was completely nominal
 223 //   and we are using two nuts
 224 hingescrew_nut_access_dia = 4.72 + 0.50;
 225 // ^ washer is 4.72 dia
 226 //   also, want to get pliers or tiny spanner in to do up locknut
 227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 228 hingescrew_nut_thick = 1.93;
 229 hingescrew_head_th = 1.38 + 0.75;
 230 hingescrew_head_dia = 3.92;
 231
 232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 233
 234 lever_cover_th = 0.75;
 235 hingemount_th = 2.5;
 236 hingemount_wd = 4.8725;
 237
 238 $fa = 5;
 239 $fs = 0.1;
 240
 241 button_l_fudge = 4.4;
 242 buttonishleg_default_l_is_fudge = 10;
 243
 244 hinge_base_slope = 1.5; // bigger is steeper
 245
 246 strut_min_at_end = 1.5;
 247
 248 hinge_x_gap = 0.125;
 249 hinge_x_postscrew_gap = 0.75;
 250 hinge_x_arms_gap = 0.35;
 251 hinge_r_arms_gap = 0.55;
 252
 253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 254
 255 catch_len = 7.5;
 256 catch_width = 15;
 257 catch_thickness = 1.0;
 258 catch_side_gap = 0.75; // each side
 259
 260 catch_depth = 0.75;
 261 catch_height = 0.35;
 262 catch_finger_height = 1.5;
 263 catch_finger_depth = 2.5;
 264
 265 catch_topcurve_r = 5.0;
 266
 267 prop_recess_under = 0.50;
 268 prop_recess_slop = 0.200; // each side
 269 prop_end_dia = 0.5;
 270 prop_main_th = 3;
 271 prop_taper_len = 6;
 272 prop_main_width = 4;
 273 prop_side_gap = 0.75; // each side
 274 prop_lidrecess_behind = 0.75;
 275 prop_caserecess_behind = 0.75;
 276 prop_caserecess_taper = 0.45; // one side only
 277 prop_prop_gap = 0.5;
 278 prop_prong_heel_slope = 0.5;
 279
 280 lid_fold_clearance_antislop = 0.5;
 281
 282 // ---------- calculated ----------
 283
 284 phone_width =  (phone + bumper*2)[0];
 285 phone_height = (phone + bumper*2)[1];
 286
 287 inside_br = [phone_width, -phone_height];
 288
 289 prop_prong_h = prop_main_th;
 290
 291 //echo(camera_pos_tl + bumper,
 292 //     camera_pos_br + bumper);
 293
 294 // ----- could be changed -----
 295 lid_buttoncover_gap = lid_gap_x;
 296 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 297
 298 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 299
 300 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 301
 302 //prop_nose_len = case_th_lid - prop_recess_under;
 303 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 304 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 305
 306
 307 //lid_lip_overlap_width xxx bad name = ;
 308 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 309
 310 epp0 = [0,0];
 311 epp1 = [0, -phone_edge_thick];
 312 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 313 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 314 epp3 = epp2i + [10, 0];
 315 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 316 epp4 = epp5 + [-1,0] * case_th_side;
 317
 318 kppe = [0,0];
 319 kppd = kppe + [1,0] * keeper_inner_width;
 320 kppc = kppd + [0,1] * keeper_th_z;
 321 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 322 kppf = kppe - [0,1] * keeper_inner_height;
 323 kppa = [ kppb[0], kppf[1] ];
 324
 325 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 326 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 327
 328 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 329 // exact x posn not very important; must extend past end of keeper
 330
 331 lpp15 = [ lpp14[0],
 332           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 333           + lid_screen_gap_extra ];
 334 // ^ beam theory says to maximise force before contact,
 335 //   the gap below the `beam' (the lid) must be 1/3
 336 //   the thickness (ie the lid thickness) if the beam
 337 //   is solid, or 1/2 if it has a top and bottom only.
 338 //   ours is mostly solid.
 339
 340 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 341              case_th_lip);
 342
 343 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 344 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 345
 346 case_bottom_z = epp2o[1] - case_th_bottom;
 347
 348 // button profile
 349 bppM = epp4 + [0,5];
 350 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 351 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 352 bppS = [ epp1[0], bppR[1] ];
 353 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 354 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 355 bppO = [ bppN[0], bppP[1] ];
 356 bppL = lpp10 + [5,0];
 357 bppK = [ bppL[0], bppN[1] ];
 358 bppJ = [ bppN[0], bppL[1] ];
 359 bppU = [ bppJ[0], lpp12[1] ];
 360 bppV = lpp11;
 361 bppW = lpp10;
 362
 363 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 364
 365 // notification led aperture
 366
 367 nla_r0 = led_aperture/2;
 368 nla_r1 = nla_r0 + led_window_ledge;
 369 nla_r2 = nla_r1 + multicolour_gap;
 370 nla_t =
 371   led_window_style >= 3 ? initial_layer_thick :
 372   led_window_style >= 2 ? led_window_ledge : 0;
 373
 374
 375 // hinge plan
 376 hp_rn = hingescrew_nut_access_dia/2;
 377 hp_r2_min = hp_rn + lever_cover_th;
 378 hp_rs = hingescrew_shaft_dia/2;
 379 hp_r1_min = hp_rs + hingemount_th;
 380
 381 hp_r1 = max(hp_r1_min, hp_r2_min);
 382 hp_r2 = hp_r1;
 383
 384 hppU = lpp13;
 385 hppS = epp2o + [0,-1] * case_th_bottom;
 386 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 387
 388 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 389          0.5 * (hppU + hppS)[1] ];
 390 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 391 hppB = hppT + [0,-1] * hp_k;
 392
 393 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 394 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 395 hppE = [ hppE_x, hppE_y ];
 396
 397 // hinge elevation x coords
 398
 399 hex20 = max(epp2o[0],
 400             phone_cnr_rad,
 401             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 402 hex21 = hex20 + hingemount_wd;
 403 hex22 = hex21 + hinge_x_gap;
 404 hex27 = hex20 + hingescrew_shaft_len;
 405 hex24 = hex27 + hinge_x_postscrew_gap;
 406 hex23 = hex27 - (hingescrew_nut_thick*2
 407                  + hingescrew_fasteners_extra_thick);
 408 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 409
 410 echo(hex20, hex21, hex22, hex23, hex24);
 411 //  6, 10.8725, 10.9975, 13.74, 18.75
 412 module chk(act,exp) {
 413   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 414   else echo("ok", act);
 415 }
 416 chk(hex20, 6);
 417 chk(hex21, 10.8725);
 418 chk(hex22, 10.9975);
 419 chk(hex23, 13.74);
 420 chk(hex24, 18.75);
 421
 422 lid_fold_clearance_skew =
 423   (lpp10[1] - hppB[1]) /
 424   (lpp10[0] - hppB[0]);
 425
 426 echo("SK",lid_fold_clearance_skew);
 427
 428 // catch
 429
 430 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 431 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 432 cppB = [ epp0[0], cppA[1] ];
 433 cppP = [ epp4[0], cppJ[1] ];
 434
 435 cppS = cppJ + [0,-1] * catch_len;
 436 cppD = [ cppA[0], cppS[1] + catch_slop ];
 437 cppC = [ cppB[0], cppD[1] ];
 438 cppT = cppS + [1,0] * catch_depth;
 439 cppU = cppT + [0,-1] * catch_height;
 440 cppV = [ cppS[0], cppU[1] - catch_depth ];
 441
 442 cppR = 0.5*(cppP + cppJ);
 443
 444 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 445 cppQ = [ cppR[0],
 446          cppV[1] - (catch_finger_height - cp_rQ) ];
 447 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 448
 449 // lanyard
 450
 451 ly_r = lanyard_half_dia / 2;
 452 ly_rc = ly_r * 2;
 453 ly_re = 10; // xxx
 454
 455 // prop recess in case
 456
 457 prop_x_pos = phone_width/2;
 458
 459 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 460
 461 prc_r1 = prop_end_dia/2;
 462 prc_r3 = prc_r1 + prop_recess_slop;
 463
 464 prcp2 = [ epp4[0] + prop_buildout_less,
 465           case_bottom_z ];
 466
 467 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 468
 469 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 470           epp2i[1] - prc_r3 - prop_recess_under];
 471
 472 // prop recess in lid
 473
 474 prl_r10 = prop_end_dia/2;
 475 prl_r10o = prl_r10 + prop_recess_slop;
 476
 477 prlp10 = lpp10 + [1,1] * prl_r10o
 478   + [1,0] * prop_lidrecess_behind
 479   + [0,1] * prop_recess_under;
 480
 481 // prop
 482
 483 $prpp10 = [0,0];
 484 $prpp11 = [0, prop_taper_len];
 485
 486 $prp_r10 = prl_r10;
 487
 488 // ---------- modules ----------
 489
 490 module AdhocMultiprintFrame(phase, z0, zs) {
 491   // from z0 to z0 + zs*layer
 492   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 493   xextra = extra + -epp4[0];
 494   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 495   yextra = extra + -epp4[0];
 496   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 497   p0 = [ xrange[0], yrange[0] ];
 498   p1 = [ xrange[1], yrange[1] ];
 499   echo(p0, p1);
 500   translate([0,0, z0])
 501     mirror([0,0, zs<0 ? 1 : 0])
 502     linear_extrude(height= initial_layer_thick)
 503     difference(){
 504       rectfromto(p0 - [1,1] * initial_layer_width,
 505                  p1 + [1,1] * initial_layer_width);
 506       rectfromto(p0, p1);
 507     }
 508 }
 509
 510 module KeeperProfile(slant=0){
 511   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 512   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 513 }
 514
 515 module EdgeProfile(){
 516   difference(){
 517     hull(){
 518       translate(epp3) square(case_th_bottom*2, center=true);
 519       circleat(epp2o, r=case_th_bottom);
 520       circleat(epp1, r=case_th_side);
 521       rectfromto(epp0, epp4);
 522     }
 523     polygon([ epp5 + [0,10],
 524               epp1,
 525               epp2i,
 526               epp3 + [10,0] ]);
 527   }
 528 }
 529
 530 module LanyardLanyardProfile(entry=false){
 531   hull(){
 532     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 533       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 534         circle(r= lanyard_half_dia/2);
 535   }
 536 }
 537
 538 module LanyardCurveChannelProfile(){
 539   translate([0, -ly_r])
 540     LanyardLanyardProfile();
 541 }
 542
 543 module LanyardEntryChannelProfile(){
 544   LanyardLanyardProfile(true);
 545 }
 546
 547 module LanyardMainChannelProfile(){
 548   LanyardCurveChannelProfile();
 549   difference(){
 550     square(center=true, ly_r * [6, 2]);
 551     for (xs=[-1,+1])
 552       translate(ly_r * [3 * xs, -1])
 553         circle(r = ly_r);
 554   }
 555 }
 556
 557 module LanyardEntry(){
 558   q_z = -(ly_rc + ly_r);
 559   d_x = -ly_rc;
 560
 561   translate([d_x, 0, q_z]) {
 562     intersection(){
 563       rotate([90,0,0])
 564         rotate_extrude(convexity=10)
 565         rotate(90)
 566         translate([0, -q_z])
 567         LanyardCurveChannelProfile();
 568       translate([0,-10,0])
 569         cube([20,20,20]);
 570     }
 571   }
 572
 573   mirror([0,0,1])
 574     translate([0,0,-1])
 575     linear_extrude(height=20)
 576     rotate(-90)
 577     LanyardEntryChannelProfile();
 578
 579   translate([0, ly_r*2, 0])
 580     rotate([90,0,0])
 581     linear_extrude(height = ly_r*4){
 582     difference(){
 583       rectfromto([d_x, q_z], [ly_r, 0]);
 584       circleat([d_x, q_z], ly_rc);
 585     }
 586   }
 587
 588   for (my=[0,1])
 589     mirror([0,my,0]){
 590       translate([0, lanyard_entry_rel_breadth * ly_r, 0]){
 591         difference(){
 592           translate(ly_re * [-1,0,-1])
 593             cube(ly_re * [2,1,1]);
 594           rotate_extrude(convexity=10)
 595             circleat([ly_re + ly_r, 0], ly_re);
 596         }
 597       }
 598     }
 599 }
 600
 601 module LanyardCutout(l){
 602   rotate([0,-90,0])
 603     linear_extrude(height=l)
 604     rotate(-90)
 605     LanyardMainChannelProfile();
 606
 607   for (ee=[0,1]){
 608     translate(ee * l * [-1,0])
 609       mirror([ee,0,0])
 610       LanyardEntry();
 611   }
 612 }
 613
 614 module LidEdgeProfile(){
 615   polygon([ lpp10,
 616             lpp11,
 617             lpp12,
 618             lpp13,
 619             lpp13 + [10, 0],
 620             lpp15 + [10, 0],
 621             lpp15,
 622             lpp14,
 623             ]);
 624   intersection(){
 625     circleat(lpp12, r=lp_r12);
 626     rectfromto( lpp12 + [-10,   0],
 627                 lpp12 + [+10, +10] );
 628   }
 629 }
 630
 631 module LidEdgeFoldClearanceProfile(){
 632   translate([-lid_fold_clearance_antislop, 0])
 633     polygon([ lpp10,
 634               lpp11,
 635               lpp11 + [-20,  0],
 636               lpp11 + [-20, 20],
 637               lpp11 + [+20, 20],
 638               lpp10 + [+20,  0] ]);
 639 }
 640
 641 module ButtonCoverProfile(){
 642   intersection(){
 643     polygon(concat([ bppM, bppP, bppO, bppJ ],
 644                    (enable_support && !$button_suppress_over_keeper
 645                     ? [ bppU, bppV, bppW ] : []),
 646                    [ bppL, bppK ]));
 647     hull(){
 648       EdgeProfile();
 649       LidEdgeProfile();
 650     }
 651   }
 652 }
 653
 654 module ButtonPlan(l, deep, cut){
 655   epsilon =
 656     (cut  ? 0 : lid_buttoncover_gap);
 657
 658   delta =
 659     (deep ? lid_buttoncover_overlap : 0);
 660
 661   C = [0,0]; // by definition
 662   T = [ 0, epp4[1] ];
 663   G = T + [0,10];
 664
 665   B0 = C + [0,-1] * button_cutout_depth;
 666   B1 = B0 + [0,1] * epsilon;
 667
 668   r0 = 0.5 * (T[1] - B0[1]);
 669   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 670   H = A + [0,-1] * delta;
 671
 672   D = A + [-2,0] * r0;
 673   F = D + [0,10];
 674
 675   E0 = 0.5 * (D + A);
 676   E1 = E0 + [1,0] * epsilon;
 677
 678   I0 = [ E0[0], H[1] ];
 679   I1 = [ E1[0], H[1] ];
 680
 681   hull(){
 682     for (m=[0,1]) mirror([m,0])
 683       circleat(H, r0 - epsilon);
 684   }
 685   for (m=[0,1]) mirror([m,0]) {
 686     difference(){
 687       polygon([ E1,
 688                 I1,
 689                 H,
 690                 B1,
 691                 G,
 692                 F,
 693                 D
 694                 ]);
 695       circleat(D, r0 + epsilon);
 696     }
 697   }
 698 }
 699
 700 module CatchCatchProfile(){
 701   hull(){
 702     for (c=[ cppR, cppQ ])
 703       circleat(c, cp_rQ);
 704   }
 705   hull(){
 706     circleat(lpp12, lp_r12);
 707     circleat(lpp12 + [5,0], lp_r12);
 708     rectfromto(cppP, cppP + [5,0.1]);
 709   }
 710   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 711 }
 712
 713 module CatchCutProfile(){
 714   polygon([ cppB,
 715             cppA,
 716             cppD,
 717             cppF,
 718             cppF + [0,-10],
 719             cppF + [-10,-10],
 720             lpp12 + [-10,0],
 721             lpp12 + [10,0]
 722             ]);
 723 }
 724
 725 module Flip_rhs(yn=[0,1]) {
 726   for ($rhsflip=yn) {
 727     translate([phone_width/2, 0, 0])
 728       mirror([$rhsflip,0,0])
 729       translate([-phone_width/2, 0, 0])
 730       children();
 731   }
 732 }
 733
 734 module Flip_bot(yn=[0,1]) {
 735   for ($botflip=yn) {
 736     translate([0, -phone_height/2, 0])
 737       mirror([0, $botflip, 0])
 738       translate([0, phone_height/2, 0])
 739       children();
 740   }
 741 }
 742
 743 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 744   // sides
 745   Flip_rhs(){
 746     translate([0, -phone_cnr_rad, 0])
 747       rotate([90,0,0])
 748       linear_extrude(height = phone_height - phone_cnr_rad*2)
 749       children(0);
 750   }
 751   // corners
 752   Flip_rhs() Flip_bot() {
 753     translate([+1,-1] * phone_cnr_rad)
 754       intersection(){
 755         rotate_extrude()
 756           intersection(){
 757             mirror([1,0,0])
 758               translate([-1,0] * phone_cnr_rad)
 759               children(0);
 760             rectfromto([0,-20],[10,20]);
 761           }
 762         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 763           cube([10,10,40]);
 764       }
 765   }
 766   // top and bottom
 767   Flip_bot(){
 768     translate([ phone_width - phone_cnr_rad, 0,0 ])
 769       rotate([90,0,-90])
 770       linear_extrude(height = phone_width - phone_cnr_rad*2)
 771       children(0);
 772   }
 773   // fill
 774   translate([0,0, fill_zstart])
 775     mirror([0,0, fill_downwards])
 776     linear_extrude(height = fill_th)
 777     rectfromto([+1,-1] * phone_cnr_rad,
 778                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 779 }
 780
 781 module CaseAperture(pos, dia, $fn) {
 782   theta = 180/$fn;
 783   translate([ pos[0] + bumper[0],
 784               -epp2i[0],
 785               -pos[1] ])
 786     rotate([-90, theta, 0])
 787     cylinder(r = dia/2 / cos(theta),
 788              h = 60);
 789 }
 790
 791 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 792   // y_ref_sign:
 793   //   +1  measured from top    of actual phone to top    of button
 794   //   -1  measured from bottom of actual phone to bottom of button
 795   //    0  y is centre of button in coordinate system
 796   $button_l= l;
 797   $button_suppress_over_keeper= suppress_over_keeper;
 798   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 799           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 800           y;
 801   //echo(eff_y);
 802   translate([0, eff_y, 0])
 803     children();
 804 }
 805
 806 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 807   $button_leg_only = true;
 808   SideButton(y, y_ref_sign, l) children();
 809 }
 810
 811 module Buttons(){
 812   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 813   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 814   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 815   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 816 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 817 }
 818
 819 module Struts(x_start, z_min, th){
 820   // if th is negative, starts at z_min and works towards -ve z
 821   // and object should then be printed other way up
 822   for (i= [1 : 1 : case_struts_count]) {
 823     translate([0,
 824                0,
 825                z_min])
 826       mirror([0,0, th<0 ? 1 : 0])
 827       translate([0,
 828                  -phone_height * i / (case_struts_count+1),
 829                  case_struts_solid_below])
 830       linear_extrude(height= abs(th)
 831                      -(case_struts_solid_below+case_struts_solid_above))
 832       rectfromto([               x_start, -0.5 * case_struts_width ],
 833                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 834   }
 835 }
 836
 837 module OrdinaryRearAperture(rhs,bot, pos){
 838   Flip_rhs(rhs) Flip_bot(bot)
 839     linextr(-20, 20)
 840     mirror([0,1])
 841     translate(pos + bumper)
 842     children();
 843 }
 844
 845 module MicroUSB(){
 846   Flip_bot(1){
 847     rotate([90,0,0])
 848       mirror([0,0,1])
 849       linextr(-epp2i[0], 60)
 850       translate([0.5 * phone_width, 0, 0])
 851       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 852                  [+microusb_width/2, epp0[1] + -microusb_above]);
 853   }
 854 }
 855
 856 module OrdinaryRearApertures(){
 857   // rear speaker
 858   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 859     rectfromto(-rearspeaker_gap,
 860                rearspeaker_size + rearspeaker_gap);
 861
 862   // finger hole to remove phone
 863   if (len(fingerpushhole_dias))
 864     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 865                                 phone[1]/2 ])
 866     scale(fingerpushhole_dias)
 867     circle(r= 0.5 );
 868 }
 869
 870 module RearCameraAperture(){
 871   Flip_rhs(1)
 872     mirror([0, 0, 1])
 873     linear_extrude(height = 20)
 874     mirror([0, 1, 0])
 875     translate(bumper)
 876     rectfromto(camera_pos_tl, camera_pos_br);
 877 }
 878
 879 module HingeLidProfile(){
 880   hull(){
 881     circleat(hppT, hp_r1);
 882     circleat(lpp12, lp_r12);
 883     polygon([lpp10,
 884              lpp13 + [2,0],
 885              lpp12,
 886              hppT]);
 887   }
 888 }
 889
 890 module HingeBaseProfile(){
 891   difference(){
 892     hull(){
 893       circleat(hppB, hp_r1);
 894       circleat(hppE, hp_r1);
 895       circleat(epp2o, case_th_bottom);
 896       circleat(hppB + [10,0], hp_r1);
 897     }
 898     polygon([epp5, epp1, epp2i, epp3, bppL]);
 899   }
 900 }
 901
 902 module HingeLeverOuterProfile(){
 903   hull(){
 904     circleat(hppT, hp_r2);
 905     circleat(hppB, hp_r2);
 906   }
 907 }
 908
 909 module HingeLeverInnerProfile(){
 910   for (s = [-1,+1]) {
 911     c = s > 0 ? hppT : hppB;
 912     translate(c)
 913       mirror([0,0,s>0])
 914       rotate(s<0 ? -40 : 0)
 915       hull()
 916       for (x=[-20,20])
 917         for (y=[0, s * 10])
 918           translate([x,y])
 919             circle(hp_rn);
 920   }
 921 }
 922
 923 module HingeLeverNutProfile(){
 924   for (c= [hppB, hppT]) {
 925     translate(c)
 926       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 927   }
 928 }
 929
 930 module Flip_hinge(doflip=1){
 931   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 932   translate(hinge_origin)
 933     rotate([doflip*180,0,0])
 934     translate(-hinge_origin)
 935     children();
 936 }
 937
 938 module HingePortion(x0,x1){
 939   Flip_rhs() Flip_bot(1)
 940     translate([x0,0,0])
 941     mirror([1,0,0])
 942     rotate([90,0,-90])
 943     linear_extrude(height=x1-x0)
 944     children();
 945 }
 946
 947 module CatchPortion(xwidth, ztop){
 948   width = catch_width + xwidth;
 949   w = width + catch_topcurve_r*2 + 1;
 950   translate([phone_width/2, 0,0]){
 951     difference(){
 952       rotate([90,0,-90])
 953         linextr(-w/2, w/2)
 954         children(0);
 955       translate([0, 50, 0])
 956         rotate([90,0,0])
 957         linear_extrude(height=100){
 958         for (m=[0,1]) mirror([m,0,0]) {
 959           hull(){
 960             translate([w/2, ztop - catch_topcurve_r])
 961               circle(catch_topcurve_r);
 962             translate([w/2, -50])
 963               square(catch_topcurve_r*2, center=true);
 964           }
 965         }
 966       }
 967     }
 968   }
 969 }
 970
 971 module CaseBase(){
 972   AroundEdges(epp3[1], case_th_bottom, 1)
 973     EdgeProfile();
 974 }
 975
 976 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 977
 978 module PropProfileAssignments(gamma){
 979   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 980   x = prop_x(gamma);
 981   p = phone_height + prlp10[0] - hppB[0];
 982   b = p + x;
 983
 984   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 985   a = q + x;
 986   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 987   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 988
 989   $prp_theta = 90 - $prp_alpha;
 990   beta = 180 - $prp_alpha - gamma;
 991   psi = 90 - beta;
 992
 993   //echo("abc", a,b,c);
 994
 995   v1 = [ [ cos(psi), -sin(psi) ],    // x
 996          [ sin(psi),  cos(psi) ] ];  // y
 997
 998   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 999
1000   $prp_r1 = prc_r1;
1001   $prp_r11 = prop_main_th/2;
1002
1003   $prpp1 = $prpp7 + [1,0] *
1004     // this is approximate, but will do
1005     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1006   $prpp3 = $prpp1 +
1007     v1[0] * -$prp_r1 +
1008     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1009   $prpp12 = $prpp3 + v1[0] *
1010     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1011   $prp_r8 = prop_main_th;
1012   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1013   $prp_r5 = $prp_r8;
1014   $prpp5 = [ $prpp12[0] - $prp_r5,
1015             $prpp3[1] - prop_prong_h + $prp_r5 ];
1016   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1017          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1018   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1019   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1020
1021   children();
1022 }
1023
1024 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
1025   PropProfileAssignments(gamma){
1026
1027     //#circleat($prpp3,1);
1028     //#circleat($prpp12,1);
1029
1030     if (!cut) {
1031       hull(){
1032         translate($prpp8)
1033           intersection(){
1034             circle($prp_r8);
1035             polygon([[-20,-0], [20,20], [0,0]]);
1036           }
1037         rectfromto($prpp6, $prpp9);
1038         translate($prpp5) intersection(){
1039           circle($prp_r5);
1040           polygon([[-10,-10], [0,0], [10,0]]);
1041         }
1042         rectfromto($prpp12 + [0,-0.1], $prpp3);
1043       }
1044       hull(){
1045         circleat($prpp1, $prp_r1);
1046         rectfromto($prpp12 + [0,-0.1], $prpp3);
1047       }
1048     }
1049     // main shaft
1050     rotate([0,0, rot*-$prp_theta]){
1051       hull(){
1052         extra = cut ? prop_recess_slop : 0;
1053         rectfromto($prpp6, $prpp9);
1054         circleat($prpp11, $prp_r11 + extra);
1055         circleat($prpp10, $prp_r10 + extra);
1056       }
1057     }
1058   }
1059 }
1060
1061 module PropAggregateProfile(){
1062   for (angle = prop_angles)
1063     PropProfile(angle, 0,0);
1064 }
1065
1066 module Prop(){ ////toplevel
1067   hw = prop_main_width/2;
1068   linextr(-hw, +hw)
1069     PropAggregateProfile();
1070 }
1071
1072 module Case(){ ////toplevel
1073   difference(){
1074     union(){
1075       CaseBase();
1076
1077       // ledge (fixed keeper)
1078       Flip_rhs(1-keeper_side) intersection(){
1079         rotate([90, 0, 0])
1080           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1081           KeeperProfile(1);
1082
1083         // outline of the whole case, to stop it protruding
1084         translate([0,0, -25])
1085           linear_extrude(height = 50)
1086           hull()
1087           Flip_bot()
1088           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1089       }
1090
1091       // hinge
1092       HingePortion(hex20, hex21) HingeBaseProfile();
1093
1094       // buildout for prop recess
1095       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1096         linextr(case_bottom_z, epp2i[1])
1097         hull() {
1098           for (dxs = [-1,+1])
1099             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1100                        -epp2o[0] ],
1101                      r = epp2o[0] - prcp2[0]);
1102         }
1103     }
1104
1105     // slot for keeper
1106     Flip_rhs(keeper_side)
1107       translate([0, -phone_cnr_rad, 0])
1108       rotate([90, 0, 0])
1109       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1110       minkowski(){
1111         KeeperProfile();
1112         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1113                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1114       }
1115
1116     // front camera
1117     RearCameraAperture();
1118
1119     // struts (invisible, because they're buried in the case)
1120     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1121
1122     Buttons(){
1123       mirror([1,0,0])
1124         rotate([90,0,90]) {
1125           if (!($button_leg_only && enable_support))
1126           intersection(){
1127             translate([0,0,-10])
1128               linear_extrude(height= 20)
1129               ButtonPlan($button_l, 0,1);
1130             if ($button_leg_only)
1131               rotate([-90,90,0])
1132                 translate([phone_width/2, -400, kppe[1]])
1133                 mirror([1-abs($rhsflip - keeper_side),0,0])
1134                 cube([400, 800, 50]);
1135             if (enable_support && !$button_suppress_over_keeper)
1136               rotate([-90,90,0])
1137               translate([-400, -400, kppd[1]])
1138                 mirror([0,0,1])
1139                 cube([800,800,100]);
1140           }
1141           translate([0,0, -bppR[0]])
1142             linear_extrude(height= 20)
1143             ButtonPlan($button_l, 1,1);
1144         }
1145
1146     }
1147
1148     // apertures along top edge
1149     CaseAperture(jack_pos, jack_dia, 8);
1150     Flip_rhs(1)
1151       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1152
1153     OrdinaryRearApertures();
1154
1155     MicroUSB();
1156
1157     // gaps for the lid's hinge arms
1158     HingePortion(hex20 - hinge_x_arms_gap,
1159                  hex21 + hinge_x_arms_gap)
1160       minkowski(){
1161         HingeLidProfile();
1162         circle(r= hinge_r_arms_gap, $fn= 8);
1163       }
1164
1165     // screw holes in the hinge arms
1166     HingeScrews();
1167
1168     // catch striker
1169     CatchPortion(catch_side_gap*2, epp4[1])
1170       CatchCutProfile();
1171
1172     // prop recess
1173     Flip_rhs(1)
1174       translate([prop_x_pos,0,0])
1175       mirror([0,1,0])
1176       rotate([90,0,90])
1177       linextr(-prop_recess_hw, +prop_recess_hw)
1178       hull(){
1179         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1180           circleat(prcp1 + 20*d,
1181                    prc_r3);
1182       }
1183   }
1184 }
1185
1186 module LidAdhocMultiprintFrame(phase){
1187   if (led_window_style >= 3) {
1188     AdhocMultiprintFrame(phase, lpp13[1], -1);
1189   }
1190 }
1191
1192 module LidAroundEdges(){
1193   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1194     children();
1195 }
1196
1197 module Lid(){ ////toplevel
1198   skew_centre = [0, lpp11[0], lpp11[1]];
1199   difference(){
1200     union(){
1201       intersection(){
1202         LidAroundEdges()
1203           LidEdgeProfile();
1204
1205         translate(skew_centre)
1206           multmatrix([[ 1, 0, 0, 0 ],
1207                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1208                       [ 0, 0, 1, 0 ],
1209                       [ 0, 0, 0, 1 ]])
1210           translate(-skew_centre)
1211           LidAroundEdges()
1212           LidEdgeFoldClearanceProfile();
1213       }
1214
1215       // button covers
1216       Buttons(){
1217         intersection(){
1218           rotate([90,0,90])
1219             translate([0,0,-10])
1220             linear_extrude(height= 20)
1221             ButtonPlan($button_l, 1,0);
1222           rotate([90,0,0])
1223              translate([0,0,-100])
1224             linear_extrude(height= 200)
1225             ButtonCoverProfile();
1226         }
1227       }
1228
1229       // hinge arms
1230       HingePortion(hex20, hex21) {
1231         LidEdgeProfile();
1232         HingeLidProfile();
1233       }
1234
1235       // catch
1236       CatchPortion(0, lpp12[1])
1237         CatchCatchProfile();
1238     }
1239     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1240
1241     // screw holes in the hinge arms
1242     HingeScrews();
1243
1244     // prop recess
1245     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1246       mirror([0,1,0])
1247       rotate([90,0,90])
1248       linextr(-prop_recess_hw, +prop_recess_hw)
1249       hull()
1250       for (pa = prop_angles)
1251         PropProfile(pa, 1,1);
1252
1253     // notification led aperture
1254     if (led_window_style)
1255       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1256         translate([0,0,-10])
1257           cylinder(r=nla_r0, h=20);
1258         if (led_window_style >= 2)
1259           translate([0,0, -nla_t])
1260             cylinder(r=nla_r2, height=20);
1261       }
1262
1263     }
1264
1265   LidAdhocMultiprintFrame(1);
1266 }
1267
1268 module HingeLever(){ ////toplevel
1269   difference() {
1270     // outer body, positive
1271     HingePortion(hex22, hex22 + phone_width/2)
1272       HingeLeverOuterProfile();
1273
1274     // space for the screws
1275     HingePortion(hex26, hex24)
1276       HingeLeverInnerProfile();
1277
1278     // recesses for the nuts
1279     HingePortion(hex23, hex26+1)
1280       HingeLeverNutProfile();
1281
1282     // bores for the screws
1283     HingeScrews();
1284
1285     // space for the charging cable
1286     MicroUSB();
1287     Flip_hinge() MicroUSB();
1288   }
1289 }
1290
1291 module LidWindow(){ ////toplevel
1292   translate([led_pos[0], -led_pos[1], lpp13[1]])
1293     mirror([0,0,1])
1294     cylinder(r= nla_r1, h=nla_t);
1295   LidAdhocMultiprintFrame(0);
1296 }
1297
1298 module LidWindowPrint(){ ////toplevel
1299   rotate([0,180,0])
1300     LidWindow();
1301 }
1302
1303 module DemoLidWindowSelect(){
1304   translate([led_pos[0], led_pos[1], -100]) {
1305     translate([0, -30, 0]) cube([400, 400, 200]);
1306   }
1307 }
1308
1309 module DemoLidWindow(){ ////toplevel
1310   %Lid();
1311   LidWindow();
1312   translate([0,40,0]){
1313     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1314     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1315   }
1316 }
1317
1318 module HingeLeverPrint(){ ////toplevel
1319   rotate([-90,0,0])
1320     translate([-phone_width/2, phone_height, 0])
1321     HingeLever();
1322 }
1323
1324 module TestSelectLength(){
1325   translate([-30, -200, -20])
1326     cube([30 + 15, 250, 40]);
1327 }
1328
1329 module TestLength(){ ////toplevel
1330   intersection(){
1331     Case();
1332     TestSelectLength();
1333   }
1334 }
1335
1336 module TestLengthRight(){ ////toplevel
1337   intersection(){
1338     Case();
1339     Flip_rhs(1)
1340       TestSelectLength();
1341   }
1342 }
1343
1344 module TestSelectWidth(){
1345   translate([-30, -(phone_height - 25), -20])
1346     mirror([0, 1, 0])
1347     cube([200, 50, 40]);
1348 }
1349
1350 module TestWidth(){ ////toplevel
1351   intersection(){
1352     Case();
1353     TestSelectWidth();
1354   }
1355 }
1356
1357 module TestLidWidthPrint(){ ////toplevel
1358   rotate([0,180.0]) intersection(){
1359     Lid();
1360     TestSelectWidth();
1361   }
1362 }
1363
1364 module TestSelectRearAperture(){
1365   minkowski(){
1366     union() children();
1367     translate([20, 0,0])
1368       cube([42, 2, 1], center=true);
1369   }
1370 }
1371
1372 module TestSelectCamera(){
1373   minkowski(){
1374     TestSelectRearAperture()
1375       RearCameraAperture();
1376     cube([0.1, 50, 0.1]);
1377   }
1378 }
1379
1380 module TestSelectOrdinaryRearApertures(){
1381   TestSelectRearAperture()
1382     OrdinaryRearApertures();
1383 }
1384
1385 module TestCamera(){ ////toplevel
1386   intersection(){
1387     Case();
1388     TestSelectCamera();
1389   }
1390 }
1391
1392 module TestLidByCamera(){ ////toplevel
1393   intersection(){
1394     Lid();
1395     TestSelectCamera();
1396   }
1397 }
1398
1399 module TestLidByCameraPrint(){ ////toplevel
1400   rotate([180,0,0]) TestLidByCamera();
1401 }
1402
1403 module DemoByCamera(){ ////toplevel
1404   color("blue") TestLidByCamera();
1405   color("red")  TestCamera();
1406 }
1407
1408 module OneKeeper(){ ////toplevel
1409   translate([0, -phone_cnr_rad, 0])
1410     rotate([90, 0, 0])
1411     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1412     KeeperProfile();
1413 }
1414
1415 module OneKeeperPrint(){ ////toplevel
1416   rotate([0,180,0])
1417     OneKeeper();
1418 }
1419
1420 module LidPrint(){ ////toplevel
1421   rotate([0,180,0])
1422     Lid();
1423 }
1424
1425 module TestSelectFrame(){
1426   include = [1,-1] * (epp2i[0] + 4);
1427
1428   difference(){
1429     cube(1000, center=true);
1430     translate([0,0, -100])
1431       linear_extrude(height=200)
1432       rectfromto(include,  inside_br - include);
1433   }
1434 }
1435
1436 module TestSelectLidFrame(){
1437   TestSelectFrame();
1438   translate([led_pos[0], -led_pos[1], -50])
1439     cylinder(r= nla_r2+3, h=100);
1440 }
1441
1442 module TestFrameCase(){ ////toplevel
1443   intersection(){
1444     Case();
1445     union(){
1446       TestSelectFrame();
1447       TestSelectCamera();
1448       TestSelectOrdinaryRearApertures();
1449     }
1450   }
1451 }
1452
1453 module TestSelectTopApertures(){
1454   translate([-100, -35, -100])
1455     cube([400, 100, 200]);
1456   LidAdhocMultiprintFrame(0);
1457   LidAdhocMultiprintFrame(1);
1458 }
1459
1460 module TestTopApertures(){ ////toplevel
1461   intersection(){
1462     Case();
1463     TestSelectFrame();
1464     TestSelectTopApertures();
1465   }
1466 }
1467
1468 module TestLidTopAperturesPrint(){ ////toplevel
1469   rotate([0,180,0]) intersection(){
1470     Lid();
1471     TestSelectLidFrame();
1472     TestSelectTopApertures();
1473   }
1474 }
1475
1476 module TestLidWindowTopAperturesPrint(){ ////toplevel
1477   rotate([0,180,0]) intersection(){
1478     LidWindow();
1479     TestSelectTopApertures();
1480   }
1481 }
1482
1483 module TestFrameLidPrint(){ ////toplevel
1484   rotate([0,180,0]) intersection(){
1485     Lid();
1486     TestSelectLidFrame();
1487   }
1488 }
1489
1490 module ButtonPlanForDemo(z, deep, cut){
1491   translate([0,0,z])
1492     ButtonPlan(8, deep, cut);
1493 }
1494
1495 module HingeScrews(){
1496   Flip_rhs() Flip_bot(1){
1497     for (c= [ hppT, hppB ])
1498       translate([ hex20,
1499                   -c[0],
1500                   c[1] ]){
1501         rotate([0,90,0])
1502           translate([0,0,-.2])
1503           cylinder( r= hingescrew_shaft_dia/2,
1504                     h = hingescrew_shaft_len+0.2 );
1505         rotate([0,-90,0])
1506           translate([0,0,+.1])
1507           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1508       }
1509   }
1510 }
1511
1512 module DemoPropAngleSelect(c){
1513   color(c) difference(){
1514     union(){ children(); }
1515     translate([ prop_x_pos, -400, -200 ])
1516       cube([ 400,800,400 ]);
1517   }
1518 }
1519
1520 module DemoPropAngle(ang){
1521   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1522   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1523
1524   translate(hL)
1525     rotate([ang/2,0,0])
1526     translate(-hL)
1527     translate(hC)
1528     rotate([ang/2,0,0])
1529     translate(-hC) {
1530       DemoPropAngleSelect("red") Case();
1531
1532       color("orange")
1533         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1534         PropProfileAssignments(ang) {
1535           echo($prpp1);
1536           rotate([-$prp_theta, 0, 0])
1537           translate([0, $prpp1[0], -$prpp1[1]])
1538           rotate([90,0,-90])
1539           Prop();
1540         }
1541     }
1542
1543   translate([0,0, -hp_k*2])
1544     DemoPropAngleSelect("blue")
1545     Lid();
1546 }
1547
1548 module DemoPropAngles(){ ////toplevel
1549   for (i=[0 : len(prop_angles)-1])
1550     translate(i * [0, -100, 100])
1551     DemoPropAngle(prop_angles[i]);
1552 }
1553
1554 module DemoHingeAngle(ang1,ang2){
1555   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1556   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1557
1558   translate(hL)
1559     rotate([ang2,0,0])
1560     translate(-hL)
1561     translate(hC)
1562     rotate([ang1,0,0])
1563     translate(-hC) {
1564       color("red") Lid();
1565     }
1566
1567   color("blue") intersection(){
1568     Case();
1569     union(){
1570       translate([bppJ[0], -400, -200])
1571         mirror([1,0,0])
1572         cube([400, 800, 400]);
1573       translate([10, -400, -200])
1574         cube([10, 800, 400]);
1575     }
1576   }
1577 }
1578
1579 module DemoHingeAngles(){ ////toplevel
1580   angles = [ 0, 4, 8, 12 ];
1581   echo("angles",angles);
1582   for (i=[0 : len(angles)-1]) {
1583     translate(i * [0, 0, 30]) {
1584       DemoHingeAngle(0,angles[i]);
1585       translate([0, 200, 0])
1586         DemoHingeAngle(angles[i],0);
1587     }
1588   }
1589 }
1590
1591 module DemoSelectAdhocLeftRight(right=0) {
1592   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1593     mirror([1-right, 0,0])
1594     cube([400, 800, 200]);
1595 }
1596
1597 module DemoLeft(){ ////toplevel
1598   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1599   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1600 }
1601
1602 module DemoFrame(){ ////toplevel
1603   color("red") TestFrameCase();
1604   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1605   color("black") HingeScrews();
1606   %HingeLever();
1607 }
1608
1609 module DemoLanyardCutout(){ ////toplevel
1610   LanyardCutout(25);
1611 }
1612
1613 module DemoHingedFrame(){ ///toplevel
1614   color("red") TestFrameCase();
1615   translate([0,0, -2*hp_k])
1616   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1617
1618   Flip_hinge(){
1619     color("orange") HingeLever();
1620     color("black") HingeScrews();
1621   }
1622 }
1623
1624 module DemoHinge(){ ////toplevel
1625   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1626     DemoFrame();
1627     translate([0,0, -hp_k*3])
1628       DemoHingedFrame();
1629   }
1630 }
1631
1632 module DemoProfiles(){ ////toplevel
1633   LidEdgeProfile();
1634   %EdgeProfile();
1635   KeeperProfile();
1636   translate([0,0,-1]) color("black") KeeperProfile(1);
1637   color("purple") translate(epp2i)
1638     rotate(atan2vector(epp2i - epp1)) {
1639     translate(lanyard_half_dia * 0.5 * [-3,-1])
1640       LanyardLanyardProfile();
1641     translate(lanyard_half_dia * 0.5 * [-3,+1])
1642       translate([0,-1] * case_th_side)
1643       LanyardLanyardProfile(true);
1644   }
1645
1646   translate([0,20]) {
1647     LanyardMainChannelProfile();
1648     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1649     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1650   }
1651
1652   translate([20,0]) {
1653     LidEdgeProfile();
1654     %EdgeProfile();
1655
1656     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1657
1658     color("blue") ButtonCoverProfile();
1659     color("red") {
1660       rectfromto(bppQ, demopoint_QR);
1661       rectfromto(bppR, demopoint_QR);
1662     }
1663   }
1664
1665   translate([-20,0]) {
1666     color("black") ButtonPlanForDemo(-2, 0,1);
1667     color("red" )  ButtonPlanForDemo(-4, 1,1);
1668     color("blue")  ButtonPlanForDemo(-6, 1,0);
1669   }
1670
1671   translate([0, -30]) {
1672     %LidEdgeProfile();
1673     %EdgeProfile();
1674     color("blue") HingeLidProfile();
1675     color("red")  HingeBaseProfile();
1676     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1677   }
1678
1679   for (f=[0,1]) {
1680     translate([-30, -60 + 30*f]) {
1681       translate([0,0,-4]) EdgeProfile();
1682       %translate([0,0,-10]) HingeBaseProfile();
1683       translate([0,-2] * f * hp_k) {
1684         translate([0,0,-4]) LidEdgeProfile();
1685         %translate([0,0,-10]) %HingeLidProfile();
1686       }
1687       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1688         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1689         translate([0,0,0]) color("red") difference(){
1690           HingeLeverOuterProfile();
1691           HingeLeverInnerProfile();
1692         }
1693         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1694       }
1695     }
1696   }
1697
1698   translate([20,-30]) {
1699     %EdgeProfile();
1700     %LidEdgeProfile();
1701     //translate([0,0,1]) CatchCutProfile();
1702     color("blue") CatchCatchProfile();
1703     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1704   }
1705
1706   translate([40,-30]) {
1707     difference(){
1708       LidEdgeProfile();
1709       translate(prlp10)
1710         PropProfile(10, 1, 0);
1711     }
1712     translate(prlp10)
1713       PropProfile(15, 0);
1714   }
1715   translate([60,-30]) {
1716     PropAggregateProfile();
1717   }
1718 }
1719
1720 //EdgeProfile();
1721 //KeeperProfile();
1722 //CaseBase();
1723 //%Case();
1724 //Keeper();
1725 //LidEdgeProfile();
1726 //KeeperProfile();
1727 //DemoProfiles();
1728 //PropRecess();