chiark / gitweb /
fairphone-case: wip lanyard, wip cutout
[reprap-play.git] / fairphone-case.scad
1 // -*- C -*-
2
3 // Hard case for Fairphone 2
4 //
5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
6 //  See below for full licensing and disclaimer.
7 //
8 // Instructions
9 //
10 //  1. You will want to git clone this repository.
11 //
12 //  2. Decide about the notification LED aperture. See the variable
13 //     led_window_style, below.  The default here is "ad-hoc
14 //     multi-colour", which can produces a translucent (clear-ish)
15 //     window set into the lid, even on a single-nozzle printer.
16 //     See "Ad-hoc multi-colour", below.
17 //
18 //  3. use "make" to generate the necessary files:
19 //
20 //     make -j8 fairphone-case.auto.scads `for f in   \
21 //        HingePrint        \
22 //        LidWindowPrint    \
23 //        LidPrint          \
24 //        OneKeeperPrint    \
25 //        Case              \
26 //     ; do echo fairphone-case,$f.auto.stl; done`
27 //
28 //  4. Print them.  Case and OneKeeperPrint should probably be
29 //     the same colour.
30 //
31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
32 //     multi-colour:
33 //        i.   Set up for clear filament
34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
35 //             It won't take long.  As soon as it finishes, tell
36 //             your printer to warm up (so that in fact it does
37 //             not cool down).
38 //        iii. Leaving the output so far on the printbed, reload
39 //             your printer with the main lid colour.
40 //        iv.  Print LidPrint.  You can let this go unattended.
41 //
42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
43 //     and 8x M2 full nuts.
44 //
45 //     Make sure you get the hinge the right way round.  If you're not
46 //     sure, run
47 //         openscad fairphone-case,DemoHinge.auto.scad
48 //     to see an assembly diagram.
49 //
50 //     The nuts recess into the hinge.  You will want very fine
51 //     pliers.  As you screw each screw in, add the second nut when
52 //     the screw thread emerges from the first - this will be a
53 //     locknut.  Screw each screw to an appropriate tightness for the
54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
55 //     that makes closing the case work better.
56 //
57 //     When you have the stiffness right, tighten the locknuts onto
58 //     each first nut.
59 //
60 //  6. In use:
61 // 
62 //      - To put the phone in, drop its RH side into the RH side of
63 //        the case.  Then feed the keeper through the small hole.
64 //        Feed it right through.
65 //
66 //      - The optional prop can be used to prop the phone up (in
67 //        portrait orientation only right now).  See
68 //            openscad fairphone-case,DemoPropAngles.auto.scad
69 //
70 // Ad-hoc multi-colour
71 //     
72 //  This file is set up to let you make a translucent window using a
73 //  single-extruder printer, using a "two print run" technique.  This
74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
75 //  Cura.  If you are using a different printer, you may need to
76 //  adjust the parameters or try a different technique.  In particular,
77 //      initial_layer_thick
78 //         set so that the window is one layer thick
79 //      initial_layer_width
80 //         set so that the slicer draws a rectangle around the whole
81 //         object, rather than putting a "skirt" or anything inside
82 //
83 //  If you have a dual-extruder printer, you can set led_window_style
84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
85 //
86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
87 //
88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
90 //
91 // Other phones
92 //
93 //  It might well be possible to adapt this file for other phones.
94 //  If you do, let me know how you get on.
95 //
96 //
97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
98 //
99 //   Copyright (C)2018 Ian Jackson.
100 //
101 //    This program for generating a 3D model is free software: you can
102 //    redistribute it and/or modify it under the terms of the GNU
103 //    General Public License as published by the Free Software
104 //    Foundation, either version 3 of the License, or (at your option)
105 //    any later version.
106 //
107 //    This program is distributed in the hope that it will be useful,
108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
110 //    GNU General Public License for more details.
111 //
112 //    You should have received a copy of the GNU General Public
113 //    License along with this program.  If not, see
114 //    <http://www.gnu.org/licenses/>.
115 //
116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
118 //  this case will meet your needs.
119
120 include <utils.scad>
121 include <funcs.scad>
122
123 phone = [ 75.0, 145.0 ];
124
125 prop_buildout_less = 3;
126
127 prop_angles = [ 15, 30, 45, 60 ];
128
129 bumper = [ 0.250, -0.025 ];
130 // ^ One side.  Overall size is increased by twice this.
131 // If no bumpers, is the gap around the phone.
132
133 enable_support = 1;
134
135 led_window_style = 3;
136 // 0: no window
137 // 1: simply an opening
138 // 2: opening with separate cover model, for printing in clear (two colour)
139 // 3: like 2 but one-layer window for ad-hoc multi-colour
140
141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
142 initial_layer_width = 0.750; // ^ needed for mode 3 only
143 multicolour_gap = 0.15; // each side
144
145 phone_cnr_rad = 6.0;
146 phone_rim_depth = 0.80; // includes allowance for a screen protector
147
148 button_cutout_depth = 9;
149
150 phone_edge_thick = 9.0;
151 phone_total_thick = 12.0;
152 phone_backside_slope_inner = 1.5; // larger means shallower
153 phone_backside_slope_outer = 1.0; // larger means shallower
154
155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
157
158 jack_pos = [ 13.83, 8.485 ];
159 jack_dia = 10.64 + .5; // some jack I had lying around
160
161 led_pos = [ 13.98, 10.00 ];
162 led_aperture = 9;
163 led_window_ledge = 0.75; // each side
164
165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
166 noisecancelmic_dia = 4.00;
167
168 //fingerpushhole_dias = [ 15, 18 ];
169 fingerpushhole_dias = [];
170
171 lanyard_half_dia = 1.15;
172
173 rearspeaker_pos_bl = [ 12.64, 18.72 ];
174 rearspeaker_size   = [  3.76,  7.36 ];
175
176 microusb_above = 3.27 - 0.25;
177 microusb_below = 0.0;
178 microusb_width = 16.12 + 1.25;
179
180 case_th_bottom = 2.5;
181 case_th_lid = 3.0;
182 case_th_side = 2.3;
183 case_th_lip = 1.2;
184
185 lid_screen_gap_extra = .66;
186
187 case_struts_count = 6;
188 case_struts_solid_below = 1.00;
189 case_struts_solid_above = 0.75;
190 case_struts_width = 0.10;
191
192 keeper_th_z = 0.75;
193 keeper_th_x = 0.75;
194 keeper_inner_width = 2.75;
195 keeper_inner_height = 2.75;
196 keeper_slant_slope = 2; // larger means steeper
197
198 keeper_gap_z_top = 0.25;
199 keeper_gap_z_bot = 0.75;
200 keeper_gap_x     = 0.25;
201 keeper_gap_x_holes = 0.75;
202
203 keeper_side = 0; // 0 = lhs; 1 = rhs
204
205 case_lip = 1.25;
206
207 lid_gap_x = 0.25;
208 lid_gap_z = 0.25;
209 lid_lip = 1.75;
210 lid_edgepart_width = 5.0;
211 lid_buttoncover_thick = 1.3;
212
213 catch_slop = 0.50;
214
215 foldover_gap = 0.50;
216 foldover_lever_gap = 0.50;
217
218 // properties of the hinge fasteners
219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
220 hingescrew_shaft_len = 12;
221 hingescrew_fasteners_extra_thick = 0.40;
222 // ^ amount of thread protruding if everything was completely nominal
223 //   and we are using two nuts
224 hingescrew_nut_access_dia = 4.72 + 0.50;
225 // ^ washer is 4.72 dia
226 //   also, want to get pliers or tiny spanner in to do up locknut
227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
228 hingescrew_nut_thick = 1.93;
229 hingescrew_head_th = 1.38 + 0.75;
230 hingescrew_head_dia = 3.92;
231
232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
233
234 lever_cover_th = 0.75;
235 hingemount_th = 2.5;
236 hingemount_wd = 4.8725;
237
238 $fa = 5;
239 $fs = 0.1;
240
241 button_l_fudge = 4.4;
242 buttonishleg_default_l_is_fudge = 10;
243
244 hinge_base_slope = 1.5; // bigger is steeper
245
246 strut_min_at_end = 1.5;
247
248 hinge_x_gap = 0.125;
249 hinge_x_postscrew_gap = 0.75;
250 hinge_x_arms_gap = 0.35;
251 hinge_r_arms_gap = 0.55;
252
253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
254
255 catch_len = 7.5;
256 catch_width = 15;
257 catch_thickness = 1.0;
258 catch_side_gap = 0.75; // each side
259
260 catch_depth = 0.75;
261 catch_height = 0.35;
262 catch_finger_height = 1.5;
263 catch_finger_depth = 2.5;
264
265 catch_topcurve_r = 5.0;
266
267 prop_recess_under = 0.50;
268 prop_recess_slop = 0.200; // each side
269 prop_end_dia = 0.5;
270 prop_main_th = 3;
271 prop_taper_len = 6;
272 prop_main_width = 4;
273 prop_side_gap = 0.75; // each side
274 prop_lidrecess_behind = 0.75;
275 prop_caserecess_behind = 0.75;
276 prop_caserecess_taper = 0.45; // one side only
277 prop_prop_gap = 0.5;
278 prop_prong_heel_slope = 0.5;
279
280 lid_fold_clearance_antislop = 0.5;
281
282 // ---------- calculated ----------
283
284 phone_width =  (phone + bumper*2)[0];
285 phone_height = (phone + bumper*2)[1];
286
287 inside_br = [phone_width, -phone_height];
288
289 prop_prong_h = prop_main_th;
290
291 //echo(camera_pos_tl + bumper,
292 //     camera_pos_br + bumper);
293
294 // ----- could be changed -----
295 lid_buttoncover_gap = lid_gap_x;
296 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
297
298 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
299
300 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
301
302 //prop_nose_len = case_th_lid - prop_recess_under;
303 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
304 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
305
306
307 //lid_lip_overlap_width xxx bad name = ;
308 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
309
310 epp0 = [0,0];
311 epp1 = [0, -phone_edge_thick];
312 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
313 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
314 epp3 = epp2i + [10, 0];
315 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
316 epp4 = epp5 + [-1,0] * case_th_side;
317
318 kppe = [0,0];
319 kppd = kppe + [1,0] * keeper_inner_width;
320 kppc = kppd + [0,1] * keeper_th_z;
321 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
322 kppf = kppe - [0,1] * keeper_inner_height;
323 kppa = [ kppb[0], kppf[1] ];
324
325 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
326 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
327
328 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
329 // exact x posn not very important; must extend past end of keeper
330
331 lpp15 = [ lpp14[0],
332           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
333           + lid_screen_gap_extra ];
334 // ^ beam theory says to maximise force before contact,
335 //   the gap below the `beam' (the lid) must be 1/3
336 //   the thickness (ie the lid thickness) if the beam
337 //   is solid, or 1/2 if it has a top and bottom only.
338 //   ours is mostly solid.
339
340 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
341              case_th_lip);
342
343 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
344 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
345
346 case_bottom_z = epp2o[1] - case_th_bottom;
347
348 // button profile
349 bppM = epp4 + [0,5];
350 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
351 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
352 bppS = [ epp1[0], bppR[1] ];
353 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
354 bppP = bppQ + [0,1] * lid_buttoncover_gap;
355 bppO = [ bppN[0], bppP[1] ];
356 bppL = lpp10 + [5,0];
357 bppK = [ bppL[0], bppN[1] ];
358 bppJ = [ bppN[0], bppL[1] ];
359 bppU = [ bppJ[0], lpp12[1] ];
360 bppV = lpp11;
361 bppW = lpp10;
362
363 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
364
365 // notification led aperture
366
367 nla_r0 = led_aperture/2;
368 nla_r1 = nla_r0 + led_window_ledge;
369 nla_r2 = nla_r1 + multicolour_gap;
370 nla_t =
371   led_window_style >= 3 ? initial_layer_thick :
372   led_window_style >= 2 ? led_window_ledge : 0;
373
374
375 // hinge plan
376 hp_rn = hingescrew_nut_access_dia/2;
377 hp_r2_min = hp_rn + lever_cover_th;
378 hp_rs = hingescrew_shaft_dia/2;
379 hp_r1_min = hp_rs + hingemount_th;
380
381 hp_r1 = max(hp_r1_min, hp_r2_min);
382 hp_r2 = hp_r1;
383
384 hppU = lpp13;
385 hppS = epp2o + [0,-1] * case_th_bottom;
386 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
387
388 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
389          0.5 * (hppU + hppS)[1] ];
390 hppT = [ hppM[0], hppU[1] - hp_r1 ];
391 hppB = hppT + [0,-1] * hp_k;
392
393 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
394 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
395 hppE = [ hppE_x, hppE_y ];
396
397 // hinge elevation x coords
398
399 hex20 = max(epp2o[0],
400             phone_cnr_rad,
401             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
402 hex21 = hex20 + hingemount_wd;
403 hex22 = hex21 + hinge_x_gap;
404 hex27 = hex20 + hingescrew_shaft_len;
405 hex24 = hex27 + hinge_x_postscrew_gap;
406 hex23 = hex27 - (hingescrew_nut_thick*2
407                  + hingescrew_fasteners_extra_thick);
408 hex26 = hex23 + hingescrew_nut_thick * 2/3;
409
410 echo(hex20, hex21, hex22, hex23, hex24);
411 //  6, 10.8725, 10.9975, 13.74, 18.75
412 module chk(act,exp) {
413   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
414   else echo("ok", act);
415 }
416 chk(hex20, 6);
417 chk(hex21, 10.8725);
418 chk(hex22, 10.9975);
419 chk(hex23, 13.74);
420 chk(hex24, 18.75);
421
422 lid_fold_clearance_skew =
423   (lpp10[1] - hppB[1]) /
424   (lpp10[0] - hppB[0]);
425
426 echo("SK",lid_fold_clearance_skew);
427
428 // catch
429
430 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
431 cppA = cppJ + [lid_gap_x, -lid_gap_z];
432 cppB = [ epp0[0], cppA[1] ];
433 cppP = [ epp4[0], cppJ[1] ];
434
435 cppS = cppJ + [0,-1] * catch_len;
436 cppD = [ cppA[0], cppS[1] + catch_slop ];
437 cppC = [ cppB[0], cppD[1] ];
438 cppT = cppS + [1,0] * catch_depth;
439 cppU = cppT + [0,-1] * catch_height;
440 cppV = [ cppS[0], cppU[1] - catch_depth ];
441
442 cppR = 0.5*(cppP + cppJ);
443
444 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
445 cppQ = [ cppR[0],
446          cppV[1] - (catch_finger_height - cp_rQ) ];
447 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
448
449 // lanyard
450
451 ly_r = lanyard_half_dia / 2;
452 ly_rc = ly_r * 2;
453
454 // prop recess in case
455
456 prop_x_pos = phone_width/2;
457
458 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
459
460 prc_r1 = prop_end_dia/2;
461 prc_r3 = prc_r1 + prop_recess_slop;
462
463 prcp2 = [ epp4[0] + prop_buildout_less,
464           case_bottom_z ];
465
466 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
467
468 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
469           epp2i[1] - prc_r3 - prop_recess_under];
470
471 // prop recess in lid
472
473 prl_r10 = prop_end_dia/2;
474 prl_r10o = prl_r10 + prop_recess_slop;
475
476 prlp10 = lpp10 + [1,1] * prl_r10o
477   + [1,0] * prop_lidrecess_behind
478   + [0,1] * prop_recess_under;
479
480 // prop
481
482 $prpp10 = [0,0];
483 $prpp11 = [0, prop_taper_len];
484
485 $prp_r10 = prl_r10;
486
487 // ---------- modules ----------
488
489 module AdhocMultiprintFrame(phase, z0, zs) {
490   // from z0 to z0 + zs*layer
491   extra = phase * (initial_layer_width + multicolour_gap) + 5;
492   xextra = extra + -epp4[0];
493   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
494   yextra = extra + -epp4[0];
495   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
496   p0 = [ xrange[0], yrange[0] ];
497   p1 = [ xrange[1], yrange[1] ];
498   echo(p0, p1);
499   translate([0,0, z0])
500     mirror([0,0, zs<0 ? 1 : 0])
501     linear_extrude(height= initial_layer_thick)
502     difference(){
503       rectfromto(p0 - [1,1] * initial_layer_width,
504                  p1 + [1,1] * initial_layer_width);
505       rectfromto(p0, p1);
506     }
507 }
508
509 module KeeperProfile(slant=0){
510   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
511   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
512 }
513
514 module EdgeProfile(){
515   difference(){
516     hull(){
517       translate(epp3) square(case_th_bottom*2, center=true);
518       circleat(epp2o, r=case_th_bottom);
519       circleat(epp1, r=case_th_side);
520       rectfromto(epp0, epp4);
521     }
522     polygon([ epp5 + [0,10],
523               epp1,
524               epp2i,
525               epp3 + [10,0] ]);
526   }
527 }
528
529 module LanyardLanyardProfile(entry=false){
530   hull(){
531     for (xs=[-1,+1] * (entry ? 2 : 1))
532       translate(xs * 0.5 * lanyard_half_dia * [1,0])
533         circle(r= lanyard_half_dia/2);
534   }
535 }
536
537 module LanyardCurveChannelProfile(){
538   translate([0, -ly_r])
539     LanyardLanyardProfile();
540 }  
541
542 module LanyardEntryChannelProfile(){
543   LanyardLanyardProfile(true);
544 }  
545
546 module LanyardMainChannelProfile(){
547   LanyardCurveChannelProfile();
548   difference(){
549     square(center=true, ly_r * [6, 2]);
550     for (xs=[-1,+1])
551       translate(ly_r * [3 * xs, -1])
552         circle(r = ly_r);
553   }
554 }
555
556 module LanyardEntry(){
557   q_z = -(ly_rc + ly_r);
558   d_x = -ly_rc;
559
560   translate([d_x, 0, q_z]) {
561     intersection(){
562       rotate([90,0,0])
563         rotate_extrude(convexity=10)
564         rotate(90)
565         translate([0, -q_z])
566         LanyardCurveChannelProfile();
567       translate([0,-10,0])
568         cube([20,20,20]);
569     }
570   }
571
572   mirror([0,0,1])
573     translate([0,0,-1])
574     linear_extrude(height=20)
575     rotate(-90)
576     LanyardEntryChannelProfile();
577 }
578
579 module LanyardCutout(l){
580   rotate([0,-90,0])
581     linear_extrude(height=l)
582     rotate(-90)
583     LanyardMainChannelProfile();
584
585   for (ee=[0,1]){
586     translate(ee * l * [-1,0])
587       mirror([ee,0,0])
588       LanyardEntry();
589   }
590 }
591
592 module LidEdgeProfile(){
593   polygon([ lpp10,
594             lpp11,
595             lpp12,
596             lpp13,
597             lpp13 + [10, 0],
598             lpp15 + [10, 0],
599             lpp15,
600             lpp14,
601             ]);
602   intersection(){
603     circleat(lpp12, r=lp_r12);
604     rectfromto( lpp12 + [-10,   0],
605                 lpp12 + [+10, +10] );
606   }
607 }
608
609 module LidEdgeFoldClearanceProfile(){
610   translate([-lid_fold_clearance_antislop, 0])
611     polygon([ lpp10,
612               lpp11,
613               lpp11 + [-20,  0],
614               lpp11 + [-20, 20],
615               lpp11 + [+20, 20],
616               lpp10 + [+20,  0] ]);
617 }
618
619 module ButtonCoverProfile(){
620   intersection(){
621     polygon(concat([ bppM, bppP, bppO, bppJ ],
622                    (enable_support && !$button_suppress_over_keeper
623                     ? [ bppU, bppV, bppW ] : []),
624                    [ bppL, bppK ]));
625     hull(){
626       EdgeProfile();
627       LidEdgeProfile();
628     }
629   }
630 }
631
632 module ButtonPlan(l, deep, cut){
633   epsilon =
634     (cut  ? 0 : lid_buttoncover_gap);
635
636   delta =
637     (deep ? lid_buttoncover_overlap : 0);
638
639   C = [0,0]; // by definition
640   T = [ 0, epp4[1] ];
641   G = T + [0,10];
642
643   B0 = C + [0,-1] * button_cutout_depth;
644   B1 = B0 + [0,1] * epsilon;
645
646   r0 = 0.5 * (T[1] - B0[1]);
647   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
648   H = A + [0,-1] * delta;
649
650   D = A + [-2,0] * r0;
651   F = D + [0,10];
652
653   E0 = 0.5 * (D + A);
654   E1 = E0 + [1,0] * epsilon;
655
656   I0 = [ E0[0], H[1] ];
657   I1 = [ E1[0], H[1] ];
658
659   hull(){
660     for (m=[0,1]) mirror([m,0])
661       circleat(H, r0 - epsilon);
662   }
663   for (m=[0,1]) mirror([m,0]) {
664     difference(){
665       polygon([ E1,
666                 I1,
667                 H,
668                 B1,
669                 G,
670                 F,
671                 D
672                 ]);
673       circleat(D, r0 + epsilon);
674     }
675   }
676 }
677
678 module CatchCatchProfile(){
679   hull(){
680     for (c=[ cppR, cppQ ])
681       circleat(c, cp_rQ);
682   }
683   hull(){
684     circleat(lpp12, lp_r12);
685     circleat(lpp12 + [5,0], lp_r12);
686     rectfromto(cppP, cppP + [5,0.1]);
687   }
688   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
689 }
690
691 module CatchCutProfile(){
692   polygon([ cppB,
693             cppA,
694             cppD,
695             cppF,
696             cppF + [0,-10],
697             cppF + [-10,-10],
698             lpp12 + [-10,0],
699             lpp12 + [10,0]
700             ]);
701 }
702
703 module Flip_rhs(yn=[0,1]) {
704   for ($rhsflip=yn) {
705     translate([phone_width/2, 0, 0])
706       mirror([$rhsflip,0,0])
707       translate([-phone_width/2, 0, 0])
708       children();
709   }
710 }
711
712 module Flip_bot(yn=[0,1]) {
713   for ($botflip=yn) {
714     translate([0, -phone_height/2, 0])
715       mirror([0, $botflip, 0])
716       translate([0, phone_height/2, 0])
717       children();
718   }
719 }  
720
721 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
722   // sides
723   Flip_rhs(){
724     translate([0, -phone_cnr_rad, 0])
725       rotate([90,0,0])
726       linear_extrude(height = phone_height - phone_cnr_rad*2)
727       children(0);
728   }
729   // corners
730   Flip_rhs() Flip_bot() {
731     translate([+1,-1] * phone_cnr_rad)
732       intersection(){
733         rotate_extrude()
734           intersection(){
735             mirror([1,0,0])
736               translate([-1,0] * phone_cnr_rad)
737               children(0);
738             rectfromto([0,-20],[10,20]);
739           }
740         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
741           cube([10,10,40]);
742       }
743   }
744   // top and bottom
745   Flip_bot(){
746     translate([ phone_width - phone_cnr_rad, 0,0 ])
747       rotate([90,0,-90])
748       linear_extrude(height = phone_width - phone_cnr_rad*2)
749       children(0);
750   }
751   // fill
752   translate([0,0, fill_zstart])
753     mirror([0,0, fill_downwards])
754     linear_extrude(height = fill_th)
755     rectfromto([+1,-1] * phone_cnr_rad,
756                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
757 }
758
759 module CaseAperture(pos, dia, $fn) {
760   theta = 180/$fn;
761   translate([ pos[0] + bumper[0],
762               -epp2i[0],
763               -pos[1] ])
764     rotate([-90, theta, 0])
765     cylinder(r = dia/2 / cos(theta),
766              h = 60);
767 }
768
769 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
770   // y_ref_sign:
771   //   +1  measured from top    of actual phone to top    of button
772   //   -1  measured from bottom of actual phone to bottom of button
773   //    0  y is centre of button in coordinate system
774   $button_l= l;
775   $button_suppress_over_keeper= suppress_over_keeper;
776   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
777           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
778           y;
779   //echo(eff_y);
780   translate([0, eff_y, 0])
781     children();
782 }
783
784 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
785   $button_leg_only = true;
786   SideButton(y, y_ref_sign, l) children();
787 }
788
789 module Buttons(){
790   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
791   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
792   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
793   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
794 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
795 }
796
797 module Struts(x_start, z_min, th){
798   // if th is negative, starts at z_min and works towards -ve z
799   // and object should then be printed other way up
800   for (i= [1 : 1 : case_struts_count]) {
801     translate([0,
802                0,
803                z_min])
804       mirror([0,0, th<0 ? 1 : 0])
805       translate([0,
806                  -phone_height * i / (case_struts_count+1),
807                  case_struts_solid_below])
808       linear_extrude(height= abs(th)
809                      -(case_struts_solid_below+case_struts_solid_above))
810       rectfromto([               x_start, -0.5 * case_struts_width ],
811                  [ phone_width - x_start, +0.5 * case_struts_width ]);
812   }
813 }
814
815 module OrdinaryRearAperture(rhs,bot, pos){
816   Flip_rhs(rhs) Flip_bot(bot)
817     linextr(-20, 20)
818     mirror([0,1])
819     translate(pos + bumper)
820     children();
821 }
822
823 module MicroUSB(){
824   Flip_bot(1){
825     rotate([90,0,0])
826       mirror([0,0,1])
827       linextr(-epp2i[0], 60)
828       translate([0.5 * phone_width, 0, 0])
829       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
830                  [+microusb_width/2, epp0[1] + -microusb_above]);
831   }
832 }
833
834 module OrdinaryRearApertures(){
835   // rear speaker
836   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
837     rectfromto(-rearspeaker_gap,
838                rearspeaker_size + rearspeaker_gap);
839
840   // finger hole to remove phone
841   if (len(fingerpushhole_dias))
842     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
843                                 phone[1]/2 ])
844     scale(fingerpushhole_dias)
845     circle(r= 0.5 );
846 }
847
848 module RearCameraAperture(){
849   Flip_rhs(1)
850     mirror([0, 0, 1])
851     linear_extrude(height = 20)
852     mirror([0, 1, 0])
853     translate(bumper)
854     rectfromto(camera_pos_tl, camera_pos_br);
855 }
856
857 module HingeLidProfile(){
858   hull(){
859     circleat(hppT, hp_r1);
860     circleat(lpp12, lp_r12);
861     polygon([lpp10,
862              lpp13 + [2,0],
863              lpp12,
864              hppT]);
865   }
866 }
867
868 module HingeBaseProfile(){
869   difference(){
870     hull(){
871       circleat(hppB, hp_r1);
872       circleat(hppE, hp_r1);
873       circleat(epp2o, case_th_bottom);
874       circleat(hppB + [10,0], hp_r1);
875     }
876     polygon([epp5, epp1, epp2i, epp3, bppL]);
877   }
878 }
879
880 module HingeLeverOuterProfile(){
881   hull(){
882     circleat(hppT, hp_r2);
883     circleat(hppB, hp_r2);
884   }
885 }
886
887 module HingeLeverInnerProfile(){
888   for (s = [-1,+1]) {
889     c = s > 0 ? hppT : hppB;
890     translate(c)
891       mirror([0,0,s>0])
892       rotate(s<0 ? -40 : 0)
893       hull()
894       for (x=[-20,20])
895         for (y=[0, s * 10])
896           translate([x,y])
897             circle(hp_rn);
898   }
899 }
900
901 module HingeLeverNutProfile(){
902   for (c= [hppB, hppT]) {
903     translate(c)
904       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
905   }
906 }
907
908 module Flip_hinge(doflip=1){
909   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
910   translate(hinge_origin)
911     rotate([doflip*180,0,0])
912     translate(-hinge_origin)
913     children();
914 }
915
916 module HingePortion(x0,x1){
917   Flip_rhs() Flip_bot(1)
918     translate([x0,0,0])
919     mirror([1,0,0])
920     rotate([90,0,-90])
921     linear_extrude(height=x1-x0)
922     children();
923 }
924
925 module CatchPortion(xwidth, ztop){
926   width = catch_width + xwidth;
927   w = width + catch_topcurve_r*2 + 1;
928   translate([phone_width/2, 0,0]){
929     difference(){
930       rotate([90,0,-90])
931         linextr(-w/2, w/2)
932         children(0);
933       translate([0, 50, 0])
934         rotate([90,0,0])
935         linear_extrude(height=100){
936         for (m=[0,1]) mirror([m,0,0]) {
937           hull(){
938             translate([w/2, ztop - catch_topcurve_r])
939               circle(catch_topcurve_r);
940             translate([w/2, -50])
941               square(catch_topcurve_r*2, center=true);
942           }
943         }
944       }
945     }
946   }
947 }
948
949 module CaseBase(){
950   AroundEdges(epp3[1], case_th_bottom, 1)
951     EdgeProfile();
952 }
953
954 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
955
956 module PropProfileAssignments(gamma){
957   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
958   x = prop_x(gamma);
959   p = phone_height + prlp10[0] - hppB[0];
960   b = p + x;
961
962   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
963   a = q + x;
964   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
965   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
966
967   $prp_theta = 90 - $prp_alpha;
968   beta = 180 - $prp_alpha - gamma;
969   psi = 90 - beta;
970
971   //echo("abc", a,b,c);
972
973   v1 = [ [ cos(psi), -sin(psi) ],    // x
974          [ sin(psi),  cos(psi) ] ];  // y
975
976   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
977
978   $prp_r1 = prc_r1;
979   $prp_r11 = prop_main_th/2;
980
981   $prpp1 = $prpp7 + [1,0] *
982     // this is approximate, but will do
983     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
984   $prpp3 = $prpp1 +
985     v1[0] * -$prp_r1 +
986     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
987   $prpp12 = $prpp3 + v1[0] *
988     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
989   $prp_r8 = prop_main_th;
990   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
991   $prp_r5 = $prp_r8;
992   $prpp5 = [ $prpp12[0] - $prp_r5,
993             $prpp3[1] - prop_prong_h + $prp_r5 ];
994   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
995          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
996   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
997   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
998
999   children();
1000 }
1001
1002 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
1003   PropProfileAssignments(gamma){
1004
1005     //#circleat($prpp3,1);
1006     //#circleat($prpp12,1);
1007
1008     if (!cut) {
1009       hull(){
1010         translate($prpp8)
1011           intersection(){
1012             circle($prp_r8);
1013             polygon([[-20,-0], [20,20], [0,0]]);
1014           }
1015         rectfromto($prpp6, $prpp9);
1016         translate($prpp5) intersection(){
1017           circle($prp_r5);
1018           polygon([[-10,-10], [0,0], [10,0]]);
1019         }
1020         rectfromto($prpp12 + [0,-0.1], $prpp3);
1021       }
1022       hull(){
1023         circleat($prpp1, $prp_r1);
1024         rectfromto($prpp12 + [0,-0.1], $prpp3);
1025       }
1026     }
1027     // main shaft
1028     rotate([0,0, rot*-$prp_theta]){
1029       hull(){
1030         extra = cut ? prop_recess_slop : 0;
1031         rectfromto($prpp6, $prpp9);
1032         circleat($prpp11, $prp_r11 + extra);
1033         circleat($prpp10, $prp_r10 + extra);
1034       }
1035     }
1036   }
1037 }
1038
1039 module PropAggregateProfile(){
1040   for (angle = prop_angles)
1041     PropProfile(angle, 0,0);
1042 }
1043
1044 module Prop(){ ////toplevel
1045   hw = prop_main_width/2;
1046   linextr(-hw, +hw)
1047     PropAggregateProfile();
1048 }
1049
1050 module Case(){ ////toplevel
1051   difference(){
1052     union(){
1053       CaseBase();
1054
1055       // ledge (fixed keeper)
1056       Flip_rhs(1-keeper_side) intersection(){
1057         rotate([90, 0, 0])
1058           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1059           KeeperProfile(1);
1060
1061         // outline of the whole case, to stop it protruding
1062         translate([0,0, -25])
1063           linear_extrude(height = 50)
1064           hull()
1065           Flip_bot()
1066           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1067       }
1068
1069       // hinge
1070       HingePortion(hex20, hex21) HingeBaseProfile();
1071
1072       // buildout for prop recess
1073       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1074         linextr(case_bottom_z, epp2i[1])
1075         hull() {
1076           for (dxs = [-1,+1])
1077             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1078                        -epp2o[0] ],
1079                      r = epp2o[0] - prcp2[0]);
1080         }
1081     }
1082
1083     // slot for keeper
1084     Flip_rhs(keeper_side)
1085       translate([0, -phone_cnr_rad, 0])
1086       rotate([90, 0, 0])
1087       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1088       minkowski(){
1089         KeeperProfile();
1090         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1091                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1092       }
1093
1094     // front camera
1095     RearCameraAperture();
1096
1097     // struts (invisible, because they're buried in the case)
1098     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1099
1100     Buttons(){
1101       mirror([1,0,0])
1102         rotate([90,0,90]) {
1103           if (!($button_leg_only && enable_support))
1104           intersection(){
1105             translate([0,0,-10])
1106               linear_extrude(height= 20)
1107               ButtonPlan($button_l, 0,1);
1108             if ($button_leg_only)
1109               rotate([-90,90,0])
1110                 translate([phone_width/2, -400, kppe[1]])
1111                 mirror([1-abs($rhsflip - keeper_side),0,0])
1112                 cube([400, 800, 50]);
1113             if (enable_support && !$button_suppress_over_keeper)
1114               rotate([-90,90,0])
1115               translate([-400, -400, kppd[1]])
1116                 mirror([0,0,1])
1117                 cube([800,800,100]);
1118           }
1119           translate([0,0, -bppR[0]])
1120             linear_extrude(height= 20)
1121             ButtonPlan($button_l, 1,1);
1122         }
1123       
1124     }
1125
1126     // apertures along top edge
1127     CaseAperture(jack_pos, jack_dia, 8);
1128     Flip_rhs(1)
1129       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1130
1131     OrdinaryRearApertures();
1132
1133     MicroUSB();
1134
1135     // gaps for the lid's hinge arms
1136     HingePortion(hex20 - hinge_x_arms_gap,
1137                  hex21 + hinge_x_arms_gap)
1138       minkowski(){
1139         HingeLidProfile();
1140         circle(r= hinge_r_arms_gap, $fn= 8);
1141       }
1142
1143     // screw holes in the hinge arms
1144     HingeScrews();
1145
1146     // catch striker
1147     CatchPortion(catch_side_gap*2, epp4[1])
1148       CatchCutProfile();
1149
1150     // prop recess
1151     Flip_rhs(1)
1152       translate([prop_x_pos,0,0])
1153       mirror([0,1,0])
1154       rotate([90,0,90])
1155       linextr(-prop_recess_hw, +prop_recess_hw)
1156       hull(){
1157         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1158           circleat(prcp1 + 20*d,
1159                    prc_r3);
1160       }
1161   }
1162 }
1163
1164 module LidAdhocMultiprintFrame(phase){
1165   if (led_window_style >= 3) {
1166     AdhocMultiprintFrame(phase, lpp13[1], -1);
1167   }
1168 }
1169
1170 module LidAroundEdges(){
1171   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1172     children();
1173 }
1174
1175 module Lid(){ ////toplevel
1176   skew_centre = [0, lpp11[0], lpp11[1]];
1177   difference(){
1178     union(){
1179       intersection(){
1180         LidAroundEdges()
1181           LidEdgeProfile();
1182
1183         translate(skew_centre)
1184           multmatrix([[ 1, 0, 0, 0 ],
1185                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1186                       [ 0, 0, 1, 0 ],
1187                       [ 0, 0, 0, 1 ]])
1188           translate(-skew_centre)
1189           LidAroundEdges()
1190           LidEdgeFoldClearanceProfile();
1191       }
1192
1193       // button covers
1194       Buttons(){
1195         intersection(){
1196           rotate([90,0,90])
1197             translate([0,0,-10])
1198             linear_extrude(height= 20)
1199             ButtonPlan($button_l, 1,0);
1200           rotate([90,0,0])
1201              translate([0,0,-100])
1202             linear_extrude(height= 200)
1203             ButtonCoverProfile();
1204         }
1205       }
1206
1207       // hinge arms
1208       HingePortion(hex20, hex21) {
1209         LidEdgeProfile();
1210         HingeLidProfile();
1211       }
1212
1213       // catch
1214       CatchPortion(0, lpp12[1])
1215         CatchCatchProfile();
1216     }
1217     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1218
1219     // screw holes in the hinge arms
1220     HingeScrews();
1221
1222     // prop recess
1223     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1224       mirror([0,1,0])
1225       rotate([90,0,90])
1226       linextr(-prop_recess_hw, +prop_recess_hw)
1227       hull()
1228       for (pa = prop_angles)
1229         PropProfile(pa, 1,1);
1230
1231     // notification led aperture
1232     if (led_window_style)
1233       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1234         translate([0,0,-10])
1235           cylinder(r=nla_r0, h=20);
1236         if (led_window_style >= 2)
1237           translate([0,0, -nla_t])
1238             cylinder(r=nla_r2, height=20);
1239       }
1240
1241     }
1242
1243   LidAdhocMultiprintFrame(1);
1244 }
1245
1246 module HingeLever(){ ////toplevel
1247   difference() {
1248     // outer body, positive
1249     HingePortion(hex22, hex22 + phone_width/2)
1250       HingeLeverOuterProfile();
1251
1252     // space for the screws
1253     HingePortion(hex26, hex24)
1254       HingeLeverInnerProfile();
1255
1256     // recesses for the nuts
1257     HingePortion(hex23, hex26+1)
1258       HingeLeverNutProfile();
1259
1260     // bores for the screws
1261     HingeScrews();
1262
1263     // space for the charging cable
1264     MicroUSB();
1265     Flip_hinge() MicroUSB();
1266   }
1267 }
1268
1269 module LidWindow(){ ////toplevel
1270   translate([led_pos[0], -led_pos[1], lpp13[1]])
1271     mirror([0,0,1])
1272     cylinder(r= nla_r1, h=nla_t);
1273   LidAdhocMultiprintFrame(0);
1274 }
1275
1276 module LidWindowPrint(){ ////toplevel
1277   rotate([0,180,0])
1278     LidWindow();
1279 }
1280
1281 module DemoLidWindowSelect(){
1282   translate([led_pos[0], led_pos[1], -100]) {
1283     translate([0, -30, 0]) cube([400, 400, 200]);
1284   }
1285 }
1286
1287 module DemoLidWindow(){ ////toplevel
1288   %Lid();
1289   LidWindow();
1290   translate([0,40,0]){
1291     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1292     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1293   }
1294 }
1295
1296 module HingeLeverPrint(){ ////toplevel
1297   rotate([-90,0,0])
1298     translate([-phone_width/2, phone_height, 0])
1299     HingeLever();
1300 }
1301
1302 module TestSelectLength(){
1303   translate([-30, -200, -20])
1304     cube([30 + 15, 250, 40]);
1305 }
1306
1307 module TestLength(){ ////toplevel
1308   intersection(){
1309     Case();
1310     TestSelectLength();
1311   }
1312 }
1313
1314 module TestLengthRight(){ ////toplevel
1315   intersection(){
1316     Case();
1317     Flip_rhs(1)
1318       TestSelectLength();
1319   }
1320 }
1321
1322 module TestSelectWidth(){
1323   translate([-30, -(phone_height - 25), -20])
1324     mirror([0, 1, 0])
1325     cube([200, 50, 40]);
1326 }
1327
1328 module TestWidth(){ ////toplevel
1329   intersection(){
1330     Case();
1331     TestSelectWidth();
1332   }
1333 }
1334
1335 module TestLidWidthPrint(){ ////toplevel
1336   rotate([0,180.0]) intersection(){
1337     Lid();
1338     TestSelectWidth();
1339   }
1340 }
1341
1342 module TestSelectRearAperture(){
1343   minkowski(){
1344     union() children();
1345     translate([20, 0,0])
1346       cube([42, 2, 1], center=true);
1347   }
1348 }
1349
1350 module TestSelectCamera(){
1351   minkowski(){
1352     TestSelectRearAperture()
1353       RearCameraAperture();
1354     cube([0.1, 50, 0.1]);
1355   }
1356 }
1357
1358 module TestSelectOrdinaryRearApertures(){
1359   TestSelectRearAperture()
1360     OrdinaryRearApertures();
1361 }
1362
1363 module TestCamera(){ ////toplevel
1364   intersection(){
1365     Case();
1366     TestSelectCamera();
1367   }
1368 }
1369
1370 module TestLidByCamera(){ ////toplevel
1371   intersection(){
1372     Lid();
1373     TestSelectCamera();
1374   }
1375 }
1376
1377 module TestLidByCameraPrint(){ ////toplevel
1378   rotate([180,0,0]) TestLidByCamera();
1379 }
1380
1381 module DemoByCamera(){ ////toplevel
1382   color("blue") TestLidByCamera();
1383   color("red")  TestCamera();
1384 }
1385
1386 module OneKeeper(){ ////toplevel
1387   translate([0, -phone_cnr_rad, 0])
1388     rotate([90, 0, 0])
1389     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1390     KeeperProfile();
1391 }
1392
1393 module OneKeeperPrint(){ ////toplevel
1394   rotate([0,180,0])
1395     OneKeeper();
1396 }
1397
1398 module LidPrint(){ ////toplevel
1399   rotate([0,180,0])
1400     Lid();
1401 }
1402
1403 module TestSelectFrame(){
1404   include = [1,-1] * (epp2i[0] + 4);
1405
1406   difference(){
1407     cube(1000, center=true);
1408     translate([0,0, -100])
1409       linear_extrude(height=200)
1410       rectfromto(include,  inside_br - include);
1411   }
1412 }
1413
1414 module TestSelectLidFrame(){
1415   TestSelectFrame();
1416   translate([led_pos[0], -led_pos[1], -50])
1417     cylinder(r= nla_r2+3, h=100);
1418 }
1419
1420 module TestFrameCase(){ ////toplevel
1421   intersection(){
1422     Case();
1423     union(){
1424       TestSelectFrame();
1425       TestSelectCamera();
1426       TestSelectOrdinaryRearApertures();
1427     }
1428   }
1429 }
1430
1431 module TestSelectTopApertures(){
1432   translate([-100, -35, -100])
1433     cube([400, 100, 200]);
1434   LidAdhocMultiprintFrame(0);
1435   LidAdhocMultiprintFrame(1);
1436 }
1437
1438 module TestTopApertures(){ ////toplevel
1439   intersection(){
1440     Case();
1441     TestSelectFrame();
1442     TestSelectTopApertures();
1443   }
1444 }
1445
1446 module TestLidTopAperturesPrint(){ ////toplevel
1447   rotate([0,180,0]) intersection(){
1448     Lid();
1449     TestSelectLidFrame();
1450     TestSelectTopApertures();
1451   }
1452 }
1453
1454 module TestLidWindowTopAperturesPrint(){ ////toplevel
1455   rotate([0,180,0]) intersection(){
1456     LidWindow();
1457     TestSelectTopApertures();
1458   }
1459 }
1460
1461 module TestFrameLidPrint(){ ////toplevel
1462   rotate([0,180,0]) intersection(){
1463     Lid();
1464     TestSelectLidFrame();
1465   }
1466 }
1467
1468 module ButtonPlanForDemo(z, deep, cut){
1469   translate([0,0,z])
1470     ButtonPlan(8, deep, cut);
1471 }
1472
1473 module HingeScrews(){
1474   Flip_rhs() Flip_bot(1){
1475     for (c= [ hppT, hppB ])
1476       translate([ hex20,
1477                   -c[0],
1478                   c[1] ]){
1479         rotate([0,90,0])
1480           translate([0,0,-.2])
1481           cylinder( r= hingescrew_shaft_dia/2,
1482                     h = hingescrew_shaft_len+0.2 );
1483         rotate([0,-90,0])
1484           translate([0,0,+.1])
1485           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1486       }
1487   }
1488 }
1489
1490 module DemoPropAngleSelect(c){
1491   color(c) difference(){
1492     union(){ children(); }
1493     translate([ prop_x_pos, -400, -200 ])
1494       cube([ 400,800,400 ]);
1495   }
1496 }
1497
1498 module DemoPropAngle(ang){
1499   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1500   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1501
1502   translate(hL)
1503     rotate([ang/2,0,0])
1504     translate(-hL)
1505     translate(hC)
1506     rotate([ang/2,0,0])
1507     translate(-hC) {
1508       DemoPropAngleSelect("red") Case();
1509
1510       color("orange")
1511         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1512         PropProfileAssignments(ang) {
1513           echo($prpp1);
1514           rotate([-$prp_theta, 0, 0])
1515           translate([0, $prpp1[0], -$prpp1[1]])
1516           rotate([90,0,-90])
1517           Prop();
1518         }
1519     }
1520
1521   translate([0,0, -hp_k*2])
1522     DemoPropAngleSelect("blue")
1523     Lid();
1524 }
1525
1526 module DemoPropAngles(){ ////toplevel
1527   for (i=[0 : len(prop_angles)-1])
1528     translate(i * [0, -100, 100])
1529     DemoPropAngle(prop_angles[i]);
1530 }
1531
1532 module DemoHingeAngle(ang1,ang2){
1533   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1534   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1535
1536   translate(hL)
1537     rotate([ang2,0,0])
1538     translate(-hL)
1539     translate(hC)
1540     rotate([ang1,0,0])
1541     translate(-hC) {
1542       color("red") Lid();
1543     }
1544
1545   color("blue") intersection(){
1546     Case();
1547     union(){
1548       translate([bppJ[0], -400, -200])
1549         mirror([1,0,0])
1550         cube([400, 800, 400]);
1551       translate([10, -400, -200])
1552         cube([10, 800, 400]);
1553     }
1554   }
1555 }
1556
1557 module DemoHingeAngles(){ ////toplevel
1558   angles = [ 0, 4, 8, 12 ];
1559   echo("angles",angles);
1560   for (i=[0 : len(angles)-1]) {
1561     translate(i * [0, 0, 30]) {
1562       DemoHingeAngle(0,angles[i]);
1563       translate([0, 200, 0])
1564         DemoHingeAngle(angles[i],0);
1565     }
1566   }
1567 }
1568
1569 module DemoSelectAdhocLeftRight(right=0) {
1570   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1571     mirror([1-right, 0,0])
1572     cube([400, 800, 200]);
1573 }
1574
1575 module DemoLeft(){ ////toplevel
1576   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1577   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1578 }
1579
1580 module DemoFrame(){ ////toplevel
1581   color("red") TestFrameCase();
1582   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1583   color("black") HingeScrews();
1584   %HingeLever();
1585 }
1586
1587 module DemoLanyardCutout(){ ////toplevel
1588   LanyardCutout(25);
1589 }
1590
1591 module DemoHingedFrame(){ ///toplevel
1592   color("red") TestFrameCase();
1593   translate([0,0, -2*hp_k])
1594   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1595
1596   Flip_hinge(){
1597     color("orange") HingeLever();
1598     color("black") HingeScrews();
1599   }
1600 }
1601
1602 module DemoHinge(){ ////toplevel
1603   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1604     DemoFrame();
1605     translate([0,0, -hp_k*3])
1606       DemoHingedFrame();
1607   }
1608 }
1609
1610 module DemoProfiles(){ ////toplevel
1611   LidEdgeProfile();
1612   %EdgeProfile();
1613   KeeperProfile();
1614   translate([0,0,-1]) color("black") KeeperProfile(1);
1615   color("purple") translate(epp2i)
1616     rotate(atan2vector(epp2i - epp1)) {
1617     translate(lanyard_half_dia * 0.5 * [-3,-1])
1618       LanyardLanyardProfile();
1619     translate(lanyard_half_dia * 0.5 * [-3,+1])
1620       translate([0,-1] * case_th_side)
1621       LanyardLanyardProfile(true);
1622   }
1623
1624   translate([0,20]) {
1625     LanyardMainChannelProfile();
1626     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1627     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1628   }
1629
1630   translate([20,0]) {
1631     LidEdgeProfile();
1632     %EdgeProfile();
1633
1634     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1635   
1636     color("blue") ButtonCoverProfile();
1637     color("red") {
1638       rectfromto(bppQ, demopoint_QR);
1639       rectfromto(bppR, demopoint_QR);
1640     }
1641   }
1642
1643   translate([-20,0]) {
1644     color("black") ButtonPlanForDemo(-2, 0,1);
1645     color("red" )  ButtonPlanForDemo(-4, 1,1);
1646     color("blue")  ButtonPlanForDemo(-6, 1,0);
1647   }
1648
1649   translate([0, -30]) {
1650     %LidEdgeProfile();
1651     %EdgeProfile();
1652     color("blue") HingeLidProfile();
1653     color("red")  HingeBaseProfile();
1654     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1655   }
1656
1657   for (f=[0,1]) {
1658     translate([-30, -60 + 30*f]) {
1659       translate([0,0,-4]) EdgeProfile();
1660       %translate([0,0,-10]) HingeBaseProfile();
1661       translate([0,-2] * f * hp_k) {
1662         translate([0,0,-4]) LidEdgeProfile();
1663         %translate([0,0,-10]) %HingeLidProfile();
1664       }
1665       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1666         translate([0,0,-2]) color("black") HingeLeverOuterProfile(); 
1667         translate([0,0,0]) color("red") difference(){
1668           HingeLeverOuterProfile();
1669           HingeLeverInnerProfile();
1670         }
1671         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1672       }
1673     }
1674   }
1675
1676   translate([20,-30]) {
1677     %EdgeProfile();
1678     %LidEdgeProfile();
1679     //translate([0,0,1]) CatchCutProfile();
1680     color("blue") CatchCatchProfile();
1681     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1682   }
1683
1684   translate([40,-30]) {
1685     difference(){
1686       LidEdgeProfile();
1687       translate(prlp10)
1688         PropProfile(10, 1, 0);
1689     }
1690     translate(prlp10)
1691       PropProfile(15, 0);
1692   }
1693   translate([60,-30]) {
1694     PropAggregateProfile();
1695   }
1696 }
1697
1698 //EdgeProfile();
1699 //KeeperProfile();
1700 //CaseBase();
1701 //%Case();
1702 //Keeper();
1703 //LidEdgeProfile();
1704 //KeeperProfile();
1705 //DemoProfiles();
1706 //PropRecess();