fairphone-case.scad

   1 // -*- C -*-
   2
   3 include <utils.scad>
   4
   5 phone = [ 75.0, 145.0 ];
   6
   7 prop_buildout_less = 3;
   8
   9 prop_angles = [ 15, 30, 45, 60 ];
  10
  11 bumper = [ 0.250, -0.025 ];
  12 // ^ One side.  Overall size is increased by twice this.
  13 // If no bumpers, is the gap around the phone.
  14
  15 enable_support = 1;
  16
  17 phone_cnr_rad = 6.0;
  18
  19 button_cutout_depth = 9;
  20
  21 phone_edge_thick = 9.0;
  22 phone_total_thick = 12.0;
  23 phone_backside_slope_inner = 1.5; // larger means shallower
  24 phone_backside_slope_outer = 1.0; // larger means shallower
  25
  26 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  27 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  28
  29 jack_pos = [ 13.83, 8.485 ];
  30 jack_dia = 10.64 + .5; // some jack I had lying around
  31
  32 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  33 noisecancelmic_dia = 4.00;
  34
  35 //fingerpushhole_dias = [ 15, 18 ];
  36 fingerpushhole_dias = [];
  37
  38 rearspeaker_pos_bl = [ 12.64, 18.72 ];
  39 rearspeaker_size   = [  3.76,  7.36 ];
  40
  41 microusb_above = 3.27 - 0.25;
  42 microusb_below = 0.0;
  43 microusb_width = 16.12 + 1.25;
  44
  45 case_th_bottom = 2.5;
  46 case_th_lid = 2.5;
  47 case_th_side = 2;
  48 case_th_lip = 1.2;
  49
  50 case_struts_count = 6;
  51 case_struts_solid_below = 1.00;
  52 case_struts_solid_above = 0.75;
  53 case_struts_width = 0.10;
  54
  55 keeper_th_z = 0.75;
  56 keeper_th_x = 0.75;
  57 keeper_inner_width = 2.75;
  58 keeper_inner_height = 2.75;
  59 keeper_slant_slope = 2; // larger means steeper
  60
  61 keeper_gap_z_top = 0.25;
  62 keeper_gap_z_bot = 0.75;
  63 keeper_gap_x     = 0.25;
  64 keeper_gap_x_holes = 0.75;
  65
  66 keeper_side = 0; // 0 = lhs; 1 = rhs
  67
  68 case_lip = 1.25;
  69
  70 lid_gap_x = 0.25;
  71 lid_gap_z = 0.25;
  72 lid_lip = 1.75;
  73
  74 catch_slop = 0.50;
  75
  76 foldover_gap = 0.50;
  77 foldover_lever_gap = 0.50;
  78
  79 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
  80 hingescrew_shaft_len = 12;
  81 hingescrew_nut_thick = 1.93 + 0.20; // incl. washer
  82 hingescrew_nut_dia = 4.72 + 0.50; // washer, actually
  83 hingescrew_head_th = 1.38 + 0.75;
  84 hingescrew_head_dia = 3.92;
  85 lever_cover_th = 0.75;
  86 hingemount_th = 2.5;
  87
  88 $fa = 5;
  89 $fs = 0.1;
  90
  91 button_l_fudge = 4.4;
  92 buttonishleg_default_l_is_fudge = 10;
  93
  94 hinge_base_slope = 1.5; // bigger is steeper
  95
  96 strut_min_at_end = 1.5;
  97
  98 hinge_x_gap = 0.125;
  99 hinge_x_postscrew_gap = 0.75;
 100 hinge_x_arms_gap = 0.35;
 101 hinge_r_arms_gap = 0.55;
 102
 103 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 104
 105 catch_len = 7.5;
 106 catch_width = 15;
 107 catch_thickness = 1.0;
 108 catch_side_gap = 0.75; // each side
 109
 110 catch_depth = 0.75;
 111 catch_height = 0.35;
 112 catch_finger_height = 1.5;
 113 catch_finger_depth = 2.5;
 114
 115 prop_recess_under = 0.50;
 116 prop_recess_slop = 0.200; // each side
 117 prop_end_dia = 0.5;
 118 prop_main_th = 3;
 119 prop_taper_len = 6;
 120 prop_main_width = 4;
 121 prop_side_gap = 0.75; // each side
 122 prop_lidrecess_behind = 0.75;
 123 prop_caserecess_behind = 0.75;
 124 prop_caserecess_taper = 0.45; // one side only
 125 prop_prop_gap = 0.5;
 126 prop_prong_heel_slope = 0.5;
 127
 128 // ---------- calculated ----------
 129
 130 phone_width =  (phone + bumper*2)[0];
 131 phone_height = (phone + bumper*2)[1];
 132
 133 inside_br = [phone_width, -phone_height];
 134
 135 prop_prong_h = prop_main_th;
 136
 137 //echo(camera_pos_tl + bumper,
 138 //     camera_pos_br + bumper);
 139
 140 // ----- could be changed -----
 141 lid_buttoncover_gap = lid_gap_x;
 142 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 143
 144 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 145
 146 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 147
 148 //prop_nose_len = case_th_lid - prop_recess_under;
 149 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 150 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 151
 152
 153 //lid_lip_overlap_width xxx bad name = ;
 154 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 155
 156 epp0 = [0,0];
 157 epp1 = [0, -phone_edge_thick];
 158 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 159 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 160 epp3 = epp2i + [10, 0];
 161 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 162 epp4 = epp5 + [-1,0] * case_th_side;
 163
 164 kppe = [0,0];
 165 kppd = kppe + [1,0] * keeper_inner_width;
 166 kppc = kppd + [0,1] * keeper_th_z;
 167 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 168 kppf = kppe - [0,1] * keeper_inner_height;
 169 kppa = [ kppb[0], kppf[1] ];
 170
 171 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 172 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 173
 174 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
 175
 176 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 177 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 178
 179 case_bottom_z = epp2o[1] - case_th_bottom;
 180
 181 // button profile
 182 bppM = epp4 + [0,5];
 183 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 184 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 185 bppS = [ epp1[0], bppR[1] ];
 186 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 187 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 188 bppO = [ bppN[0], bppP[1] ];
 189 bppL = lpp10 + [5,0];
 190 bppK = [ bppL[0], bppN[1] ];
 191 bppJ = [ bppN[0], bppL[1] ];
 192 bppU = [ bppJ[0], lpp12[1] ];
 193 bppV = lpp11;
 194 bppW = lpp10;
 195
 196 // hinge plan
 197 hp_rn = hingescrew_nut_dia/2;
 198 hp_r2_min = hp_rn + lever_cover_th;
 199 hp_rs = hingescrew_shaft_dia/2;
 200 hp_r1_min = hp_rs + hingemount_th;
 201
 202 hp_r1 = max(hp_r1_min, hp_r2_min);
 203 hp_r2 = hp_r1;
 204
 205 hppU = lpp13;
 206 hppS = epp2o + [0,-1] * case_th_bottom;
 207 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 208
 209 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 210          0.5 * (hppU + hppS)[1] ];
 211 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 212 hppB = hppT + [0,-1] * hp_k;
 213
 214 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 215 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 216 hppE = [ hppE_x, hppE_y ];
 217
 218 // hinge elevation x coords
 219
 220 hingescrew_portion_len =
 221   0.5* (hingescrew_shaft_len - hingescrew_nut_thick - hinge_x_gap);
 222
 223 hex20 = max(epp2o[0],
 224             phone_cnr_rad,
 225             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 226 hex21 = hex20 + hingescrew_portion_len;
 227 hex22 = hex21 + hinge_x_gap;
 228 hex23 = hex22 + hingescrew_portion_len
 229   - hingescrew_nut_thick; // bodge, need to divvy this up more sensibly
 230 hex24 = hex20 + hingescrew_shaft_len + hinge_x_postscrew_gap;
 231 //echo(hex20, hex21, hex22, hex23, hex24);
 232 //echo(hingescrew_portion_len);
 233
 234 // catch
 235
 236 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 237 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 238 cppB = [ epp0[0], cppA[1] ];
 239 cppP = [ epp4[0], cppJ[1] ];
 240
 241 cppS = cppJ + [0,-1] * catch_len;
 242 cppD = [ cppA[0], cppS[1] + catch_slop ];
 243 cppC = [ cppB[0], cppD[1] ];
 244 cppT = cppS + [1,0] * catch_depth;
 245 cppU = cppT + [0,-1] * catch_height;
 246 cppV = [ cppS[0], cppU[1] - catch_depth ];
 247
 248 cppR = 0.5*(cppP + cppJ);
 249
 250 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 251 cppQ = [ cppR[0],
 252          cppV[1] - (catch_finger_height - cp_rQ) ];
 253 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 254
 255 // prop recess in case
 256
 257 prop_x_pos = phone_width/2;
 258
 259 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 260
 261 prc_r1 = prop_end_dia/2;
 262 prc_r3 = prc_r1 + prop_recess_slop;
 263
 264 prcp2 = [ epp4[0] + prop_buildout_less,
 265           case_bottom_z ];
 266
 267 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 268
 269 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 270           epp2i[1] - prc_r3 - prop_recess_under];
 271
 272 // prop recess in lid
 273
 274 prl_r10 = prop_end_dia/2;
 275 prl_r10o = prl_r10 + prop_recess_slop;
 276
 277 prlp10 = lpp10 + [1,1] * prl_r10o
 278   + [1,0] * prop_lidrecess_behind
 279   + [0,1] * prop_recess_under;
 280
 281 // prop
 282
 283 $prpp10 = [0,0];
 284 $prpp11 = [0, prop_taper_len];
 285
 286 $prp_r10 = prl_r10;
 287
 288 // ---------- modules ----------
 289
 290 module KeeperProfile(slant=0){
 291   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 292   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 293 }
 294
 295 module EdgeProfile(){
 296   difference(){
 297     hull(){
 298       translate(epp3) square(case_th_bottom*2, center=true);
 299       circleat(epp2o, r=case_th_bottom);
 300       circleat(epp1, r=case_th_side);
 301       rectfromto(epp0, epp4);
 302     }
 303     polygon([ epp5 + [0,10],
 304               epp1,
 305               epp2i,
 306               epp3 + [10,0] ]);
 307   }
 308 }
 309
 310 module LidEdgeProfile(){
 311   polygon([ lpp10,
 312             lpp11,
 313             lpp12,
 314             lpp13,
 315             lpp13 + [10, 0],
 316             lpp10 + [10, 0]
 317             ]);
 318   intersection(){
 319     circleat(lpp12, r=lp_r12);
 320     rectfromto( lpp12 + [-10,   0],
 321                 lpp12 + [+10, +10] );
 322   }
 323 }
 324
 325 module ButtonCoverProfile(){
 326   intersection(){
 327     polygon(concat([ bppM, bppP, bppO, bppJ ],
 328                    (enable_support ? [ bppU, bppV, bppW ] : []),
 329                    [ bppL, bppK ]));
 330     hull(){
 331       EdgeProfile();
 332       LidEdgeProfile();
 333     }
 334   }
 335 }
 336
 337 module ButtonPlan(l, deep, cut){
 338   epsilon =
 339     (cut  ? 0 : lid_buttoncover_gap);
 340
 341   delta =
 342     (deep ? lid_buttoncover_overlap : 0);
 343
 344   C = [0,0]; // by definition
 345   T = [ 0, epp4[1] ];
 346   G = T + [0,10];
 347
 348   B0 = C + [0,-1] * button_cutout_depth;
 349   B1 = B0 + [0,1] * epsilon;
 350
 351   r0 = 0.5 * (T[1] - B0[1]);
 352   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 353   H = A + [0,-1] * delta;
 354
 355   D = A + [-2,0] * r0;
 356   F = D + [0,10];
 357
 358   E0 = 0.5 * (D + A);
 359   E1 = E0 + [1,0] * epsilon;
 360
 361   I0 = [ E0[0], H[1] ];
 362   I1 = [ E1[0], H[1] ];
 363
 364   hull(){
 365     for (m=[0,1]) mirror([m,0])
 366       circleat(H, r0 - epsilon);
 367   }
 368   for (m=[0,1]) mirror([m,0]) {
 369     difference(){
 370       polygon([ E1,
 371                 I1,
 372                 H,
 373                 B1,
 374                 G,
 375                 F,
 376                 D
 377                 ]);
 378       circleat(D, r0 + epsilon);
 379     }
 380   }
 381 }
 382
 383 module CatchCatchProfile(){
 384   hull(){
 385     for (c=[ cppR, cppQ ])
 386       circleat(c, cp_rQ);
 387   }
 388   hull(){
 389     circleat(lpp12, lp_r12);
 390     circleat(lpp12 + [5,0], lp_r12);
 391     rectfromto(cppP, cppP + [5,0.1]);
 392   }
 393   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 394 }
 395
 396 module CatchCutProfile(){
 397   polygon([ cppB,
 398             cppA,
 399             cppD,
 400             cppF,
 401             cppF + [0,-10],
 402             cppF + [-10,-10],
 403             lpp12 + [-10,0],
 404             lpp12 + [10,0]
 405             ]);
 406 }
 407
 408 module Flip_rhs(yn=[0,1]) {
 409   for ($rhsflip=yn) {
 410     translate([phone_width/2, 0, 0])
 411       mirror([$rhsflip,0,0])
 412       translate([-phone_width/2, 0, 0])
 413       children();
 414   }
 415 }
 416
 417 module Flip_bot(yn=[0,1]) {
 418   for ($botflip=yn) {
 419     translate([0, -phone_height/2, 0])
 420       mirror([0, $botflip, 0])
 421       translate([0, phone_height/2, 0])
 422       children();
 423   }
 424 }
 425
 426 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 427   // sides
 428   Flip_rhs(){
 429     translate([0, -phone_cnr_rad, 0])
 430       rotate([90,0,0])
 431       linear_extrude(height = phone_height - phone_cnr_rad*2)
 432       children(0);
 433   }
 434   // corners
 435   Flip_rhs() Flip_bot() {
 436     translate([+1,-1] * phone_cnr_rad)
 437       intersection(){
 438         rotate_extrude()
 439           intersection(){
 440             mirror([1,0,0])
 441               translate([-1,0] * phone_cnr_rad)
 442               children(0);
 443             rectfromto([0,-20],[10,20]);
 444           }
 445         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 446           cube([10,10,40]);
 447       }
 448   }
 449   // top and bottom
 450   Flip_bot(){
 451     translate([ phone_width - phone_cnr_rad, 0,0 ])
 452       rotate([90,0,-90])
 453       linear_extrude(height = phone_width - phone_cnr_rad*2)
 454       children(0);
 455   }
 456   // fill
 457   translate([0,0, fill_zstart])
 458     mirror([0,0, fill_downwards])
 459     linear_extrude(height = fill_th)
 460     rectfromto([+1,-1] * phone_cnr_rad,
 461                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 462 }
 463
 464 module CaseAperture(pos, dia, $fn) {
 465   theta = 180/$fn;
 466   translate([ pos[0] + bumper[0],
 467               -epp2i[0],
 468               -pos[1] ])
 469     rotate([-90, theta, 0])
 470     cylinder(r = dia/2 / cos(theta),
 471              h = 60);
 472 }
 473
 474 module SideButton(y, y_ref_sign, l){
 475   // y_ref_sign:
 476   //   +1  measured from top    of actual phone to top    of button
 477   //   -1  measured from bottom of actual phone to bottom of button
 478   //    0  y is centre of button in coordinate system
 479   $button_l= l;
 480   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 481           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 482           y;
 483   //echo(eff_y);
 484   translate([0, eff_y, 0])
 485     children();
 486 }
 487
 488 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 489   $button_leg_only = true;
 490   SideButton(y, y_ref_sign, l) children();
 491 }
 492
 493 module Buttons(){
 494   Flip_rhs(1) SideButton(15.580, +1, 8.9) children(); // power
 495   Flip_rhs(1) SideButton(48.700, -1, 8.920) children(); // camera
 496   Flip_rhs(0) SideButton(30.800, +1, 21.96) children(); // volume
 497   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 498 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 499 }
 500
 501 module Struts(x_start, z_min, th){
 502   // if th is negative, starts at z_min and works towards -ve z
 503   // and object should then be printed other way up
 504   for (i= [1 : 1 : case_struts_count]) {
 505     translate([0,
 506                0,
 507                z_min])
 508       mirror([0,0, th<0 ? 1 : 0])
 509       translate([0,
 510                  -phone_height * i / (case_struts_count+1),
 511                  case_struts_solid_below])
 512       linear_extrude(height= abs(th)
 513                      -(case_struts_solid_below+case_struts_solid_above))
 514       rectfromto([               x_start, -0.5 * case_struts_width ],
 515                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 516   }
 517 }
 518
 519 module OrdinaryRearAperture(rhs,bot, pos){
 520   Flip_rhs(rhs) Flip_bot(bot)
 521     linextr(-20, 20)
 522     mirror([0,1])
 523     translate(pos + bumper)
 524     children();
 525 }
 526
 527 module MicroUSB(){
 528   Flip_bot(1){
 529     rotate([90,0,0])
 530       mirror([0,0,1])
 531       linextr(-epp2i[0], 60)
 532       translate([0.5 * phone_width, 0, 0])
 533       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 534                  [+microusb_width/2, epp0[1] + -microusb_above]);
 535   }
 536 }
 537
 538 module OrdinaryRearApertures(){
 539   // rear speaker
 540   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 541     rectfromto(-rearspeaker_gap,
 542                rearspeaker_size + rearspeaker_gap);
 543
 544   // finger hole to remove phone
 545   if (len(fingerpushhole_dias))
 546     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 547                                 phone[1]/2 ])
 548     scale(fingerpushhole_dias)
 549     circle(r= 0.5 );
 550 }
 551
 552 module RearCameraAperture(){
 553   Flip_rhs(1)
 554     mirror([0, 0, 1])
 555     linear_extrude(height = 20)
 556     mirror([0, 1, 0])
 557     translate(bumper)
 558     rectfromto(camera_pos_tl, camera_pos_br);
 559 }
 560
 561 module HingeLidProfile(){
 562   hull(){
 563     circleat(hppT, hp_r1);
 564     circleat(lpp12, lp_r12);
 565     polygon([lpp10,
 566              lpp13 + [2,0],
 567              lpp12,
 568              hppT]);
 569   }
 570 }
 571
 572 module HingeBaseProfile(){
 573   difference(){
 574     hull(){
 575       circleat(hppB, hp_r1);
 576       circleat(hppE, hp_r1);
 577       circleat(epp2o, case_th_bottom);
 578       circleat(hppB + [10,0], hp_r1);
 579     }
 580     polygon([epp5, epp1, epp2i, epp3, bppL]);
 581   }
 582 }
 583
 584 module HingeLeverOuterProfile(){
 585   hull(){
 586     circleat(hppT, hp_r2);
 587     circleat(hppB, hp_r2);
 588   }
 589 }
 590
 591 module HingeLeverInnerProfile(){
 592   for (c = [hppT, hppB]) {
 593     hull()
 594       for (x=[-20,20])
 595         for (y=[0, c[1] - hppM[1]])
 596           translate([x,y])
 597             circleat(c, hp_rn);
 598   }
 599 }
 600
 601 module Flip_hinge(){
 602   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 603   translate(hinge_origin)
 604     rotate([180,0,0])
 605     translate(-hinge_origin)
 606     children();
 607 }
 608
 609 module HingePortion(x0,x1){
 610   Flip_rhs() Flip_bot(1)
 611     translate([x0,0,0])
 612     mirror([1,0,0])
 613     rotate([90,0,-90])
 614     linear_extrude(height=x1-x0)
 615     children(0);
 616 }
 617
 618 module CatchPortion(width){
 619   translate([phone_width/2, 0,0])
 620     rotate([90,0,-90])
 621     linextr(-width/2, width/2)
 622     children(0);
 623 }
 624
 625 module CaseBase(){
 626   AroundEdges(epp3[1], case_th_bottom, 1)
 627     EdgeProfile();
 628 }
 629
 630 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 631
 632 module PropProfileAssignments(gamma){
 633   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 634   x = prop_x(gamma);
 635   p = phone_height + prlp10[0] - hppB[0];
 636   b = p + x;
 637
 638   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 639   a = q + x;
 640   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 641   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 642
 643   $prp_theta = 90 - $prp_alpha;
 644   beta = 180 - $prp_alpha - gamma;
 645   psi = 90 - beta;
 646
 647   //echo("abc", a,b,c);
 648
 649   v1 = [ [ cos(psi), -sin(psi) ],    // x
 650          [ sin(psi),  cos(psi) ] ];  // y
 651
 652   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 653
 654   $prp_r1 = prc_r1;
 655   $prp_r11 = prop_main_th/2;
 656
 657   $prpp1 = $prpp7 + [1,0] *
 658     // this is approximate, but will do
 659     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 660   $prpp3 = $prpp1 +
 661     v1[0] * -$prp_r1 +
 662     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 663   $prpp12 = $prpp3 + v1[0] *
 664     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 665   $prp_r8 = prop_main_th;
 666   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 667   $prp_r5 = $prp_r8;
 668   $prpp5 = [ $prpp12[0] - $prp_r5,
 669             $prpp3[1] - prop_prong_h + $prp_r5 ];
 670   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 671          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 672   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 673   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 674
 675   children();
 676 }
 677
 678 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 679   PropProfileAssignments(gamma){
 680
 681     //#circleat($prpp3,1);
 682     //#circleat($prpp12,1);
 683
 684     if (!cut) {
 685       hull(){
 686         translate($prpp8)
 687           intersection(){
 688             circle($prp_r8);
 689             polygon([[-20,-0], [20,20], [0,0]]);
 690           }
 691         rectfromto($prpp6, $prpp9);
 692         translate($prpp5) intersection(){
 693           circle($prp_r5);
 694           polygon([[-10,-10], [0,0], [10,0]]);
 695         }
 696         rectfromto($prpp12 + [0,-0.1], $prpp3);
 697       }
 698       hull(){
 699         circleat($prpp1, $prp_r1);
 700         rectfromto($prpp12 + [0,-0.1], $prpp3);
 701       }
 702     }
 703     // main shaft
 704     rotate([0,0, rot*-$prp_theta]){
 705       hull(){
 706         extra = cut ? prop_recess_slop : 0;
 707         rectfromto($prpp6, $prpp9);
 708         circleat($prpp11, $prp_r11 + extra);
 709         circleat($prpp10, $prp_r10 + extra);
 710       }
 711     }
 712   }
 713 }
 714
 715 module PropAggregateProfile(){
 716   for (angle = prop_angles)
 717     PropProfile(angle, 0,0);
 718 }
 719
 720 module Prop(){ ////toplevel
 721   hw = prop_main_width/2;
 722   linextr(-hw, +hw)
 723     PropAggregateProfile();
 724 }
 725
 726 module Case(){ ////toplevel
 727   difference(){
 728     union(){
 729       CaseBase();
 730
 731       // ledge (fixed keeper)
 732       Flip_rhs(1-keeper_side) intersection(){
 733         rotate([90, 0, 0])
 734           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 735           KeeperProfile(1);
 736
 737         // outline of the whole case, to stop it protruding
 738         translate([0,0, -25])
 739           linear_extrude(height = 50)
 740           hull()
 741           Flip_bot()
 742           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 743       }
 744
 745       // hinge
 746       HingePortion(hex20, hex21) HingeBaseProfile();
 747
 748       // buildout for prop recess
 749       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
 750         linextr(case_bottom_z, epp2i[1])
 751         hull() {
 752           for (dxs = [-1,+1])
 753             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
 754                        -epp2o[0] ],
 755                      r = epp2o[0] - prcp2[0]);
 756         }
 757     }
 758
 759     // slot for keeper
 760     Flip_rhs(keeper_side)
 761       translate([0, -phone_cnr_rad, 0])
 762       rotate([90, 0, 0])
 763       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 764       minkowski(){
 765         KeeperProfile();
 766         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 767                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 768       }
 769
 770     // front camera
 771     RearCameraAperture();
 772
 773     // struts (invisible, because they're buried in the case)
 774     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 775
 776     Buttons(){
 777       mirror([1,0,0])
 778         rotate([90,0,90]) {
 779           if (!($button_leg_only && enable_support))
 780           intersection(){
 781             translate([0,0,-10])
 782               linear_extrude(height= 20)
 783               ButtonPlan($button_l, 0,1);
 784             if ($button_leg_only)
 785               rotate([-90,90,0])
 786                 translate([phone_width/2, -400, kppe[1]])
 787                 mirror([1-abs($rhsflip - keeper_side),0,0])
 788                 cube([400, 800, 50]);
 789             if (enable_support)
 790               rotate([-90,90,0])
 791               translate([-400, -400, kppd[1]])
 792                 mirror([0,0,1])
 793                 cube([800,800,100]);
 794           }
 795           translate([0,0, -bppR[0]])
 796             linear_extrude(height= 20)
 797             ButtonPlan($button_l, 1,1);
 798         }
 799
 800     }
 801
 802     // apertures along top edge
 803     CaseAperture(jack_pos, jack_dia, 8);
 804     Flip_rhs(1)
 805       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
 806
 807     OrdinaryRearApertures();
 808
 809     MicroUSB();
 810
 811     // gaps for the lid's hinge arms
 812     HingePortion(hex20 - hinge_x_arms_gap,
 813                  hex21 + hinge_x_arms_gap)
 814       minkowski(){
 815         HingeLidProfile();
 816         circle(r= hinge_r_arms_gap, $fn= 8);
 817       }
 818
 819     // screw holes in the hinge arms
 820     HingeScrews();
 821
 822     // catch striker
 823     CatchPortion(catch_width + catch_side_gap*2)
 824       CatchCutProfile();
 825
 826     // prop recess
 827     Flip_rhs(1)
 828       translate([prop_x_pos,0,0])
 829       mirror([0,1,0])
 830       rotate([90,0,90])
 831       linextr(-prop_recess_hw, +prop_recess_hw)
 832       hull(){
 833         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
 834           circleat(prcp1 + 20*d,
 835                    prc_r3);
 836       }
 837   }
 838 }
 839
 840 module Lid(){ ////toplevel
 841   difference(){
 842     union(){
 843       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 844         LidEdgeProfile();
 845
 846       // button covers
 847       Buttons(){
 848         intersection(){
 849           rotate([90,0,90])
 850             translate([0,0,-10])
 851             linear_extrude(height= 20)
 852             ButtonPlan($button_l, 1,0);
 853           rotate([90,0,0])
 854              translate([0,0,-100])
 855             linear_extrude(height= 200)
 856             ButtonCoverProfile();
 857         }
 858       }
 859
 860       // hinge arms
 861       HingePortion(hex20, hex21) HingeLidProfile();
 862
 863       // catch
 864       CatchPortion(catch_width)
 865         CatchCatchProfile();
 866     }
 867     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 868
 869     // screw holes in the hinge arms
 870     HingeScrews();
 871
 872     // prop recess
 873     translate([prop_x_pos, -prlp10[0], prlp10[1]])
 874       mirror([0,1,0])
 875       rotate([90,0,90])
 876       linextr(-prop_recess_hw, +prop_recess_hw)
 877       hull()
 878       for (pa = prop_angles)
 879         PropProfile(pa, 1,1);
 880   }
 881 }
 882
 883 module HingeLever(){ ////toplevel
 884   difference() {
 885     // outer body, positive
 886     HingePortion(hex22, hex22 + phone_width/2)
 887       HingeLeverOuterProfile();
 888
 889     // space for the screws
 890     HingePortion(hex23, hex24)
 891       HingeLeverInnerProfile();
 892
 893     // bores for the screws
 894     HingeScrews();
 895
 896     // space for the charging cable
 897     MicroUSB();
 898     Flip_hinge() MicroUSB();
 899   }
 900 }
 901
 902 module HingeLeverPrint(){ ////toplevel
 903   rotate([90,0,0])
 904     HingeLever();
 905 }
 906
 907 module TestSelectLength(){
 908   translate([-30, -200, -20])
 909     cube([30 + 15, 250, 40]);
 910 }
 911
 912 module TestLength(){ ////toplevel
 913   intersection(){
 914     Case();
 915     TestSelectLength();
 916   }
 917 }
 918
 919 module TestLengthRight(){ ////toplevel
 920   intersection(){
 921     Case();
 922     Flip_rhs(1)
 923       TestSelectLength();
 924   }
 925 }
 926
 927 module TestSelectWidth(){
 928   translate([-30, -(phone_height - 25), -20])
 929     mirror([0, 1, 0])
 930     cube([200, 50, 40]);
 931 }
 932
 933 module TestWidth(){ ////toplevel
 934   intersection(){
 935     Case();
 936     TestSelectWidth();
 937   }
 938 }
 939
 940 module TestLidWidthPrint(){ ////toplevel
 941   rotate([0,180.0]) intersection(){
 942     Lid();
 943     TestSelectWidth();
 944   }
 945 }
 946
 947 module TestSelectRearAperture(){
 948   minkowski(){
 949     union() children();
 950     translate([20, 0,0])
 951       cube([42, 2, 1], center=true);
 952   }
 953 }
 954
 955 module TestSelectCamera(){
 956   minkowski(){
 957     TestSelectRearAperture()
 958       RearCameraAperture();
 959     cube([0.1, 50, 0.1]);
 960   }
 961 }
 962
 963 module TestSelectOrdinaryRearApertures(){
 964   TestSelectRearAperture()
 965     OrdinaryRearApertures();
 966 }
 967
 968 module TestCamera(){ ////toplevel
 969   intersection(){
 970     Case();
 971     TestSelectCamera();
 972   }
 973 }
 974
 975 module TestLidByCamera(){ ////toplevel
 976   intersection(){
 977     Lid();
 978     TestSelectCamera();
 979   }
 980 }
 981
 982 module TestLidByCameraPrint(){ ////toplevel
 983   rotate([180,0,0]) TestLidByCamera();
 984 }
 985
 986 module DemoByCamera(){ ////toplevel
 987   color("blue") TestLidByCamera();
 988   color("red")  TestCamera();
 989 }
 990
 991 module OneKeeper(){ ////toplevel
 992   translate([0, -phone_cnr_rad, 0])
 993     rotate([90, 0, 0])
 994     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 995     KeeperProfile();
 996 }
 997
 998 module OneKeeperPrint(){ ////toplevel
 999   rotate([0,180,0])
1000     OneKeeper();
1001 }
1002
1003 module LidPrint(){ ////toplevel
1004   rotate([0,180,0])
1005     Lid();
1006 }
1007
1008 module TestSelectFrame(){
1009   include = [1,-1] * (epp2i[0] + 4);
1010
1011   difference(){
1012     cube(1000, center=true);
1013     translate([0,0, -100])
1014       linear_extrude(height=200)
1015       rectfromto(include,  inside_br - include);
1016   }
1017 }
1018
1019 module TestSelectLidFrame(){
1020   TestSelectFrame();
1021 }
1022
1023 module TestFrameCase(){ ////toplevel
1024   intersection(){
1025     Case();
1026     union(){
1027       TestSelectFrame();
1028       TestSelectCamera();
1029       TestSelectOrdinaryRearApertures();
1030     }
1031   }
1032 }
1033
1034 module TestTopApertures(){ ////toplevel
1035   intersection(){
1036     Case();
1037     TestSelectFrame();
1038     translate([-100, -35, -100])
1039       cube([400, 100, 200]);
1040   }
1041 }
1042
1043 module TestFrameLidPrint(){ ////toplevel
1044   rotate([0,180,0]) intersection(){
1045     Lid();
1046     TestSelectLidFrame();
1047   }
1048 }
1049
1050 module ButtonPlanForDemo(z, deep, cut){
1051   translate([0,0,z])
1052     ButtonPlan(8, deep, cut);
1053 }
1054
1055 module HingeScrews(){
1056   Flip_rhs() Flip_bot(1){
1057     for (c= [ hppT, hppB ])
1058       translate([ hex20,
1059                   -c[0],
1060                   c[1] ]){
1061         rotate([0,90,0])
1062           translate([0,0,-.2])
1063           cylinder( r= hingescrew_shaft_dia/2,
1064                     h = hingescrew_shaft_len+0.2 );
1065         rotate([0,-90,0])
1066           translate([0,0,+.1])
1067           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1068       }
1069   }
1070 }
1071
1072 module DemoPropAngleSelect(c){
1073   color(c) difference(){
1074     union(){ children(); }
1075     translate([ prop_x_pos, -400, -200 ])
1076       cube([ 400,800,400 ]);
1077   }
1078 }
1079
1080 module DemoPropAngle(ang){
1081   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1082   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1083
1084   translate(hL)
1085     rotate([ang/2,0,0])
1086     translate(-hL)
1087     translate(hC)
1088     rotate([ang/2,0,0])
1089     translate(-hC) {
1090       DemoPropAngleSelect("red") Case();
1091
1092       color("orange")
1093         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1094         PropProfileAssignments(ang) {
1095           echo($prpp1);
1096           rotate([-$prp_theta, 0, 0])
1097           translate([0, $prpp1[0], -$prpp1[1]])
1098           rotate([90,0,-90])
1099           Prop();
1100         }
1101     }
1102
1103   translate([0,0, -hp_k*2])
1104     DemoPropAngleSelect("blue")
1105     Lid();
1106 }
1107
1108 module DemoPropAngles(){ ////toplevel
1109   for (i=[0 : len(prop_angles)-1])
1110     translate(i * [0, -100, 100])
1111     DemoPropAngle(prop_angles[i]);
1112 }
1113
1114 module DemoFrame(){ ////toplevel
1115   color("red") TestFrameCase();
1116   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1117   color("black") HingeScrews();
1118   %HingeLever();
1119 }
1120
1121 module DemoHingedFrame(){ ///toplevel
1122   color("red") TestFrameCase();
1123   translate([0,0, -2*hp_k])
1124   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1125
1126   Flip_hinge(){
1127     color("orange") HingeLever();
1128     color("black") HingeScrews();
1129   }
1130 }
1131
1132 module DemoHinge(){ ////toplevel
1133   DemoFrame();
1134   translate([0,0, -hp_k*3])
1135     DemoHingedFrame();
1136 }
1137
1138 module DemoProfiles(){ ////toplevel
1139   LidEdgeProfile();
1140   %EdgeProfile();
1141   KeeperProfile();
1142   translate([0,0,-1]) color("black") KeeperProfile(1);
1143
1144   translate([20,0]) {
1145     LidEdgeProfile();
1146     %EdgeProfile();
1147
1148     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1149
1150     color("blue") ButtonCoverProfile();
1151     color("red") {
1152       rectfromto(bppQ, demopoint_QR);
1153       rectfromto(bppR, demopoint_QR);
1154     }
1155   }
1156
1157   translate([-20,0]) {
1158     color("black") ButtonPlanForDemo(-2, 0,1);
1159     color("red" )  ButtonPlanForDemo(-4, 1,1);
1160     color("blue")  ButtonPlanForDemo(-6, 1,0);
1161   }
1162
1163   translate([0, -30]) {
1164     %LidEdgeProfile();
1165     %EdgeProfile();
1166     color("blue") HingeLidProfile();
1167     color("red")  HingeBaseProfile();
1168     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1169     color("orange") translate([0,0,-1]) HingeLeverInnerProfile();
1170   }
1171
1172   translate([20,-30]) {
1173     %EdgeProfile();
1174     %LidEdgeProfile();
1175     //translate([0,0,1]) CatchCutProfile();
1176     color("blue") CatchCatchProfile();
1177     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1178   }
1179
1180   translate([40,-30]) {
1181     difference(){
1182       LidEdgeProfile();
1183       translate(prlp10)
1184         PropProfile(10, 1, 0);
1185     }
1186     translate(prlp10)
1187       PropProfile(15, 0);
1188   }
1189   translate([60,-30]) {
1190     PropAggregateProfile();
1191   }
1192 }
1193
1194 //EdgeProfile();
1195 //KeeperProfile();
1196 //CaseBase();
1197 //%Case();
1198 //Keeper();
1199 //LidEdgeProfile();
1200 //KeeperProfile();
1201 //DemoProfiles();
1202 //PropRecess();