fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121
 122 phone = [ 75.0, 145.0 ];
 123
 124 prop_buildout_less = 3;
 125
 126 prop_angles = [ 15, 30, 45, 60 ];
 127
 128 bumper = [ 0.250, -0.025 ];
 129 // ^ One side.  Overall size is increased by twice this.
 130 // If no bumpers, is the gap around the phone.
 131
 132 enable_support = 1;
 133
 134 led_window_style = 3;
 135 // 0: no window
 136 // 1: simply an opening
 137 // 2: opening with separate cover model, for printing in clear (two colour)
 138 // 3: like 2 but one-layer window for ad-hoc multi-colour
 139
 140 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 141 initial_layer_width = 0.750; // ^ needed for mode 3 only
 142 multicolour_gap = 0.15; // each side
 143
 144 phone_cnr_rad = 6.0;
 145 phone_rim_depth = 0.80; // includes allowance for a screen protector
 146
 147 button_cutout_depth = 9;
 148
 149 phone_edge_thick = 9.0;
 150 phone_total_thick = 12.0;
 151 phone_backside_slope_inner = 1.5; // larger means shallower
 152 phone_backside_slope_outer = 1.0; // larger means shallower
 153
 154 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 155 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 156
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 led_pos = [ 13.98, 10.00 ];
 161 led_aperture = 9;
 162 led_window_ledge = 0.75; // each side
 163
 164 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 165 noisecancelmic_dia = 4.00;
 166
 167 //fingerpushhole_dias = [ 15, 18 ];
 168 fingerpushhole_dias = [];
 169
 170 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 171 rearspeaker_size   = [  3.76,  7.36 ];
 172
 173 microusb_above = 3.27 - 0.25;
 174 microusb_below = 0.0;
 175 microusb_width = 16.12 + 1.25;
 176
 177 case_th_bottom = 2.5;
 178 case_th_lid = 3.0;
 179 case_th_side = 2.3;
 180 case_th_lip = 1.2;
 181
 182 lid_screen_gap_extra = .66;
 183
 184 case_struts_count = 6;
 185 case_struts_solid_below = 1.00;
 186 case_struts_solid_above = 0.75;
 187 case_struts_width = 0.10;
 188
 189 keeper_th_z = 0.75;
 190 keeper_th_x = 0.75;
 191 keeper_inner_width = 2.75;
 192 keeper_inner_height = 2.75;
 193 keeper_slant_slope = 2; // larger means steeper
 194
 195 keeper_gap_z_top = 0.25;
 196 keeper_gap_z_bot = 0.75;
 197 keeper_gap_x     = 0.25;
 198 keeper_gap_x_holes = 0.75;
 199
 200 keeper_side = 0; // 0 = lhs; 1 = rhs
 201
 202 case_lip = 1.25;
 203
 204 lid_gap_x = 0.25;
 205 lid_gap_z = 0.25;
 206 lid_lip = 1.75;
 207 lid_edgepart_width = 5.0;
 208 lid_buttoncover_thick = 1.3;
 209
 210 catch_slop = 0.50;
 211
 212 foldover_gap = 0.50;
 213 foldover_lever_gap = 0.50;
 214
 215 // properties of the hinge fasteners
 216 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 217 hingescrew_shaft_len = 12;
 218 hingescrew_fasteners_extra_thick = 0.40;
 219 // ^ amount of thread protruding if everything was completely nominal
 220 //   and we are using two nuts
 221 hingescrew_nut_access_dia = 4.72 + 0.50;
 222 // ^ washer is 4.72 dia
 223 //   also, want to get pliers or tiny spanner in to do up locknut
 224 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 225 hingescrew_nut_thick = 1.93;
 226 hingescrew_head_th = 1.38 + 0.75;
 227 hingescrew_head_dia = 3.92;
 228
 229 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 230
 231 lever_cover_th = 0.75;
 232 hingemount_th = 2.5;
 233 hingemount_wd = 4.8725;
 234
 235 $fa = 5;
 236 $fs = 0.1;
 237
 238 button_l_fudge = 4.4;
 239 buttonishleg_default_l_is_fudge = 10;
 240
 241 hinge_base_slope = 1.5; // bigger is steeper
 242
 243 strut_min_at_end = 1.5;
 244
 245 hinge_x_gap = 0.125;
 246 hinge_x_postscrew_gap = 0.75;
 247 hinge_x_arms_gap = 0.35;
 248 hinge_r_arms_gap = 0.55;
 249
 250 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 251
 252 catch_len = 7.5;
 253 catch_width = 15;
 254 catch_thickness = 1.0;
 255 catch_side_gap = 0.75; // each side
 256
 257 catch_depth = 0.75;
 258 catch_height = 0.35;
 259 catch_finger_height = 1.5;
 260 catch_finger_depth = 2.5;
 261
 262 prop_recess_under = 0.50;
 263 prop_recess_slop = 0.200; // each side
 264 prop_end_dia = 0.5;
 265 prop_main_th = 3;
 266 prop_taper_len = 6;
 267 prop_main_width = 4;
 268 prop_side_gap = 0.75; // each side
 269 prop_lidrecess_behind = 0.75;
 270 prop_caserecess_behind = 0.75;
 271 prop_caserecess_taper = 0.45; // one side only
 272 prop_prop_gap = 0.5;
 273 prop_prong_heel_slope = 0.5;
 274
 275 lid_fold_clearance_antislop = 0.5;
 276
 277 // ---------- calculated ----------
 278
 279 phone_width =  (phone + bumper*2)[0];
 280 phone_height = (phone + bumper*2)[1];
 281
 282 inside_br = [phone_width, -phone_height];
 283
 284 prop_prong_h = prop_main_th;
 285
 286 //echo(camera_pos_tl + bumper,
 287 //     camera_pos_br + bumper);
 288
 289 // ----- could be changed -----
 290 lid_buttoncover_gap = lid_gap_x;
 291 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 292
 293 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 294
 295 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 296
 297 //prop_nose_len = case_th_lid - prop_recess_under;
 298 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 299 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 300
 301
 302 //lid_lip_overlap_width xxx bad name = ;
 303 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 304
 305 epp0 = [0,0];
 306 epp1 = [0, -phone_edge_thick];
 307 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 308 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 309 epp3 = epp2i + [10, 0];
 310 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 311 epp4 = epp5 + [-1,0] * case_th_side;
 312
 313 kppe = [0,0];
 314 kppd = kppe + [1,0] * keeper_inner_width;
 315 kppc = kppd + [0,1] * keeper_th_z;
 316 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 317 kppf = kppe - [0,1] * keeper_inner_height;
 318 kppa = [ kppb[0], kppf[1] ];
 319
 320 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 321 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 322
 323 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 324 // exact x posn not very important; must extend past end of keeper
 325
 326 lpp15 = [ lpp14[0],
 327           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 328           + lid_screen_gap_extra ];
 329 // ^ beam theory says to maximise force before contact,
 330 //   the gap below the `beam' (the lid) must be 1/3
 331 //   the thickness (ie the lid thickness) if the beam
 332 //   is solid, or 1/2 if it has a top and bottom only.
 333 //   ours is mostly solid.
 334
 335 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 336              case_th_lip);
 337
 338 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 339 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 340
 341 case_bottom_z = epp2o[1] - case_th_bottom;
 342
 343 // button profile
 344 bppM = epp4 + [0,5];
 345 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 346 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 347 bppS = [ epp1[0], bppR[1] ];
 348 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 349 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 350 bppO = [ bppN[0], bppP[1] ];
 351 bppL = lpp10 + [5,0];
 352 bppK = [ bppL[0], bppN[1] ];
 353 bppJ = [ bppN[0], bppL[1] ];
 354 bppU = [ bppJ[0], lpp12[1] ];
 355 bppV = lpp11;
 356 bppW = lpp10;
 357
 358 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 359
 360 // notification led aperture
 361
 362 nla_r0 = led_aperture/2;
 363 nla_r1 = nla_r0 + led_window_ledge;
 364 nla_r2 = nla_r1 + multicolour_gap;
 365 nla_t =
 366   led_window_style >= 3 ? initial_layer_thick :
 367   led_window_style >= 2 ? led_window_ledge : 0;
 368
 369
 370 // hinge plan
 371 hp_rn = hingescrew_nut_access_dia/2;
 372 hp_r2_min = hp_rn + lever_cover_th;
 373 hp_rs = hingescrew_shaft_dia/2;
 374 hp_r1_min = hp_rs + hingemount_th;
 375
 376 hp_r1 = max(hp_r1_min, hp_r2_min);
 377 hp_r2 = hp_r1;
 378
 379 hppU = lpp13;
 380 hppS = epp2o + [0,-1] * case_th_bottom;
 381 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 382
 383 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 384          0.5 * (hppU + hppS)[1] ];
 385 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 386 hppB = hppT + [0,-1] * hp_k;
 387
 388 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 389 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 390 hppE = [ hppE_x, hppE_y ];
 391
 392 // hinge elevation x coords
 393
 394 hex20 = max(epp2o[0],
 395             phone_cnr_rad,
 396             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 397 hex21 = hex20 + hingemount_wd;
 398 hex22 = hex21 + hinge_x_gap;
 399 hex27 = hex20 + hingescrew_shaft_len;
 400 hex24 = hex27 + hinge_x_postscrew_gap;
 401 hex23 = hex27 - (hingescrew_nut_thick*2
 402                  + hingescrew_fasteners_extra_thick);
 403 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 404
 405 echo(hex20, hex21, hex22, hex23, hex24);
 406 //  6, 10.8725, 10.9975, 13.74, 18.75
 407 module chk(act,exp) {
 408   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 409   else echo("ok", act);
 410 }
 411 chk(hex20, 6);
 412 chk(hex21, 10.8725);
 413 chk(hex22, 10.9975);
 414 chk(hex23, 13.74);
 415 chk(hex24, 18.75);
 416
 417 lid_fold_clearance_skew =
 418   (lpp10[1] - hppB[1]) /
 419   (lpp10[0] - hppB[0]);
 420
 421 echo("SK",lid_fold_clearance_skew);
 422
 423 // catch
 424
 425 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 426 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 427 cppB = [ epp0[0], cppA[1] ];
 428 cppP = [ epp4[0], cppJ[1] ];
 429
 430 cppS = cppJ + [0,-1] * catch_len;
 431 cppD = [ cppA[0], cppS[1] + catch_slop ];
 432 cppC = [ cppB[0], cppD[1] ];
 433 cppT = cppS + [1,0] * catch_depth;
 434 cppU = cppT + [0,-1] * catch_height;
 435 cppV = [ cppS[0], cppU[1] - catch_depth ];
 436
 437 cppR = 0.5*(cppP + cppJ);
 438
 439 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 440 cppQ = [ cppR[0],
 441          cppV[1] - (catch_finger_height - cp_rQ) ];
 442 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 443
 444 // prop recess in case
 445
 446 prop_x_pos = phone_width/2;
 447
 448 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 449
 450 prc_r1 = prop_end_dia/2;
 451 prc_r3 = prc_r1 + prop_recess_slop;
 452
 453 prcp2 = [ epp4[0] + prop_buildout_less,
 454           case_bottom_z ];
 455
 456 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 457
 458 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 459           epp2i[1] - prc_r3 - prop_recess_under];
 460
 461 // prop recess in lid
 462
 463 prl_r10 = prop_end_dia/2;
 464 prl_r10o = prl_r10 + prop_recess_slop;
 465
 466 prlp10 = lpp10 + [1,1] * prl_r10o
 467   + [1,0] * prop_lidrecess_behind
 468   + [0,1] * prop_recess_under;
 469
 470 // prop
 471
 472 $prpp10 = [0,0];
 473 $prpp11 = [0, prop_taper_len];
 474
 475 $prp_r10 = prl_r10;
 476
 477 // ---------- modules ----------
 478
 479 module AdhocMultiprintFrame(phase, z0, zs) {
 480   // from z0 to z0 + zs*layer
 481   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 482   xextra = extra + -epp4[0];
 483   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 484   yextra = extra + -epp4[0];
 485   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 486   p0 = [ xrange[0], yrange[0] ];
 487   p1 = [ xrange[1], yrange[1] ];
 488   echo(p0, p1);
 489   translate([0,0, z0])
 490     mirror([0,0, zs<0 ? 1 : 0])
 491     linear_extrude(height= initial_layer_thick)
 492     difference(){
 493       rectfromto(p0 - [1,1] * initial_layer_width,
 494                  p1 + [1,1] * initial_layer_width);
 495       rectfromto(p0, p1);
 496     }
 497 }
 498
 499 module KeeperProfile(slant=0){
 500   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 501   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 502 }
 503
 504 module EdgeProfile(){
 505   difference(){
 506     hull(){
 507       translate(epp3) square(case_th_bottom*2, center=true);
 508       circleat(epp2o, r=case_th_bottom);
 509       circleat(epp1, r=case_th_side);
 510       rectfromto(epp0, epp4);
 511     }
 512     polygon([ epp5 + [0,10],
 513               epp1,
 514               epp2i,
 515               epp3 + [10,0] ]);
 516   }
 517 }
 518
 519 module LidEdgeProfile(){
 520   polygon([ lpp10,
 521             lpp11,
 522             lpp12,
 523             lpp13,
 524             lpp13 + [10, 0],
 525             lpp15 + [10, 0],
 526             lpp15,
 527             lpp14,
 528             ]);
 529   intersection(){
 530     circleat(lpp12, r=lp_r12);
 531     rectfromto( lpp12 + [-10,   0],
 532                 lpp12 + [+10, +10] );
 533   }
 534 }
 535
 536 module LidEdgeFoldClearanceProfile(){
 537   translate([-lid_fold_clearance_antislop, 0])
 538     polygon([ lpp10,
 539               lpp11,
 540               lpp11 + [-20,  0],
 541               lpp11 + [-20, 20],
 542               lpp11 + [+20, 20],
 543               lpp10 + [+20,  0] ]);
 544 }
 545
 546 module ButtonCoverProfile(){
 547   intersection(){
 548     polygon(concat([ bppM, bppP, bppO, bppJ ],
 549                    (enable_support && !$button_suppress_over_keeper
 550                     ? [ bppU, bppV, bppW ] : []),
 551                    [ bppL, bppK ]));
 552     hull(){
 553       EdgeProfile();
 554       LidEdgeProfile();
 555     }
 556   }
 557 }
 558
 559 module ButtonPlan(l, deep, cut){
 560   epsilon =
 561     (cut  ? 0 : lid_buttoncover_gap);
 562
 563   delta =
 564     (deep ? lid_buttoncover_overlap : 0);
 565
 566   C = [0,0]; // by definition
 567   T = [ 0, epp4[1] ];
 568   G = T + [0,10];
 569
 570   B0 = C + [0,-1] * button_cutout_depth;
 571   B1 = B0 + [0,1] * epsilon;
 572
 573   r0 = 0.5 * (T[1] - B0[1]);
 574   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 575   H = A + [0,-1] * delta;
 576
 577   D = A + [-2,0] * r0;
 578   F = D + [0,10];
 579
 580   E0 = 0.5 * (D + A);
 581   E1 = E0 + [1,0] * epsilon;
 582
 583   I0 = [ E0[0], H[1] ];
 584   I1 = [ E1[0], H[1] ];
 585
 586   hull(){
 587     for (m=[0,1]) mirror([m,0])
 588       circleat(H, r0 - epsilon);
 589   }
 590   for (m=[0,1]) mirror([m,0]) {
 591     difference(){
 592       polygon([ E1,
 593                 I1,
 594                 H,
 595                 B1,
 596                 G,
 597                 F,
 598                 D
 599                 ]);
 600       circleat(D, r0 + epsilon);
 601     }
 602   }
 603 }
 604
 605 module CatchCatchProfile(){
 606   hull(){
 607     for (c=[ cppR, cppQ ])
 608       circleat(c, cp_rQ);
 609   }
 610   hull(){
 611     circleat(lpp12, lp_r12);
 612     circleat(lpp12 + [5,0], lp_r12);
 613     rectfromto(cppP, cppP + [5,0.1]);
 614   }
 615   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 616 }
 617
 618 module CatchCutProfile(){
 619   polygon([ cppB,
 620             cppA,
 621             cppD,
 622             cppF,
 623             cppF + [0,-10],
 624             cppF + [-10,-10],
 625             lpp12 + [-10,0],
 626             lpp12 + [10,0]
 627             ]);
 628 }
 629
 630 module Flip_rhs(yn=[0,1]) {
 631   for ($rhsflip=yn) {
 632     translate([phone_width/2, 0, 0])
 633       mirror([$rhsflip,0,0])
 634       translate([-phone_width/2, 0, 0])
 635       children();
 636   }
 637 }
 638
 639 module Flip_bot(yn=[0,1]) {
 640   for ($botflip=yn) {
 641     translate([0, -phone_height/2, 0])
 642       mirror([0, $botflip, 0])
 643       translate([0, phone_height/2, 0])
 644       children();
 645   }
 646 }
 647
 648 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 649   // sides
 650   Flip_rhs(){
 651     translate([0, -phone_cnr_rad, 0])
 652       rotate([90,0,0])
 653       linear_extrude(height = phone_height - phone_cnr_rad*2)
 654       children(0);
 655   }
 656   // corners
 657   Flip_rhs() Flip_bot() {
 658     translate([+1,-1] * phone_cnr_rad)
 659       intersection(){
 660         rotate_extrude()
 661           intersection(){
 662             mirror([1,0,0])
 663               translate([-1,0] * phone_cnr_rad)
 664               children(0);
 665             rectfromto([0,-20],[10,20]);
 666           }
 667         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 668           cube([10,10,40]);
 669       }
 670   }
 671   // top and bottom
 672   Flip_bot(){
 673     translate([ phone_width - phone_cnr_rad, 0,0 ])
 674       rotate([90,0,-90])
 675       linear_extrude(height = phone_width - phone_cnr_rad*2)
 676       children(0);
 677   }
 678   // fill
 679   translate([0,0, fill_zstart])
 680     mirror([0,0, fill_downwards])
 681     linear_extrude(height = fill_th)
 682     rectfromto([+1,-1] * phone_cnr_rad,
 683                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 684 }
 685
 686 module CaseAperture(pos, dia, $fn) {
 687   theta = 180/$fn;
 688   translate([ pos[0] + bumper[0],
 689               -epp2i[0],
 690               -pos[1] ])
 691     rotate([-90, theta, 0])
 692     cylinder(r = dia/2 / cos(theta),
 693              h = 60);
 694 }
 695
 696 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 697   // y_ref_sign:
 698   //   +1  measured from top    of actual phone to top    of button
 699   //   -1  measured from bottom of actual phone to bottom of button
 700   //    0  y is centre of button in coordinate system
 701   $button_l= l;
 702   $button_suppress_over_keeper= suppress_over_keeper;
 703   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 704           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 705           y;
 706   //echo(eff_y);
 707   translate([0, eff_y, 0])
 708     children();
 709 }
 710
 711 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 712   $button_leg_only = true;
 713   SideButton(y, y_ref_sign, l) children();
 714 }
 715
 716 module Buttons(){
 717   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 718   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 719   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 720   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 721 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 722 }
 723
 724 module Struts(x_start, z_min, th){
 725   // if th is negative, starts at z_min and works towards -ve z
 726   // and object should then be printed other way up
 727   for (i= [1 : 1 : case_struts_count]) {
 728     translate([0,
 729                0,
 730                z_min])
 731       mirror([0,0, th<0 ? 1 : 0])
 732       translate([0,
 733                  -phone_height * i / (case_struts_count+1),
 734                  case_struts_solid_below])
 735       linear_extrude(height= abs(th)
 736                      -(case_struts_solid_below+case_struts_solid_above))
 737       rectfromto([               x_start, -0.5 * case_struts_width ],
 738                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 739   }
 740 }
 741
 742 module OrdinaryRearAperture(rhs,bot, pos){
 743   Flip_rhs(rhs) Flip_bot(bot)
 744     linextr(-20, 20)
 745     mirror([0,1])
 746     translate(pos + bumper)
 747     children();
 748 }
 749
 750 module MicroUSB(){
 751   Flip_bot(1){
 752     rotate([90,0,0])
 753       mirror([0,0,1])
 754       linextr(-epp2i[0], 60)
 755       translate([0.5 * phone_width, 0, 0])
 756       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 757                  [+microusb_width/2, epp0[1] + -microusb_above]);
 758   }
 759 }
 760
 761 module OrdinaryRearApertures(){
 762   // rear speaker
 763   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 764     rectfromto(-rearspeaker_gap,
 765                rearspeaker_size + rearspeaker_gap);
 766
 767   // finger hole to remove phone
 768   if (len(fingerpushhole_dias))
 769     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 770                                 phone[1]/2 ])
 771     scale(fingerpushhole_dias)
 772     circle(r= 0.5 );
 773 }
 774
 775 module RearCameraAperture(){
 776   Flip_rhs(1)
 777     mirror([0, 0, 1])
 778     linear_extrude(height = 20)
 779     mirror([0, 1, 0])
 780     translate(bumper)
 781     rectfromto(camera_pos_tl, camera_pos_br);
 782 }
 783
 784 module HingeLidProfile(){
 785   hull(){
 786     circleat(hppT, hp_r1);
 787     circleat(lpp12, lp_r12);
 788     polygon([lpp10,
 789              lpp13 + [2,0],
 790              lpp12,
 791              hppT]);
 792   }
 793 }
 794
 795 module HingeBaseProfile(){
 796   difference(){
 797     hull(){
 798       circleat(hppB, hp_r1);
 799       circleat(hppE, hp_r1);
 800       circleat(epp2o, case_th_bottom);
 801       circleat(hppB + [10,0], hp_r1);
 802     }
 803     polygon([epp5, epp1, epp2i, epp3, bppL]);
 804   }
 805 }
 806
 807 module HingeLeverOuterProfile(){
 808   hull(){
 809     circleat(hppT, hp_r2);
 810     circleat(hppB, hp_r2);
 811   }
 812 }
 813
 814 module HingeLeverInnerProfile(){
 815   for (s = [-1,+1]) {
 816     c = s > 0 ? hppT : hppB;
 817     translate(c)
 818       mirror([0,0,s>0])
 819       rotate(s<0 ? -40 : 0)
 820       hull()
 821       for (x=[-20,20])
 822         for (y=[0, s * 10])
 823           translate([x,y])
 824             circle(hp_rn);
 825   }
 826 }
 827
 828 module HingeLeverNutProfile(){
 829   for (c= [hppB, hppT]) {
 830     translate(c)
 831       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 832   }
 833 }
 834
 835 module Flip_hinge(doflip=1){
 836   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 837   translate(hinge_origin)
 838     rotate([doflip*180,0,0])
 839     translate(-hinge_origin)
 840     children();
 841 }
 842
 843 module HingePortion(x0,x1){
 844   Flip_rhs() Flip_bot(1)
 845     translate([x0,0,0])
 846     mirror([1,0,0])
 847     rotate([90,0,-90])
 848     linear_extrude(height=x1-x0)
 849     children();
 850 }
 851
 852 module CatchPortion(xwidth){
 853   width = catch_width + xwidth;
 854   translate([phone_width/2, 0,0])
 855     rotate([90,0,-90])
 856     linextr(-width/2, width/2)
 857     children(0);
 858 }
 859
 860 module CaseBase(){
 861   AroundEdges(epp3[1], case_th_bottom, 1)
 862     EdgeProfile();
 863 }
 864
 865 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 866
 867 module PropProfileAssignments(gamma){
 868   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 869   x = prop_x(gamma);
 870   p = phone_height + prlp10[0] - hppB[0];
 871   b = p + x;
 872
 873   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 874   a = q + x;
 875   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 876   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 877
 878   $prp_theta = 90 - $prp_alpha;
 879   beta = 180 - $prp_alpha - gamma;
 880   psi = 90 - beta;
 881
 882   //echo("abc", a,b,c);
 883
 884   v1 = [ [ cos(psi), -sin(psi) ],    // x
 885          [ sin(psi),  cos(psi) ] ];  // y
 886
 887   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 888
 889   $prp_r1 = prc_r1;
 890   $prp_r11 = prop_main_th/2;
 891
 892   $prpp1 = $prpp7 + [1,0] *
 893     // this is approximate, but will do
 894     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 895   $prpp3 = $prpp1 +
 896     v1[0] * -$prp_r1 +
 897     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 898   $prpp12 = $prpp3 + v1[0] *
 899     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 900   $prp_r8 = prop_main_th;
 901   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 902   $prp_r5 = $prp_r8;
 903   $prpp5 = [ $prpp12[0] - $prp_r5,
 904             $prpp3[1] - prop_prong_h + $prp_r5 ];
 905   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 906          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 907   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 908   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 909
 910   children();
 911 }
 912
 913 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 914   PropProfileAssignments(gamma){
 915
 916     //#circleat($prpp3,1);
 917     //#circleat($prpp12,1);
 918
 919     if (!cut) {
 920       hull(){
 921         translate($prpp8)
 922           intersection(){
 923             circle($prp_r8);
 924             polygon([[-20,-0], [20,20], [0,0]]);
 925           }
 926         rectfromto($prpp6, $prpp9);
 927         translate($prpp5) intersection(){
 928           circle($prp_r5);
 929           polygon([[-10,-10], [0,0], [10,0]]);
 930         }
 931         rectfromto($prpp12 + [0,-0.1], $prpp3);
 932       }
 933       hull(){
 934         circleat($prpp1, $prp_r1);
 935         rectfromto($prpp12 + [0,-0.1], $prpp3);
 936       }
 937     }
 938     // main shaft
 939     rotate([0,0, rot*-$prp_theta]){
 940       hull(){
 941         extra = cut ? prop_recess_slop : 0;
 942         rectfromto($prpp6, $prpp9);
 943         circleat($prpp11, $prp_r11 + extra);
 944         circleat($prpp10, $prp_r10 + extra);
 945       }
 946     }
 947   }
 948 }
 949
 950 module PropAggregateProfile(){
 951   for (angle = prop_angles)
 952     PropProfile(angle, 0,0);
 953 }
 954
 955 module Prop(){ ////toplevel
 956   hw = prop_main_width/2;
 957   linextr(-hw, +hw)
 958     PropAggregateProfile();
 959 }
 960
 961 module Case(){ ////toplevel
 962   difference(){
 963     union(){
 964       CaseBase();
 965
 966       // ledge (fixed keeper)
 967       Flip_rhs(1-keeper_side) intersection(){
 968         rotate([90, 0, 0])
 969           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 970           KeeperProfile(1);
 971
 972         // outline of the whole case, to stop it protruding
 973         translate([0,0, -25])
 974           linear_extrude(height = 50)
 975           hull()
 976           Flip_bot()
 977           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 978       }
 979
 980       // hinge
 981       HingePortion(hex20, hex21) HingeBaseProfile();
 982
 983       // buildout for prop recess
 984       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
 985         linextr(case_bottom_z, epp2i[1])
 986         hull() {
 987           for (dxs = [-1,+1])
 988             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
 989                        -epp2o[0] ],
 990                      r = epp2o[0] - prcp2[0]);
 991         }
 992     }
 993
 994     // slot for keeper
 995     Flip_rhs(keeper_side)
 996       translate([0, -phone_cnr_rad, 0])
 997       rotate([90, 0, 0])
 998       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 999       minkowski(){
1000         KeeperProfile();
1001         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1002                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1003       }
1004
1005     // front camera
1006     RearCameraAperture();
1007
1008     // struts (invisible, because they're buried in the case)
1009     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1010
1011     Buttons(){
1012       mirror([1,0,0])
1013         rotate([90,0,90]) {
1014           if (!($button_leg_only && enable_support))
1015           intersection(){
1016             translate([0,0,-10])
1017               linear_extrude(height= 20)
1018               ButtonPlan($button_l, 0,1);
1019             if ($button_leg_only)
1020               rotate([-90,90,0])
1021                 translate([phone_width/2, -400, kppe[1]])
1022                 mirror([1-abs($rhsflip - keeper_side),0,0])
1023                 cube([400, 800, 50]);
1024             if (enable_support && !$button_suppress_over_keeper)
1025               rotate([-90,90,0])
1026               translate([-400, -400, kppd[1]])
1027                 mirror([0,0,1])
1028                 cube([800,800,100]);
1029           }
1030           translate([0,0, -bppR[0]])
1031             linear_extrude(height= 20)
1032             ButtonPlan($button_l, 1,1);
1033         }
1034
1035     }
1036
1037     // apertures along top edge
1038     CaseAperture(jack_pos, jack_dia, 8);
1039     Flip_rhs(1)
1040       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1041
1042     OrdinaryRearApertures();
1043
1044     MicroUSB();
1045
1046     // gaps for the lid's hinge arms
1047     HingePortion(hex20 - hinge_x_arms_gap,
1048                  hex21 + hinge_x_arms_gap)
1049       minkowski(){
1050         HingeLidProfile();
1051         circle(r= hinge_r_arms_gap, $fn= 8);
1052       }
1053
1054     // screw holes in the hinge arms
1055     HingeScrews();
1056
1057     // catch striker
1058     CatchPortion(catch_side_gap*2)
1059       CatchCutProfile();
1060
1061     // prop recess
1062     Flip_rhs(1)
1063       translate([prop_x_pos,0,0])
1064       mirror([0,1,0])
1065       rotate([90,0,90])
1066       linextr(-prop_recess_hw, +prop_recess_hw)
1067       hull(){
1068         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1069           circleat(prcp1 + 20*d,
1070                    prc_r3);
1071       }
1072   }
1073 }
1074
1075 module LidAdhocMultiprintFrame(phase){
1076   if (led_window_style >= 3) {
1077     AdhocMultiprintFrame(phase, lpp13[1], -1);
1078   }
1079 }
1080
1081 module LidAroundEdges(){
1082   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1083     children();
1084 }
1085
1086 module Lid(){ ////toplevel
1087   skew_centre = [0, lpp11[0], lpp11[1]];
1088   difference(){
1089     union(){
1090       intersection(){
1091         LidAroundEdges()
1092           LidEdgeProfile();
1093
1094         translate(skew_centre)
1095           multmatrix([[ 1, 0, 0, 0 ],
1096                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1097                       [ 0, 0, 1, 0 ],
1098                       [ 0, 0, 0, 1 ]])
1099           translate(-skew_centre)
1100           LidAroundEdges()
1101           LidEdgeFoldClearanceProfile();
1102       }
1103
1104       // button covers
1105       Buttons(){
1106         intersection(){
1107           rotate([90,0,90])
1108             translate([0,0,-10])
1109             linear_extrude(height= 20)
1110             ButtonPlan($button_l, 1,0);
1111           rotate([90,0,0])
1112              translate([0,0,-100])
1113             linear_extrude(height= 200)
1114             ButtonCoverProfile();
1115         }
1116       }
1117
1118       // hinge arms
1119       HingePortion(hex20, hex21) {
1120         LidEdgeProfile();
1121         HingeLidProfile();
1122       }
1123
1124       // catch
1125       CatchPortion(0)
1126         CatchCatchProfile();
1127     }
1128     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1129
1130     // screw holes in the hinge arms
1131     HingeScrews();
1132
1133     // prop recess
1134     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1135       mirror([0,1,0])
1136       rotate([90,0,90])
1137       linextr(-prop_recess_hw, +prop_recess_hw)
1138       hull()
1139       for (pa = prop_angles)
1140         PropProfile(pa, 1,1);
1141
1142     // notification led aperture
1143     if (led_window_style)
1144       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1145         translate([0,0,-10])
1146           cylinder(r=nla_r0, h=20);
1147         if (led_window_style >= 2)
1148           translate([0,0, -nla_t])
1149             cylinder(r=nla_r2, height=20);
1150       }
1151
1152     }
1153
1154   LidAdhocMultiprintFrame(1);
1155 }
1156
1157 module HingeLever(){ ////toplevel
1158   difference() {
1159     // outer body, positive
1160     HingePortion(hex22, hex22 + phone_width/2)
1161       HingeLeverOuterProfile();
1162
1163     // space for the screws
1164     HingePortion(hex26, hex24)
1165       HingeLeverInnerProfile();
1166
1167     // recesses for the nuts
1168     HingePortion(hex23, hex26+1)
1169       HingeLeverNutProfile();
1170
1171     // bores for the screws
1172     HingeScrews();
1173
1174     // space for the charging cable
1175     MicroUSB();
1176     Flip_hinge() MicroUSB();
1177   }
1178 }
1179
1180 module LidWindow(){ ////toplevel
1181   translate([led_pos[0], -led_pos[1], lpp13[1]])
1182     mirror([0,0,1])
1183     cylinder(r= nla_r1, h=nla_t);
1184   LidAdhocMultiprintFrame(0);
1185 }
1186
1187 module LidWindowPrint(){ ////toplevel
1188   rotate([0,180,0])
1189     LidWindow();
1190 }
1191
1192 module DemoLidWindowSelect(){
1193   translate([led_pos[0], led_pos[1], -100]) {
1194     translate([0, -30, 0]) cube([400, 400, 200]);
1195   }
1196 }
1197
1198 module DemoLidWindow(){ ////toplevel
1199   %Lid();
1200   LidWindow();
1201   translate([0,40,0]){
1202     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1203     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1204   }
1205 }
1206
1207 module HingeLeverPrint(){ ////toplevel
1208   rotate([-90,0,0])
1209     translate([-phone_width/2, phone_height, 0])
1210     HingeLever();
1211 }
1212
1213 module TestSelectLength(){
1214   translate([-30, -200, -20])
1215     cube([30 + 15, 250, 40]);
1216 }
1217
1218 module TestLength(){ ////toplevel
1219   intersection(){
1220     Case();
1221     TestSelectLength();
1222   }
1223 }
1224
1225 module TestLengthRight(){ ////toplevel
1226   intersection(){
1227     Case();
1228     Flip_rhs(1)
1229       TestSelectLength();
1230   }
1231 }
1232
1233 module TestSelectWidth(){
1234   translate([-30, -(phone_height - 25), -20])
1235     mirror([0, 1, 0])
1236     cube([200, 50, 40]);
1237 }
1238
1239 module TestWidth(){ ////toplevel
1240   intersection(){
1241     Case();
1242     TestSelectWidth();
1243   }
1244 }
1245
1246 module TestLidWidthPrint(){ ////toplevel
1247   rotate([0,180.0]) intersection(){
1248     Lid();
1249     TestSelectWidth();
1250   }
1251 }
1252
1253 module TestSelectRearAperture(){
1254   minkowski(){
1255     union() children();
1256     translate([20, 0,0])
1257       cube([42, 2, 1], center=true);
1258   }
1259 }
1260
1261 module TestSelectCamera(){
1262   minkowski(){
1263     TestSelectRearAperture()
1264       RearCameraAperture();
1265     cube([0.1, 50, 0.1]);
1266   }
1267 }
1268
1269 module TestSelectOrdinaryRearApertures(){
1270   TestSelectRearAperture()
1271     OrdinaryRearApertures();
1272 }
1273
1274 module TestCamera(){ ////toplevel
1275   intersection(){
1276     Case();
1277     TestSelectCamera();
1278   }
1279 }
1280
1281 module TestLidByCamera(){ ////toplevel
1282   intersection(){
1283     Lid();
1284     TestSelectCamera();
1285   }
1286 }
1287
1288 module TestLidByCameraPrint(){ ////toplevel
1289   rotate([180,0,0]) TestLidByCamera();
1290 }
1291
1292 module DemoByCamera(){ ////toplevel
1293   color("blue") TestLidByCamera();
1294   color("red")  TestCamera();
1295 }
1296
1297 module OneKeeper(){ ////toplevel
1298   translate([0, -phone_cnr_rad, 0])
1299     rotate([90, 0, 0])
1300     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1301     KeeperProfile();
1302 }
1303
1304 module OneKeeperPrint(){ ////toplevel
1305   rotate([0,180,0])
1306     OneKeeper();
1307 }
1308
1309 module LidPrint(){ ////toplevel
1310   rotate([0,180,0])
1311     Lid();
1312 }
1313
1314 module TestSelectFrame(){
1315   include = [1,-1] * (epp2i[0] + 4);
1316
1317   difference(){
1318     cube(1000, center=true);
1319     translate([0,0, -100])
1320       linear_extrude(height=200)
1321       rectfromto(include,  inside_br - include);
1322   }
1323 }
1324
1325 module TestSelectLidFrame(){
1326   TestSelectFrame();
1327   translate([led_pos[0], -led_pos[1], -50])
1328     cylinder(r= nla_r2+3, h=100);
1329 }
1330
1331 module TestFrameCase(){ ////toplevel
1332   intersection(){
1333     Case();
1334     union(){
1335       TestSelectFrame();
1336       TestSelectCamera();
1337       TestSelectOrdinaryRearApertures();
1338     }
1339   }
1340 }
1341
1342 module TestSelectTopApertures(){
1343   translate([-100, -35, -100])
1344     cube([400, 100, 200]);
1345   LidAdhocMultiprintFrame(0);
1346   LidAdhocMultiprintFrame(1);
1347 }
1348
1349 module TestTopApertures(){ ////toplevel
1350   intersection(){
1351     Case();
1352     TestSelectFrame();
1353     TestSelectTopApertures();
1354   }
1355 }
1356
1357 module TestLidTopAperturesPrint(){ ////toplevel
1358   rotate([0,180,0]) intersection(){
1359     Lid();
1360     TestSelectLidFrame();
1361     TestSelectTopApertures();
1362   }
1363 }
1364
1365 module TestLidWindowTopAperturesPrint(){ ////toplevel
1366   rotate([0,180,0]) intersection(){
1367     LidWindow();
1368     TestSelectTopApertures();
1369   }
1370 }
1371
1372 module TestFrameLidPrint(){ ////toplevel
1373   rotate([0,180,0]) intersection(){
1374     Lid();
1375     TestSelectLidFrame();
1376   }
1377 }
1378
1379 module ButtonPlanForDemo(z, deep, cut){
1380   translate([0,0,z])
1381     ButtonPlan(8, deep, cut);
1382 }
1383
1384 module HingeScrews(){
1385   Flip_rhs() Flip_bot(1){
1386     for (c= [ hppT, hppB ])
1387       translate([ hex20,
1388                   -c[0],
1389                   c[1] ]){
1390         rotate([0,90,0])
1391           translate([0,0,-.2])
1392           cylinder( r= hingescrew_shaft_dia/2,
1393                     h = hingescrew_shaft_len+0.2 );
1394         rotate([0,-90,0])
1395           translate([0,0,+.1])
1396           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1397       }
1398   }
1399 }
1400
1401 module DemoPropAngleSelect(c){
1402   color(c) difference(){
1403     union(){ children(); }
1404     translate([ prop_x_pos, -400, -200 ])
1405       cube([ 400,800,400 ]);
1406   }
1407 }
1408
1409 module DemoPropAngle(ang){
1410   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1411   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1412
1413   translate(hL)
1414     rotate([ang/2,0,0])
1415     translate(-hL)
1416     translate(hC)
1417     rotate([ang/2,0,0])
1418     translate(-hC) {
1419       DemoPropAngleSelect("red") Case();
1420
1421       color("orange")
1422         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1423         PropProfileAssignments(ang) {
1424           echo($prpp1);
1425           rotate([-$prp_theta, 0, 0])
1426           translate([0, $prpp1[0], -$prpp1[1]])
1427           rotate([90,0,-90])
1428           Prop();
1429         }
1430     }
1431
1432   translate([0,0, -hp_k*2])
1433     DemoPropAngleSelect("blue")
1434     Lid();
1435 }
1436
1437 module DemoPropAngles(){ ////toplevel
1438   for (i=[0 : len(prop_angles)-1])
1439     translate(i * [0, -100, 100])
1440     DemoPropAngle(prop_angles[i]);
1441 }
1442
1443 module DemoHingeAngle(ang1,ang2){
1444   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1445   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1446
1447   translate(hL)
1448     rotate([ang2,0,0])
1449     translate(-hL)
1450     translate(hC)
1451     rotate([ang1,0,0])
1452     translate(-hC) {
1453       color("red") Lid();
1454     }
1455
1456   color("blue") intersection(){
1457     Case();
1458     union(){
1459       translate([bppJ[0], -400, -200])
1460         mirror([1,0,0])
1461         cube([400, 800, 400]);
1462       translate([10, -400, -200])
1463         cube([10, 800, 400]);
1464     }
1465   }
1466 }
1467
1468 module DemoHingeAngles(){ ////toplevel
1469   angles = [ 0, 4, 8, 12 ];
1470   echo("angles",angles);
1471   for (i=[0 : len(angles)-1]) {
1472     translate(i * [0, 0, 30]) {
1473       DemoHingeAngle(0,angles[i]);
1474       translate([0, 200, 0])
1475         DemoHingeAngle(angles[i],0);
1476     }
1477   }
1478 }
1479
1480 module DemoSelectAdhocLeftRight(right=0) {
1481   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1482     mirror([1-right, 0,0])
1483     cube([400, 800, 200]);
1484 }
1485
1486 module DemoLeft(){ ////toplevel
1487   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1488   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1489 }
1490
1491 module DemoFrame(){ ////toplevel
1492   color("red") TestFrameCase();
1493   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1494   color("black") HingeScrews();
1495   %HingeLever();
1496 }
1497
1498 module DemoHingedFrame(){ ///toplevel
1499   color("red") TestFrameCase();
1500   translate([0,0, -2*hp_k])
1501   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1502
1503   Flip_hinge(){
1504     color("orange") HingeLever();
1505     color("black") HingeScrews();
1506   }
1507 }
1508
1509 module DemoHinge(){ ////toplevel
1510   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1511     DemoFrame();
1512     translate([0,0, -hp_k*3])
1513       DemoHingedFrame();
1514   }
1515 }
1516
1517 module DemoProfiles(){ ////toplevel
1518   LidEdgeProfile();
1519   %EdgeProfile();
1520   KeeperProfile();
1521   translate([0,0,-1]) color("black") KeeperProfile(1);
1522
1523   translate([20,0]) {
1524     LidEdgeProfile();
1525     %EdgeProfile();
1526
1527     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1528
1529     color("blue") ButtonCoverProfile();
1530     color("red") {
1531       rectfromto(bppQ, demopoint_QR);
1532       rectfromto(bppR, demopoint_QR);
1533     }
1534   }
1535
1536   translate([-20,0]) {
1537     color("black") ButtonPlanForDemo(-2, 0,1);
1538     color("red" )  ButtonPlanForDemo(-4, 1,1);
1539     color("blue")  ButtonPlanForDemo(-6, 1,0);
1540   }
1541
1542   translate([0, -30]) {
1543     %LidEdgeProfile();
1544     %EdgeProfile();
1545     color("blue") HingeLidProfile();
1546     color("red")  HingeBaseProfile();
1547     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1548   }
1549
1550   for (f=[0,1]) {
1551     translate([-30, -60 + 30*f]) {
1552       translate([0,0,-4]) EdgeProfile();
1553       %translate([0,0,-10]) HingeBaseProfile();
1554       translate([0,-2] * f * hp_k) {
1555         translate([0,0,-4]) LidEdgeProfile();
1556         %translate([0,0,-10]) %HingeLidProfile();
1557       }
1558       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1559         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1560         translate([0,0,0]) color("red") difference(){
1561           HingeLeverOuterProfile();
1562           HingeLeverInnerProfile();
1563         }
1564         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1565       }
1566     }
1567   }
1568
1569   translate([20,-30]) {
1570     %EdgeProfile();
1571     %LidEdgeProfile();
1572     //translate([0,0,1]) CatchCutProfile();
1573     color("blue") CatchCatchProfile();
1574     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1575   }
1576
1577   translate([40,-30]) {
1578     difference(){
1579       LidEdgeProfile();
1580       translate(prlp10)
1581         PropProfile(10, 1, 0);
1582     }
1583     translate(prlp10)
1584       PropProfile(15, 0);
1585   }
1586   translate([60,-30]) {
1587     PropAggregateProfile();
1588   }
1589 }
1590
1591 //EdgeProfile();
1592 //KeeperProfile();
1593 //CaseBase();
1594 //%Case();
1595 //Keeper();
1596 //LidEdgeProfile();
1597 //KeeperProfile();
1598 //DemoProfiles();
1599 //PropRecess();