fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121
 122 phone = [ 75.0, 145.0 ];
 123
 124 prop_buildout_less = 3;
 125
 126 prop_angles = [ 15, 30, 45, 60 ];
 127
 128 bumper = [ 0.250, -0.025 ];
 129 // ^ One side.  Overall size is increased by twice this.
 130 // If no bumpers, is the gap around the phone.
 131
 132 enable_support = 1;
 133
 134 led_window_style = 3;
 135 // 0: no window
 136 // 1: simply an opening
 137 // 2: opening with separate cover model, for printing in clear (two colour)
 138 // 3: like 2 but one-layer window for ad-hoc multi-colour
 139
 140 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 141 initial_layer_width = 0.750; // ^ needed for mode 3 only
 142 multicolour_gap = 0.15; // each side
 143
 144 phone_cnr_rad = 6.0;
 145 phone_rim_depth = 0.80; // includes allowance for a screen protector
 146
 147 button_cutout_depth = 9;
 148
 149 phone_edge_thick = 9.0;
 150 phone_total_thick = 12.0;
 151 phone_backside_slope_inner = 1.5; // larger means shallower
 152 phone_backside_slope_outer = 1.0; // larger means shallower
 153
 154 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 155 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 156
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 led_pos = [ 13.98, 10.00 ];
 161 led_aperture = 9;
 162 led_window_ledge = 0.75; // each side
 163
 164 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 165 noisecancelmic_dia = 4.00;
 166
 167 //fingerpushhole_dias = [ 15, 18 ];
 168 fingerpushhole_dias = [];
 169
 170 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 171 rearspeaker_size   = [  3.76,  7.36 ];
 172
 173 microusb_above = 3.27 - 0.25;
 174 microusb_below = 0.0;
 175 microusb_width = 16.12 + 1.25;
 176
 177 case_th_bottom = 2.5;
 178 case_th_lid = 3.0;
 179 case_th_side = 2;
 180 case_th_lip = 1.2;
 181
 182 lid_screen_gap_extra = .66;
 183
 184 case_struts_count = 6;
 185 case_struts_solid_below = 1.00;
 186 case_struts_solid_above = 0.75;
 187 case_struts_width = 0.10;
 188
 189 keeper_th_z = 0.75;
 190 keeper_th_x = 0.75;
 191 keeper_inner_width = 2.75;
 192 keeper_inner_height = 2.75;
 193 keeper_slant_slope = 2; // larger means steeper
 194
 195 keeper_gap_z_top = 0.25;
 196 keeper_gap_z_bot = 0.75;
 197 keeper_gap_x     = 0.25;
 198 keeper_gap_x_holes = 0.75;
 199
 200 keeper_side = 0; // 0 = lhs; 1 = rhs
 201
 202 case_lip = 1.25;
 203
 204 lid_gap_x = 0.25;
 205 lid_gap_z = 0.25;
 206 lid_lip = 1.75;
 207
 208 catch_slop = 0.50;
 209
 210 foldover_gap = 0.50;
 211 foldover_lever_gap = 0.50;
 212
 213 // properties of the hinge fasteners
 214 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 215 hingescrew_shaft_len = 12;
 216 hingescrew_fasteners_extra_thick = 0.40;
 217 // ^ amount of thread protruding if everything was completely nominal
 218 //   and we are using two nuts
 219 hingescrew_nut_access_dia = 4.72 + 0.50;
 220 // ^ washer is 4.72 dia
 221 //   also, want to get pliers or tiny spanner in to do up locknut
 222 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 223 hingescrew_nut_thick = 1.93;
 224 hingescrew_head_th = 1.38 + 0.75;
 225 hingescrew_head_dia = 3.92;
 226
 227 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 228
 229 lever_cover_th = 0.75;
 230 hingemount_th = 2.5;
 231 hingemount_wd = 4.8725;
 232
 233 $fa = 5;
 234 $fs = 0.1;
 235
 236 button_l_fudge = 4.4;
 237 buttonishleg_default_l_is_fudge = 10;
 238
 239 hinge_base_slope = 1.5; // bigger is steeper
 240
 241 strut_min_at_end = 1.5;
 242
 243 hinge_x_gap = 0.125;
 244 hinge_x_postscrew_gap = 0.75;
 245 hinge_x_arms_gap = 0.35;
 246 hinge_r_arms_gap = 0.55;
 247
 248 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 249
 250 catch_len = 7.5;
 251 catch_width = 15;
 252 catch_thickness = 1.0;
 253 catch_side_gap = 0.75; // each side
 254
 255 catch_depth = 0.75;
 256 catch_height = 0.35;
 257 catch_finger_height = 1.5;
 258 catch_finger_depth = 2.5;
 259
 260 prop_recess_under = 0.50;
 261 prop_recess_slop = 0.200; // each side
 262 prop_end_dia = 0.5;
 263 prop_main_th = 3;
 264 prop_taper_len = 6;
 265 prop_main_width = 4;
 266 prop_side_gap = 0.75; // each side
 267 prop_lidrecess_behind = 0.75;
 268 prop_caserecess_behind = 0.75;
 269 prop_caserecess_taper = 0.45; // one side only
 270 prop_prop_gap = 0.5;
 271 prop_prong_heel_slope = 0.5;
 272
 273 // ---------- calculated ----------
 274
 275 phone_width =  (phone + bumper*2)[0];
 276 phone_height = (phone + bumper*2)[1];
 277
 278 inside_br = [phone_width, -phone_height];
 279
 280 prop_prong_h = prop_main_th;
 281
 282 //echo(camera_pos_tl + bumper,
 283 //     camera_pos_br + bumper);
 284
 285 // ----- could be changed -----
 286 lid_buttoncover_gap = lid_gap_x;
 287 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 288
 289 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 290
 291 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 292
 293 //prop_nose_len = case_th_lid - prop_recess_under;
 294 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 295 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 296
 297
 298 //lid_lip_overlap_width xxx bad name = ;
 299 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 300
 301 epp0 = [0,0];
 302 epp1 = [0, -phone_edge_thick];
 303 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 304 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 305 epp3 = epp2i + [10, 0];
 306 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 307 epp4 = epp5 + [-1,0] * case_th_side;
 308
 309 kppe = [0,0];
 310 kppd = kppe + [1,0] * keeper_inner_width;
 311 kppc = kppd + [0,1] * keeper_th_z;
 312 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 313 kppf = kppe - [0,1] * keeper_inner_height;
 314 kppa = [ kppb[0], kppf[1] ];
 315
 316 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 317 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 318
 319 lpp14 = lpp10 + [1,0] * keeper_inner_width;
 320 // exact x posn not very important; must extend past end of keeper
 321
 322 lpp15 = [ lpp14[0],
 323           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 324           + lid_screen_gap_extra ];
 325 // ^ beam theory says to maximise force before contact,
 326 //   the gap below the `beam' (the lid) must be 1/3
 327 //   the thickness (ie the lid thickness) if the beam
 328 //   is solid, or 1/2 if it has a top and bottom only.
 329 //   ours is mostly solid.
 330
 331 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 332              case_th_lip);
 333
 334 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 335 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 336
 337 case_bottom_z = epp2o[1] - case_th_bottom;
 338
 339 // button profile
 340 bppM = epp4 + [0,5];
 341 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 342 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 343 bppS = [ epp1[0], bppR[1] ];
 344 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 345 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 346 bppO = [ bppN[0], bppP[1] ];
 347 bppL = lpp10 + [5,0];
 348 bppK = [ bppL[0], bppN[1] ];
 349 bppJ = [ bppN[0], bppL[1] ];
 350 bppU = [ bppJ[0], lpp12[1] ];
 351 bppV = lpp11;
 352 bppW = lpp10;
 353
 354 // notification led aperture
 355
 356 nla_r0 = led_aperture/2;
 357 nla_r1 = nla_r0 + led_window_ledge;
 358 nla_r2 = nla_r1 + multicolour_gap;
 359 nla_t =
 360   led_window_style >= 3 ? initial_layer_thick :
 361   led_window_style >= 2 ? led_window_ledge : 0;
 362
 363
 364 // hinge plan
 365 hp_rn = hingescrew_nut_access_dia/2;
 366 hp_r2_min = hp_rn + lever_cover_th;
 367 hp_rs = hingescrew_shaft_dia/2;
 368 hp_r1_min = hp_rs + hingemount_th;
 369
 370 hp_r1 = max(hp_r1_min, hp_r2_min);
 371 hp_r2 = hp_r1;
 372
 373 hppU = lpp13;
 374 hppS = epp2o + [0,-1] * case_th_bottom;
 375 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 376
 377 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 378          0.5 * (hppU + hppS)[1] ];
 379 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 380 hppB = hppT + [0,-1] * hp_k;
 381
 382 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 383 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 384 hppE = [ hppE_x, hppE_y ];
 385
 386 // hinge elevation x coords
 387
 388 hex20 = max(epp2o[0],
 389             phone_cnr_rad,
 390             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 391 hex21 = hex20 + hingemount_wd;
 392 hex22 = hex21 + hinge_x_gap;
 393 hex27 = hex20 + hingescrew_shaft_len;
 394 hex24 = hex27 + hinge_x_postscrew_gap;
 395 hex23 = hex27 - (hingescrew_nut_thick*2
 396                  + hingescrew_fasteners_extra_thick);
 397 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 398
 399 echo(hex20, hex21, hex22, hex23, hex24);
 400 //  6, 10.8725, 10.9975, 13.74, 18.75
 401 module chk(act,exp) {
 402   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 403   else echo("ok", act);
 404 }
 405 chk(hex20, 6);
 406 chk(hex21, 10.8725);
 407 chk(hex22, 10.9975);
 408 chk(hex23, 13.74);
 409 chk(hex24, 18.75);
 410
 411 // catch
 412
 413 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 414 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 415 cppB = [ epp0[0], cppA[1] ];
 416 cppP = [ epp4[0], cppJ[1] ];
 417
 418 cppS = cppJ + [0,-1] * catch_len;
 419 cppD = [ cppA[0], cppS[1] + catch_slop ];
 420 cppC = [ cppB[0], cppD[1] ];
 421 cppT = cppS + [1,0] * catch_depth;
 422 cppU = cppT + [0,-1] * catch_height;
 423 cppV = [ cppS[0], cppU[1] - catch_depth ];
 424
 425 cppR = 0.5*(cppP + cppJ);
 426
 427 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 428 cppQ = [ cppR[0],
 429          cppV[1] - (catch_finger_height - cp_rQ) ];
 430 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 431
 432 // prop recess in case
 433
 434 prop_x_pos = phone_width/2;
 435
 436 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 437
 438 prc_r1 = prop_end_dia/2;
 439 prc_r3 = prc_r1 + prop_recess_slop;
 440
 441 prcp2 = [ epp4[0] + prop_buildout_less,
 442           case_bottom_z ];
 443
 444 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 445
 446 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 447           epp2i[1] - prc_r3 - prop_recess_under];
 448
 449 // prop recess in lid
 450
 451 prl_r10 = prop_end_dia/2;
 452 prl_r10o = prl_r10 + prop_recess_slop;
 453
 454 prlp10 = lpp10 + [1,1] * prl_r10o
 455   + [1,0] * prop_lidrecess_behind
 456   + [0,1] * prop_recess_under;
 457
 458 // prop
 459
 460 $prpp10 = [0,0];
 461 $prpp11 = [0, prop_taper_len];
 462
 463 $prp_r10 = prl_r10;
 464
 465 // ---------- modules ----------
 466
 467 module AdhocMultiprintFrame(phase, z0, zs) {
 468   // from z0 to z0 + zs*layer
 469   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 470   xextra = extra + -epp4[0];
 471   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 472   yextra = extra + -epp4[0];
 473   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 474   p0 = [ xrange[0], yrange[0] ];
 475   p1 = [ xrange[1], yrange[1] ];
 476   echo(p0, p1);
 477   translate([0,0, z0])
 478     mirror([0,0, zs<0 ? 1 : 0])
 479     linear_extrude(height= initial_layer_thick)
 480     difference(){
 481       rectfromto(p0 - [1,1] * initial_layer_width,
 482                  p1 + [1,1] * initial_layer_width);
 483       rectfromto(p0, p1);
 484     }
 485 }
 486
 487 module KeeperProfile(slant=0){
 488   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 489   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 490 }
 491
 492 module EdgeProfile(){
 493   difference(){
 494     hull(){
 495       translate(epp3) square(case_th_bottom*2, center=true);
 496       circleat(epp2o, r=case_th_bottom);
 497       circleat(epp1, r=case_th_side);
 498       rectfromto(epp0, epp4);
 499     }
 500     polygon([ epp5 + [0,10],
 501               epp1,
 502               epp2i,
 503               epp3 + [10,0] ]);
 504   }
 505 }
 506
 507 module LidEdgeProfile(){
 508   polygon([ lpp10,
 509             lpp11,
 510             lpp12,
 511             lpp13,
 512             lpp13 + [10, 0],
 513             lpp15 + [10, 0],
 514             lpp15,
 515             lpp14,
 516             ]);
 517   intersection(){
 518     circleat(lpp12, r=lp_r12);
 519     rectfromto( lpp12 + [-10,   0],
 520                 lpp12 + [+10, +10] );
 521   }
 522 }
 523
 524 module LidEdgeFoldClearanceProfile(){
 525   polygon([ lpp10,
 526             lpp11,
 527             lpp11 + [-20,  0],
 528             lpp11 + [-20, 20],
 529             lpp11 + [+20, 20],
 530             lpp10 + [+20,  0] ]);
 531 }
 532
 533 module ButtonCoverProfile(){
 534   intersection(){
 535     polygon(concat([ bppM, bppP, bppO, bppJ ],
 536                    (enable_support && !$button_suppress_over_keeper
 537                     ? [ bppU, bppV, bppW ] : []),
 538                    [ bppL, bppK ]));
 539     hull(){
 540       EdgeProfile();
 541       LidEdgeProfile();
 542     }
 543   }
 544 }
 545
 546 module ButtonPlan(l, deep, cut){
 547   epsilon =
 548     (cut  ? 0 : lid_buttoncover_gap);
 549
 550   delta =
 551     (deep ? lid_buttoncover_overlap : 0);
 552
 553   C = [0,0]; // by definition
 554   T = [ 0, epp4[1] ];
 555   G = T + [0,10];
 556
 557   B0 = C + [0,-1] * button_cutout_depth;
 558   B1 = B0 + [0,1] * epsilon;
 559
 560   r0 = 0.5 * (T[1] - B0[1]);
 561   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 562   H = A + [0,-1] * delta;
 563
 564   D = A + [-2,0] * r0;
 565   F = D + [0,10];
 566
 567   E0 = 0.5 * (D + A);
 568   E1 = E0 + [1,0] * epsilon;
 569
 570   I0 = [ E0[0], H[1] ];
 571   I1 = [ E1[0], H[1] ];
 572
 573   hull(){
 574     for (m=[0,1]) mirror([m,0])
 575       circleat(H, r0 - epsilon);
 576   }
 577   for (m=[0,1]) mirror([m,0]) {
 578     difference(){
 579       polygon([ E1,
 580                 I1,
 581                 H,
 582                 B1,
 583                 G,
 584                 F,
 585                 D
 586                 ]);
 587       circleat(D, r0 + epsilon);
 588     }
 589   }
 590 }
 591
 592 module CatchCatchProfile(){
 593   hull(){
 594     for (c=[ cppR, cppQ ])
 595       circleat(c, cp_rQ);
 596   }
 597   hull(){
 598     circleat(lpp12, lp_r12);
 599     circleat(lpp12 + [5,0], lp_r12);
 600     rectfromto(cppP, cppP + [5,0.1]);
 601   }
 602   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 603 }
 604
 605 module CatchCutProfile(){
 606   polygon([ cppB,
 607             cppA,
 608             cppD,
 609             cppF,
 610             cppF + [0,-10],
 611             cppF + [-10,-10],
 612             lpp12 + [-10,0],
 613             lpp12 + [10,0]
 614             ]);
 615 }
 616
 617 module Flip_rhs(yn=[0,1]) {
 618   for ($rhsflip=yn) {
 619     translate([phone_width/2, 0, 0])
 620       mirror([$rhsflip,0,0])
 621       translate([-phone_width/2, 0, 0])
 622       children();
 623   }
 624 }
 625
 626 module Flip_bot(yn=[0,1]) {
 627   for ($botflip=yn) {
 628     translate([0, -phone_height/2, 0])
 629       mirror([0, $botflip, 0])
 630       translate([0, phone_height/2, 0])
 631       children();
 632   }
 633 }
 634
 635 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 636   // sides
 637   Flip_rhs(){
 638     translate([0, -phone_cnr_rad, 0])
 639       rotate([90,0,0])
 640       linear_extrude(height = phone_height - phone_cnr_rad*2)
 641       children(0);
 642   }
 643   // corners
 644   Flip_rhs() Flip_bot() {
 645     translate([+1,-1] * phone_cnr_rad)
 646       intersection(){
 647         rotate_extrude()
 648           intersection(){
 649             mirror([1,0,0])
 650               translate([-1,0] * phone_cnr_rad)
 651               children(0);
 652             rectfromto([0,-20],[10,20]);
 653           }
 654         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 655           cube([10,10,40]);
 656       }
 657   }
 658   // top and bottom
 659   Flip_bot(){
 660     translate([ phone_width - phone_cnr_rad, 0,0 ])
 661       rotate([90,0,-90])
 662       linear_extrude(height = phone_width - phone_cnr_rad*2)
 663       children(0);
 664   }
 665   // fill
 666   translate([0,0, fill_zstart])
 667     mirror([0,0, fill_downwards])
 668     linear_extrude(height = fill_th)
 669     rectfromto([+1,-1] * phone_cnr_rad,
 670                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 671 }
 672
 673 module CaseAperture(pos, dia, $fn) {
 674   theta = 180/$fn;
 675   translate([ pos[0] + bumper[0],
 676               -epp2i[0],
 677               -pos[1] ])
 678     rotate([-90, theta, 0])
 679     cylinder(r = dia/2 / cos(theta),
 680              h = 60);
 681 }
 682
 683 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 684   // y_ref_sign:
 685   //   +1  measured from top    of actual phone to top    of button
 686   //   -1  measured from bottom of actual phone to bottom of button
 687   //    0  y is centre of button in coordinate system
 688   $button_l= l;
 689   $button_suppress_over_keeper= suppress_over_keeper;
 690   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 691           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 692           y;
 693   //echo(eff_y);
 694   translate([0, eff_y, 0])
 695     children();
 696 }
 697
 698 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 699   $button_leg_only = true;
 700   SideButton(y, y_ref_sign, l) children();
 701 }
 702
 703 module Buttons(){
 704   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 705   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 706   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 707   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 708 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 709 }
 710
 711 module Struts(x_start, z_min, th){
 712   // if th is negative, starts at z_min and works towards -ve z
 713   // and object should then be printed other way up
 714   for (i= [1 : 1 : case_struts_count]) {
 715     translate([0,
 716                0,
 717                z_min])
 718       mirror([0,0, th<0 ? 1 : 0])
 719       translate([0,
 720                  -phone_height * i / (case_struts_count+1),
 721                  case_struts_solid_below])
 722       linear_extrude(height= abs(th)
 723                      -(case_struts_solid_below+case_struts_solid_above))
 724       rectfromto([               x_start, -0.5 * case_struts_width ],
 725                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 726   }
 727 }
 728
 729 module OrdinaryRearAperture(rhs,bot, pos){
 730   Flip_rhs(rhs) Flip_bot(bot)
 731     linextr(-20, 20)
 732     mirror([0,1])
 733     translate(pos + bumper)
 734     children();
 735 }
 736
 737 module MicroUSB(){
 738   Flip_bot(1){
 739     rotate([90,0,0])
 740       mirror([0,0,1])
 741       linextr(-epp2i[0], 60)
 742       translate([0.5 * phone_width, 0, 0])
 743       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 744                  [+microusb_width/2, epp0[1] + -microusb_above]);
 745   }
 746 }
 747
 748 module OrdinaryRearApertures(){
 749   // rear speaker
 750   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 751     rectfromto(-rearspeaker_gap,
 752                rearspeaker_size + rearspeaker_gap);
 753
 754   // finger hole to remove phone
 755   if (len(fingerpushhole_dias))
 756     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 757                                 phone[1]/2 ])
 758     scale(fingerpushhole_dias)
 759     circle(r= 0.5 );
 760 }
 761
 762 module RearCameraAperture(){
 763   Flip_rhs(1)
 764     mirror([0, 0, 1])
 765     linear_extrude(height = 20)
 766     mirror([0, 1, 0])
 767     translate(bumper)
 768     rectfromto(camera_pos_tl, camera_pos_br);
 769 }
 770
 771 module HingeLidProfile(){
 772   hull(){
 773     circleat(hppT, hp_r1);
 774     circleat(lpp12, lp_r12);
 775     polygon([lpp10,
 776              lpp13 + [2,0],
 777              lpp12,
 778              hppT]);
 779   }
 780 }
 781
 782 module HingeBaseProfile(){
 783   difference(){
 784     hull(){
 785       circleat(hppB, hp_r1);
 786       circleat(hppE, hp_r1);
 787       circleat(epp2o, case_th_bottom);
 788       circleat(hppB + [10,0], hp_r1);
 789     }
 790     polygon([epp5, epp1, epp2i, epp3, bppL]);
 791   }
 792 }
 793
 794 module HingeLeverOuterProfile(){
 795   hull(){
 796     circleat(hppT, hp_r2);
 797     circleat(hppB, hp_r2);
 798   }
 799 }
 800
 801 module HingeLeverInnerProfile(){
 802   for (s = [-1,+1]) {
 803     c = s > 0 ? hppT : hppB;
 804     translate(c)
 805       mirror([0,0,s>0])
 806       rotate(s<0 ? -40 : 0)
 807       hull()
 808       for (x=[-20,20])
 809         for (y=[0, s * 10])
 810           translate([x,y])
 811             circle(hp_rn);
 812   }
 813 }
 814
 815 module HingeLeverNutProfile(){
 816   for (c= [hppB, hppT]) {
 817     translate(c)
 818       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 819   }
 820 }
 821
 822 module Flip_hinge(doflip=1){
 823   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 824   translate(hinge_origin)
 825     rotate([doflip*180,0,0])
 826     translate(-hinge_origin)
 827     children();
 828 }
 829
 830 module HingePortion(x0,x1){
 831   Flip_rhs() Flip_bot(1)
 832     translate([x0,0,0])
 833     mirror([1,0,0])
 834     rotate([90,0,-90])
 835     linear_extrude(height=x1-x0)
 836     children();
 837 }
 838
 839 module CatchPortion(width){
 840   translate([phone_width/2, 0,0])
 841     rotate([90,0,-90])
 842     linextr(-width/2, width/2)
 843     children(0);
 844 }
 845
 846 module CaseBase(){
 847   AroundEdges(epp3[1], case_th_bottom, 1)
 848     EdgeProfile();
 849 }
 850
 851 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 852
 853 module PropProfileAssignments(gamma){
 854   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 855   x = prop_x(gamma);
 856   p = phone_height + prlp10[0] - hppB[0];
 857   b = p + x;
 858
 859   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 860   a = q + x;
 861   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 862   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 863
 864   $prp_theta = 90 - $prp_alpha;
 865   beta = 180 - $prp_alpha - gamma;
 866   psi = 90 - beta;
 867
 868   //echo("abc", a,b,c);
 869
 870   v1 = [ [ cos(psi), -sin(psi) ],    // x
 871          [ sin(psi),  cos(psi) ] ];  // y
 872
 873   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 874
 875   $prp_r1 = prc_r1;
 876   $prp_r11 = prop_main_th/2;
 877
 878   $prpp1 = $prpp7 + [1,0] *
 879     // this is approximate, but will do
 880     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 881   $prpp3 = $prpp1 +
 882     v1[0] * -$prp_r1 +
 883     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 884   $prpp12 = $prpp3 + v1[0] *
 885     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 886   $prp_r8 = prop_main_th;
 887   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 888   $prp_r5 = $prp_r8;
 889   $prpp5 = [ $prpp12[0] - $prp_r5,
 890             $prpp3[1] - prop_prong_h + $prp_r5 ];
 891   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 892          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 893   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 894   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 895
 896   children();
 897 }
 898
 899 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 900   PropProfileAssignments(gamma){
 901
 902     //#circleat($prpp3,1);
 903     //#circleat($prpp12,1);
 904
 905     if (!cut) {
 906       hull(){
 907         translate($prpp8)
 908           intersection(){
 909             circle($prp_r8);
 910             polygon([[-20,-0], [20,20], [0,0]]);
 911           }
 912         rectfromto($prpp6, $prpp9);
 913         translate($prpp5) intersection(){
 914           circle($prp_r5);
 915           polygon([[-10,-10], [0,0], [10,0]]);
 916         }
 917         rectfromto($prpp12 + [0,-0.1], $prpp3);
 918       }
 919       hull(){
 920         circleat($prpp1, $prp_r1);
 921         rectfromto($prpp12 + [0,-0.1], $prpp3);
 922       }
 923     }
 924     // main shaft
 925     rotate([0,0, rot*-$prp_theta]){
 926       hull(){
 927         extra = cut ? prop_recess_slop : 0;
 928         rectfromto($prpp6, $prpp9);
 929         circleat($prpp11, $prp_r11 + extra);
 930         circleat($prpp10, $prp_r10 + extra);
 931       }
 932     }
 933   }
 934 }
 935
 936 module PropAggregateProfile(){
 937   for (angle = prop_angles)
 938     PropProfile(angle, 0,0);
 939 }
 940
 941 module Prop(){ ////toplevel
 942   hw = prop_main_width/2;
 943   linextr(-hw, +hw)
 944     PropAggregateProfile();
 945 }
 946
 947 module Case(){ ////toplevel
 948   difference(){
 949     union(){
 950       CaseBase();
 951
 952       // ledge (fixed keeper)
 953       Flip_rhs(1-keeper_side) intersection(){
 954         rotate([90, 0, 0])
 955           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 956           KeeperProfile(1);
 957
 958         // outline of the whole case, to stop it protruding
 959         translate([0,0, -25])
 960           linear_extrude(height = 50)
 961           hull()
 962           Flip_bot()
 963           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 964       }
 965
 966       // hinge
 967       HingePortion(hex20, hex21) HingeBaseProfile();
 968
 969       // buildout for prop recess
 970       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
 971         linextr(case_bottom_z, epp2i[1])
 972         hull() {
 973           for (dxs = [-1,+1])
 974             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
 975                        -epp2o[0] ],
 976                      r = epp2o[0] - prcp2[0]);
 977         }
 978     }
 979
 980     // slot for keeper
 981     Flip_rhs(keeper_side)
 982       translate([0, -phone_cnr_rad, 0])
 983       rotate([90, 0, 0])
 984       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 985       minkowski(){
 986         KeeperProfile();
 987         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 988                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 989       }
 990
 991     // front camera
 992     RearCameraAperture();
 993
 994     // struts (invisible, because they're buried in the case)
 995     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 996
 997     Buttons(){
 998       mirror([1,0,0])
 999         rotate([90,0,90]) {
1000           if (!($button_leg_only && enable_support))
1001           intersection(){
1002             translate([0,0,-10])
1003               linear_extrude(height= 20)
1004               ButtonPlan($button_l, 0,1);
1005             if ($button_leg_only)
1006               rotate([-90,90,0])
1007                 translate([phone_width/2, -400, kppe[1]])
1008                 mirror([1-abs($rhsflip - keeper_side),0,0])
1009                 cube([400, 800, 50]);
1010             if (enable_support && !$button_suppress_over_keeper)
1011               rotate([-90,90,0])
1012               translate([-400, -400, kppd[1]])
1013                 mirror([0,0,1])
1014                 cube([800,800,100]);
1015           }
1016           translate([0,0, -bppR[0]])
1017             linear_extrude(height= 20)
1018             ButtonPlan($button_l, 1,1);
1019         }
1020
1021     }
1022
1023     // apertures along top edge
1024     CaseAperture(jack_pos, jack_dia, 8);
1025     Flip_rhs(1)
1026       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1027
1028     OrdinaryRearApertures();
1029
1030     MicroUSB();
1031
1032     // gaps for the lid's hinge arms
1033     HingePortion(hex20 - hinge_x_arms_gap,
1034                  hex21 + hinge_x_arms_gap)
1035       minkowski(){
1036         HingeLidProfile();
1037         circle(r= hinge_r_arms_gap, $fn= 8);
1038       }
1039
1040     // screw holes in the hinge arms
1041     HingeScrews();
1042
1043     // catch striker
1044     CatchPortion(catch_width + catch_side_gap*2)
1045       CatchCutProfile();
1046
1047     // prop recess
1048     Flip_rhs(1)
1049       translate([prop_x_pos,0,0])
1050       mirror([0,1,0])
1051       rotate([90,0,90])
1052       linextr(-prop_recess_hw, +prop_recess_hw)
1053       hull(){
1054         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1055           circleat(prcp1 + 20*d,
1056                    prc_r3);
1057       }
1058   }
1059 }
1060
1061 module LidAdhocMultiprintFrame(phase){
1062   if (led_window_style >= 3) {
1063     AdhocMultiprintFrame(phase, lpp13[1], -1);
1064   }
1065 }
1066
1067 module LidAroundEdges(){
1068   AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
1069     children();
1070 }
1071
1072 module Lid(){ ////toplevel
1073   skew_centre = [0, lpp11[0], lpp11[1]];
1074   difference(){
1075     union(){
1076       intersection(){
1077         LidAroundEdges()
1078           LidEdgeProfile();
1079
1080         translate(skew_centre)
1081           multmatrix([[ 1, 0, 0, 0 ],
1082                       [ 0, 1, -2, 0 ],
1083                       [ 0, 0, 1, 0 ],
1084                       [ 0, 0, 0, 1 ]])
1085           translate(-skew_centre)
1086           LidAroundEdges()
1087           LidEdgeFoldClearanceProfile();
1088       }
1089
1090       // button covers
1091       Buttons(){
1092         intersection(){
1093           rotate([90,0,90])
1094             translate([0,0,-10])
1095             linear_extrude(height= 20)
1096             ButtonPlan($button_l, 1,0);
1097           rotate([90,0,0])
1098              translate([0,0,-100])
1099             linear_extrude(height= 200)
1100             ButtonCoverProfile();
1101         }
1102       }
1103
1104       // hinge arms
1105       HingePortion(hex20, hex21) {
1106         LidEdgeProfile();
1107         HingeLidProfile();
1108       }
1109
1110       // catch
1111       CatchPortion(catch_width)
1112         CatchCatchProfile();
1113     }
1114     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1115
1116     // screw holes in the hinge arms
1117     HingeScrews();
1118
1119     // prop recess
1120     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1121       mirror([0,1,0])
1122       rotate([90,0,90])
1123       linextr(-prop_recess_hw, +prop_recess_hw)
1124       hull()
1125       for (pa = prop_angles)
1126         PropProfile(pa, 1,1);
1127
1128     // notification led aperture
1129     if (led_window_style)
1130       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1131         translate([0,0,-10])
1132           cylinder(r=nla_r0, h=20);
1133         if (led_window_style >= 2)
1134           translate([0,0, -nla_t])
1135             cylinder(r=nla_r2, height=20);
1136       }
1137
1138     }
1139
1140   LidAdhocMultiprintFrame(1);
1141 }
1142
1143 module HingeLever(){ ////toplevel
1144   difference() {
1145     // outer body, positive
1146     HingePortion(hex22, hex22 + phone_width/2)
1147       HingeLeverOuterProfile();
1148
1149     // space for the screws
1150     HingePortion(hex26, hex24)
1151       HingeLeverInnerProfile();
1152
1153     // recesses for the nuts
1154     HingePortion(hex23, hex26+1)
1155       HingeLeverNutProfile();
1156
1157     // bores for the screws
1158     HingeScrews();
1159
1160     // space for the charging cable
1161     MicroUSB();
1162     Flip_hinge() MicroUSB();
1163   }
1164 }
1165
1166 module LidWindow(){ ////toplevel
1167   translate([led_pos[0], -led_pos[1], lpp13[1]])
1168     mirror([0,0,1])
1169     cylinder(r= nla_r1, h=nla_t);
1170   LidAdhocMultiprintFrame(0);
1171 }
1172
1173 module LidWindowPrint(){ ////toplevel
1174   rotate([0,180,0])
1175     LidWindow();
1176 }
1177
1178 module DemoLidWindowSelect(){
1179   translate([led_pos[0], led_pos[1], -100]) {
1180     translate([0, -30, 0]) cube([400, 400, 200]);
1181   }
1182 }
1183
1184 module DemoLidWindow(){ ////toplevel
1185   %Lid();
1186   LidWindow();
1187   translate([0,40,0]){
1188     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1189     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1190   }
1191 }
1192
1193 module HingeLeverPrint(){ ////toplevel
1194   rotate([-90,0,0])
1195     translate([-phone_width/2, phone_height, 0])
1196     HingeLever();
1197 }
1198
1199 module TestSelectLength(){
1200   translate([-30, -200, -20])
1201     cube([30 + 15, 250, 40]);
1202 }
1203
1204 module TestLength(){ ////toplevel
1205   intersection(){
1206     Case();
1207     TestSelectLength();
1208   }
1209 }
1210
1211 module TestLengthRight(){ ////toplevel
1212   intersection(){
1213     Case();
1214     Flip_rhs(1)
1215       TestSelectLength();
1216   }
1217 }
1218
1219 module TestSelectWidth(){
1220   translate([-30, -(phone_height - 25), -20])
1221     mirror([0, 1, 0])
1222     cube([200, 50, 40]);
1223 }
1224
1225 module TestWidth(){ ////toplevel
1226   intersection(){
1227     Case();
1228     TestSelectWidth();
1229   }
1230 }
1231
1232 module TestLidWidthPrint(){ ////toplevel
1233   rotate([0,180.0]) intersection(){
1234     Lid();
1235     TestSelectWidth();
1236   }
1237 }
1238
1239 module TestSelectRearAperture(){
1240   minkowski(){
1241     union() children();
1242     translate([20, 0,0])
1243       cube([42, 2, 1], center=true);
1244   }
1245 }
1246
1247 module TestSelectCamera(){
1248   minkowski(){
1249     TestSelectRearAperture()
1250       RearCameraAperture();
1251     cube([0.1, 50, 0.1]);
1252   }
1253 }
1254
1255 module TestSelectOrdinaryRearApertures(){
1256   TestSelectRearAperture()
1257     OrdinaryRearApertures();
1258 }
1259
1260 module TestCamera(){ ////toplevel
1261   intersection(){
1262     Case();
1263     TestSelectCamera();
1264   }
1265 }
1266
1267 module TestLidByCamera(){ ////toplevel
1268   intersection(){
1269     Lid();
1270     TestSelectCamera();
1271   }
1272 }
1273
1274 module TestLidByCameraPrint(){ ////toplevel
1275   rotate([180,0,0]) TestLidByCamera();
1276 }
1277
1278 module DemoByCamera(){ ////toplevel
1279   color("blue") TestLidByCamera();
1280   color("red")  TestCamera();
1281 }
1282
1283 module OneKeeper(){ ////toplevel
1284   translate([0, -phone_cnr_rad, 0])
1285     rotate([90, 0, 0])
1286     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1287     KeeperProfile();
1288 }
1289
1290 module OneKeeperPrint(){ ////toplevel
1291   rotate([0,180,0])
1292     OneKeeper();
1293 }
1294
1295 module LidPrint(){ ////toplevel
1296   rotate([0,180,0])
1297     Lid();
1298 }
1299
1300 module TestSelectFrame(){
1301   include = [1,-1] * (epp2i[0] + 4);
1302
1303   difference(){
1304     cube(1000, center=true);
1305     translate([0,0, -100])
1306       linear_extrude(height=200)
1307       rectfromto(include,  inside_br - include);
1308   }
1309 }
1310
1311 module TestSelectLidFrame(){
1312   TestSelectFrame();
1313   translate([led_pos[0], -led_pos[1], -50])
1314     cylinder(r= nla_r2+3, h=100);
1315 }
1316
1317 module TestFrameCase(){ ////toplevel
1318   intersection(){
1319     Case();
1320     union(){
1321       TestSelectFrame();
1322       TestSelectCamera();
1323       TestSelectOrdinaryRearApertures();
1324     }
1325   }
1326 }
1327
1328 module TestSelectTopApertures(){
1329   translate([-100, -35, -100])
1330     cube([400, 100, 200]);
1331   LidAdhocMultiprintFrame(0);
1332   LidAdhocMultiprintFrame(1);
1333 }
1334
1335 module TestTopApertures(){ ////toplevel
1336   intersection(){
1337     Case();
1338     TestSelectFrame();
1339     TestSelectTopApertures();
1340   }
1341 }
1342
1343 module TestLidTopAperturesPrint(){ ////toplevel
1344   rotate([0,180,0]) intersection(){
1345     Lid();
1346     TestSelectLidFrame();
1347     TestSelectTopApertures();
1348   }
1349 }
1350
1351 module TestLidWindowTopAperturesPrint(){ ////toplevel
1352   rotate([0,180,0]) intersection(){
1353     LidWindow();
1354     TestSelectTopApertures();
1355   }
1356 }
1357
1358 module TestFrameLidPrint(){ ////toplevel
1359   rotate([0,180,0]) intersection(){
1360     Lid();
1361     TestSelectLidFrame();
1362   }
1363 }
1364
1365 module ButtonPlanForDemo(z, deep, cut){
1366   translate([0,0,z])
1367     ButtonPlan(8, deep, cut);
1368 }
1369
1370 module HingeScrews(){
1371   Flip_rhs() Flip_bot(1){
1372     for (c= [ hppT, hppB ])
1373       translate([ hex20,
1374                   -c[0],
1375                   c[1] ]){
1376         rotate([0,90,0])
1377           translate([0,0,-.2])
1378           cylinder( r= hingescrew_shaft_dia/2,
1379                     h = hingescrew_shaft_len+0.2 );
1380         rotate([0,-90,0])
1381           translate([0,0,+.1])
1382           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1383       }
1384   }
1385 }
1386
1387 module DemoPropAngleSelect(c){
1388   color(c) difference(){
1389     union(){ children(); }
1390     translate([ prop_x_pos, -400, -200 ])
1391       cube([ 400,800,400 ]);
1392   }
1393 }
1394
1395 module DemoPropAngle(ang){
1396   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1397   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1398
1399   translate(hL)
1400     rotate([ang/2,0,0])
1401     translate(-hL)
1402     translate(hC)
1403     rotate([ang/2,0,0])
1404     translate(-hC) {
1405       DemoPropAngleSelect("red") Case();
1406
1407       color("orange")
1408         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1409         PropProfileAssignments(ang) {
1410           echo($prpp1);
1411           rotate([-$prp_theta, 0, 0])
1412           translate([0, $prpp1[0], -$prpp1[1]])
1413           rotate([90,0,-90])
1414           Prop();
1415         }
1416     }
1417
1418   translate([0,0, -hp_k*2])
1419     DemoPropAngleSelect("blue")
1420     Lid();
1421 }
1422
1423 module DemoPropAngles(){ ////toplevel
1424   for (i=[0 : len(prop_angles)-1])
1425     translate(i * [0, -100, 100])
1426     DemoPropAngle(prop_angles[i]);
1427 }
1428
1429 module DemoHingeAngle(ang1,ang2){
1430   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1431   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1432
1433   translate(hL)
1434     rotate([ang2,0,0])
1435     translate(-hL)
1436     translate(hC)
1437     rotate([ang1,0,0])
1438     translate(-hC) {
1439       color("red") Lid();
1440     }
1441
1442   color("blue") intersection(){
1443     Case();
1444     union(){
1445       translate([bppJ[0], -400, -200])
1446         mirror([1,0,0])
1447         cube([400, 800, 400]);
1448       translate([10, -400, -200])
1449         cube([10, 800, 400]);
1450     }
1451   }
1452 }
1453
1454 module DemoHingeAngles(){ ////toplevel
1455   angles = [ 0, 4, 8, 12 ];
1456   echo("angles",angles);
1457   for (i=[0 : len(angles)-1]) {
1458     translate(i * [0, 0, 30]) {
1459       DemoHingeAngle(0,angles[i]);
1460       translate([0, 200, 0])
1461         DemoHingeAngle(angles[i],0);
1462     }
1463   }
1464 }
1465
1466 module DemoSelectAdhocLeftRight(right=0) {
1467   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1468     mirror([1-right, 0,0])
1469     cube([400, 800, 200]);
1470 }
1471
1472 module DemoLeft(){ ////toplevel
1473   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1474   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1475 }
1476
1477 module DemoFrame(){ ////toplevel
1478   color("red") TestFrameCase();
1479   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1480   color("black") HingeScrews();
1481   %HingeLever();
1482 }
1483
1484 module DemoHingedFrame(){ ///toplevel
1485   color("red") TestFrameCase();
1486   translate([0,0, -2*hp_k])
1487   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1488
1489   Flip_hinge(){
1490     color("orange") HingeLever();
1491     color("black") HingeScrews();
1492   }
1493 }
1494
1495 module DemoHinge(){ ////toplevel
1496   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1497     DemoFrame();
1498     translate([0,0, -hp_k*3])
1499       DemoHingedFrame();
1500   }
1501 }
1502
1503 module DemoProfiles(){ ////toplevel
1504   LidEdgeProfile();
1505   %EdgeProfile();
1506   KeeperProfile();
1507   translate([0,0,-1]) color("black") KeeperProfile(1);
1508
1509   translate([20,0]) {
1510     LidEdgeProfile();
1511     %EdgeProfile();
1512
1513     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1514
1515     color("blue") ButtonCoverProfile();
1516     color("red") {
1517       rectfromto(bppQ, demopoint_QR);
1518       rectfromto(bppR, demopoint_QR);
1519     }
1520   }
1521
1522   translate([-20,0]) {
1523     color("black") ButtonPlanForDemo(-2, 0,1);
1524     color("red" )  ButtonPlanForDemo(-4, 1,1);
1525     color("blue")  ButtonPlanForDemo(-6, 1,0);
1526   }
1527
1528   translate([0, -30]) {
1529     %LidEdgeProfile();
1530     %EdgeProfile();
1531     color("blue") HingeLidProfile();
1532     color("red")  HingeBaseProfile();
1533     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1534   }
1535
1536   for (f=[0,1]) {
1537     translate([-30, -60 + 30*f]) {
1538       translate([0,0,-4]) EdgeProfile();
1539       %translate([0,0,-10]) HingeBaseProfile();
1540       translate([0,-2] * f * hp_k) {
1541         translate([0,0,-4]) LidEdgeProfile();
1542         %translate([0,0,-10]) %HingeLidProfile();
1543       }
1544       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1545         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1546         translate([0,0,0]) color("red") difference(){
1547           HingeLeverOuterProfile();
1548           HingeLeverInnerProfile();
1549         }
1550         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1551       }
1552     }
1553   }
1554
1555   translate([20,-30]) {
1556     %EdgeProfile();
1557     %LidEdgeProfile();
1558     //translate([0,0,1]) CatchCutProfile();
1559     color("blue") CatchCatchProfile();
1560     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1561   }
1562
1563   translate([40,-30]) {
1564     difference(){
1565       LidEdgeProfile();
1566       translate(prlp10)
1567         PropProfile(10, 1, 0);
1568     }
1569     translate(prlp10)
1570       PropProfile(15, 0);
1571   }
1572   translate([60,-30]) {
1573     PropAggregateProfile();
1574   }
1575 }
1576
1577 //EdgeProfile();
1578 //KeeperProfile();
1579 //CaseBase();
1580 //%Case();
1581 //Keeper();
1582 //LidEdgeProfile();
1583 //KeeperProfile();
1584 //DemoProfiles();
1585 //PropRecess();