fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172
 173 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 174 rearspeaker_size   = [  3.76,  7.36 ];
 175
 176 microusb_above = 3.27 - 0.25;
 177 microusb_below = 0.0;
 178 microusb_width = 16.12 + 1.25;
 179
 180 case_th_bottom = 2.5;
 181 case_th_lid = 3.0;
 182 case_th_side = 2.3;
 183 case_th_lip = 1.2;
 184
 185 lid_screen_gap_extra = .66;
 186
 187 case_struts_count = 6;
 188 case_struts_solid_below = 1.00;
 189 case_struts_solid_above = 0.75;
 190 case_struts_width = 0.10;
 191
 192 keeper_th_z = 0.75;
 193 keeper_th_x = 0.75;
 194 keeper_inner_width = 2.75;
 195 keeper_inner_height = 2.75;
 196 keeper_slant_slope = 2; // larger means steeper
 197
 198 keeper_gap_z_top = 0.25;
 199 keeper_gap_z_bot = 0.75;
 200 keeper_gap_x     = 0.25;
 201 keeper_gap_x_holes = 0.75;
 202
 203 keeper_side = 0; // 0 = lhs; 1 = rhs
 204
 205 case_lip = 1.25;
 206
 207 lid_gap_x = 0.25;
 208 lid_gap_z = 0.25;
 209 lid_lip = 1.75;
 210 lid_edgepart_width = 5.0;
 211 lid_buttoncover_thick = 1.3;
 212
 213 catch_slop = 0.50;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // properties of the hinge fasteners
 219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 220 hingescrew_shaft_len = 12;
 221 hingescrew_fasteners_extra_thick = 0.40;
 222 // ^ amount of thread protruding if everything was completely nominal
 223 //   and we are using two nuts
 224 hingescrew_nut_access_dia = 4.72 + 0.50;
 225 // ^ washer is 4.72 dia
 226 //   also, want to get pliers or tiny spanner in to do up locknut
 227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 228 hingescrew_nut_thick = 1.93;
 229 hingescrew_head_th = 1.38 + 0.75;
 230 hingescrew_head_dia = 3.92;
 231
 232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 233
 234 lever_cover_th = 0.75;
 235 hingemount_th = 2.5;
 236 hingemount_wd = 4.8725;
 237
 238 $fa = 5;
 239 $fs = 0.1;
 240
 241 button_l_fudge = 4.4;
 242 buttonishleg_default_l_is_fudge = 10;
 243
 244 hinge_base_slope = 1.5; // bigger is steeper
 245
 246 strut_min_at_end = 1.5;
 247
 248 hinge_x_gap = 0.125;
 249 hinge_x_postscrew_gap = 0.75;
 250 hinge_x_arms_gap = 0.35;
 251 hinge_r_arms_gap = 0.55;
 252
 253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 254
 255 catch_len = 7.5;
 256 catch_width = 15;
 257 catch_thickness = 1.0;
 258 catch_side_gap = 0.75; // each side
 259
 260 catch_depth = 0.75;
 261 catch_height = 0.35;
 262 catch_finger_height = 1.5;
 263 catch_finger_depth = 2.5;
 264
 265 catch_topcurve_r = 5.0;
 266
 267 prop_recess_under = 0.50;
 268 prop_recess_slop = 0.200; // each side
 269 prop_end_dia = 0.5;
 270 prop_main_th = 3;
 271 prop_taper_len = 6;
 272 prop_main_width = 4;
 273 prop_side_gap = 0.75; // each side
 274 prop_lidrecess_behind = 0.75;
 275 prop_caserecess_behind = 0.75;
 276 prop_caserecess_taper = 0.45; // one side only
 277 prop_prop_gap = 0.5;
 278 prop_prong_heel_slope = 0.5;
 279
 280 lid_fold_clearance_antislop = 0.5;
 281
 282 // ---------- calculated ----------
 283
 284 phone_width =  (phone + bumper*2)[0];
 285 phone_height = (phone + bumper*2)[1];
 286
 287 inside_br = [phone_width, -phone_height];
 288
 289 prop_prong_h = prop_main_th;
 290
 291 //echo(camera_pos_tl + bumper,
 292 //     camera_pos_br + bumper);
 293
 294 // ----- could be changed -----
 295 lid_buttoncover_gap = lid_gap_x;
 296 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 297
 298 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 299
 300 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 301
 302 //prop_nose_len = case_th_lid - prop_recess_under;
 303 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 304 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 305
 306
 307 //lid_lip_overlap_width xxx bad name = ;
 308 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 309
 310 epp0 = [0,0];
 311 epp1 = [0, -phone_edge_thick];
 312 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 313 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 314 epp3 = epp2i + [10, 0];
 315 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 316 epp4 = epp5 + [-1,0] * case_th_side;
 317
 318 kppe = [0,0];
 319 kppd = kppe + [1,0] * keeper_inner_width;
 320 kppc = kppd + [0,1] * keeper_th_z;
 321 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 322 kppf = kppe - [0,1] * keeper_inner_height;
 323 kppa = [ kppb[0], kppf[1] ];
 324
 325 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 326 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 327
 328 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 329 // exact x posn not very important; must extend past end of keeper
 330
 331 lpp15 = [ lpp14[0],
 332           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 333           + lid_screen_gap_extra ];
 334 // ^ beam theory says to maximise force before contact,
 335 //   the gap below the `beam' (the lid) must be 1/3
 336 //   the thickness (ie the lid thickness) if the beam
 337 //   is solid, or 1/2 if it has a top and bottom only.
 338 //   ours is mostly solid.
 339
 340 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 341              case_th_lip);
 342
 343 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 344 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 345
 346 case_bottom_z = epp2o[1] - case_th_bottom;
 347
 348 // button profile
 349 bppM = epp4 + [0,5];
 350 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 351 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 352 bppS = [ epp1[0], bppR[1] ];
 353 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 354 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 355 bppO = [ bppN[0], bppP[1] ];
 356 bppL = lpp10 + [5,0];
 357 bppK = [ bppL[0], bppN[1] ];
 358 bppJ = [ bppN[0], bppL[1] ];
 359 bppU = [ bppJ[0], lpp12[1] ];
 360 bppV = lpp11;
 361 bppW = lpp10;
 362
 363 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 364
 365 // notification led aperture
 366
 367 nla_r0 = led_aperture/2;
 368 nla_r1 = nla_r0 + led_window_ledge;
 369 nla_r2 = nla_r1 + multicolour_gap;
 370 nla_t =
 371   led_window_style >= 3 ? initial_layer_thick :
 372   led_window_style >= 2 ? led_window_ledge : 0;
 373
 374
 375 // hinge plan
 376 hp_rn = hingescrew_nut_access_dia/2;
 377 hp_r2_min = hp_rn + lever_cover_th;
 378 hp_rs = hingescrew_shaft_dia/2;
 379 hp_r1_min = hp_rs + hingemount_th;
 380
 381 hp_r1 = max(hp_r1_min, hp_r2_min);
 382 hp_r2 = hp_r1;
 383
 384 hppU = lpp13;
 385 hppS = epp2o + [0,-1] * case_th_bottom;
 386 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 387
 388 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 389          0.5 * (hppU + hppS)[1] ];
 390 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 391 hppB = hppT + [0,-1] * hp_k;
 392
 393 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 394 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 395 hppE = [ hppE_x, hppE_y ];
 396
 397 // hinge elevation x coords
 398
 399 hex20 = max(epp2o[0],
 400             phone_cnr_rad,
 401             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 402 hex21 = hex20 + hingemount_wd;
 403 hex22 = hex21 + hinge_x_gap;
 404 hex27 = hex20 + hingescrew_shaft_len;
 405 hex24 = hex27 + hinge_x_postscrew_gap;
 406 hex23 = hex27 - (hingescrew_nut_thick*2
 407                  + hingescrew_fasteners_extra_thick);
 408 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 409
 410 echo(hex20, hex21, hex22, hex23, hex24);
 411 //  6, 10.8725, 10.9975, 13.74, 18.75
 412 module chk(act,exp) {
 413   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 414   else echo("ok", act);
 415 }
 416 chk(hex20, 6);
 417 chk(hex21, 10.8725);
 418 chk(hex22, 10.9975);
 419 chk(hex23, 13.74);
 420 chk(hex24, 18.75);
 421
 422 lid_fold_clearance_skew =
 423   (lpp10[1] - hppB[1]) /
 424   (lpp10[0] - hppB[0]);
 425
 426 echo("SK",lid_fold_clearance_skew);
 427
 428 // catch
 429
 430 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 431 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 432 cppB = [ epp0[0], cppA[1] ];
 433 cppP = [ epp4[0], cppJ[1] ];
 434
 435 cppS = cppJ + [0,-1] * catch_len;
 436 cppD = [ cppA[0], cppS[1] + catch_slop ];
 437 cppC = [ cppB[0], cppD[1] ];
 438 cppT = cppS + [1,0] * catch_depth;
 439 cppU = cppT + [0,-1] * catch_height;
 440 cppV = [ cppS[0], cppU[1] - catch_depth ];
 441
 442 cppR = 0.5*(cppP + cppJ);
 443
 444 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 445 cppQ = [ cppR[0],
 446          cppV[1] - (catch_finger_height - cp_rQ) ];
 447 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 448
 449 // prop recess in case
 450
 451 prop_x_pos = phone_width/2;
 452
 453 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 454
 455 prc_r1 = prop_end_dia/2;
 456 prc_r3 = prc_r1 + prop_recess_slop;
 457
 458 prcp2 = [ epp4[0] + prop_buildout_less,
 459           case_bottom_z ];
 460
 461 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 462
 463 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 464           epp2i[1] - prc_r3 - prop_recess_under];
 465
 466 // prop recess in lid
 467
 468 prl_r10 = prop_end_dia/2;
 469 prl_r10o = prl_r10 + prop_recess_slop;
 470
 471 prlp10 = lpp10 + [1,1] * prl_r10o
 472   + [1,0] * prop_lidrecess_behind
 473   + [0,1] * prop_recess_under;
 474
 475 // prop
 476
 477 $prpp10 = [0,0];
 478 $prpp11 = [0, prop_taper_len];
 479
 480 $prp_r10 = prl_r10;
 481
 482 // ---------- modules ----------
 483
 484 module AdhocMultiprintFrame(phase, z0, zs) {
 485   // from z0 to z0 + zs*layer
 486   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 487   xextra = extra + -epp4[0];
 488   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 489   yextra = extra + -epp4[0];
 490   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 491   p0 = [ xrange[0], yrange[0] ];
 492   p1 = [ xrange[1], yrange[1] ];
 493   echo(p0, p1);
 494   translate([0,0, z0])
 495     mirror([0,0, zs<0 ? 1 : 0])
 496     linear_extrude(height= initial_layer_thick)
 497     difference(){
 498       rectfromto(p0 - [1,1] * initial_layer_width,
 499                  p1 + [1,1] * initial_layer_width);
 500       rectfromto(p0, p1);
 501     }
 502 }
 503
 504 module KeeperProfile(slant=0){
 505   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 506   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 507 }
 508
 509 module EdgeProfile(){
 510   difference(){
 511     hull(){
 512       translate(epp3) square(case_th_bottom*2, center=true);
 513       circleat(epp2o, r=case_th_bottom);
 514       circleat(epp1, r=case_th_side);
 515       rectfromto(epp0, epp4);
 516     }
 517     polygon([ epp5 + [0,10],
 518               epp1,
 519               epp2i,
 520               epp3 + [10,0] ]);
 521   }
 522 }
 523
 524 module LanyardLanyardProfile(){
 525   hull(){
 526     for (xs=[-1,+1])
 527       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 528         circle(r= lanyard_half_dia/2);
 529   }
 530 }
 531
 532 module LidEdgeProfile(){
 533   polygon([ lpp10,
 534             lpp11,
 535             lpp12,
 536             lpp13,
 537             lpp13 + [10, 0],
 538             lpp15 + [10, 0],
 539             lpp15,
 540             lpp14,
 541             ]);
 542   intersection(){
 543     circleat(lpp12, r=lp_r12);
 544     rectfromto( lpp12 + [-10,   0],
 545                 lpp12 + [+10, +10] );
 546   }
 547 }
 548
 549 module LidEdgeFoldClearanceProfile(){
 550   translate([-lid_fold_clearance_antislop, 0])
 551     polygon([ lpp10,
 552               lpp11,
 553               lpp11 + [-20,  0],
 554               lpp11 + [-20, 20],
 555               lpp11 + [+20, 20],
 556               lpp10 + [+20,  0] ]);
 557 }
 558
 559 module ButtonCoverProfile(){
 560   intersection(){
 561     polygon(concat([ bppM, bppP, bppO, bppJ ],
 562                    (enable_support && !$button_suppress_over_keeper
 563                     ? [ bppU, bppV, bppW ] : []),
 564                    [ bppL, bppK ]));
 565     hull(){
 566       EdgeProfile();
 567       LidEdgeProfile();
 568     }
 569   }
 570 }
 571
 572 module ButtonPlan(l, deep, cut){
 573   epsilon =
 574     (cut  ? 0 : lid_buttoncover_gap);
 575
 576   delta =
 577     (deep ? lid_buttoncover_overlap : 0);
 578
 579   C = [0,0]; // by definition
 580   T = [ 0, epp4[1] ];
 581   G = T + [0,10];
 582
 583   B0 = C + [0,-1] * button_cutout_depth;
 584   B1 = B0 + [0,1] * epsilon;
 585
 586   r0 = 0.5 * (T[1] - B0[1]);
 587   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 588   H = A + [0,-1] * delta;
 589
 590   D = A + [-2,0] * r0;
 591   F = D + [0,10];
 592
 593   E0 = 0.5 * (D + A);
 594   E1 = E0 + [1,0] * epsilon;
 595
 596   I0 = [ E0[0], H[1] ];
 597   I1 = [ E1[0], H[1] ];
 598
 599   hull(){
 600     for (m=[0,1]) mirror([m,0])
 601       circleat(H, r0 - epsilon);
 602   }
 603   for (m=[0,1]) mirror([m,0]) {
 604     difference(){
 605       polygon([ E1,
 606                 I1,
 607                 H,
 608                 B1,
 609                 G,
 610                 F,
 611                 D
 612                 ]);
 613       circleat(D, r0 + epsilon);
 614     }
 615   }
 616 }
 617
 618 module CatchCatchProfile(){
 619   hull(){
 620     for (c=[ cppR, cppQ ])
 621       circleat(c, cp_rQ);
 622   }
 623   hull(){
 624     circleat(lpp12, lp_r12);
 625     circleat(lpp12 + [5,0], lp_r12);
 626     rectfromto(cppP, cppP + [5,0.1]);
 627   }
 628   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 629 }
 630
 631 module CatchCutProfile(){
 632   polygon([ cppB,
 633             cppA,
 634             cppD,
 635             cppF,
 636             cppF + [0,-10],
 637             cppF + [-10,-10],
 638             lpp12 + [-10,0],
 639             lpp12 + [10,0]
 640             ]);
 641 }
 642
 643 module Flip_rhs(yn=[0,1]) {
 644   for ($rhsflip=yn) {
 645     translate([phone_width/2, 0, 0])
 646       mirror([$rhsflip,0,0])
 647       translate([-phone_width/2, 0, 0])
 648       children();
 649   }
 650 }
 651
 652 module Flip_bot(yn=[0,1]) {
 653   for ($botflip=yn) {
 654     translate([0, -phone_height/2, 0])
 655       mirror([0, $botflip, 0])
 656       translate([0, phone_height/2, 0])
 657       children();
 658   }
 659 }
 660
 661 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 662   // sides
 663   Flip_rhs(){
 664     translate([0, -phone_cnr_rad, 0])
 665       rotate([90,0,0])
 666       linear_extrude(height = phone_height - phone_cnr_rad*2)
 667       children(0);
 668   }
 669   // corners
 670   Flip_rhs() Flip_bot() {
 671     translate([+1,-1] * phone_cnr_rad)
 672       intersection(){
 673         rotate_extrude()
 674           intersection(){
 675             mirror([1,0,0])
 676               translate([-1,0] * phone_cnr_rad)
 677               children(0);
 678             rectfromto([0,-20],[10,20]);
 679           }
 680         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 681           cube([10,10,40]);
 682       }
 683   }
 684   // top and bottom
 685   Flip_bot(){
 686     translate([ phone_width - phone_cnr_rad, 0,0 ])
 687       rotate([90,0,-90])
 688       linear_extrude(height = phone_width - phone_cnr_rad*2)
 689       children(0);
 690   }
 691   // fill
 692   translate([0,0, fill_zstart])
 693     mirror([0,0, fill_downwards])
 694     linear_extrude(height = fill_th)
 695     rectfromto([+1,-1] * phone_cnr_rad,
 696                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 697 }
 698
 699 module CaseAperture(pos, dia, $fn) {
 700   theta = 180/$fn;
 701   translate([ pos[0] + bumper[0],
 702               -epp2i[0],
 703               -pos[1] ])
 704     rotate([-90, theta, 0])
 705     cylinder(r = dia/2 / cos(theta),
 706              h = 60);
 707 }
 708
 709 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 710   // y_ref_sign:
 711   //   +1  measured from top    of actual phone to top    of button
 712   //   -1  measured from bottom of actual phone to bottom of button
 713   //    0  y is centre of button in coordinate system
 714   $button_l= l;
 715   $button_suppress_over_keeper= suppress_over_keeper;
 716   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 717           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 718           y;
 719   //echo(eff_y);
 720   translate([0, eff_y, 0])
 721     children();
 722 }
 723
 724 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 725   $button_leg_only = true;
 726   SideButton(y, y_ref_sign, l) children();
 727 }
 728
 729 module Buttons(){
 730   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 731   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 732   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 733   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 734 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 735 }
 736
 737 module Struts(x_start, z_min, th){
 738   // if th is negative, starts at z_min and works towards -ve z
 739   // and object should then be printed other way up
 740   for (i= [1 : 1 : case_struts_count]) {
 741     translate([0,
 742                0,
 743                z_min])
 744       mirror([0,0, th<0 ? 1 : 0])
 745       translate([0,
 746                  -phone_height * i / (case_struts_count+1),
 747                  case_struts_solid_below])
 748       linear_extrude(height= abs(th)
 749                      -(case_struts_solid_below+case_struts_solid_above))
 750       rectfromto([               x_start, -0.5 * case_struts_width ],
 751                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 752   }
 753 }
 754
 755 module OrdinaryRearAperture(rhs,bot, pos){
 756   Flip_rhs(rhs) Flip_bot(bot)
 757     linextr(-20, 20)
 758     mirror([0,1])
 759     translate(pos + bumper)
 760     children();
 761 }
 762
 763 module MicroUSB(){
 764   Flip_bot(1){
 765     rotate([90,0,0])
 766       mirror([0,0,1])
 767       linextr(-epp2i[0], 60)
 768       translate([0.5 * phone_width, 0, 0])
 769       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 770                  [+microusb_width/2, epp0[1] + -microusb_above]);
 771   }
 772 }
 773
 774 module OrdinaryRearApertures(){
 775   // rear speaker
 776   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 777     rectfromto(-rearspeaker_gap,
 778                rearspeaker_size + rearspeaker_gap);
 779
 780   // finger hole to remove phone
 781   if (len(fingerpushhole_dias))
 782     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 783                                 phone[1]/2 ])
 784     scale(fingerpushhole_dias)
 785     circle(r= 0.5 );
 786 }
 787
 788 module RearCameraAperture(){
 789   Flip_rhs(1)
 790     mirror([0, 0, 1])
 791     linear_extrude(height = 20)
 792     mirror([0, 1, 0])
 793     translate(bumper)
 794     rectfromto(camera_pos_tl, camera_pos_br);
 795 }
 796
 797 module HingeLidProfile(){
 798   hull(){
 799     circleat(hppT, hp_r1);
 800     circleat(lpp12, lp_r12);
 801     polygon([lpp10,
 802              lpp13 + [2,0],
 803              lpp12,
 804              hppT]);
 805   }
 806 }
 807
 808 module HingeBaseProfile(){
 809   difference(){
 810     hull(){
 811       circleat(hppB, hp_r1);
 812       circleat(hppE, hp_r1);
 813       circleat(epp2o, case_th_bottom);
 814       circleat(hppB + [10,0], hp_r1);
 815     }
 816     polygon([epp5, epp1, epp2i, epp3, bppL]);
 817   }
 818 }
 819
 820 module HingeLeverOuterProfile(){
 821   hull(){
 822     circleat(hppT, hp_r2);
 823     circleat(hppB, hp_r2);
 824   }
 825 }
 826
 827 module HingeLeverInnerProfile(){
 828   for (s = [-1,+1]) {
 829     c = s > 0 ? hppT : hppB;
 830     translate(c)
 831       mirror([0,0,s>0])
 832       rotate(s<0 ? -40 : 0)
 833       hull()
 834       for (x=[-20,20])
 835         for (y=[0, s * 10])
 836           translate([x,y])
 837             circle(hp_rn);
 838   }
 839 }
 840
 841 module HingeLeverNutProfile(){
 842   for (c= [hppB, hppT]) {
 843     translate(c)
 844       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 845   }
 846 }
 847
 848 module Flip_hinge(doflip=1){
 849   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 850   translate(hinge_origin)
 851     rotate([doflip*180,0,0])
 852     translate(-hinge_origin)
 853     children();
 854 }
 855
 856 module HingePortion(x0,x1){
 857   Flip_rhs() Flip_bot(1)
 858     translate([x0,0,0])
 859     mirror([1,0,0])
 860     rotate([90,0,-90])
 861     linear_extrude(height=x1-x0)
 862     children();
 863 }
 864
 865 module CatchPortion(xwidth, ztop){
 866   width = catch_width + xwidth;
 867   w = width + catch_topcurve_r*2 + 1;
 868   translate([phone_width/2, 0,0]){
 869     difference(){
 870       rotate([90,0,-90])
 871         linextr(-w/2, w/2)
 872         children(0);
 873       translate([0, 50, 0])
 874         rotate([90,0,0])
 875         linear_extrude(height=100){
 876         for (m=[0,1]) mirror([m,0,0]) {
 877           hull(){
 878             translate([w/2, ztop - catch_topcurve_r])
 879               circle(catch_topcurve_r);
 880             translate([w/2, -50])
 881               square(catch_topcurve_r*2, center=true);
 882           }
 883         }
 884       }
 885     }
 886   }
 887 }
 888
 889 module CaseBase(){
 890   AroundEdges(epp3[1], case_th_bottom, 1)
 891     EdgeProfile();
 892 }
 893
 894 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 895
 896 module PropProfileAssignments(gamma){
 897   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 898   x = prop_x(gamma);
 899   p = phone_height + prlp10[0] - hppB[0];
 900   b = p + x;
 901
 902   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 903   a = q + x;
 904   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 905   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 906
 907   $prp_theta = 90 - $prp_alpha;
 908   beta = 180 - $prp_alpha - gamma;
 909   psi = 90 - beta;
 910
 911   //echo("abc", a,b,c);
 912
 913   v1 = [ [ cos(psi), -sin(psi) ],    // x
 914          [ sin(psi),  cos(psi) ] ];  // y
 915
 916   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 917
 918   $prp_r1 = prc_r1;
 919   $prp_r11 = prop_main_th/2;
 920
 921   $prpp1 = $prpp7 + [1,0] *
 922     // this is approximate, but will do
 923     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 924   $prpp3 = $prpp1 +
 925     v1[0] * -$prp_r1 +
 926     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 927   $prpp12 = $prpp3 + v1[0] *
 928     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 929   $prp_r8 = prop_main_th;
 930   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 931   $prp_r5 = $prp_r8;
 932   $prpp5 = [ $prpp12[0] - $prp_r5,
 933             $prpp3[1] - prop_prong_h + $prp_r5 ];
 934   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 935          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 936   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 937   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 938
 939   children();
 940 }
 941
 942 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 943   PropProfileAssignments(gamma){
 944
 945     //#circleat($prpp3,1);
 946     //#circleat($prpp12,1);
 947
 948     if (!cut) {
 949       hull(){
 950         translate($prpp8)
 951           intersection(){
 952             circle($prp_r8);
 953             polygon([[-20,-0], [20,20], [0,0]]);
 954           }
 955         rectfromto($prpp6, $prpp9);
 956         translate($prpp5) intersection(){
 957           circle($prp_r5);
 958           polygon([[-10,-10], [0,0], [10,0]]);
 959         }
 960         rectfromto($prpp12 + [0,-0.1], $prpp3);
 961       }
 962       hull(){
 963         circleat($prpp1, $prp_r1);
 964         rectfromto($prpp12 + [0,-0.1], $prpp3);
 965       }
 966     }
 967     // main shaft
 968     rotate([0,0, rot*-$prp_theta]){
 969       hull(){
 970         extra = cut ? prop_recess_slop : 0;
 971         rectfromto($prpp6, $prpp9);
 972         circleat($prpp11, $prp_r11 + extra);
 973         circleat($prpp10, $prp_r10 + extra);
 974       }
 975     }
 976   }
 977 }
 978
 979 module PropAggregateProfile(){
 980   for (angle = prop_angles)
 981     PropProfile(angle, 0,0);
 982 }
 983
 984 module Prop(){ ////toplevel
 985   hw = prop_main_width/2;
 986   linextr(-hw, +hw)
 987     PropAggregateProfile();
 988 }
 989
 990 module Case(){ ////toplevel
 991   difference(){
 992     union(){
 993       CaseBase();
 994
 995       // ledge (fixed keeper)
 996       Flip_rhs(1-keeper_side) intersection(){
 997         rotate([90, 0, 0])
 998           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 999           KeeperProfile(1);
1000
1001         // outline of the whole case, to stop it protruding
1002         translate([0,0, -25])
1003           linear_extrude(height = 50)
1004           hull()
1005           Flip_bot()
1006           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1007       }
1008
1009       // hinge
1010       HingePortion(hex20, hex21) HingeBaseProfile();
1011
1012       // buildout for prop recess
1013       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1014         linextr(case_bottom_z, epp2i[1])
1015         hull() {
1016           for (dxs = [-1,+1])
1017             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1018                        -epp2o[0] ],
1019                      r = epp2o[0] - prcp2[0]);
1020         }
1021     }
1022
1023     // slot for keeper
1024     Flip_rhs(keeper_side)
1025       translate([0, -phone_cnr_rad, 0])
1026       rotate([90, 0, 0])
1027       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1028       minkowski(){
1029         KeeperProfile();
1030         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1031                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1032       }
1033
1034     // front camera
1035     RearCameraAperture();
1036
1037     // struts (invisible, because they're buried in the case)
1038     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1039
1040     Buttons(){
1041       mirror([1,0,0])
1042         rotate([90,0,90]) {
1043           if (!($button_leg_only && enable_support))
1044           intersection(){
1045             translate([0,0,-10])
1046               linear_extrude(height= 20)
1047               ButtonPlan($button_l, 0,1);
1048             if ($button_leg_only)
1049               rotate([-90,90,0])
1050                 translate([phone_width/2, -400, kppe[1]])
1051                 mirror([1-abs($rhsflip - keeper_side),0,0])
1052                 cube([400, 800, 50]);
1053             if (enable_support && !$button_suppress_over_keeper)
1054               rotate([-90,90,0])
1055               translate([-400, -400, kppd[1]])
1056                 mirror([0,0,1])
1057                 cube([800,800,100]);
1058           }
1059           translate([0,0, -bppR[0]])
1060             linear_extrude(height= 20)
1061             ButtonPlan($button_l, 1,1);
1062         }
1063
1064     }
1065
1066     // apertures along top edge
1067     CaseAperture(jack_pos, jack_dia, 8);
1068     Flip_rhs(1)
1069       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1070
1071     OrdinaryRearApertures();
1072
1073     MicroUSB();
1074
1075     // gaps for the lid's hinge arms
1076     HingePortion(hex20 - hinge_x_arms_gap,
1077                  hex21 + hinge_x_arms_gap)
1078       minkowski(){
1079         HingeLidProfile();
1080         circle(r= hinge_r_arms_gap, $fn= 8);
1081       }
1082
1083     // screw holes in the hinge arms
1084     HingeScrews();
1085
1086     // catch striker
1087     CatchPortion(catch_side_gap*2, epp4[1])
1088       CatchCutProfile();
1089
1090     // prop recess
1091     Flip_rhs(1)
1092       translate([prop_x_pos,0,0])
1093       mirror([0,1,0])
1094       rotate([90,0,90])
1095       linextr(-prop_recess_hw, +prop_recess_hw)
1096       hull(){
1097         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1098           circleat(prcp1 + 20*d,
1099                    prc_r3);
1100       }
1101   }
1102 }
1103
1104 module LidAdhocMultiprintFrame(phase){
1105   if (led_window_style >= 3) {
1106     AdhocMultiprintFrame(phase, lpp13[1], -1);
1107   }
1108 }
1109
1110 module LidAroundEdges(){
1111   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1112     children();
1113 }
1114
1115 module Lid(){ ////toplevel
1116   skew_centre = [0, lpp11[0], lpp11[1]];
1117   difference(){
1118     union(){
1119       intersection(){
1120         LidAroundEdges()
1121           LidEdgeProfile();
1122
1123         translate(skew_centre)
1124           multmatrix([[ 1, 0, 0, 0 ],
1125                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1126                       [ 0, 0, 1, 0 ],
1127                       [ 0, 0, 0, 1 ]])
1128           translate(-skew_centre)
1129           LidAroundEdges()
1130           LidEdgeFoldClearanceProfile();
1131       }
1132
1133       // button covers
1134       Buttons(){
1135         intersection(){
1136           rotate([90,0,90])
1137             translate([0,0,-10])
1138             linear_extrude(height= 20)
1139             ButtonPlan($button_l, 1,0);
1140           rotate([90,0,0])
1141              translate([0,0,-100])
1142             linear_extrude(height= 200)
1143             ButtonCoverProfile();
1144         }
1145       }
1146
1147       // hinge arms
1148       HingePortion(hex20, hex21) {
1149         LidEdgeProfile();
1150         HingeLidProfile();
1151       }
1152
1153       // catch
1154       CatchPortion(0, lpp12[1])
1155         CatchCatchProfile();
1156     }
1157     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1158
1159     // screw holes in the hinge arms
1160     HingeScrews();
1161
1162     // prop recess
1163     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1164       mirror([0,1,0])
1165       rotate([90,0,90])
1166       linextr(-prop_recess_hw, +prop_recess_hw)
1167       hull()
1168       for (pa = prop_angles)
1169         PropProfile(pa, 1,1);
1170
1171     // notification led aperture
1172     if (led_window_style)
1173       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1174         translate([0,0,-10])
1175           cylinder(r=nla_r0, h=20);
1176         if (led_window_style >= 2)
1177           translate([0,0, -nla_t])
1178             cylinder(r=nla_r2, height=20);
1179       }
1180
1181     }
1182
1183   LidAdhocMultiprintFrame(1);
1184 }
1185
1186 module HingeLever(){ ////toplevel
1187   difference() {
1188     // outer body, positive
1189     HingePortion(hex22, hex22 + phone_width/2)
1190       HingeLeverOuterProfile();
1191
1192     // space for the screws
1193     HingePortion(hex26, hex24)
1194       HingeLeverInnerProfile();
1195
1196     // recesses for the nuts
1197     HingePortion(hex23, hex26+1)
1198       HingeLeverNutProfile();
1199
1200     // bores for the screws
1201     HingeScrews();
1202
1203     // space for the charging cable
1204     MicroUSB();
1205     Flip_hinge() MicroUSB();
1206   }
1207 }
1208
1209 module LidWindow(){ ////toplevel
1210   translate([led_pos[0], -led_pos[1], lpp13[1]])
1211     mirror([0,0,1])
1212     cylinder(r= nla_r1, h=nla_t);
1213   LidAdhocMultiprintFrame(0);
1214 }
1215
1216 module LidWindowPrint(){ ////toplevel
1217   rotate([0,180,0])
1218     LidWindow();
1219 }
1220
1221 module DemoLidWindowSelect(){
1222   translate([led_pos[0], led_pos[1], -100]) {
1223     translate([0, -30, 0]) cube([400, 400, 200]);
1224   }
1225 }
1226
1227 module DemoLidWindow(){ ////toplevel
1228   %Lid();
1229   LidWindow();
1230   translate([0,40,0]){
1231     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1232     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1233   }
1234 }
1235
1236 module HingeLeverPrint(){ ////toplevel
1237   rotate([-90,0,0])
1238     translate([-phone_width/2, phone_height, 0])
1239     HingeLever();
1240 }
1241
1242 module TestSelectLength(){
1243   translate([-30, -200, -20])
1244     cube([30 + 15, 250, 40]);
1245 }
1246
1247 module TestLength(){ ////toplevel
1248   intersection(){
1249     Case();
1250     TestSelectLength();
1251   }
1252 }
1253
1254 module TestLengthRight(){ ////toplevel
1255   intersection(){
1256     Case();
1257     Flip_rhs(1)
1258       TestSelectLength();
1259   }
1260 }
1261
1262 module TestSelectWidth(){
1263   translate([-30, -(phone_height - 25), -20])
1264     mirror([0, 1, 0])
1265     cube([200, 50, 40]);
1266 }
1267
1268 module TestWidth(){ ////toplevel
1269   intersection(){
1270     Case();
1271     TestSelectWidth();
1272   }
1273 }
1274
1275 module TestLidWidthPrint(){ ////toplevel
1276   rotate([0,180.0]) intersection(){
1277     Lid();
1278     TestSelectWidth();
1279   }
1280 }
1281
1282 module TestSelectRearAperture(){
1283   minkowski(){
1284     union() children();
1285     translate([20, 0,0])
1286       cube([42, 2, 1], center=true);
1287   }
1288 }
1289
1290 module TestSelectCamera(){
1291   minkowski(){
1292     TestSelectRearAperture()
1293       RearCameraAperture();
1294     cube([0.1, 50, 0.1]);
1295   }
1296 }
1297
1298 module TestSelectOrdinaryRearApertures(){
1299   TestSelectRearAperture()
1300     OrdinaryRearApertures();
1301 }
1302
1303 module TestCamera(){ ////toplevel
1304   intersection(){
1305     Case();
1306     TestSelectCamera();
1307   }
1308 }
1309
1310 module TestLidByCamera(){ ////toplevel
1311   intersection(){
1312     Lid();
1313     TestSelectCamera();
1314   }
1315 }
1316
1317 module TestLidByCameraPrint(){ ////toplevel
1318   rotate([180,0,0]) TestLidByCamera();
1319 }
1320
1321 module DemoByCamera(){ ////toplevel
1322   color("blue") TestLidByCamera();
1323   color("red")  TestCamera();
1324 }
1325
1326 module OneKeeper(){ ////toplevel
1327   translate([0, -phone_cnr_rad, 0])
1328     rotate([90, 0, 0])
1329     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1330     KeeperProfile();
1331 }
1332
1333 module OneKeeperPrint(){ ////toplevel
1334   rotate([0,180,0])
1335     OneKeeper();
1336 }
1337
1338 module LidPrint(){ ////toplevel
1339   rotate([0,180,0])
1340     Lid();
1341 }
1342
1343 module TestSelectFrame(){
1344   include = [1,-1] * (epp2i[0] + 4);
1345
1346   difference(){
1347     cube(1000, center=true);
1348     translate([0,0, -100])
1349       linear_extrude(height=200)
1350       rectfromto(include,  inside_br - include);
1351   }
1352 }
1353
1354 module TestSelectLidFrame(){
1355   TestSelectFrame();
1356   translate([led_pos[0], -led_pos[1], -50])
1357     cylinder(r= nla_r2+3, h=100);
1358 }
1359
1360 module TestFrameCase(){ ////toplevel
1361   intersection(){
1362     Case();
1363     union(){
1364       TestSelectFrame();
1365       TestSelectCamera();
1366       TestSelectOrdinaryRearApertures();
1367     }
1368   }
1369 }
1370
1371 module TestSelectTopApertures(){
1372   translate([-100, -35, -100])
1373     cube([400, 100, 200]);
1374   LidAdhocMultiprintFrame(0);
1375   LidAdhocMultiprintFrame(1);
1376 }
1377
1378 module TestTopApertures(){ ////toplevel
1379   intersection(){
1380     Case();
1381     TestSelectFrame();
1382     TestSelectTopApertures();
1383   }
1384 }
1385
1386 module TestLidTopAperturesPrint(){ ////toplevel
1387   rotate([0,180,0]) intersection(){
1388     Lid();
1389     TestSelectLidFrame();
1390     TestSelectTopApertures();
1391   }
1392 }
1393
1394 module TestLidWindowTopAperturesPrint(){ ////toplevel
1395   rotate([0,180,0]) intersection(){
1396     LidWindow();
1397     TestSelectTopApertures();
1398   }
1399 }
1400
1401 module TestFrameLidPrint(){ ////toplevel
1402   rotate([0,180,0]) intersection(){
1403     Lid();
1404     TestSelectLidFrame();
1405   }
1406 }
1407
1408 module ButtonPlanForDemo(z, deep, cut){
1409   translate([0,0,z])
1410     ButtonPlan(8, deep, cut);
1411 }
1412
1413 module HingeScrews(){
1414   Flip_rhs() Flip_bot(1){
1415     for (c= [ hppT, hppB ])
1416       translate([ hex20,
1417                   -c[0],
1418                   c[1] ]){
1419         rotate([0,90,0])
1420           translate([0,0,-.2])
1421           cylinder( r= hingescrew_shaft_dia/2,
1422                     h = hingescrew_shaft_len+0.2 );
1423         rotate([0,-90,0])
1424           translate([0,0,+.1])
1425           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1426       }
1427   }
1428 }
1429
1430 module DemoPropAngleSelect(c){
1431   color(c) difference(){
1432     union(){ children(); }
1433     translate([ prop_x_pos, -400, -200 ])
1434       cube([ 400,800,400 ]);
1435   }
1436 }
1437
1438 module DemoPropAngle(ang){
1439   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1440   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1441
1442   translate(hL)
1443     rotate([ang/2,0,0])
1444     translate(-hL)
1445     translate(hC)
1446     rotate([ang/2,0,0])
1447     translate(-hC) {
1448       DemoPropAngleSelect("red") Case();
1449
1450       color("orange")
1451         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1452         PropProfileAssignments(ang) {
1453           echo($prpp1);
1454           rotate([-$prp_theta, 0, 0])
1455           translate([0, $prpp1[0], -$prpp1[1]])
1456           rotate([90,0,-90])
1457           Prop();
1458         }
1459     }
1460
1461   translate([0,0, -hp_k*2])
1462     DemoPropAngleSelect("blue")
1463     Lid();
1464 }
1465
1466 module DemoPropAngles(){ ////toplevel
1467   for (i=[0 : len(prop_angles)-1])
1468     translate(i * [0, -100, 100])
1469     DemoPropAngle(prop_angles[i]);
1470 }
1471
1472 module DemoHingeAngle(ang1,ang2){
1473   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1474   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1475
1476   translate(hL)
1477     rotate([ang2,0,0])
1478     translate(-hL)
1479     translate(hC)
1480     rotate([ang1,0,0])
1481     translate(-hC) {
1482       color("red") Lid();
1483     }
1484
1485   color("blue") intersection(){
1486     Case();
1487     union(){
1488       translate([bppJ[0], -400, -200])
1489         mirror([1,0,0])
1490         cube([400, 800, 400]);
1491       translate([10, -400, -200])
1492         cube([10, 800, 400]);
1493     }
1494   }
1495 }
1496
1497 module DemoHingeAngles(){ ////toplevel
1498   angles = [ 0, 4, 8, 12 ];
1499   echo("angles",angles);
1500   for (i=[0 : len(angles)-1]) {
1501     translate(i * [0, 0, 30]) {
1502       DemoHingeAngle(0,angles[i]);
1503       translate([0, 200, 0])
1504         DemoHingeAngle(angles[i],0);
1505     }
1506   }
1507 }
1508
1509 module DemoSelectAdhocLeftRight(right=0) {
1510   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1511     mirror([1-right, 0,0])
1512     cube([400, 800, 200]);
1513 }
1514
1515 module DemoLeft(){ ////toplevel
1516   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1517   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1518 }
1519
1520 module DemoFrame(){ ////toplevel
1521   color("red") TestFrameCase();
1522   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1523   color("black") HingeScrews();
1524   %HingeLever();
1525 }
1526
1527 module DemoHingedFrame(){ ///toplevel
1528   color("red") TestFrameCase();
1529   translate([0,0, -2*hp_k])
1530   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1531
1532   Flip_hinge(){
1533     color("orange") HingeLever();
1534     color("black") HingeScrews();
1535   }
1536 }
1537
1538 module DemoHinge(){ ////toplevel
1539   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1540     DemoFrame();
1541     translate([0,0, -hp_k*3])
1542       DemoHingedFrame();
1543   }
1544 }
1545
1546 module DemoProfiles(){ ////toplevel
1547   LidEdgeProfile();
1548   %EdgeProfile();
1549   KeeperProfile();
1550   translate([0,0,-1]) color("black") KeeperProfile(1);
1551   translate(epp2i)
1552     rotate(atan2vector(epp2i - epp1))
1553     translate(lanyard_half_dia * 0.5 * [-3,-1])
1554     color("purple") LanyardLanyardProfile();
1555
1556   translate([20,0]) {
1557     LidEdgeProfile();
1558     %EdgeProfile();
1559
1560     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1561
1562     color("blue") ButtonCoverProfile();
1563     color("red") {
1564       rectfromto(bppQ, demopoint_QR);
1565       rectfromto(bppR, demopoint_QR);
1566     }
1567   }
1568
1569   translate([-20,0]) {
1570     color("black") ButtonPlanForDemo(-2, 0,1);
1571     color("red" )  ButtonPlanForDemo(-4, 1,1);
1572     color("blue")  ButtonPlanForDemo(-6, 1,0);
1573   }
1574
1575   translate([0, -30]) {
1576     %LidEdgeProfile();
1577     %EdgeProfile();
1578     color("blue") HingeLidProfile();
1579     color("red")  HingeBaseProfile();
1580     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1581   }
1582
1583   for (f=[0,1]) {
1584     translate([-30, -60 + 30*f]) {
1585       translate([0,0,-4]) EdgeProfile();
1586       %translate([0,0,-10]) HingeBaseProfile();
1587       translate([0,-2] * f * hp_k) {
1588         translate([0,0,-4]) LidEdgeProfile();
1589         %translate([0,0,-10]) %HingeLidProfile();
1590       }
1591       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1592         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1593         translate([0,0,0]) color("red") difference(){
1594           HingeLeverOuterProfile();
1595           HingeLeverInnerProfile();
1596         }
1597         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1598       }
1599     }
1600   }
1601
1602   translate([20,-30]) {
1603     %EdgeProfile();
1604     %LidEdgeProfile();
1605     //translate([0,0,1]) CatchCutProfile();
1606     color("blue") CatchCatchProfile();
1607     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1608   }
1609
1610   translate([40,-30]) {
1611     difference(){
1612       LidEdgeProfile();
1613       translate(prlp10)
1614         PropProfile(10, 1, 0);
1615     }
1616     translate(prlp10)
1617       PropProfile(15, 0);
1618   }
1619   translate([60,-30]) {
1620     PropAggregateProfile();
1621   }
1622 }
1623
1624 //EdgeProfile();
1625 //KeeperProfile();
1626 //CaseBase();
1627 //%Case();
1628 //Keeper();
1629 //LidEdgeProfile();
1630 //KeeperProfile();
1631 //DemoProfiles();
1632 //PropRecess();