fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121
 122 phone = [ 75.0, 145.0 ];
 123
 124 prop_buildout_less = 3;
 125
 126 prop_angles = [ 15, 30, 45, 60 ];
 127
 128 bumper = [ 0.250, -0.025 ];
 129 // ^ One side.  Overall size is increased by twice this.
 130 // If no bumpers, is the gap around the phone.
 131
 132 enable_support = 1;
 133
 134 led_window_style = 3;
 135 // 0: no window
 136 // 1: simply an opening
 137 // 2: opening with separate cover model, for printing in clear (two colour)
 138 // 3: like 2 but one-layer window for ad-hoc multi-colour
 139
 140 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 141 initial_layer_width = 0.750; // ^ needed for mode 3 only
 142 multicolour_gap = 0.15; // each side
 143
 144 phone_cnr_rad = 6.0;
 145 phone_rim_depth = 0.80; // includes allowance for a screen protector
 146
 147 button_cutout_depth = 9;
 148
 149 phone_edge_thick = 9.0;
 150 phone_total_thick = 12.0;
 151 phone_backside_slope_inner = 1.5; // larger means shallower
 152 phone_backside_slope_outer = 1.0; // larger means shallower
 153
 154 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 155 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 156
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 led_pos = [ 13.98, 10.00 ];
 161 led_aperture = 9;
 162 led_window_ledge = 0.75; // each side
 163
 164 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 165 noisecancelmic_dia = 4.00;
 166
 167 //fingerpushhole_dias = [ 15, 18 ];
 168 fingerpushhole_dias = [];
 169
 170 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 171 rearspeaker_size   = [  3.76,  7.36 ];
 172
 173 microusb_above = 3.27 - 0.25;
 174 microusb_below = 0.0;
 175 microusb_width = 16.12 + 1.25;
 176
 177 case_th_bottom = 2.5;
 178 case_th_lid = 3.0;
 179 case_th_side = 2;
 180 case_th_lip = 1.2;
 181
 182 lid_screen_gap_extra = .66;
 183
 184 case_struts_count = 6;
 185 case_struts_solid_below = 1.00;
 186 case_struts_solid_above = 0.75;
 187 case_struts_width = 0.10;
 188
 189 keeper_th_z = 0.75;
 190 keeper_th_x = 0.75;
 191 keeper_inner_width = 2.75;
 192 keeper_inner_height = 2.75;
 193 keeper_slant_slope = 2; // larger means steeper
 194
 195 keeper_gap_z_top = 0.25;
 196 keeper_gap_z_bot = 0.75;
 197 keeper_gap_x     = 0.25;
 198 keeper_gap_x_holes = 0.75;
 199
 200 keeper_side = 0; // 0 = lhs; 1 = rhs
 201
 202 case_lip = 1.25;
 203
 204 lid_gap_x = 0.25;
 205 lid_gap_z = 0.25;
 206 lid_lip = 1.75;
 207 lid_edgepart_width = 5.0;
 208
 209 catch_slop = 0.50;
 210
 211 foldover_gap = 0.50;
 212 foldover_lever_gap = 0.50;
 213
 214 // properties of the hinge fasteners
 215 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 216 hingescrew_shaft_len = 12;
 217 hingescrew_fasteners_extra_thick = 0.40;
 218 // ^ amount of thread protruding if everything was completely nominal
 219 //   and we are using two nuts
 220 hingescrew_nut_access_dia = 4.72 + 0.50;
 221 // ^ washer is 4.72 dia
 222 //   also, want to get pliers or tiny spanner in to do up locknut
 223 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 224 hingescrew_nut_thick = 1.93;
 225 hingescrew_head_th = 1.38 + 0.75;
 226 hingescrew_head_dia = 3.92;
 227
 228 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 229
 230 lever_cover_th = 0.75;
 231 hingemount_th = 2.5;
 232 hingemount_wd = 4.8725;
 233
 234 $fa = 5;
 235 $fs = 0.1;
 236
 237 button_l_fudge = 4.4;
 238 buttonishleg_default_l_is_fudge = 10;
 239
 240 hinge_base_slope = 1.5; // bigger is steeper
 241
 242 strut_min_at_end = 1.5;
 243
 244 hinge_x_gap = 0.125;
 245 hinge_x_postscrew_gap = 0.75;
 246 hinge_x_arms_gap = 0.35;
 247 hinge_r_arms_gap = 0.55;
 248
 249 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 250
 251 catch_len = 7.5;
 252 catch_width = 15;
 253 catch_thickness = 1.0;
 254 catch_side_gap = 0.75; // each side
 255
 256 catch_depth = 0.75;
 257 catch_height = 0.35;
 258 catch_finger_height = 1.5;
 259 catch_finger_depth = 2.5;
 260
 261 prop_recess_under = 0.50;
 262 prop_recess_slop = 0.200; // each side
 263 prop_end_dia = 0.5;
 264 prop_main_th = 3;
 265 prop_taper_len = 6;
 266 prop_main_width = 4;
 267 prop_side_gap = 0.75; // each side
 268 prop_lidrecess_behind = 0.75;
 269 prop_caserecess_behind = 0.75;
 270 prop_caserecess_taper = 0.45; // one side only
 271 prop_prop_gap = 0.5;
 272 prop_prong_heel_slope = 0.5;
 273
 274 lid_fold_clearance_antislop = 0.5;
 275
 276 // ---------- calculated ----------
 277
 278 phone_width =  (phone + bumper*2)[0];
 279 phone_height = (phone + bumper*2)[1];
 280
 281 inside_br = [phone_width, -phone_height];
 282
 283 prop_prong_h = prop_main_th;
 284
 285 //echo(camera_pos_tl + bumper,
 286 //     camera_pos_br + bumper);
 287
 288 // ----- could be changed -----
 289 lid_buttoncover_gap = lid_gap_x;
 290 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 291
 292 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 293
 294 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 295
 296 //prop_nose_len = case_th_lid - prop_recess_under;
 297 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 298 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 299
 300
 301 //lid_lip_overlap_width xxx bad name = ;
 302 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 303
 304 epp0 = [0,0];
 305 epp1 = [0, -phone_edge_thick];
 306 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 307 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 308 epp3 = epp2i + [10, 0];
 309 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 310 epp4 = epp5 + [-1,0] * case_th_side;
 311
 312 kppe = [0,0];
 313 kppd = kppe + [1,0] * keeper_inner_width;
 314 kppc = kppd + [0,1] * keeper_th_z;
 315 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 316 kppf = kppe - [0,1] * keeper_inner_height;
 317 kppa = [ kppb[0], kppf[1] ];
 318
 319 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 320 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 321
 322 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 323 // exact x posn not very important; must extend past end of keeper
 324
 325 lpp15 = [ lpp14[0],
 326           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 327           + lid_screen_gap_extra ];
 328 // ^ beam theory says to maximise force before contact,
 329 //   the gap below the `beam' (the lid) must be 1/3
 330 //   the thickness (ie the lid thickness) if the beam
 331 //   is solid, or 1/2 if it has a top and bottom only.
 332 //   ours is mostly solid.
 333
 334 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 335              case_th_lip);
 336
 337 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 338 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 339
 340 case_bottom_z = epp2o[1] - case_th_bottom;
 341
 342 // button profile
 343 bppM = epp4 + [0,5];
 344 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 345 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 346 bppS = [ epp1[0], bppR[1] ];
 347 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 348 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 349 bppO = [ bppN[0], bppP[1] ];
 350 bppL = lpp10 + [5,0];
 351 bppK = [ bppL[0], bppN[1] ];
 352 bppJ = [ bppN[0], bppL[1] ];
 353 bppU = [ bppJ[0], lpp12[1] ];
 354 bppV = lpp11;
 355 bppW = lpp10;
 356
 357 // notification led aperture
 358
 359 nla_r0 = led_aperture/2;
 360 nla_r1 = nla_r0 + led_window_ledge;
 361 nla_r2 = nla_r1 + multicolour_gap;
 362 nla_t =
 363   led_window_style >= 3 ? initial_layer_thick :
 364   led_window_style >= 2 ? led_window_ledge : 0;
 365
 366
 367 // hinge plan
 368 hp_rn = hingescrew_nut_access_dia/2;
 369 hp_r2_min = hp_rn + lever_cover_th;
 370 hp_rs = hingescrew_shaft_dia/2;
 371 hp_r1_min = hp_rs + hingemount_th;
 372
 373 hp_r1 = max(hp_r1_min, hp_r2_min);
 374 hp_r2 = hp_r1;
 375
 376 hppU = lpp13;
 377 hppS = epp2o + [0,-1] * case_th_bottom;
 378 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 379
 380 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 381          0.5 * (hppU + hppS)[1] ];
 382 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 383 hppB = hppT + [0,-1] * hp_k;
 384
 385 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 386 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 387 hppE = [ hppE_x, hppE_y ];
 388
 389 // hinge elevation x coords
 390
 391 hex20 = max(epp2o[0],
 392             phone_cnr_rad,
 393             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 394 hex21 = hex20 + hingemount_wd;
 395 hex22 = hex21 + hinge_x_gap;
 396 hex27 = hex20 + hingescrew_shaft_len;
 397 hex24 = hex27 + hinge_x_postscrew_gap;
 398 hex23 = hex27 - (hingescrew_nut_thick*2
 399                  + hingescrew_fasteners_extra_thick);
 400 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 401
 402 echo(hex20, hex21, hex22, hex23, hex24);
 403 //  6, 10.8725, 10.9975, 13.74, 18.75
 404 module chk(act,exp) {
 405   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 406   else echo("ok", act);
 407 }
 408 chk(hex20, 6);
 409 chk(hex21, 10.8725);
 410 chk(hex22, 10.9975);
 411 chk(hex23, 13.74);
 412 chk(hex24, 18.75);
 413
 414 lid_fold_clearance_skew =
 415   (lpp10[1] - hppB[1]) /
 416   (lpp10[0] - hppB[0]);
 417
 418 echo("SK",lid_fold_clearance_skew);
 419
 420 // catch
 421
 422 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 423 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 424 cppB = [ epp0[0], cppA[1] ];
 425 cppP = [ epp4[0], cppJ[1] ];
 426
 427 cppS = cppJ + [0,-1] * catch_len;
 428 cppD = [ cppA[0], cppS[1] + catch_slop ];
 429 cppC = [ cppB[0], cppD[1] ];
 430 cppT = cppS + [1,0] * catch_depth;
 431 cppU = cppT + [0,-1] * catch_height;
 432 cppV = [ cppS[0], cppU[1] - catch_depth ];
 433
 434 cppR = 0.5*(cppP + cppJ);
 435
 436 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 437 cppQ = [ cppR[0],
 438          cppV[1] - (catch_finger_height - cp_rQ) ];
 439 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 440
 441 // prop recess in case
 442
 443 prop_x_pos = phone_width/2;
 444
 445 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 446
 447 prc_r1 = prop_end_dia/2;
 448 prc_r3 = prc_r1 + prop_recess_slop;
 449
 450 prcp2 = [ epp4[0] + prop_buildout_less,
 451           case_bottom_z ];
 452
 453 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 454
 455 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 456           epp2i[1] - prc_r3 - prop_recess_under];
 457
 458 // prop recess in lid
 459
 460 prl_r10 = prop_end_dia/2;
 461 prl_r10o = prl_r10 + prop_recess_slop;
 462
 463 prlp10 = lpp10 + [1,1] * prl_r10o
 464   + [1,0] * prop_lidrecess_behind
 465   + [0,1] * prop_recess_under;
 466
 467 // prop
 468
 469 $prpp10 = [0,0];
 470 $prpp11 = [0, prop_taper_len];
 471
 472 $prp_r10 = prl_r10;
 473
 474 // ---------- modules ----------
 475
 476 module AdhocMultiprintFrame(phase, z0, zs) {
 477   // from z0 to z0 + zs*layer
 478   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 479   xextra = extra + -epp4[0];
 480   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 481   yextra = extra + -epp4[0];
 482   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 483   p0 = [ xrange[0], yrange[0] ];
 484   p1 = [ xrange[1], yrange[1] ];
 485   echo(p0, p1);
 486   translate([0,0, z0])
 487     mirror([0,0, zs<0 ? 1 : 0])
 488     linear_extrude(height= initial_layer_thick)
 489     difference(){
 490       rectfromto(p0 - [1,1] * initial_layer_width,
 491                  p1 + [1,1] * initial_layer_width);
 492       rectfromto(p0, p1);
 493     }
 494 }
 495
 496 module KeeperProfile(slant=0){
 497   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 498   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 499 }
 500
 501 module EdgeProfile(){
 502   difference(){
 503     hull(){
 504       translate(epp3) square(case_th_bottom*2, center=true);
 505       circleat(epp2o, r=case_th_bottom);
 506       circleat(epp1, r=case_th_side);
 507       rectfromto(epp0, epp4);
 508     }
 509     polygon([ epp5 + [0,10],
 510               epp1,
 511               epp2i,
 512               epp3 + [10,0] ]);
 513   }
 514 }
 515
 516 module LidEdgeProfile(){
 517   polygon([ lpp10,
 518             lpp11,
 519             lpp12,
 520             lpp13,
 521             lpp13 + [10, 0],
 522             lpp15 + [10, 0],
 523             lpp15,
 524             lpp14,
 525             ]);
 526   intersection(){
 527     circleat(lpp12, r=lp_r12);
 528     rectfromto( lpp12 + [-10,   0],
 529                 lpp12 + [+10, +10] );
 530   }
 531 }
 532
 533 module LidEdgeFoldClearanceProfile(){
 534   translate([-lid_fold_clearance_antislop, 0])
 535     polygon([ lpp10,
 536               lpp11,
 537               lpp11 + [-20,  0],
 538               lpp11 + [-20, 20],
 539               lpp11 + [+20, 20],
 540               lpp10 + [+20,  0] ]);
 541 }
 542
 543 module ButtonCoverProfile(){
 544   intersection(){
 545     polygon(concat([ bppM, bppP, bppO, bppJ ],
 546                    (enable_support && !$button_suppress_over_keeper
 547                     ? [ bppU, bppV, bppW ] : []),
 548                    [ bppL, bppK ]));
 549     hull(){
 550       EdgeProfile();
 551       LidEdgeProfile();
 552     }
 553   }
 554 }
 555
 556 module ButtonPlan(l, deep, cut){
 557   epsilon =
 558     (cut  ? 0 : lid_buttoncover_gap);
 559
 560   delta =
 561     (deep ? lid_buttoncover_overlap : 0);
 562
 563   C = [0,0]; // by definition
 564   T = [ 0, epp4[1] ];
 565   G = T + [0,10];
 566
 567   B0 = C + [0,-1] * button_cutout_depth;
 568   B1 = B0 + [0,1] * epsilon;
 569
 570   r0 = 0.5 * (T[1] - B0[1]);
 571   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 572   H = A + [0,-1] * delta;
 573
 574   D = A + [-2,0] * r0;
 575   F = D + [0,10];
 576
 577   E0 = 0.5 * (D + A);
 578   E1 = E0 + [1,0] * epsilon;
 579
 580   I0 = [ E0[0], H[1] ];
 581   I1 = [ E1[0], H[1] ];
 582
 583   hull(){
 584     for (m=[0,1]) mirror([m,0])
 585       circleat(H, r0 - epsilon);
 586   }
 587   for (m=[0,1]) mirror([m,0]) {
 588     difference(){
 589       polygon([ E1,
 590                 I1,
 591                 H,
 592                 B1,
 593                 G,
 594                 F,
 595                 D
 596                 ]);
 597       circleat(D, r0 + epsilon);
 598     }
 599   }
 600 }
 601
 602 module CatchCatchProfile(){
 603   hull(){
 604     for (c=[ cppR, cppQ ])
 605       circleat(c, cp_rQ);
 606   }
 607   hull(){
 608     circleat(lpp12, lp_r12);
 609     circleat(lpp12 + [5,0], lp_r12);
 610     rectfromto(cppP, cppP + [5,0.1]);
 611   }
 612   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 613 }
 614
 615 module CatchCutProfile(){
 616   polygon([ cppB,
 617             cppA,
 618             cppD,
 619             cppF,
 620             cppF + [0,-10],
 621             cppF + [-10,-10],
 622             lpp12 + [-10,0],
 623             lpp12 + [10,0]
 624             ]);
 625 }
 626
 627 module Flip_rhs(yn=[0,1]) {
 628   for ($rhsflip=yn) {
 629     translate([phone_width/2, 0, 0])
 630       mirror([$rhsflip,0,0])
 631       translate([-phone_width/2, 0, 0])
 632       children();
 633   }
 634 }
 635
 636 module Flip_bot(yn=[0,1]) {
 637   for ($botflip=yn) {
 638     translate([0, -phone_height/2, 0])
 639       mirror([0, $botflip, 0])
 640       translate([0, phone_height/2, 0])
 641       children();
 642   }
 643 }
 644
 645 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 646   // sides
 647   Flip_rhs(){
 648     translate([0, -phone_cnr_rad, 0])
 649       rotate([90,0,0])
 650       linear_extrude(height = phone_height - phone_cnr_rad*2)
 651       children(0);
 652   }
 653   // corners
 654   Flip_rhs() Flip_bot() {
 655     translate([+1,-1] * phone_cnr_rad)
 656       intersection(){
 657         rotate_extrude()
 658           intersection(){
 659             mirror([1,0,0])
 660               translate([-1,0] * phone_cnr_rad)
 661               children(0);
 662             rectfromto([0,-20],[10,20]);
 663           }
 664         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 665           cube([10,10,40]);
 666       }
 667   }
 668   // top and bottom
 669   Flip_bot(){
 670     translate([ phone_width - phone_cnr_rad, 0,0 ])
 671       rotate([90,0,-90])
 672       linear_extrude(height = phone_width - phone_cnr_rad*2)
 673       children(0);
 674   }
 675   // fill
 676   translate([0,0, fill_zstart])
 677     mirror([0,0, fill_downwards])
 678     linear_extrude(height = fill_th)
 679     rectfromto([+1,-1] * phone_cnr_rad,
 680                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 681 }
 682
 683 module CaseAperture(pos, dia, $fn) {
 684   theta = 180/$fn;
 685   translate([ pos[0] + bumper[0],
 686               -epp2i[0],
 687               -pos[1] ])
 688     rotate([-90, theta, 0])
 689     cylinder(r = dia/2 / cos(theta),
 690              h = 60);
 691 }
 692
 693 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 694   // y_ref_sign:
 695   //   +1  measured from top    of actual phone to top    of button
 696   //   -1  measured from bottom of actual phone to bottom of button
 697   //    0  y is centre of button in coordinate system
 698   $button_l= l;
 699   $button_suppress_over_keeper= suppress_over_keeper;
 700   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 701           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 702           y;
 703   //echo(eff_y);
 704   translate([0, eff_y, 0])
 705     children();
 706 }
 707
 708 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 709   $button_leg_only = true;
 710   SideButton(y, y_ref_sign, l) children();
 711 }
 712
 713 module Buttons(){
 714   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 715   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 716   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 717   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 718 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 719 }
 720
 721 module Struts(x_start, z_min, th){
 722   // if th is negative, starts at z_min and works towards -ve z
 723   // and object should then be printed other way up
 724   for (i= [1 : 1 : case_struts_count]) {
 725     translate([0,
 726                0,
 727                z_min])
 728       mirror([0,0, th<0 ? 1 : 0])
 729       translate([0,
 730                  -phone_height * i / (case_struts_count+1),
 731                  case_struts_solid_below])
 732       linear_extrude(height= abs(th)
 733                      -(case_struts_solid_below+case_struts_solid_above))
 734       rectfromto([               x_start, -0.5 * case_struts_width ],
 735                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 736   }
 737 }
 738
 739 module OrdinaryRearAperture(rhs,bot, pos){
 740   Flip_rhs(rhs) Flip_bot(bot)
 741     linextr(-20, 20)
 742     mirror([0,1])
 743     translate(pos + bumper)
 744     children();
 745 }
 746
 747 module MicroUSB(){
 748   Flip_bot(1){
 749     rotate([90,0,0])
 750       mirror([0,0,1])
 751       linextr(-epp2i[0], 60)
 752       translate([0.5 * phone_width, 0, 0])
 753       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 754                  [+microusb_width/2, epp0[1] + -microusb_above]);
 755   }
 756 }
 757
 758 module OrdinaryRearApertures(){
 759   // rear speaker
 760   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 761     rectfromto(-rearspeaker_gap,
 762                rearspeaker_size + rearspeaker_gap);
 763
 764   // finger hole to remove phone
 765   if (len(fingerpushhole_dias))
 766     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 767                                 phone[1]/2 ])
 768     scale(fingerpushhole_dias)
 769     circle(r= 0.5 );
 770 }
 771
 772 module RearCameraAperture(){
 773   Flip_rhs(1)
 774     mirror([0, 0, 1])
 775     linear_extrude(height = 20)
 776     mirror([0, 1, 0])
 777     translate(bumper)
 778     rectfromto(camera_pos_tl, camera_pos_br);
 779 }
 780
 781 module HingeLidProfile(){
 782   hull(){
 783     circleat(hppT, hp_r1);
 784     circleat(lpp12, lp_r12);
 785     polygon([lpp10,
 786              lpp13 + [2,0],
 787              lpp12,
 788              hppT]);
 789   }
 790 }
 791
 792 module HingeBaseProfile(){
 793   difference(){
 794     hull(){
 795       circleat(hppB, hp_r1);
 796       circleat(hppE, hp_r1);
 797       circleat(epp2o, case_th_bottom);
 798       circleat(hppB + [10,0], hp_r1);
 799     }
 800     polygon([epp5, epp1, epp2i, epp3, bppL]);
 801   }
 802 }
 803
 804 module HingeLeverOuterProfile(){
 805   hull(){
 806     circleat(hppT, hp_r2);
 807     circleat(hppB, hp_r2);
 808   }
 809 }
 810
 811 module HingeLeverInnerProfile(){
 812   for (s = [-1,+1]) {
 813     c = s > 0 ? hppT : hppB;
 814     translate(c)
 815       mirror([0,0,s>0])
 816       rotate(s<0 ? -40 : 0)
 817       hull()
 818       for (x=[-20,20])
 819         for (y=[0, s * 10])
 820           translate([x,y])
 821             circle(hp_rn);
 822   }
 823 }
 824
 825 module HingeLeverNutProfile(){
 826   for (c= [hppB, hppT]) {
 827     translate(c)
 828       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 829   }
 830 }
 831
 832 module Flip_hinge(doflip=1){
 833   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 834   translate(hinge_origin)
 835     rotate([doflip*180,0,0])
 836     translate(-hinge_origin)
 837     children();
 838 }
 839
 840 module HingePortion(x0,x1){
 841   Flip_rhs() Flip_bot(1)
 842     translate([x0,0,0])
 843     mirror([1,0,0])
 844     rotate([90,0,-90])
 845     linear_extrude(height=x1-x0)
 846     children();
 847 }
 848
 849 module CatchPortion(width){
 850   translate([phone_width/2, 0,0])
 851     rotate([90,0,-90])
 852     linextr(-width/2, width/2)
 853     children(0);
 854 }
 855
 856 module CaseBase(){
 857   AroundEdges(epp3[1], case_th_bottom, 1)
 858     EdgeProfile();
 859 }
 860
 861 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 862
 863 module PropProfileAssignments(gamma){
 864   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 865   x = prop_x(gamma);
 866   p = phone_height + prlp10[0] - hppB[0];
 867   b = p + x;
 868
 869   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 870   a = q + x;
 871   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 872   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 873
 874   $prp_theta = 90 - $prp_alpha;
 875   beta = 180 - $prp_alpha - gamma;
 876   psi = 90 - beta;
 877
 878   //echo("abc", a,b,c);
 879
 880   v1 = [ [ cos(psi), -sin(psi) ],    // x
 881          [ sin(psi),  cos(psi) ] ];  // y
 882
 883   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 884
 885   $prp_r1 = prc_r1;
 886   $prp_r11 = prop_main_th/2;
 887
 888   $prpp1 = $prpp7 + [1,0] *
 889     // this is approximate, but will do
 890     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 891   $prpp3 = $prpp1 +
 892     v1[0] * -$prp_r1 +
 893     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 894   $prpp12 = $prpp3 + v1[0] *
 895     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 896   $prp_r8 = prop_main_th;
 897   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 898   $prp_r5 = $prp_r8;
 899   $prpp5 = [ $prpp12[0] - $prp_r5,
 900             $prpp3[1] - prop_prong_h + $prp_r5 ];
 901   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 902          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 903   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 904   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 905
 906   children();
 907 }
 908
 909 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 910   PropProfileAssignments(gamma){
 911
 912     //#circleat($prpp3,1);
 913     //#circleat($prpp12,1);
 914
 915     if (!cut) {
 916       hull(){
 917         translate($prpp8)
 918           intersection(){
 919             circle($prp_r8);
 920             polygon([[-20,-0], [20,20], [0,0]]);
 921           }
 922         rectfromto($prpp6, $prpp9);
 923         translate($prpp5) intersection(){
 924           circle($prp_r5);
 925           polygon([[-10,-10], [0,0], [10,0]]);
 926         }
 927         rectfromto($prpp12 + [0,-0.1], $prpp3);
 928       }
 929       hull(){
 930         circleat($prpp1, $prp_r1);
 931         rectfromto($prpp12 + [0,-0.1], $prpp3);
 932       }
 933     }
 934     // main shaft
 935     rotate([0,0, rot*-$prp_theta]){
 936       hull(){
 937         extra = cut ? prop_recess_slop : 0;
 938         rectfromto($prpp6, $prpp9);
 939         circleat($prpp11, $prp_r11 + extra);
 940         circleat($prpp10, $prp_r10 + extra);
 941       }
 942     }
 943   }
 944 }
 945
 946 module PropAggregateProfile(){
 947   for (angle = prop_angles)
 948     PropProfile(angle, 0,0);
 949 }
 950
 951 module Prop(){ ////toplevel
 952   hw = prop_main_width/2;
 953   linextr(-hw, +hw)
 954     PropAggregateProfile();
 955 }
 956
 957 module Case(){ ////toplevel
 958   difference(){
 959     union(){
 960       CaseBase();
 961
 962       // ledge (fixed keeper)
 963       Flip_rhs(1-keeper_side) intersection(){
 964         rotate([90, 0, 0])
 965           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 966           KeeperProfile(1);
 967
 968         // outline of the whole case, to stop it protruding
 969         translate([0,0, -25])
 970           linear_extrude(height = 50)
 971           hull()
 972           Flip_bot()
 973           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 974       }
 975
 976       // hinge
 977       HingePortion(hex20, hex21) HingeBaseProfile();
 978
 979       // buildout for prop recess
 980       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
 981         linextr(case_bottom_z, epp2i[1])
 982         hull() {
 983           for (dxs = [-1,+1])
 984             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
 985                        -epp2o[0] ],
 986                      r = epp2o[0] - prcp2[0]);
 987         }
 988     }
 989
 990     // slot for keeper
 991     Flip_rhs(keeper_side)
 992       translate([0, -phone_cnr_rad, 0])
 993       rotate([90, 0, 0])
 994       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 995       minkowski(){
 996         KeeperProfile();
 997         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 998                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 999       }
1000
1001     // front camera
1002     RearCameraAperture();
1003
1004     // struts (invisible, because they're buried in the case)
1005     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1006
1007     Buttons(){
1008       mirror([1,0,0])
1009         rotate([90,0,90]) {
1010           if (!($button_leg_only && enable_support))
1011           intersection(){
1012             translate([0,0,-10])
1013               linear_extrude(height= 20)
1014               ButtonPlan($button_l, 0,1);
1015             if ($button_leg_only)
1016               rotate([-90,90,0])
1017                 translate([phone_width/2, -400, kppe[1]])
1018                 mirror([1-abs($rhsflip - keeper_side),0,0])
1019                 cube([400, 800, 50]);
1020             if (enable_support && !$button_suppress_over_keeper)
1021               rotate([-90,90,0])
1022               translate([-400, -400, kppd[1]])
1023                 mirror([0,0,1])
1024                 cube([800,800,100]);
1025           }
1026           translate([0,0, -bppR[0]])
1027             linear_extrude(height= 20)
1028             ButtonPlan($button_l, 1,1);
1029         }
1030
1031     }
1032
1033     // apertures along top edge
1034     CaseAperture(jack_pos, jack_dia, 8);
1035     Flip_rhs(1)
1036       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1037
1038     OrdinaryRearApertures();
1039
1040     MicroUSB();
1041
1042     // gaps for the lid's hinge arms
1043     HingePortion(hex20 - hinge_x_arms_gap,
1044                  hex21 + hinge_x_arms_gap)
1045       minkowski(){
1046         HingeLidProfile();
1047         circle(r= hinge_r_arms_gap, $fn= 8);
1048       }
1049
1050     // screw holes in the hinge arms
1051     HingeScrews();
1052
1053     // catch striker
1054     CatchPortion(catch_width + catch_side_gap*2)
1055       CatchCutProfile();
1056
1057     // prop recess
1058     Flip_rhs(1)
1059       translate([prop_x_pos,0,0])
1060       mirror([0,1,0])
1061       rotate([90,0,90])
1062       linextr(-prop_recess_hw, +prop_recess_hw)
1063       hull(){
1064         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1065           circleat(prcp1 + 20*d,
1066                    prc_r3);
1067       }
1068   }
1069 }
1070
1071 module LidAdhocMultiprintFrame(phase){
1072   if (led_window_style >= 3) {
1073     AdhocMultiprintFrame(phase, lpp13[1], -1);
1074   }
1075 }
1076
1077 module LidAroundEdges(){
1078   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1079     children();
1080 }
1081
1082 module Lid(){ ////toplevel
1083   skew_centre = [0, lpp11[0], lpp11[1]];
1084   difference(){
1085     union(){
1086       intersection(){
1087         LidAroundEdges()
1088           LidEdgeProfile();
1089
1090         translate(skew_centre)
1091           multmatrix([[ 1, 0, 0, 0 ],
1092                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1093                       [ 0, 0, 1, 0 ],
1094                       [ 0, 0, 0, 1 ]])
1095           translate(-skew_centre)
1096           LidAroundEdges()
1097           LidEdgeFoldClearanceProfile();
1098       }
1099
1100       // button covers
1101       Buttons(){
1102         intersection(){
1103           rotate([90,0,90])
1104             translate([0,0,-10])
1105             linear_extrude(height= 20)
1106             ButtonPlan($button_l, 1,0);
1107           rotate([90,0,0])
1108              translate([0,0,-100])
1109             linear_extrude(height= 200)
1110             ButtonCoverProfile();
1111         }
1112       }
1113
1114       // hinge arms
1115       HingePortion(hex20, hex21) {
1116         LidEdgeProfile();
1117         HingeLidProfile();
1118       }
1119
1120       // catch
1121       CatchPortion(catch_width)
1122         CatchCatchProfile();
1123     }
1124     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1125
1126     // screw holes in the hinge arms
1127     HingeScrews();
1128
1129     // prop recess
1130     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1131       mirror([0,1,0])
1132       rotate([90,0,90])
1133       linextr(-prop_recess_hw, +prop_recess_hw)
1134       hull()
1135       for (pa = prop_angles)
1136         PropProfile(pa, 1,1);
1137
1138     // notification led aperture
1139     if (led_window_style)
1140       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1141         translate([0,0,-10])
1142           cylinder(r=nla_r0, h=20);
1143         if (led_window_style >= 2)
1144           translate([0,0, -nla_t])
1145             cylinder(r=nla_r2, height=20);
1146       }
1147
1148     }
1149
1150   LidAdhocMultiprintFrame(1);
1151 }
1152
1153 module HingeLever(){ ////toplevel
1154   difference() {
1155     // outer body, positive
1156     HingePortion(hex22, hex22 + phone_width/2)
1157       HingeLeverOuterProfile();
1158
1159     // space for the screws
1160     HingePortion(hex26, hex24)
1161       HingeLeverInnerProfile();
1162
1163     // recesses for the nuts
1164     HingePortion(hex23, hex26+1)
1165       HingeLeverNutProfile();
1166
1167     // bores for the screws
1168     HingeScrews();
1169
1170     // space for the charging cable
1171     MicroUSB();
1172     Flip_hinge() MicroUSB();
1173   }
1174 }
1175
1176 module LidWindow(){ ////toplevel
1177   translate([led_pos[0], -led_pos[1], lpp13[1]])
1178     mirror([0,0,1])
1179     cylinder(r= nla_r1, h=nla_t);
1180   LidAdhocMultiprintFrame(0);
1181 }
1182
1183 module LidWindowPrint(){ ////toplevel
1184   rotate([0,180,0])
1185     LidWindow();
1186 }
1187
1188 module DemoLidWindowSelect(){
1189   translate([led_pos[0], led_pos[1], -100]) {
1190     translate([0, -30, 0]) cube([400, 400, 200]);
1191   }
1192 }
1193
1194 module DemoLidWindow(){ ////toplevel
1195   %Lid();
1196   LidWindow();
1197   translate([0,40,0]){
1198     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1199     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1200   }
1201 }
1202
1203 module HingeLeverPrint(){ ////toplevel
1204   rotate([-90,0,0])
1205     translate([-phone_width/2, phone_height, 0])
1206     HingeLever();
1207 }
1208
1209 module TestSelectLength(){
1210   translate([-30, -200, -20])
1211     cube([30 + 15, 250, 40]);
1212 }
1213
1214 module TestLength(){ ////toplevel
1215   intersection(){
1216     Case();
1217     TestSelectLength();
1218   }
1219 }
1220
1221 module TestLengthRight(){ ////toplevel
1222   intersection(){
1223     Case();
1224     Flip_rhs(1)
1225       TestSelectLength();
1226   }
1227 }
1228
1229 module TestSelectWidth(){
1230   translate([-30, -(phone_height - 25), -20])
1231     mirror([0, 1, 0])
1232     cube([200, 50, 40]);
1233 }
1234
1235 module TestWidth(){ ////toplevel
1236   intersection(){
1237     Case();
1238     TestSelectWidth();
1239   }
1240 }
1241
1242 module TestLidWidthPrint(){ ////toplevel
1243   rotate([0,180.0]) intersection(){
1244     Lid();
1245     TestSelectWidth();
1246   }
1247 }
1248
1249 module TestSelectRearAperture(){
1250   minkowski(){
1251     union() children();
1252     translate([20, 0,0])
1253       cube([42, 2, 1], center=true);
1254   }
1255 }
1256
1257 module TestSelectCamera(){
1258   minkowski(){
1259     TestSelectRearAperture()
1260       RearCameraAperture();
1261     cube([0.1, 50, 0.1]);
1262   }
1263 }
1264
1265 module TestSelectOrdinaryRearApertures(){
1266   TestSelectRearAperture()
1267     OrdinaryRearApertures();
1268 }
1269
1270 module TestCamera(){ ////toplevel
1271   intersection(){
1272     Case();
1273     TestSelectCamera();
1274   }
1275 }
1276
1277 module TestLidByCamera(){ ////toplevel
1278   intersection(){
1279     Lid();
1280     TestSelectCamera();
1281   }
1282 }
1283
1284 module TestLidByCameraPrint(){ ////toplevel
1285   rotate([180,0,0]) TestLidByCamera();
1286 }
1287
1288 module DemoByCamera(){ ////toplevel
1289   color("blue") TestLidByCamera();
1290   color("red")  TestCamera();
1291 }
1292
1293 module OneKeeper(){ ////toplevel
1294   translate([0, -phone_cnr_rad, 0])
1295     rotate([90, 0, 0])
1296     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1297     KeeperProfile();
1298 }
1299
1300 module OneKeeperPrint(){ ////toplevel
1301   rotate([0,180,0])
1302     OneKeeper();
1303 }
1304
1305 module LidPrint(){ ////toplevel
1306   rotate([0,180,0])
1307     Lid();
1308 }
1309
1310 module TestSelectFrame(){
1311   include = [1,-1] * (epp2i[0] + 4);
1312
1313   difference(){
1314     cube(1000, center=true);
1315     translate([0,0, -100])
1316       linear_extrude(height=200)
1317       rectfromto(include,  inside_br - include);
1318   }
1319 }
1320
1321 module TestSelectLidFrame(){
1322   TestSelectFrame();
1323   translate([led_pos[0], -led_pos[1], -50])
1324     cylinder(r= nla_r2+3, h=100);
1325 }
1326
1327 module TestFrameCase(){ ////toplevel
1328   intersection(){
1329     Case();
1330     union(){
1331       TestSelectFrame();
1332       TestSelectCamera();
1333       TestSelectOrdinaryRearApertures();
1334     }
1335   }
1336 }
1337
1338 module TestSelectTopApertures(){
1339   translate([-100, -35, -100])
1340     cube([400, 100, 200]);
1341   LidAdhocMultiprintFrame(0);
1342   LidAdhocMultiprintFrame(1);
1343 }
1344
1345 module TestTopApertures(){ ////toplevel
1346   intersection(){
1347     Case();
1348     TestSelectFrame();
1349     TestSelectTopApertures();
1350   }
1351 }
1352
1353 module TestLidTopAperturesPrint(){ ////toplevel
1354   rotate([0,180,0]) intersection(){
1355     Lid();
1356     TestSelectLidFrame();
1357     TestSelectTopApertures();
1358   }
1359 }
1360
1361 module TestLidWindowTopAperturesPrint(){ ////toplevel
1362   rotate([0,180,0]) intersection(){
1363     LidWindow();
1364     TestSelectTopApertures();
1365   }
1366 }
1367
1368 module TestFrameLidPrint(){ ////toplevel
1369   rotate([0,180,0]) intersection(){
1370     Lid();
1371     TestSelectLidFrame();
1372   }
1373 }
1374
1375 module ButtonPlanForDemo(z, deep, cut){
1376   translate([0,0,z])
1377     ButtonPlan(8, deep, cut);
1378 }
1379
1380 module HingeScrews(){
1381   Flip_rhs() Flip_bot(1){
1382     for (c= [ hppT, hppB ])
1383       translate([ hex20,
1384                   -c[0],
1385                   c[1] ]){
1386         rotate([0,90,0])
1387           translate([0,0,-.2])
1388           cylinder( r= hingescrew_shaft_dia/2,
1389                     h = hingescrew_shaft_len+0.2 );
1390         rotate([0,-90,0])
1391           translate([0,0,+.1])
1392           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1393       }
1394   }
1395 }
1396
1397 module DemoPropAngleSelect(c){
1398   color(c) difference(){
1399     union(){ children(); }
1400     translate([ prop_x_pos, -400, -200 ])
1401       cube([ 400,800,400 ]);
1402   }
1403 }
1404
1405 module DemoPropAngle(ang){
1406   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1407   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1408
1409   translate(hL)
1410     rotate([ang/2,0,0])
1411     translate(-hL)
1412     translate(hC)
1413     rotate([ang/2,0,0])
1414     translate(-hC) {
1415       DemoPropAngleSelect("red") Case();
1416
1417       color("orange")
1418         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1419         PropProfileAssignments(ang) {
1420           echo($prpp1);
1421           rotate([-$prp_theta, 0, 0])
1422           translate([0, $prpp1[0], -$prpp1[1]])
1423           rotate([90,0,-90])
1424           Prop();
1425         }
1426     }
1427
1428   translate([0,0, -hp_k*2])
1429     DemoPropAngleSelect("blue")
1430     Lid();
1431 }
1432
1433 module DemoPropAngles(){ ////toplevel
1434   for (i=[0 : len(prop_angles)-1])
1435     translate(i * [0, -100, 100])
1436     DemoPropAngle(prop_angles[i]);
1437 }
1438
1439 module DemoHingeAngle(ang1,ang2){
1440   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1441   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1442
1443   translate(hL)
1444     rotate([ang2,0,0])
1445     translate(-hL)
1446     translate(hC)
1447     rotate([ang1,0,0])
1448     translate(-hC) {
1449       color("red") Lid();
1450     }
1451
1452   color("blue") intersection(){
1453     Case();
1454     union(){
1455       translate([bppJ[0], -400, -200])
1456         mirror([1,0,0])
1457         cube([400, 800, 400]);
1458       translate([10, -400, -200])
1459         cube([10, 800, 400]);
1460     }
1461   }
1462 }
1463
1464 module DemoHingeAngles(){ ////toplevel
1465   angles = [ 0, 4, 8, 12 ];
1466   echo("angles",angles);
1467   for (i=[0 : len(angles)-1]) {
1468     translate(i * [0, 0, 30]) {
1469       DemoHingeAngle(0,angles[i]);
1470       translate([0, 200, 0])
1471         DemoHingeAngle(angles[i],0);
1472     }
1473   }
1474 }
1475
1476 module DemoSelectAdhocLeftRight(right=0) {
1477   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1478     mirror([1-right, 0,0])
1479     cube([400, 800, 200]);
1480 }
1481
1482 module DemoLeft(){ ////toplevel
1483   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1484   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1485 }
1486
1487 module DemoFrame(){ ////toplevel
1488   color("red") TestFrameCase();
1489   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1490   color("black") HingeScrews();
1491   %HingeLever();
1492 }
1493
1494 module DemoHingedFrame(){ ///toplevel
1495   color("red") TestFrameCase();
1496   translate([0,0, -2*hp_k])
1497   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1498
1499   Flip_hinge(){
1500     color("orange") HingeLever();
1501     color("black") HingeScrews();
1502   }
1503 }
1504
1505 module DemoHinge(){ ////toplevel
1506   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1507     DemoFrame();
1508     translate([0,0, -hp_k*3])
1509       DemoHingedFrame();
1510   }
1511 }
1512
1513 module DemoProfiles(){ ////toplevel
1514   LidEdgeProfile();
1515   %EdgeProfile();
1516   KeeperProfile();
1517   translate([0,0,-1]) color("black") KeeperProfile(1);
1518
1519   translate([20,0]) {
1520     LidEdgeProfile();
1521     %EdgeProfile();
1522
1523     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1524
1525     color("blue") ButtonCoverProfile();
1526     color("red") {
1527       rectfromto(bppQ, demopoint_QR);
1528       rectfromto(bppR, demopoint_QR);
1529     }
1530   }
1531
1532   translate([-20,0]) {
1533     color("black") ButtonPlanForDemo(-2, 0,1);
1534     color("red" )  ButtonPlanForDemo(-4, 1,1);
1535     color("blue")  ButtonPlanForDemo(-6, 1,0);
1536   }
1537
1538   translate([0, -30]) {
1539     %LidEdgeProfile();
1540     %EdgeProfile();
1541     color("blue") HingeLidProfile();
1542     color("red")  HingeBaseProfile();
1543     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1544   }
1545
1546   for (f=[0,1]) {
1547     translate([-30, -60 + 30*f]) {
1548       translate([0,0,-4]) EdgeProfile();
1549       %translate([0,0,-10]) HingeBaseProfile();
1550       translate([0,-2] * f * hp_k) {
1551         translate([0,0,-4]) LidEdgeProfile();
1552         %translate([0,0,-10]) %HingeLidProfile();
1553       }
1554       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1555         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1556         translate([0,0,0]) color("red") difference(){
1557           HingeLeverOuterProfile();
1558           HingeLeverInnerProfile();
1559         }
1560         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1561       }
1562     }
1563   }
1564
1565   translate([20,-30]) {
1566     %EdgeProfile();
1567     %LidEdgeProfile();
1568     //translate([0,0,1]) CatchCutProfile();
1569     color("blue") CatchCatchProfile();
1570     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1571   }
1572
1573   translate([40,-30]) {
1574     difference(){
1575       LidEdgeProfile();
1576       translate(prlp10)
1577         PropProfile(10, 1, 0);
1578     }
1579     translate(prlp10)
1580       PropProfile(15, 0);
1581   }
1582   translate([60,-30]) {
1583     PropAggregateProfile();
1584   }
1585 }
1586
1587 //EdgeProfile();
1588 //KeeperProfile();
1589 //CaseBase();
1590 //%Case();
1591 //Keeper();
1592 //LidEdgeProfile();
1593 //KeeperProfile();
1594 //DemoProfiles();
1595 //PropRecess();