chiark / gitweb /
d83c53474f4b548972d672539cecb5210bf28c8b
[reprap-play.git] / fairphone-case.scad
1 // -*- C -*-
2
3 // Hard case for Fairphone 2
4 //
5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
6 //  See below for full licensing and disclaimer.
7 //
8 // Instructions
9 //
10 //  1. You will want to git clone this repository.
11 //
12 //  2. Decide about the notification LED aperture. See the variable
13 //     led_window_style, below.  The default here is "ad-hoc
14 //     multi-colour", which can produces a translucent (clear-ish)
15 //     window set into the lid, even on a single-nozzle printer.
16 //     See "Ad-hoc multi-colour", below.
17 //
18 //  3. use "make" to generate the necessary files:
19 //
20 //     make -j8 fairphone-case.auto.scads `for f in   \
21 //        HingePrint        \
22 //        LidWindowPrint    \
23 //        LidPrint          \
24 //        OneKeeperPrint    \
25 //        Case              \
26 //     ; do echo fairphone-case,$f.auto.stl; done`
27 //
28 //  4. Print them.  Case and OneKeeperPrint should probably be
29 //     the same colour.
30 //
31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
32 //     multi-colour:
33 //        i.   Set up for clear filament
34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
35 //             It won't take long.  As soon as it finishes, tell
36 //             your printer to warm up (so that in fact it does
37 //             not cool down).
38 //        iii. Leaving the output so far on the printbed, reload
39 //             your printer with the main lid colour.
40 //        iv.  Print LidPrint.  You can let this go unattended.
41 //
42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
43 //     and 8x M2 full nuts.
44 //
45 //     Make sure you get the hinge the right way round.  If you're not
46 //     sure, run
47 //         openscad fairphone-case,DemoHinge.auto.scad
48 //     to see an assembly diagram.
49 //
50 //     The nuts recess into the hinge.  You will want very fine
51 //     pliers.  As you screw each screw in, add the second nut when
52 //     the screw thread emerges from the first - this will be a
53 //     locknut.  Screw each screw to an appropriate tightness for the
54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
55 //     that makes closing the case work better.
56 //
57 //     When you have the stiffness right, tighten the locknuts onto
58 //     each first nut.
59 //
60 //  6. In use:
61 // 
62 //      - To put the phone in, drop its RH side into the RH side of
63 //        the case.  Then feed the keeper through the small hole.
64 //        Feed it right through.
65 //
66 //      - The optional prop can be used to prop the phone up (in
67 //        portrait orientation only right now).  See
68 //            openscad fairphone-case,DemoPropAngles.auto.scad
69 //
70 // Ad-hoc multi-colour
71 //     
72 //  This file is set up to let you make a translucent window using a
73 //  single-extruder printer, using a "two print run" technique.  This
74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
75 //  Cura.  If you are using a different printer, you may need to
76 //  adjust the parameters or try a different technique.  In particular,
77 //      initial_layer_thick
78 //         set so that the window is one layer thick
79 //      initial_layer_width
80 //         set so that the slicer draws a rectangle around the whole
81 //         object, rather than putting a "skirt" or anything inside
82 //
83 //  If you have a dual-extruder printer, you can set led_window_style
84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
85 //
86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
87 //
88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
90 //
91 // Other phones
92 //
93 //  It might well be possible to adapt this file for other phones.
94 //  If you do, let me know how you get on.
95 //
96 //
97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
98 //
99 //   Copyright (C)2018 Ian Jackson.
100 //
101 //    This program for generating a 3D model is free software: you can
102 //    redistribute it and/or modify it under the terms of the GNU
103 //    General Public License as published by the Free Software
104 //    Foundation, either version 3 of the License, or (at your option)
105 //    any later version.
106 //
107 //    This program is distributed in the hope that it will be useful,
108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
110 //    GNU General Public License for more details.
111 //
112 //    You should have received a copy of the GNU General Public
113 //    License along with this program.  If not, see
114 //    <http://www.gnu.org/licenses/>.
115 //
116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
118 //  this case will meet your needs.
119
120 include <utils.scad>
121 include <funcs.scad>
122
123 phone = [ 75.0, 145.0 ];
124
125 prop_buildout_less = 3;
126
127 prop_angles = [ 15, 30, 45, 60 ];
128
129 bumper = [ 0.250, -0.025 ];
130 // ^ One side.  Overall size is increased by twice this.
131 // If no bumpers, is the gap around the phone.
132
133 enable_support = 1;
134
135 led_window_style = 3;
136 // 0: no window
137 // 1: simply an opening
138 // 2: opening with separate cover model, for printing in clear (two colour)
139 // 3: like 2 but one-layer window for ad-hoc multi-colour
140
141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
142 initial_layer_width = 0.750; // ^ needed for mode 3 only
143 multicolour_gap = 0.15; // each side
144
145 phone_cnr_rad = 6.0;
146 phone_rim_depth = 0.80; // includes allowance for a screen protector
147
148 button_cutout_depth = 9;
149
150 phone_edge_thick = 9.0;
151 phone_total_thick = 12.0;
152 phone_backside_slope_inner = 1.5; // larger means shallower
153 phone_backside_slope_outer = 1.0; // larger means shallower
154
155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
157
158 jack_pos = [ 13.83, 8.485 ];
159 jack_dia = 10.64 + .5; // some jack I had lying around
160
161 led_pos = [ 13.98, 10.00 ];
162 led_aperture = 9;
163 led_window_ledge = 0.75; // each side
164
165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
166 noisecancelmic_dia = 4.00;
167
168 //fingerpushhole_dias = [ 15, 18 ];
169 fingerpushhole_dias = [];
170
171 lanyard_half_dia = 1.15;
172 lanyard_entry_rel_breadth = 2;
173 lanyard_channel_len = 15;
174 rearspeaker_pos_bl = [ 12.64, 18.72 ];
175 rearspeaker_size   = [  3.76,  7.36 ];
176
177 microusb_above = 3.27 - 0.25;
178 microusb_below = 0.0;
179 microusb_width = 16.12 + 1.25;
180
181 case_th_bottom = 2.5;
182 case_th_lid = 3.0;
183 case_th_side = 2.3;
184 case_th_lip = 1.2;
185
186 lid_screen_gap_extra = .66;
187
188 case_struts_count = 6;
189 case_struts_solid_below = 1.00;
190 case_struts_solid_above = 0.75;
191 case_struts_width = 0.10;
192
193 keeper_th_z = 0.75;
194 keeper_th_x = 0.75;
195 keeper_inner_width = 2.75;
196 keeper_inner_height = 2.75;
197 keeper_slant_slope = 2; // larger means steeper
198
199 keeper_gap_z_top = 0.25;
200 keeper_gap_z_bot = 0.75;
201 keeper_gap_x     = 0.25;
202 keeper_gap_x_holes = 0.75;
203
204 keeper_side = 0; // 0 = lhs; 1 = rhs
205
206 case_lip = 1.25;
207
208 lid_gap_x = 0.25;
209 lid_gap_z = 0.25;
210 lid_lip = 1.75;
211 lid_edgepart_width = 5.0;
212 lid_buttoncover_thick = 1.3;
213
214 catch_slop = 0.50;
215
216 foldover_gap = 0.50;
217 foldover_lever_gap = 0.50;
218
219 // properties of the hinge fasteners
220 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
221 hingescrew_shaft_len = 12;
222 hingescrew_fasteners_extra_thick = 0.40;
223 // ^ amount of thread protruding if everything was completely nominal
224 //   and we are using two nuts
225 hingescrew_nut_access_dia = 4.72 + 0.50;
226 // ^ washer is 4.72 dia
227 //   also, want to get pliers or tiny spanner in to do up locknut
228 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
229 hingescrew_nut_thick = 1.93;
230 hingescrew_head_th = 1.38 + 0.75;
231 hingescrew_head_dia = 3.92;
232
233 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
234
235 lever_cover_th = 0.75;
236 hingemount_th = 2.5;
237 hingemount_wd = 4.8725;
238
239 $fa = 5;
240 $fs = 0.1;
241
242 button_l_fudge = 4.4;
243 buttonishleg_default_l_is_fudge = 10;
244
245 hinge_base_slope = 1.5; // bigger is steeper
246
247 strut_min_at_end = 1.5;
248
249 hinge_x_gap = 0.125;
250 hinge_x_postscrew_gap = 0.75;
251 hinge_x_arms_gap = 0.35;
252 hinge_r_arms_gap = 0.55;
253
254 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
255
256 catch_len = 7.5;
257 catch_width = 15;
258 catch_thickness = 1.3;
259 catch_side_gap = 0.75; // each side
260
261 catch_depth = 1.25;
262 catch_height = 0.35;
263 catch_finger_height = 1.5;
264 catch_finger_depth = 2.5;
265 catch_catch_slope = 0.25;
266
267 catch_topcurve_r = 5.0;
268
269 prop_recess_under = 0.50;
270 prop_recess_slop = 0.200; // each side
271 prop_end_dia = 0.5;
272 prop_main_th = 3;
273 prop_taper_len = 6;
274 prop_main_width = 4;
275 prop_side_gap = 0.75; // each side
276 prop_lidrecess_behind = 0.75;
277 prop_caserecess_behind = 0.75;
278 prop_caserecess_taper = 0.45; // one side only
279 prop_prop_gap = 0.5;
280 prop_prong_heel_slope = 0.5;
281
282 lid_fold_clearance_antislop = 0.5;
283
284 // ---------- calculated ----------
285
286 phone_width =  (phone + bumper*2)[0];
287 phone_height = (phone + bumper*2)[1];
288
289 inside_br = [phone_width, -phone_height];
290
291 prop_prong_h = prop_main_th;
292
293 //echo(camera_pos_tl + bumper,
294 //     camera_pos_br + bumper);
295
296 // ----- could be changed -----
297 lid_buttoncover_gap = lid_gap_x;
298 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
299
300 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
301
302 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
303
304 //prop_nose_len = case_th_lid - prop_recess_under;
305 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
306 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
307
308
309 //lid_lip_overlap_width xxx bad name = ;
310 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
311
312 epp0 = [0,0];
313 epp1 = [0, -phone_edge_thick];
314 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
315 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
316 epp3 = epp2i + [10, 0];
317 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
318 epp4 = epp5 + [-1,0] * case_th_side;
319
320 kppe = [0,0];
321 kppd = kppe + [1,0] * keeper_inner_width;
322 kppc = kppd + [0,1] * keeper_th_z;
323 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
324 kppf = kppe - [0,1] * keeper_inner_height;
325 kppa = [ kppb[0], kppf[1] ];
326
327 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
328 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
329
330 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
331 // exact x posn not very important; must extend past end of keeper
332
333 lpp15 = [ lpp14[0],
334           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
335           + lid_screen_gap_extra ];
336 // ^ beam theory says to maximise force before contact,
337 //   the gap below the `beam' (the lid) must be 1/3
338 //   the thickness (ie the lid thickness) if the beam
339 //   is solid, or 1/2 if it has a top and bottom only.
340 //   ours is mostly solid.
341
342 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
343              case_th_lip);
344
345 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
346 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
347
348 case_bottom_z = epp2o[1] - case_th_bottom;
349
350 // button profile
351 bppM = epp4 + [0,5];
352 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
353 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
354 bppS = [ epp1[0], bppR[1] ];
355 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
356 bppP = bppQ + [0,1] * lid_buttoncover_gap;
357 bppO = [ bppN[0], bppP[1] ];
358 bppL = lpp10 + [5,0];
359 bppK = [ bppL[0], bppN[1] ];
360 bppJ = [ bppN[0], bppL[1] ];
361 bppU = [ bppJ[0], lpp12[1] ];
362 bppV = lpp11;
363 bppW = lpp10;
364
365 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
366
367 // notification led aperture
368
369 nla_r0 = led_aperture/2;
370 nla_r1 = nla_r0 + led_window_ledge;
371 nla_r2 = nla_r1 + multicolour_gap;
372 nla_t =
373   led_window_style >= 3 ? initial_layer_thick :
374   led_window_style >= 2 ? led_window_ledge : 0;
375
376
377 // hinge plan
378 hp_rn = hingescrew_nut_access_dia/2;
379 hp_r2_min = hp_rn + lever_cover_th;
380 hp_rs = hingescrew_shaft_dia/2;
381 hp_r1_min = hp_rs + hingemount_th;
382
383 hp_r1 = max(hp_r1_min, hp_r2_min);
384 hp_r2 = hp_r1;
385
386 hppU = lpp13;
387 hppS = epp2o + [0,-1] * case_th_bottom;
388 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
389
390 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
391          0.5 * (hppU + hppS)[1] ];
392 hppT = [ hppM[0], hppU[1] - hp_r1 ];
393 hppB = hppT + [0,-1] * hp_k;
394
395 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
396 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
397 hppE = [ hppE_x, hppE_y ];
398
399 // hinge elevation x coords
400
401 hex20 = max(epp2o[0],
402             phone_cnr_rad,
403             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
404 hex21 = hex20 + hingemount_wd;
405 hex22 = hex21 + hinge_x_gap;
406 hex27 = hex20 + hingescrew_shaft_len;
407 hex24 = hex27 + hinge_x_postscrew_gap;
408 hex23 = hex27 - (hingescrew_nut_thick*2
409                  + hingescrew_fasteners_extra_thick);
410 hex26 = hex23 + hingescrew_nut_thick * 2/3;
411
412 echo(hex20, hex21, hex22, hex23, hex24);
413 //  6, 10.8725, 10.9975, 13.74, 18.75
414 module chk(act,exp) {
415   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
416   else echo("ok", act);
417 }
418 chk(hex20, 6);
419 chk(hex21, 10.8725);
420 chk(hex22, 10.9975);
421 chk(hex23, 13.74);
422 chk(hex24, 18.75);
423
424 lid_fold_clearance_skew =
425   (lpp10[1] - hppB[1]) /
426   (lpp10[0] - hppB[0]);
427
428 echo("SK",lid_fold_clearance_skew);
429
430 // catch
431
432 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
433 cppA = cppJ + [lid_gap_x, -lid_gap_z];
434 cppB = [ epp0[0], cppA[1] ];
435 cppP = [ epp4[0], cppJ[1] ];
436
437 cppS = cppJ + [0,-1] * catch_len;
438 cppD = [ cppA[0], cppS[1] + catch_slop ];
439 cppC = [ cppB[0], cppD[1] ];
440 cppT = cppS + [1, -catch_catch_slope] * catch_depth;
441 cppU = cppT + [0,-1] * catch_height;
442 cppV = [ cppS[0], cppU[1] - catch_depth ];
443
444 cppR = 0.5*(cppP + cppJ);
445
446 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
447 cppQ = [ cppR[0],
448          cppV[1] - (catch_finger_height - cp_rQ) ];
449 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
450
451 // lanyard
452
453 ly_r = lanyard_half_dia / 2;
454 ly_rc = ly_r * 2;
455
456 ly_theta = -atan2vector(epp2i - epp1);
457 ly_o = epp2i + 3 * ly_r * unitvector2d(epp1 - epp2i);
458
459 max_case_bottom_edge_thickness =
460   case_th_bottom
461   + sin(ly_theta) * (epp2i-epp2o)[0];
462
463 ly_q_z = -(ly_rc + ly_r);
464 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
465
466 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
467
468 // prop recess in case
469
470 prop_x_pos = phone_width/2;
471
472 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
473
474 prc_r1 = prop_end_dia/2;
475 prc_r3 = prc_r1 + prop_recess_slop;
476
477 prcp2 = [ epp4[0] + prop_buildout_less,
478           case_bottom_z ];
479
480 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
481
482 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
483           epp2i[1] - prc_r3 - prop_recess_under];
484
485 // prop recess in lid
486
487 prl_r10 = prop_end_dia/2;
488 prl_r10o = prl_r10 + prop_recess_slop;
489
490 prlp10 = lpp10 + [1,1] * prl_r10o
491   + [1,0] * prop_lidrecess_behind
492   + [0,1] * prop_recess_under;
493
494 // prop
495
496 $prpp10 = [0,0];
497 $prpp11 = [0, prop_taper_len];
498
499 $prp_r10 = prl_r10;
500
501 // ---------- modules ----------
502
503 module AdhocMultiprintFrame(phase, z0, zs) {
504   // from z0 to z0 + zs*layer
505   extra = phase * (initial_layer_width + multicolour_gap) + 5;
506   xextra = extra + -epp4[0];
507   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
508   yextra = extra + -epp4[0];
509   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
510   p0 = [ xrange[0], yrange[0] ];
511   p1 = [ xrange[1], yrange[1] ];
512   echo(p0, p1);
513   translate([0,0, z0])
514     mirror([0,0, zs<0 ? 1 : 0])
515     linear_extrude(height= initial_layer_thick)
516     difference(){
517       rectfromto(p0 - [1,1] * initial_layer_width,
518                  p1 + [1,1] * initial_layer_width);
519       rectfromto(p0, p1);
520     }
521 }
522
523 module KeeperProfile(slant=0){
524   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
525   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
526 }
527
528 module EdgeProfile(){
529   difference(){
530     hull(){
531       translate(epp3) square(case_th_bottom*2, center=true);
532       circleat(epp2o, r=case_th_bottom);
533       circleat(epp1, r=case_th_side);
534       rectfromto(epp0, epp4);
535     }
536     polygon([ epp5 + [0,10],
537               epp1,
538               epp2i,
539               epp3 + [10,0] ]);
540   }
541 }
542
543 module LanyardLanyardProfile(entry=false){
544   hull(){
545     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
546       translate(xs * 0.5 * lanyard_half_dia * [1,0])
547         circle(r= lanyard_half_dia/2);
548   }
549 }
550
551 module LanyardCurveChannelProfile(){
552   translate([0, -ly_r])
553     LanyardLanyardProfile();
554 }  
555
556 module LanyardEntryChannelProfile(){
557   LanyardLanyardProfile(true);
558 }  
559
560 module LanyardMainChannelProfile(){
561   LanyardCurveChannelProfile();
562   difference(){
563     square(center=true, ly_r * [6, 2]);
564     for (xs=[-1,+1])
565       translate(ly_r * [3 * xs, -1])
566         circle(r = ly_r);
567   }
568 }
569
570 module LanyardEntryOuterProfile(){
571   circleat([ly_re + ly_r, 0], ly_re);
572 }
573
574 module LanyardEntry(){
575   q_z = ly_q_z;
576   oec_y = ly_oec_y;
577
578   d_x = -ly_rc;
579
580   translate([d_x, 0, q_z]) {
581     intersection(){
582       rotate([90,0,0])
583         rotate_extrude(convexity=10)
584         rotate(90)
585         translate([0, -q_z])
586         LanyardCurveChannelProfile();
587       translate([0,-10,0])
588         cube([20,20,20]);
589     }
590   }
591
592   mirror([0,0,1])
593     translate([0,0,-1])
594     linear_extrude(height=20)
595     rotate(-90)
596     LanyardEntryChannelProfile();
597
598   translate([0, ly_r*2, 0])
599     rotate([90,0,0])
600     linear_extrude(height = ly_r*4){
601     difference(){
602       rectfromto([d_x, q_z], [ly_r, 0]);
603       circleat([d_x, q_z], ly_rc);
604     }
605   }
606
607   translate([0,0,q_z]){
608     for (my=[0,1])
609       mirror([0,my,0]){
610         translate([0, oec_y, 0]){
611           difference(){
612             translate(ly_re * [-1,0,-2])
613               cube(ly_re * [2,1,2]);
614             rotate_extrude(convexity=10)
615               LanyardEntryOuterProfile();
616           }
617         }
618       }
619     difference(){
620       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
621         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
622       for (mx=[0,1])
623         mirror([mx,0,0])
624           rotate([90,0,0])
625           translate([0,0,-10])
626           linear_extrude(height=20)
627           LanyardEntryOuterProfile();
628     }
629   }
630 }
631
632 module LanyardCutout(l){
633   rotate([0,-90,0])
634     linear_extrude(height=l)
635     rotate(-90)
636     LanyardMainChannelProfile();
637
638   for (ee=[0,1]){
639     translate(ee * l * [-1,0])
640       mirror([ee,0,0])
641       LanyardEntry();
642   }
643 }
644
645 module LidEdgeProfile(){
646   polygon([ lpp10,
647             lpp11,
648             lpp12,
649             lpp13,
650             lpp13 + [10, 0],
651             lpp15 + [10, 0],
652             lpp15,
653             lpp14,
654             ]);
655   intersection(){
656     circleat(lpp12, r=lp_r12);
657     rectfromto( lpp12 + [-10,   0],
658                 lpp12 + [+10, +10] );
659   }
660 }
661
662 module LidEdgeFoldClearanceProfile(){
663   translate([-lid_fold_clearance_antislop, 0])
664     polygon([ lpp10,
665               lpp11,
666               lpp11 + [-20,  0],
667               lpp11 + [-20, 20],
668               lpp11 + [+20, 20],
669               lpp10 + [+20,  0] ]);
670 }
671
672 module ButtonCoverProfile(){
673   intersection(){
674     polygon(concat([ bppM, bppP, bppO, bppJ ],
675                    (enable_support && !$button_suppress_over_keeper
676                     ? [ bppU, bppV, bppW ] : []),
677                    [ bppL, bppK ]));
678     hull(){
679       EdgeProfile();
680       LidEdgeProfile();
681     }
682   }
683 }
684
685 module ButtonPlan(l, deep, cut){
686   epsilon =
687     (cut  ? 0 : lid_buttoncover_gap);
688
689   delta =
690     (deep ? lid_buttoncover_overlap : 0);
691
692   C = [0,0]; // by definition
693   T = [ 0, epp4[1] ];
694   G = T + [0,10];
695
696   B0 = C + [0,-1] * button_cutout_depth;
697   B1 = B0 + [0,1] * epsilon;
698
699   r0 = 0.5 * (T[1] - B0[1]);
700   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
701   H = A + [0,-1] * delta;
702
703   D = A + [-2,0] * r0;
704   F = D + [0,10];
705
706   E0 = 0.5 * (D + A);
707   E1 = E0 + [1,0] * epsilon;
708
709   I0 = [ E0[0], H[1] ];
710   I1 = [ E1[0], H[1] ];
711
712   hull(){
713     for (m=[0,1]) mirror([m,0])
714       circleat(H, r0 - epsilon);
715   }
716   for (m=[0,1]) mirror([m,0]) {
717     difference(){
718       polygon([ E1,
719                 I1,
720                 H,
721                 B1,
722                 G,
723                 F,
724                 D
725                 ]);
726       circleat(D, r0 + epsilon);
727     }
728   }
729 }
730
731 module CatchCatchProfile(){
732   hull(){
733     for (c=[ cppR, cppQ ])
734       circleat(c, cp_rQ);
735   }
736   hull(){
737     circleat(lpp12, lp_r12);
738     circleat(lpp12 + [5,0], lp_r12);
739     rectfromto(cppP, cppP + [5,0.1]);
740   }
741   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
742 }
743
744 module CatchCutProfile(){
745   polygon([ cppB,
746             cppA,
747             cppD,
748             cppF,
749             cppF + [0,-10],
750             cppF + [-10,-10],
751             lpp12 + [-10,0],
752             lpp12 + [10,0]
753             ]);
754 }
755
756 module Flip_rhs(yn=[0,1]) {
757   for ($rhsflip=yn) {
758     translate([phone_width/2, 0, 0])
759       mirror([$rhsflip,0,0])
760       translate([-phone_width/2, 0, 0])
761       children();
762   }
763 }
764
765 module Flip_bot(yn=[0,1]) {
766   for ($botflip=yn) {
767     translate([0, -phone_height/2, 0])
768       mirror([0, $botflip, 0])
769       translate([0, phone_height/2, 0])
770       children();
771   }
772 }  
773
774 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
775   // sides
776   Flip_rhs(){
777     translate([0, -phone_cnr_rad, 0])
778       rotate([90,0,0])
779       linear_extrude(height = phone_height - phone_cnr_rad*2)
780       children(0);
781   }
782   // corners
783   Flip_rhs() Flip_bot() {
784     translate([+1,-1] * phone_cnr_rad)
785       intersection(){
786         rotate_extrude()
787           intersection(){
788             mirror([1,0,0])
789               translate([-1,0] * phone_cnr_rad)
790               children(0);
791             rectfromto([0,-20],[10,20]);
792           }
793         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
794           cube([10,10,40]);
795       }
796   }
797   // top and bottom
798   Flip_bot(){
799     translate([ phone_width - phone_cnr_rad, 0,0 ])
800       rotate([90,0,-90])
801       linear_extrude(height = phone_width - phone_cnr_rad*2)
802       children(0);
803   }
804   // fill
805   translate([0,0, fill_zstart])
806     mirror([0,0, fill_downwards])
807     linear_extrude(height = fill_th)
808     rectfromto([+1,-1] * phone_cnr_rad,
809                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
810 }
811
812 module CaseAperture(pos, dia, $fn) {
813   theta = 180/$fn;
814   translate([ pos[0] + bumper[0],
815               -epp2i[0],
816               -pos[1] ])
817     rotate([-90, theta, 0])
818     cylinder(r = dia/2 / cos(theta),
819              h = 60);
820 }
821
822 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
823   // y_ref_sign:
824   //   +1  measured from top    of actual phone to top    of button
825   //   -1  measured from bottom of actual phone to bottom of button
826   //    0  y is centre of button in coordinate system
827   $button_l= l;
828   $button_suppress_over_keeper= suppress_over_keeper;
829   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
830           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
831           y;
832   //echo(eff_y);
833   translate([0, eff_y, 0])
834     children();
835 }
836
837 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
838   $button_leg_only = true;
839   SideButton(y, y_ref_sign, l) children();
840 }
841
842 module Buttons(){
843   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
844   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
845   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
846   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
847 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
848 }
849
850 module Struts(x_start, z_min, th){
851   // if th is negative, starts at z_min and works towards -ve z
852   // and object should then be printed other way up
853   for (i= [1 : 1 : case_struts_count]) {
854     translate([0,
855                0,
856                z_min])
857       mirror([0,0, th<0 ? 1 : 0])
858       translate([0,
859                  -phone_height * i / (case_struts_count+1),
860                  case_struts_solid_below])
861       linear_extrude(height= abs(th)
862                      -(case_struts_solid_below+case_struts_solid_above))
863       rectfromto([               x_start, -0.5 * case_struts_width ],
864                  [ phone_width - x_start, +0.5 * case_struts_width ]);
865   }
866 }
867
868 module OrdinaryRearAperture(rhs,bot, pos){
869   Flip_rhs(rhs) Flip_bot(bot)
870     linextr(-20, 20)
871     mirror([0,1])
872     translate(pos + bumper)
873     children();
874 }
875
876 module MicroUSB(){
877   Flip_bot(1){
878     rotate([90,0,0])
879       mirror([0,0,1])
880       linextr(-epp2i[0], 60)
881       translate([0.5 * phone_width, 0, 0])
882       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
883                  [+microusb_width/2, epp0[1] + -microusb_above]);
884   }
885 }
886
887 module OrdinaryRearApertures(){
888   // rear speaker
889   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
890     rectfromto(-rearspeaker_gap,
891                rearspeaker_size + rearspeaker_gap);
892
893   // finger hole to remove phone
894   if (len(fingerpushhole_dias))
895     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
896                                 phone[1]/2 ])
897     scale(fingerpushhole_dias)
898     circle(r= 0.5 );
899 }
900
901 module RearCameraAperture(){
902   Flip_rhs(1)
903     mirror([0, 0, 1])
904     linear_extrude(height = 20)
905     mirror([0, 1, 0])
906     translate(bumper)
907     rectfromto(camera_pos_tl, camera_pos_br);
908 }
909
910 module HingeLidProfile(){
911   hull(){
912     circleat(hppT, hp_r1);
913     circleat(lpp12, lp_r12);
914     polygon([lpp10,
915              lpp13 + [2,0],
916              lpp12,
917              hppT]);
918   }
919 }
920
921 module HingeBaseProfile(){
922   difference(){
923     hull(){
924       circleat(hppB, hp_r1);
925       circleat(hppE, hp_r1);
926       circleat(epp2o, case_th_bottom);
927       circleat(hppB + [10,0], hp_r1);
928     }
929     polygon([epp5, epp1, epp2i, epp3, bppL]);
930   }
931 }
932
933 module HingeLeverOuterProfile(){
934   hull(){
935     circleat(hppT, hp_r2);
936     circleat(hppB, hp_r2);
937   }
938 }
939
940 module HingeLeverInnerProfile(){
941   for (s = [-1,+1]) {
942     c = s > 0 ? hppT : hppB;
943     translate(c)
944       mirror([0,0,s>0])
945       rotate(s<0 ? -40 : 0)
946       hull()
947       for (x=[-20,20])
948         for (y=[0, s * 10])
949           translate([x,y])
950             circle(hp_rn);
951   }
952 }
953
954 module HingeLeverNutProfile(){
955   for (c= [hppB, hppT]) {
956     translate(c)
957       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
958   }
959 }
960
961 module Flip_hinge(doflip=1){
962   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
963   translate(hinge_origin)
964     rotate([doflip*180,0,0])
965     translate(-hinge_origin)
966     children();
967 }
968
969 module HingePortion(x0,x1){
970   Flip_rhs() Flip_bot(1)
971     translate([x0,0,0])
972     mirror([1,0,0])
973     rotate([90,0,-90])
974     linear_extrude(height=x1-x0)
975     children();
976 }
977
978 module CatchPortion(xwidth, ztop){
979   width = catch_width + xwidth;
980   w = width + catch_topcurve_r*2 + 1;
981   translate([phone_width/2, 0,0]){
982     difference(){
983       rotate([90,0,-90])
984         linextr(-w/2, w/2)
985         children(0);
986       translate([0, 50, 0])
987         rotate([90,0,0])
988         linear_extrude(height=100){
989         for (m=[0,1]) mirror([m,0,0]) {
990           hull(){
991             translate([w/2, ztop - catch_topcurve_r])
992               circle(catch_topcurve_r);
993             translate([w/2, -50])
994               square(catch_topcurve_r*2, center=true);
995           }
996         }
997       }
998     }
999   }
1000 }
1001
1002 module CaseBase(){
1003   AroundEdges(epp3[1], case_th_bottom, 1)
1004     EdgeProfile();
1005 }
1006
1007 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
1008
1009 module PropProfileAssignments(gamma){
1010   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
1011   x = prop_x(gamma);
1012   p = phone_height + prlp10[0] - hppB[0];
1013   b = p + x;
1014
1015   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1016   a = q + x;
1017   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1018   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1019
1020   $prp_theta = 90 - $prp_alpha;
1021   beta = 180 - $prp_alpha - gamma;
1022   psi = 90 - beta;
1023
1024   //echo("abc", a,b,c);
1025
1026   v1 = [ [ cos(psi), -sin(psi) ],    // x
1027          [ sin(psi),  cos(psi) ] ];  // y
1028
1029   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1030
1031   $prp_r1 = prc_r1;
1032   $prp_r11 = prop_main_th/2;
1033
1034   $prpp1 = $prpp7 + [1,0] *
1035     // this is approximate, but will do
1036     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1037   $prpp3 = $prpp1 +
1038     v1[0] * -$prp_r1 +
1039     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1040   $prpp12 = $prpp3 + v1[0] *
1041     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1042   $prp_r8 = prop_main_th;
1043   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1044   $prp_r5 = $prp_r8;
1045   $prpp5 = [ $prpp12[0] - $prp_r5,
1046             $prpp3[1] - prop_prong_h + $prp_r5 ];
1047   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1048          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1049   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1050   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1051
1052   children();
1053 }
1054
1055 module PropProfile(gamma, cut=0, rot=0){
1056   PropProfileAssignments(gamma){
1057
1058     //#circleat($prpp3,1);
1059     //#circleat($prpp12,1);
1060
1061     if (!cut) {
1062       hull(){
1063         translate($prpp8)
1064           intersection(){
1065             circle($prp_r8);
1066             polygon([[-20,-0], [20,20], [0,0]]);
1067           }
1068         rectfromto($prpp6, $prpp9);
1069         translate($prpp5) intersection(){
1070           circle($prp_r5);
1071           polygon([[-10,-10], [0,0], [10,0]]);
1072         }
1073         rectfromto($prpp12 + [0,-0.1], $prpp3);
1074       }
1075       hull(){
1076         circleat($prpp1, $prp_r1);
1077         rectfromto($prpp12 + [0,-0.1], $prpp3);
1078       }
1079     }
1080     // main shaft
1081     rotate([0,0, rot*-$prp_theta]){
1082       hull(){
1083         extra = cut ? prop_recess_slop : 0;
1084         rectfromto($prpp6, $prpp9);
1085         circleat($prpp11, $prp_r11 + extra);
1086         circleat($prpp10, $prp_r10 + extra);
1087       }
1088     }
1089   }
1090 }
1091
1092 module PropAggregateProfile(){
1093   for (angle = prop_angles)
1094     PropProfile(angle, 0,0);
1095 }
1096
1097 module Prop(){ ////toplevel
1098   hw = prop_main_width/2;
1099   linextr(-hw, +hw)
1100     PropAggregateProfile();
1101 }
1102
1103 module Case(){ ////toplevel
1104   difference(){
1105     union(){
1106       CaseBase();
1107
1108       // ledge (fixed keeper)
1109       Flip_rhs(1-keeper_side) intersection(){
1110         rotate([90, 0, 0])
1111           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1112           KeeperProfile(1);
1113
1114         // outline of the whole case, to stop it protruding
1115         translate([0,0, -25])
1116           linear_extrude(height = 50)
1117           hull()
1118           Flip_bot()
1119           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1120       }
1121
1122       // hinge
1123       HingePortion(hex20, hex21) HingeBaseProfile();
1124
1125       // buildout for prop recess
1126       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1127         linextr(case_bottom_z, epp2i[1])
1128         hull() {
1129           for (dxs = [-1,+1])
1130             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1131                        -epp2o[0] ],
1132                      r = epp2o[0] - prcp2[0]);
1133         }
1134     }
1135
1136     // slot for keeper
1137     Flip_rhs(keeper_side)
1138       translate([0, -phone_cnr_rad, 0])
1139       rotate([90, 0, 0])
1140       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1141       minkowski(){
1142         KeeperProfile();
1143         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1144                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1145       }
1146
1147     // front camera
1148     RearCameraAperture();
1149
1150     // struts (invisible, because they're buried in the case)
1151     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1152
1153     Buttons(){
1154       mirror([1,0,0])
1155         rotate([90,0,90]) {
1156           if (!($button_leg_only && enable_support))
1157           intersection(){
1158             translate([0,0,-10])
1159               linear_extrude(height= 20)
1160               ButtonPlan($button_l, 0,1);
1161             if ($button_leg_only)
1162               rotate([-90,90,0])
1163                 translate([phone_width/2, -400, kppe[1]])
1164                 mirror([1-abs($rhsflip - keeper_side),0,0])
1165                 cube([400, 800, 50]);
1166             if (enable_support && !$button_suppress_over_keeper)
1167               rotate([-90,90,0])
1168               translate([-400, -400, kppd[1]])
1169                 mirror([0,0,1])
1170                 cube([800,800,100]);
1171           }
1172           translate([0,0, -bppR[0]])
1173             linear_extrude(height= 20)
1174             ButtonPlan($button_l, 1,1);
1175         }
1176       
1177     }
1178
1179     // apertures along top edge
1180     CaseAperture(jack_pos, jack_dia, 8);
1181     Flip_rhs(1)
1182       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1183
1184     OrdinaryRearApertures();
1185
1186     MicroUSB();
1187
1188     // gaps for the lid's hinge arms
1189     HingePortion(hex20 - hinge_x_arms_gap,
1190                  hex21 + hinge_x_arms_gap)
1191       minkowski(){
1192         HingeLidProfile();
1193         circle(r= hinge_r_arms_gap, $fn= 8);
1194       }
1195
1196     // screw holes in the hinge arms
1197     HingeScrews();
1198
1199     // catch striker
1200     CatchPortion(catch_side_gap*2, epp4[1])
1201       CatchCutProfile();
1202
1203     // lanyard
1204     Flip_bot(1)
1205       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1206       rotate([0, ly_theta, 0])
1207       rotate([0,0,90])
1208       LanyardCutout(lanyard_channel_len);
1209
1210     // prop recess
1211     Flip_rhs(1)
1212       translate([prop_x_pos,0,0])
1213       mirror([0,1,0])
1214       rotate([90,0,90])
1215       linextr(-prop_recess_hw, +prop_recess_hw)
1216       hull(){
1217         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1218           circleat(prcp1 + 20*d,
1219                    prc_r3);
1220       }
1221   }
1222 }
1223
1224 module LidAdhocMultiprintFrame(phase){
1225   if (led_window_style >= 3) {
1226     AdhocMultiprintFrame(phase, lpp13[1], -1);
1227   }
1228 }
1229
1230 module LidAroundEdges(){
1231   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1232     children();
1233 }
1234
1235 module Lid(){ ////toplevel
1236   skew_centre = [0, lpp11[0], lpp11[1]];
1237   difference(){
1238     union(){
1239       intersection(){
1240         LidAroundEdges()
1241           LidEdgeProfile();
1242
1243         translate(skew_centre)
1244           multmatrix([[ 1, 0, 0, 0 ],
1245                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1246                       [ 0, 0, 1, 0 ],
1247                       [ 0, 0, 0, 1 ]])
1248           translate(-skew_centre)
1249           LidAroundEdges()
1250           LidEdgeFoldClearanceProfile();
1251       }
1252
1253       // button covers
1254       Buttons(){
1255         intersection(){
1256           rotate([90,0,90])
1257             translate([0,0,-10])
1258             linear_extrude(height= 20)
1259             ButtonPlan($button_l, 1,0);
1260           rotate([90,0,0])
1261              translate([0,0,-100])
1262             linear_extrude(height= 200)
1263             ButtonCoverProfile();
1264         }
1265       }
1266
1267       // hinge arms
1268       HingePortion(hex20, hex21) {
1269         LidEdgeProfile();
1270         HingeLidProfile();
1271       }
1272
1273       // catch
1274       CatchPortion(0, lpp12[1])
1275         CatchCatchProfile();
1276     }
1277     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1278
1279     // screw holes in the hinge arms
1280     HingeScrews();
1281
1282     // prop recess
1283     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1284       mirror([0,1,0])
1285       rotate([90,0,90])
1286       linextr(-prop_recess_hw, +prop_recess_hw)
1287       hull()
1288       for (pa = prop_angles)
1289         PropProfile(pa, 1,1);
1290
1291     // notification led aperture
1292     if (led_window_style)
1293       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1294         translate([0,0,-10])
1295           cylinder(r=nla_r0, h=20);
1296         if (led_window_style >= 2)
1297           translate([0,0, -nla_t])
1298             cylinder(r=nla_r2, height=20);
1299       }
1300
1301     }
1302
1303   LidAdhocMultiprintFrame(1);
1304 }
1305
1306 module HingeLever(){ ////toplevel
1307   difference() {
1308     // outer body, positive
1309     HingePortion(hex22, hex22 + phone_width/2)
1310       HingeLeverOuterProfile();
1311
1312     // space for the screws
1313     HingePortion(hex26, hex24)
1314       HingeLeverInnerProfile();
1315
1316     // recesses for the nuts
1317     HingePortion(hex23, hex26+1)
1318       HingeLeverNutProfile();
1319
1320     // bores for the screws
1321     HingeScrews();
1322
1323     // space for the charging cable
1324     MicroUSB();
1325     Flip_hinge() MicroUSB();
1326   }
1327 }
1328
1329 module LidWindow(){ ////toplevel
1330   translate([led_pos[0], -led_pos[1], lpp13[1]])
1331     mirror([0,0,1])
1332     cylinder(r= nla_r1, h=nla_t);
1333   LidAdhocMultiprintFrame(0);
1334 }
1335
1336 module LidWindowPrint(){ ////toplevel
1337   rotate([0,180,0])
1338     LidWindow();
1339 }
1340
1341 module DemoLidWindowSelect(){
1342   translate([led_pos[0], led_pos[1], -100]) {
1343     translate([0, -30, 0]) cube([400, 400, 200]);
1344   }
1345 }
1346
1347 module DemoLidWindow(){ ////toplevel
1348   %Lid();
1349   LidWindow();
1350   translate([0,40,0]){
1351     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1352     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1353   }
1354 }
1355
1356 module HingeLeverPrint(){ ////toplevel
1357   rotate([-90,0,0])
1358     translate([-phone_width/2, phone_height, 0])
1359     HingeLever();
1360 }
1361
1362 module TestSelectLength(){
1363   translate([-30, -200, -20])
1364     cube([30 + 15, 250, 40]);
1365 }
1366
1367 module TestLength(){ ////toplevel
1368   intersection(){
1369     Case();
1370     TestSelectLength();
1371   }
1372 }
1373
1374 module TestLengthRight(){ ////toplevel
1375   intersection(){
1376     Case();
1377     Flip_rhs(1)
1378       TestSelectLength();
1379   }
1380 }
1381
1382 module TestSelectWidth(){
1383   translate([-30, -(phone_height - 25), -20])
1384     mirror([0, 1, 0])
1385     cube([200, 50, 40]);
1386 }
1387
1388 module TestWidth(){ ////toplevel
1389   intersection(){
1390     Case();
1391     TestSelectWidth();
1392   }
1393 }
1394
1395 module TestLidWidthPrint(){ ////toplevel
1396   rotate([0,180.0]) intersection(){
1397     Lid();
1398     TestSelectWidth();
1399   }
1400 }
1401
1402 module TestSelectRearAperture(){
1403   minkowski(){
1404     union() children();
1405     translate([20, 0,0])
1406       cube([42, 2, 1], center=true);
1407   }
1408 }
1409
1410 module TestSelectCamera(){
1411   minkowski(){
1412     TestSelectRearAperture()
1413       RearCameraAperture();
1414     cube([0.1, 50, 0.1]);
1415   }
1416 }
1417
1418 module TestSelectOrdinaryRearApertures(){
1419   TestSelectRearAperture()
1420     OrdinaryRearApertures();
1421 }
1422
1423 module TestCamera(){ ////toplevel
1424   intersection(){
1425     Case();
1426     TestSelectCamera();
1427   }
1428 }
1429
1430 module TestLidByCamera(){ ////toplevel
1431   intersection(){
1432     Lid();
1433     TestSelectCamera();
1434   }
1435 }
1436
1437 module TestLidByCameraPrint(){ ////toplevel
1438   rotate([180,0,0]) TestLidByCamera();
1439 }
1440
1441 module DemoByCamera(){ ////toplevel
1442   color("blue") TestLidByCamera();
1443   color("red")  TestCamera();
1444 }
1445
1446 module OneKeeper(){ ////toplevel
1447   translate([0, -phone_cnr_rad, 0])
1448     rotate([90, 0, 0])
1449     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1450     KeeperProfile();
1451 }
1452
1453 module OneKeeperPrint(){ ////toplevel
1454   rotate([0,180,0])
1455     OneKeeper();
1456 }
1457
1458 module LidPrint(){ ////toplevel
1459   rotate([0,180,0])
1460     Lid();
1461 }
1462
1463 module TestSelectFrame(){
1464   include = [1,-1] * (epp2i[0] + 4);
1465
1466   difference(){
1467     cube(1000, center=true);
1468     translate([0,0, -100])
1469       linear_extrude(height=200)
1470       rectfromto(include,  inside_br - include);
1471   }
1472 }
1473
1474 module TestSelectLidFrame(){
1475   TestSelectFrame();
1476   translate([led_pos[0], -led_pos[1], -50])
1477     cylinder(r= nla_r2+3, h=100);
1478 }
1479
1480 module TestFrameCase(){ ////toplevel
1481   intersection(){
1482     Case();
1483     union(){
1484       TestSelectFrame();
1485       TestSelectCamera();
1486       TestSelectOrdinaryRearApertures();
1487     }
1488   }
1489 }
1490
1491 module TestSelectTopApertures(){
1492   translate([-100, -35, -100])
1493     cube([400, 100, 200]);
1494   LidAdhocMultiprintFrame(0);
1495   LidAdhocMultiprintFrame(1);
1496 }
1497
1498 module TestTopApertures(){ ////toplevel
1499   intersection(){
1500     Case();
1501     TestSelectFrame();
1502     TestSelectTopApertures();
1503   }
1504 }
1505
1506 module TestLidTopAperturesPrint(){ ////toplevel
1507   rotate([0,180,0]) intersection(){
1508     Lid();
1509     TestSelectLidFrame();
1510     TestSelectTopApertures();
1511   }
1512 }
1513
1514 module TestLidWindowTopAperturesPrint(){ ////toplevel
1515   rotate([0,180,0]) intersection(){
1516     LidWindow();
1517     TestSelectTopApertures();
1518   }
1519 }
1520
1521 module TestFrameLidPrint(){ ////toplevel
1522   rotate([0,180,0]) intersection(){
1523     Lid();
1524     TestSelectLidFrame();
1525   }
1526 }
1527
1528 module ButtonPlanForDemo(z, deep, cut){
1529   translate([0,0,z])
1530     ButtonPlan(8, deep, cut);
1531 }
1532
1533 module HingeScrews(){
1534   Flip_rhs() Flip_bot(1){
1535     for (c= [ hppT, hppB ])
1536       translate([ hex20,
1537                   -c[0],
1538                   c[1] ]){
1539         rotate([0,90,0])
1540           translate([0,0,-.2])
1541           cylinder( r= hingescrew_shaft_dia/2,
1542                     h = hingescrew_shaft_len+0.2 );
1543         rotate([0,-90,0])
1544           translate([0,0,+.1])
1545           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1546       }
1547   }
1548 }
1549
1550 module DemoPropAngleSelect(c){
1551   color(c) difference(){
1552     union(){ children(); }
1553     translate([ prop_x_pos, -400, -200 ])
1554       cube([ 400,800,400 ]);
1555   }
1556 }
1557
1558 module DemoPropAngle(ang){
1559   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1560   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1561
1562   translate(hL)
1563     rotate([ang/2,0,0])
1564     translate(-hL)
1565     translate(hC)
1566     rotate([ang/2,0,0])
1567     translate(-hC) {
1568       DemoPropAngleSelect("red") Case();
1569
1570       color("orange")
1571         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1572         PropProfileAssignments(ang) {
1573           echo($prpp1);
1574           rotate([-$prp_theta, 0, 0])
1575           translate([0, $prpp1[0], -$prpp1[1]])
1576           rotate([90,0,-90])
1577           Prop();
1578         }
1579     }
1580
1581   translate([0,0, -hp_k*2])
1582     DemoPropAngleSelect("blue")
1583     Lid();
1584 }
1585
1586 module DemoPropAngles(){ ////toplevel
1587   for (i=[0 : len(prop_angles)-1])
1588     translate(i * [0, -100, 100])
1589     DemoPropAngle(prop_angles[i]);
1590 }
1591
1592 module DemoHingeAngle(ang1,ang2){
1593   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1594   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1595
1596   translate(hL)
1597     rotate([ang2,0,0])
1598     translate(-hL)
1599     translate(hC)
1600     rotate([ang1,0,0])
1601     translate(-hC) {
1602       color("red") Lid();
1603     }
1604
1605   color("blue") intersection(){
1606     Case();
1607     union(){
1608       translate([bppJ[0], -400, -200])
1609         mirror([1,0,0])
1610         cube([400, 800, 400]);
1611       translate([10, -400, -200])
1612         cube([10, 800, 400]);
1613     }
1614   }
1615 }
1616
1617 module DemoHingeAngles(){ ////toplevel
1618   angles = [ 0, 4, 8, 12 ];
1619   echo("angles",angles);
1620   for (i=[0 : len(angles)-1]) {
1621     translate(i * [0, 0, 30]) {
1622       DemoHingeAngle(0,angles[i]);
1623       translate([0, 200, 0])
1624         DemoHingeAngle(angles[i],0);
1625     }
1626   }
1627 }
1628
1629 module DemoSelectAdhocLeftRight(right=0) {
1630   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1631     mirror([1-right, 0,0])
1632     cube([400, 800, 200]);
1633 }
1634
1635 module DemoLeft(){ ////toplevel
1636   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1637   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1638 }
1639
1640 module DemoFrame(){ ////toplevel
1641   color("red") TestFrameCase();
1642   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1643   color("black") HingeScrews();
1644   %HingeLever();
1645 }
1646
1647 module DemoLanyardCutout(){ ////toplevel
1648   LanyardCutout(25);
1649 }
1650
1651 module DemoHingedFrame(){ ///toplevel
1652   color("red") TestFrameCase();
1653   translate([0,0, -2*hp_k])
1654   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1655
1656   Flip_hinge(){
1657     color("orange") HingeLever();
1658     color("black") HingeScrews();
1659   }
1660 }
1661
1662 module DemoHinge(){ ////toplevel
1663   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1664     DemoFrame();
1665     translate([0,0, -hp_k*3])
1666       DemoHingedFrame();
1667   }
1668 }
1669
1670 module DemoProfiles(){ ////toplevel
1671   LidEdgeProfile();
1672   %EdgeProfile();
1673   KeeperProfile();
1674   translate([0,0,-1]) color("black") KeeperProfile(1);
1675   translate(ly_o){
1676     rotate(-ly_theta){
1677       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1678       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1679       translate([0, ly_q_z]){
1680         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1681         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1682       }
1683     }
1684   }
1685   translate([0,0,-5]) color("white") translate(epp2i)
1686     rotate(-ly_theta)
1687     rectfromto([-15, 0],
1688                [+15, -max_case_bottom_edge_thickness]);
1689
1690   translate([0,20]) {
1691     LanyardMainChannelProfile();
1692     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1693     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1694   }
1695
1696   translate([20,0]) {
1697     LidEdgeProfile();
1698     %EdgeProfile();
1699
1700     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1701   
1702     color("blue") ButtonCoverProfile();
1703     color("red") {
1704       rectfromto(bppQ, demopoint_QR);
1705       rectfromto(bppR, demopoint_QR);
1706     }
1707   }
1708
1709   translate([-20,0]) {
1710     color("black") ButtonPlanForDemo(-2, 0,1);
1711     color("red" )  ButtonPlanForDemo(-4, 1,1);
1712     color("blue")  ButtonPlanForDemo(-6, 1,0);
1713   }
1714
1715   translate([0, -30]) {
1716     %LidEdgeProfile();
1717     %EdgeProfile();
1718     color("blue") HingeLidProfile();
1719     color("red")  HingeBaseProfile();
1720     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1721   }
1722
1723   for (f=[0,1]) {
1724     translate([-30, -60 + 30*f]) {
1725       translate([0,0,-4]) EdgeProfile();
1726       %translate([0,0,-10]) HingeBaseProfile();
1727       translate([0,-2] * f * hp_k) {
1728         translate([0,0,-4]) LidEdgeProfile();
1729         %translate([0,0,-10]) %HingeLidProfile();
1730       }
1731       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1732         translate([0,0,-2]) color("black") HingeLeverOuterProfile(); 
1733         translate([0,0,0]) color("red") difference(){
1734           HingeLeverOuterProfile();
1735           HingeLeverInnerProfile();
1736         }
1737         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1738       }
1739     }
1740   }
1741
1742   translate([20,-30]) {
1743     %EdgeProfile();
1744     %LidEdgeProfile();
1745     //translate([0,0,1]) CatchCutProfile();
1746     color("blue") CatchCatchProfile();
1747     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1748   }
1749
1750   translate([40,-30]) {
1751     difference(){
1752       LidEdgeProfile();
1753       translate(prlp10)
1754         PropProfile(10, 1, 0);
1755     }
1756     translate(prlp10)
1757       PropProfile(15, 0);
1758   }
1759   translate([60,-30]) {
1760     PropAggregateProfile();
1761   }
1762 }
1763
1764 //EdgeProfile();
1765 //KeeperProfile();
1766 //CaseBase();
1767 //%Case();
1768 //Keeper();
1769 //LidEdgeProfile();
1770 //KeeperProfile();
1771 //DemoProfiles();
1772 //PropRecess();