fairphone-case.scad

   1 // -*- C -*-
   2
   3 include <utils.scad>
   4
   5 phone = [ 75.0, 145.0 ];
   6
   7 prop_buildout_less = 3;
   8
   9 prop_angles = [ 15, 30, 45, 60 ];
  10
  11 bumper = [ 0.250, -0.025 ];
  12 // ^ One side.  Overall size is increased by twice this.
  13 // If no bumpers, is the gap around the phone.
  14
  15 enable_support = 1;
  16
  17 phone_cnr_rad = 6.0;
  18
  19 button_cutout_depth = 9;
  20
  21 phone_edge_thick = 9.0;
  22 phone_total_thick = 12.0;
  23 phone_backside_slope_inner = 1.5; // larger means shallower
  24 phone_backside_slope_outer = 1.0; // larger means shallower
  25
  26 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  27 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  28
  29 jack_pos = [ 14.38, 7.96 ];
  30 jack_dia = 10.64 + .5; // some jack I had lying around
  31
  32 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  33 noisecancelmic_dia = 4.00;
  34
  35 //fingerpushhole_dias = [ 15, 18 ];
  36 fingerpushhole_dias = [];
  37
  38 rearspeaker_pos_bl = [ 12.64, 18.72 ];
  39 rearspeaker_size   = [  3.76,  7.36 ];
  40
  41 microusb_above = 3.27 - 0.25;
  42 microusb_below = 0.0;
  43 microusb_width = 16.12 + 1.25;
  44
  45 case_th_bottom = 2.5;
  46 case_th_lid = 2.5;
  47 case_th_side = 2;
  48 case_th_lip = 1.2;
  49
  50 case_struts_count = 6;
  51 case_struts_solid_below = 1.00;
  52 case_struts_solid_above = 0.75;
  53 case_struts_width = 0.10;
  54
  55 keeper_th_z = 0.75;
  56 keeper_th_x = 0.75;
  57 keeper_inner_width = 2.75;
  58 keeper_inner_height = 2.75;
  59 keeper_slant_slope = 2; // larger means steeper
  60
  61 keeper_gap_z_top = 0.25;
  62 keeper_gap_z_bot = 0.75;
  63 keeper_gap_x     = 0.25;
  64 keeper_gap_x_holes = 0.75;
  65
  66 keeper_side = 0; // 0 = lhs; 1 = rhs
  67
  68 case_lip = 1.25;
  69
  70 lid_gap_x = 0.25;
  71 lid_gap_z = 0.25;
  72 lid_lip = 1.75;
  73
  74 catch_slop = 0.50;
  75
  76 foldover_gap = 0.50;
  77 foldover_lever_gap = 0.50;
  78
  79 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
  80 hingescrew_shaft_len = 12;
  81 hingescrew_nut_thick = 1.93 + 0.20; // incl. washer
  82 hingescrew_nut_dia = 4.72 + 0.50; // washer, actually
  83 hingescrew_head_th = 1.38 + 0.75;
  84 hingescrew_head_dia = 3.92;
  85 lever_cover_th = 0.75;
  86 hingemount_th = 2.5;
  87
  88 $fa = 5;
  89 $fs = 0.1;
  90
  91 button_l_fudge = 4.4;
  92 buttonishleg_default_l_is_fudge = 10;
  93
  94 hinge_base_slope = 1.5; // bigger is steeper
  95
  96 strut_min_at_end = 1.5;
  97
  98 hinge_x_gap = 0.125;
  99 hinge_x_postscrew_gap = 0.75;
 100 hinge_x_arms_gap = 0.35;
 101 hinge_r_arms_gap = 0.55;
 102
 103 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 104
 105 catch_len = 7.5;
 106 catch_width = 15;
 107 catch_thickness = 1.0;
 108 catch_side_gap = 0.75; // each side
 109
 110 catch_depth = 0.75;
 111 catch_height = 0.35;
 112 catch_finger_height = 1.5;
 113 catch_finger_depth = 2.5;
 114
 115 prop_recess_under = 0.50;
 116 prop_recess_slop = 0.200; // each side
 117 prop_end_dia = 0.5;
 118 prop_main_th = 3;
 119 prop_taper_len = 6;
 120 prop_main_width = 3;
 121 prop_side_gap = 0.75; // each side
 122 prop_lidrecess_behind = 0.75;
 123 prop_caserecess_behind = 0.75;
 124 prop_caserecess_taper = 0.45; // one side only
 125 prop_prop_gap = 0.5;
 126 prop_prong_heel_slope = 0.5;
 127
 128 // ---------- calculated ----------
 129
 130 phone_width =  (phone + bumper*2)[0];
 131 phone_height = (phone + bumper*2)[1];
 132
 133 inside_br = [phone_width, -phone_height];
 134
 135 prop_prong_h = prop_main_th;
 136
 137 //echo(camera_pos_tl + bumper,
 138 //     camera_pos_br + bumper);
 139
 140 // ----- could be changed -----
 141 lid_buttoncover_gap = lid_gap_x;
 142 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 143
 144 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 145
 146 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 147
 148 //prop_nose_len = case_th_lid - prop_recess_under;
 149 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 150 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 151
 152
 153 //lid_lip_overlap_width xxx bad name = ;
 154 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 155
 156 epp0 = [0,0];
 157 epp1 = [0, -phone_edge_thick];
 158 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 159 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 160 epp3 = epp2i + [10, 0];
 161 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 162 epp4 = epp5 + [-1,0] * case_th_side;
 163
 164 kppe = [0,0];
 165 kppd = kppe + [1,0] * keeper_inner_width;
 166 kppc = kppd + [0,1] * keeper_th_z;
 167 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 168 kppf = kppe - [0,1] * keeper_inner_height;
 169 kppa = [ kppb[0], kppf[1] ];
 170
 171 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 172 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 173
 174 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
 175
 176 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 177 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 178
 179 case_bottom_z = epp2o[1] - case_th_bottom;
 180
 181 // button profile
 182 bppM = epp4 + [0,5];
 183 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 184 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 185 bppS = [ epp1[0], bppR[1] ];
 186 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 187 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 188 bppO = [ bppN[0], bppP[1] ];
 189 bppL = lpp10 + [5,0];
 190 bppK = [ bppL[0], bppN[1] ];
 191 bppJ = [ bppN[0], bppL[1] ];
 192
 193 // hinge plan
 194 hp_rn = hingescrew_nut_dia/2;
 195 hp_r2_min = hp_rn + lever_cover_th;
 196 hp_rs = hingescrew_shaft_dia/2;
 197 hp_r1_min = hp_rs + hingemount_th;
 198
 199 hp_r1 = max(hp_r1_min, hp_r2_min);
 200 hp_r2 = hp_r1;
 201
 202 hppU = lpp13;
 203 hppS = epp2o + [0,-1] * case_th_bottom;
 204 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 205
 206 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 207          0.5 * (hppU + hppS)[1] ];
 208 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 209 hppB = hppT + [0,-1] * hp_k;
 210
 211 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 212 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 213 hppE = [ hppE_x, hppE_y ];
 214
 215 // hinge elevation x coords
 216
 217 hingescrew_portion_len =
 218   0.5* (hingescrew_shaft_len - hingescrew_nut_thick - hinge_x_gap);
 219
 220 hex20 = max(epp2o[0],
 221             phone_cnr_rad,
 222             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 223 hex21 = hex20 + hingescrew_portion_len;
 224 hex22 = hex21 + hinge_x_gap;
 225 hex23 = hex22 + hingescrew_portion_len
 226   - hingescrew_nut_thick; // bodge, need to divvy this up more sensibly
 227 hex24 = hex20 + hingescrew_shaft_len + hinge_x_postscrew_gap;
 228 //echo(hex20, hex21, hex22, hex23, hex24);
 229 //echo(hingescrew_portion_len);
 230
 231 // catch
 232
 233 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 234 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 235 cppB = [ epp0[0], cppA[1] ];
 236 cppP = [ epp4[0], cppJ[1] ];
 237
 238 cppS = cppJ + [0,-1] * catch_len;
 239 cppD = [ cppA[0], cppS[1] + catch_slop ];
 240 cppC = [ cppB[0], cppD[1] ];
 241 cppT = cppS + [1,0] * catch_depth;
 242 cppU = cppT + [0,-1] * catch_height;
 243 cppV = [ cppS[0], cppU[1] - catch_depth ];
 244
 245 cppR = 0.5*(cppP + cppJ);
 246
 247 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 248 cppQ = [ cppR[0],
 249          cppV[1] - (catch_finger_height - cp_rQ) ];
 250 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 251
 252 // prop recess in case
 253
 254 prop_x_pos = phone_width/2;
 255
 256 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 257
 258 prc_r1 = prop_end_dia/2;
 259 prc_r3 = prc_r1 + prop_recess_slop;
 260
 261 prcp2 = [ epp4[0] + prop_buildout_less,
 262           case_bottom_z ];
 263
 264 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 265
 266 prcp1 = [ epp2o[0],
 267           epp2i[1] - prc_r3 ];
 268
 269 // prop recess in lid
 270
 271 prl_r10 = prop_end_dia/2;
 272 prl_r10o = prl_r10 + prop_recess_slop;
 273
 274 prlp10 = lpp10 + [1,1] * prl_r10o
 275   + [1,0] * prop_lidrecess_behind
 276   + [0,1] * prop_recess_under;
 277
 278 // prop
 279
 280 prpp10 = [0,0];
 281 prpp11 = [0, prop_taper_len];
 282
 283 prp_r10 = prl_r10;
 284
 285 // ---------- modules ----------
 286
 287 module KeeperProfile(slant=0){
 288   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 289   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 290 }
 291
 292 module EdgeProfile(){
 293   difference(){
 294     hull(){
 295       translate(epp3) square(case_th_bottom*2, center=true);
 296       circleat(epp2o, r=case_th_bottom);
 297       circleat(epp1, r=case_th_side);
 298       rectfromto(epp0, epp4);
 299     }
 300     polygon([ epp5 + [0,10],
 301               epp1,
 302               epp2i,
 303               epp3 + [10,0] ]);
 304   }
 305 }
 306
 307 module LidEdgeProfile(){
 308   polygon([ lpp10,
 309             lpp11,
 310             lpp12,
 311             lpp13,
 312             lpp13 + [10, 0],
 313             lpp10 + [10, 0]
 314             ]);
 315   intersection(){
 316     circleat(lpp12, r=lp_r12);
 317     rectfromto( lpp12 + [-10,   0],
 318                 lpp12 + [+10, +10] );
 319   }
 320 }
 321
 322 module ButtonCoverProfile(){
 323   intersection(){
 324     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 325     hull(){
 326       EdgeProfile();
 327       LidEdgeProfile();
 328     }
 329   }
 330 }
 331
 332 module ButtonPlan(l, deep, cut){
 333   epsilon =
 334     (cut  ? 0 : lid_buttoncover_gap);
 335
 336   delta =
 337     (deep ? lid_buttoncover_overlap : 0);
 338
 339   C = [0,0]; // by definition
 340   T = [ 0, epp4[1] ];
 341   G = T + [0,10];
 342
 343   B0 = C + [0,-1] * button_cutout_depth;
 344   B1 = B0 + [0,1] * epsilon;
 345
 346   r0 = 0.5 * (T[1] - B0[1]);
 347   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 348   H = A + [0,-1] * delta;
 349
 350   D = A + [-2,0] * r0;
 351   F = D + [0,10];
 352
 353   E0 = 0.5 * (D + A);
 354   E1 = E0 + [1,0] * epsilon;
 355
 356   I0 = [ E0[0], H[1] ];
 357   I1 = [ E1[0], H[1] ];
 358
 359   hull(){
 360     for (m=[0,1]) mirror([m,0])
 361       circleat(H, r0 - epsilon);
 362   }
 363   for (m=[0,1]) mirror([m,0]) {
 364     difference(){
 365       polygon([ E1,
 366                 I1,
 367                 H,
 368                 B1,
 369                 G,
 370                 F,
 371                 D
 372                 ]);
 373       circleat(D, r0 + epsilon);
 374     }
 375   }
 376 }
 377
 378 module CatchCatchProfile(){
 379   hull(){
 380     for (c=[ cppR, cppQ ])
 381       circleat(c, cp_rQ);
 382   }
 383   hull(){
 384     circleat(lpp12, lp_r12);
 385     circleat(lpp12 + [5,0], lp_r12);
 386     rectfromto(cppP, cppP + [5,0.1]);
 387   }
 388   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 389 }
 390
 391 module CatchCutProfile(){
 392   polygon([ cppB,
 393             cppA,
 394             cppD,
 395             cppF,
 396             cppF + [0,-10],
 397             cppF + [-10,-10],
 398             lpp12 + [-10,0],
 399             lpp12 + [10,0]
 400             ]);
 401 }
 402
 403 module Flip_rhs(yn=[0,1]) {
 404   for ($rhsflip=yn) {
 405     translate([phone_width/2, 0, 0])
 406       mirror([$rhsflip,0,0])
 407       translate([-phone_width/2, 0, 0])
 408       children();
 409   }
 410 }
 411
 412 module Flip_bot(yn=[0,1]) {
 413   for ($botflip=yn) {
 414     translate([0, -phone_height/2, 0])
 415       mirror([0, $botflip, 0])
 416       translate([0, phone_height/2, 0])
 417       children();
 418   }
 419 }
 420
 421 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 422   // sides
 423   Flip_rhs(){
 424     translate([0, -phone_cnr_rad, 0])
 425       rotate([90,0,0])
 426       linear_extrude(height = phone_height - phone_cnr_rad*2)
 427       children(0);
 428   }
 429   // corners
 430   Flip_rhs() Flip_bot() {
 431     translate([+1,-1] * phone_cnr_rad)
 432       intersection(){
 433         rotate_extrude()
 434           intersection(){
 435             mirror([1,0,0])
 436               translate([-1,0] * phone_cnr_rad)
 437               children(0);
 438             rectfromto([0,-20],[10,20]);
 439           }
 440         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 441           cube([10,10,40]);
 442       }
 443   }
 444   // top and bottom
 445   Flip_bot(){
 446     translate([ phone_width - phone_cnr_rad, 0,0 ])
 447       rotate([90,0,-90])
 448       linear_extrude(height = phone_width - phone_cnr_rad*2)
 449       children(0);
 450   }
 451   // fill
 452   translate([0,0, fill_zstart])
 453     mirror([0,0, fill_downwards])
 454     linear_extrude(height = fill_th)
 455     rectfromto([+1,-1] * phone_cnr_rad,
 456                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 457 }
 458
 459 module CaseAperture(pos, dia, $fn) {
 460   theta = 180/$fn;
 461   translate([ pos[0] + bumper[0],
 462               -epp2i[0],
 463               -pos[1] ])
 464     rotate([-90, theta, 0])
 465     cylinder(r = dia/2 / cos(theta),
 466              h = 60);
 467 }
 468
 469 module SideButton(y, y_ref_sign, l){
 470   // y_ref_sign:
 471   //   +1  measured from top    of actual phone to top    of button
 472   //   -1  measured from bottom of actual phone to bottom of button
 473   //    0  y is centre of button in coordinate system
 474   $button_l= l;
 475   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 476           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 477           y;
 478   //echo(eff_y);
 479   translate([0, eff_y, 0])
 480     children();
 481 }
 482
 483 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 484   $button_leg_only = true;
 485   SideButton(y, y_ref_sign, l) children();
 486 }
 487
 488 module Buttons(){
 489   Flip_rhs(1) SideButton(15.580, +1, 8.9) children(); // power
 490   Flip_rhs(1) SideButton(48.700, -1, 8.920) children(); // camera
 491   Flip_rhs(0) SideButton(30.800, +1, 21.96) children(); // volume
 492   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 493 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 494 }
 495
 496 module Struts(x_start, z_min, th){
 497   // if th is negative, starts at z_min and works towards -ve z
 498   // and object should then be printed other way up
 499   for (i= [1 : 1 : case_struts_count]) {
 500     translate([0,
 501                0,
 502                z_min])
 503       mirror([0,0, th<0 ? 1 : 0])
 504       translate([0,
 505                  -phone_height * i / (case_struts_count+1),
 506                  case_struts_solid_below])
 507       linear_extrude(height= abs(th)
 508                      -(case_struts_solid_below+case_struts_solid_above))
 509       rectfromto([               x_start, -0.5 * case_struts_width ],
 510                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 511   }
 512 }
 513
 514 module OrdinaryRearAperture(rhs,bot, pos){
 515   Flip_rhs(rhs) Flip_bot(bot)
 516     linextr(-20, 20)
 517     mirror([0,1])
 518     translate(pos + bumper)
 519     children();
 520 }
 521
 522 module MicroUSB(){
 523   Flip_bot(1){
 524     rotate([90,0,0])
 525       mirror([0,0,1])
 526       linextr(-epp2i[0], 60)
 527       translate([0.5 * phone_width, 0, 0])
 528       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 529                  [+microusb_width/2, epp0[1] + -microusb_above]);
 530   }
 531 }
 532
 533 module OrdinaryRearApertures(){
 534   // rear speaker
 535   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 536     rectfromto(-rearspeaker_gap,
 537                rearspeaker_size + rearspeaker_gap);
 538
 539   // finger hole to remove phone
 540   if (len(fingerpushhole_dias))
 541     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 542                                 phone[1]/2 ])
 543     scale(fingerpushhole_dias)
 544     circle(r= 0.5 );
 545 }
 546
 547 module RearCameraAperture(){
 548   Flip_rhs(1)
 549     mirror([0, 0, 1])
 550     linear_extrude(height = 20)
 551     mirror([0, 1, 0])
 552     translate(bumper)
 553     rectfromto(camera_pos_tl, camera_pos_br);
 554 }
 555
 556 module HingeLidProfile(){
 557   hull(){
 558     circleat(hppT, hp_r1);
 559     circleat(lpp12, lp_r12);
 560     polygon([lpp10,
 561              lpp13 + [2,0],
 562              lpp12,
 563              hppT]);
 564   }
 565 }
 566
 567 module HingeBaseProfile(){
 568   difference(){
 569     hull(){
 570       circleat(hppB, hp_r1);
 571       circleat(hppE, hp_r1);
 572       circleat(epp2o, case_th_bottom);
 573       circleat(hppB + [10,0], hp_r1);
 574     }
 575     polygon([epp5, epp1, epp2i, epp3, bppL]);
 576   }
 577 }
 578
 579 module HingeLeverOuterProfile(){
 580   hull(){
 581     circleat(hppT, hp_r2);
 582     circleat(hppB, hp_r2);
 583   }
 584 }
 585
 586 module HingeLeverInnerProfile(){
 587   for (c = [hppT, hppB]) {
 588     hull()
 589       for (x=[-20,20])
 590         for (y=[0, c[1] - hppM[1]])
 591           translate([x,y])
 592             circleat(c, hp_rn);
 593   }
 594 }
 595
 596 module Flip_hinge(){
 597   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 598   translate(hinge_origin)
 599     rotate([180,0,0])
 600     translate(-hinge_origin)
 601     children();
 602 }
 603
 604 module HingePortion(x0,x1){
 605   Flip_rhs() Flip_bot(1)
 606     translate([x0,0,0])
 607     mirror([1,0,0])
 608     rotate([90,0,-90])
 609     linear_extrude(height=x1-x0)
 610     children(0);
 611 }
 612
 613 module CatchPortion(width){
 614   translate([phone_width/2, 0,0])
 615     rotate([90,0,-90])
 616     linextr(-width/2, width/2)
 617     children(0);
 618 }
 619
 620 module CaseBase(){
 621   AroundEdges(epp3[1], case_th_bottom, 1)
 622     EdgeProfile();
 623 }
 624
 625 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 626   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 627   k = hp_k;
 628   p = phone_height - prlp10[0] - hppB[0];
 629   x = k / (2 * sin(gamma/2)) - hppT[0];
 630   b = p + x;
 631
 632   q = phone_height - hppT[0]; // prpp7[0] is 0 by definition
 633   a = q + x;
 634   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 635   alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 636
 637   theta = 90 - alpha;
 638   beta = 180 - alpha - gamma;
 639   psi = 90 - beta;
 640
 641   echo("abc", a,b,c);
 642
 643   v1 = [ [ cos(psi), -sin(psi) ],    // x
 644          [ sin(psi),  cos(psi) ] ];  // y
 645
 646   prpp7 = [0, c + (lpp13[1] - prpp10[1]) ];
 647
 648   prp_r1 = prc_r1;
 649   prp_r11 = prop_main_th/2;
 650
 651   prpp1 = prpp7 + [1,0] *
 652     // this is approximate, but will do
 653     (prop_main_th/2 + prop_prop_gap + prcp1[0] - epp4[0]);
 654   prpp3 = prpp1 +
 655     v1[0] * -prp_r1 +
 656     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 657   prpp12 = prpp3 + v1[0] *
 658     (prop_end_dia + prop_caserecess_taper * (prpp1[1] - prpp3[1]));
 659   prp_r8 = prop_main_th;
 660   prpp4 = [ prop_main_th/2, prpp3[1] ];
 661   prp_r5 = prp_r8;
 662   prpp5 = [ prpp12[0] - prp_r5,
 663             prpp3[1] - prop_prong_h + prp_r5 ];
 664   prpp6 = prpp4 + [0,-1] * (prop_prong_h +
 665          prop_prong_heel_slope * (prpp5[0] - prpp4[0]));
 666   prpp8 = prpp4 + [0,-1] * prp_r8;
 667   prpp9 = prpp8 + [-1,0] * prp_r8;
 668
 669   //#circleat(prpp3,1);
 670   //#circleat(prpp12,1);
 671
 672   if (!cut) {
 673     hull(){
 674       translate(prpp8)
 675         intersection(){
 676           circle(prp_r8);
 677           polygon([[-20,-0], [0,0], [20,20]]);
 678         }
 679       rectfromto(prpp6, prpp9);
 680       translate(prpp5) intersection(){
 681         circle(prp_r5);
 682         polygon([[-10,-10], [0,0], [10,0]]);
 683       }
 684       rectfromto(prpp12 + [0,-0.1], prpp3);
 685     }
 686     hull(){
 687       circleat(prpp1, prp_r1);
 688       rectfromto(prpp12 + [0,-0.1], prpp3);
 689     }
 690   }
 691   // main shaft
 692   rotate([0,0, rot*-theta]){
 693     hull(){
 694       extra = cut ? prop_recess_slop : 0;
 695       rectfromto(prpp6, prpp9);
 696       circleat(prpp11, prp_r11 + extra);
 697       circleat(prpp10, prp_r10 + extra);
 698     }
 699   }
 700 }
 701
 702 module PropAggregateProfile(){
 703   for (angle = prop_angles)
 704     PropProfile(angle, 0,0);
 705 }
 706
 707 module Case(){ ////toplevel
 708   difference(){
 709     union(){
 710       CaseBase();
 711
 712       // ledge (fixed keeper)
 713       Flip_rhs(1-keeper_side) intersection(){
 714         rotate([90, 0, 0])
 715           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 716           KeeperProfile(1);
 717
 718         // outline of the whole case, to stop it protruding
 719         translate([0,0, -25])
 720           linear_extrude(height = 50)
 721           hull()
 722           Flip_bot()
 723           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 724       }
 725
 726       // hinge
 727       HingePortion(hex20, hex21) HingeBaseProfile();
 728
 729       // buildout for prop recess
 730       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
 731         linextr(case_bottom_z, epp2i[1])
 732         hull() {
 733           for (dxs = [-1,+1])
 734             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
 735                        -epp2o[0] ],
 736                      r = epp2o[0] - prcp2[0]);
 737         }
 738     }
 739
 740     // slot for keeper
 741     Flip_rhs(keeper_side)
 742       translate([0, -phone_cnr_rad, 0])
 743       rotate([90, 0, 0])
 744       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 745       minkowski(){
 746         KeeperProfile();
 747         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 748                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 749       }
 750
 751     // front camera
 752     RearCameraAperture();
 753
 754     // struts (invisible, because they're buried in the case)
 755     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 756
 757     Buttons(){
 758       mirror([1,0,0])
 759         rotate([90,0,90]) {
 760           if (!($button_leg_only && enable_support))
 761           intersection(){
 762             translate([0,0,-10])
 763               linear_extrude(height= 20)
 764               ButtonPlan($button_l, 0,1);
 765             if ($button_leg_only)
 766               rotate([-90,90,0])
 767                 translate([phone_width/2, -400, kppe[1]])
 768                 mirror([1-abs($rhsflip - keeper_side),0,0])
 769                 cube([400, 800, 50]);
 770             if (enable_support)
 771               rotate([-90,90,0])
 772               translate([-400, -400, kppd[1]])
 773                 mirror([0,0,1])
 774                 cube([800,800,100]);
 775           }
 776           translate([0,0, -bppR[0]])
 777             linear_extrude(height= 20)
 778             ButtonPlan($button_l, 1,1);
 779         }
 780
 781     }
 782
 783     // apertures along top edge
 784     CaseAperture(jack_pos, jack_dia, 8);
 785     Flip_rhs(1)
 786       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
 787
 788     OrdinaryRearApertures();
 789
 790     MicroUSB();
 791
 792     // gaps for the lid's hinge arms
 793     HingePortion(hex20 - hinge_x_arms_gap,
 794                  hex21 + hinge_x_arms_gap)
 795       minkowski(){
 796         HingeLidProfile();
 797         circle(r= hinge_r_arms_gap, $fn= 8);
 798       }
 799
 800     // screw holes in the hinge arms
 801     HingeScrews();
 802
 803     // catch striker
 804     CatchPortion(catch_width + catch_side_gap*2)
 805       CatchCutProfile();
 806
 807     // prop recess
 808     Flip_rhs(1)
 809       translate([prop_x_pos,0,0])
 810       rotate([90,0,90])
 811       linextr(-prop_recess_hw, +prop_recess_hw)
 812       mirror([1,0])
 813       hull(){
 814         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
 815           circleat(prcp1 + 20*d,
 816                    prc_r3);
 817       }
 818   }
 819 }
 820
 821 module Lid(){ ////toplevel
 822   difference(){
 823     union(){
 824       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 825         LidEdgeProfile();
 826
 827       // button covers
 828       Buttons(){
 829         intersection(){
 830           rotate([90,0,90])
 831             translate([0,0,-10])
 832             linear_extrude(height= 20)
 833             ButtonPlan($button_l, 1,0);
 834           rotate([90,0,0])
 835              translate([0,0,-100])
 836             linear_extrude(height= 200)
 837             ButtonCoverProfile();
 838         }
 839       }
 840
 841       // hinge arms
 842       HingePortion(hex20, hex21) HingeLidProfile();
 843
 844       // catch
 845       CatchPortion(catch_width)
 846         CatchCatchProfile();
 847     }
 848     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 849
 850     // screw holes in the hinge arms
 851     HingeScrews();
 852   }
 853 }
 854
 855 module HingeLever(){ ////toplevel
 856   difference() {
 857     // outer body, positive
 858     HingePortion(hex22, hex22 + phone_width/2)
 859       HingeLeverOuterProfile();
 860
 861     // space for the screws
 862     HingePortion(hex23, hex24)
 863       HingeLeverInnerProfile();
 864
 865     // bores for the screws
 866     HingeScrews();
 867
 868     // space for the charging cable
 869     MicroUSB();
 870     Flip_hinge() MicroUSB();
 871   }
 872 }
 873
 874 module HingeLeverPrint(){ ////toplevel
 875   rotate([90,0,0])
 876     HingeLever();
 877 }
 878
 879 module TestSelectLength(){
 880   translate([-30, -200, -20])
 881     cube([30 + 15, 250, 40]);
 882 }
 883
 884 module TestLength(){ ////toplevel
 885   intersection(){
 886     Case();
 887     TestSelectLength();
 888   }
 889 }
 890
 891 module TestLengthRight(){ ////toplevel
 892   intersection(){
 893     Case();
 894     Flip_rhs(1)
 895       TestSelectLength();
 896   }
 897 }
 898
 899 module TestSelectWidth(){
 900   translate([-30, -(phone_height - 25), -20])
 901     mirror([0, 1, 0])
 902     cube([200, 50, 40]);
 903 }
 904
 905 module TestWidth(){ ////toplevel
 906   intersection(){
 907     Case();
 908     TestSelectWidth();
 909   }
 910 }
 911
 912 module TestLidWidthPrint(){ ////toplevel
 913   rotate([0,180.0]) intersection(){
 914     Lid();
 915     TestSelectWidth();
 916   }
 917 }
 918
 919 module TestSelectRearAperture(){
 920   minkowski(){
 921     union() children();
 922     translate([20, 0,0])
 923       cube([42, 2, 1], center=true);
 924   }
 925 }
 926
 927 module TestSelectCamera(){
 928   minkowski(){
 929     TestSelectRearAperture()
 930       RearCameraAperture();
 931     cube([0.1, 50, 0.1]);
 932   }
 933 }
 934
 935 module TestSelectOrdinaryRearApertures(){
 936   TestSelectRearAperture()
 937     OrdinaryRearApertures();
 938 }
 939
 940 module TestCamera(){ ////toplevel
 941   intersection(){
 942     Case();
 943     TestSelectCamera();
 944   }
 945 }
 946
 947 module TestLidByCamera(){ ////toplevel
 948   intersection(){
 949     Lid();
 950     TestSelectCamera();
 951   }
 952 }
 953
 954 module TestLidByCameraPrint(){ ////toplevel
 955   rotate([180,0,0]) TestLidByCamera();
 956 }
 957
 958 module DemoByCamera(){ ////toplevel
 959   color("blue") TestLidByCamera();
 960   color("red")  TestCamera();
 961 }
 962
 963 module OneKeeper(){ ////toplevel
 964   translate([0, -phone_cnr_rad, 0])
 965     rotate([90, 0, 0])
 966     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 967     KeeperProfile();
 968 }
 969
 970 module OneKeeperPrint(){ ////toplevel
 971   rotate([0,180,0])
 972     OneKeeper();
 973 }
 974
 975 module LidPrint(){ ////toplevel
 976   rotate([0,180,0])
 977     Lid();
 978 }
 979
 980 module TestSelectPropRecesses(posns){
 981   linextr(-100,100){
 982     translate([phone_width/2, -phone_height]){
 983       square([ 3, 500 ], center=true);
 984       for (y=posns)
 985         hull()
 986           for (dy=[ -prp5[0], -prp2[0] ])
 987             translate([0,y+dy])
 988               square([prop_main_width+5, 5], center=true);
 989     }
 990   }
 991 }
 992
 993 module TestSelectFrame(){
 994   include = [1,-1] * (epp2i[0] + 4);
 995
 996   difference(){
 997     cube(1000, center=true);
 998     translate([0,0, -100])
 999       linear_extrude(height=200)
1000       rectfromto(include,  inside_br - include);
1001   }
1002 }
1003
1004 module TestSelectLidFrame(){
1005   TestSelectFrame();
1006   TestSelectPropRecesses(prop_lid_posns);
1007 }
1008
1009 module TestFrameCase(){ ////toplevel
1010   intersection(){
1011     Case();
1012     union(){
1013       TestSelectFrame();
1014       TestSelectCamera();
1015       TestSelectOrdinaryRearApertures();
1016     }
1017   }
1018 }
1019
1020 module TestFrameLidPrint(){ ////toplevel
1021   rotate([0,180,0]) intersection(){
1022     Lid();
1023     TestSelectLidFrame();
1024   }
1025 }
1026
1027 module ButtonPlanForDemo(z, deep, cut){
1028   translate([0,0,z])
1029     ButtonPlan(8, deep, cut);
1030 }
1031
1032 module HingeScrews(){
1033   Flip_rhs() Flip_bot(1){
1034     for (c= [ hppT, hppB ])
1035       translate([ hex20,
1036                   -c[0],
1037                   c[1] ]){
1038         rotate([0,90,0])
1039           translate([0,0,-.2])
1040           cylinder( r= hingescrew_shaft_dia/2,
1041                     h = hingescrew_shaft_len+0.2 );
1042         rotate([0,-90,0])
1043           translate([0,0,+.1])
1044           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1045       }
1046   }
1047 }
1048
1049 module DemoFrame(){ ////toplevel
1050   color("red") TestFrameCase();
1051   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1052   color("black") HingeScrews();
1053   %HingeLever();
1054 }
1055
1056 module DemoHingedFrame(){ ///toplevel
1057   color("red") TestFrameCase();
1058   translate([0,0, -2*hp_k])
1059   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1060
1061   Flip_hinge(){
1062     color("orange") HingeLever();
1063     color("black") HingeScrews();
1064   }
1065 }
1066
1067 module DemoHinge(){ ////toplevel
1068   DemoFrame();
1069   translate([0,0, -hp_k*3])
1070     DemoHingedFrame();
1071 }
1072
1073 module DemoProfiles(){ ////toplevel
1074   LidEdgeProfile();
1075   %EdgeProfile();
1076   KeeperProfile();
1077   translate([0,0,-1]) color("black") KeeperProfile(1);
1078
1079   translate([20,0]) {
1080     LidEdgeProfile();
1081     %EdgeProfile();
1082
1083     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1084
1085     color("blue") ButtonCoverProfile();
1086     color("red") {
1087       rectfromto(bppQ, demopoint_QR);
1088       rectfromto(bppR, demopoint_QR);
1089     }
1090   }
1091
1092   translate([-20,0]) {
1093     color("black") ButtonPlanForDemo(-2, 0,1);
1094     color("red" )  ButtonPlanForDemo(-4, 1,1);
1095     color("blue")  ButtonPlanForDemo(-6, 1,0);
1096   }
1097
1098   translate([0, -30]) {
1099     %LidEdgeProfile();
1100     %EdgeProfile();
1101     color("blue") HingeLidProfile();
1102     color("red")  HingeBaseProfile();
1103     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1104     color("orange") translate([0,0,-1]) HingeLeverInnerProfile();
1105   }
1106
1107   translate([20,-30]) {
1108     %EdgeProfile();
1109     %LidEdgeProfile();
1110     //translate([0,0,1]) CatchCutProfile();
1111     color("blue") CatchCatchProfile();
1112     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1113   }
1114
1115   translate([40,-30]) {
1116     difference(){
1117       LidEdgeProfile();
1118       translate(prlp10)
1119         PropProfile(10, 1, 0);
1120     }
1121     translate(prlp10)
1122       PropProfile(15, 0);
1123   }
1124   translate([60,-30]) {
1125     PropAggregateProfile();
1126   }
1127 }
1128
1129 //EdgeProfile();
1130 //KeeperProfile();
1131 //CaseBase();
1132 //%Case();
1133 //Keeper();
1134 //LidEdgeProfile();
1135 //KeeperProfile();
1136 //DemoProfiles();
1137 //PropRecess();