fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121
 122 phone = [ 75.0, 145.0 ];
 123
 124 prop_buildout_less = 3;
 125
 126 prop_angles = [ 15, 30, 45, 60 ];
 127
 128 bumper = [ 0.250, -0.025 ];
 129 // ^ One side.  Overall size is increased by twice this.
 130 // If no bumpers, is the gap around the phone.
 131
 132 enable_support = 1;
 133
 134 led_window_style = 3;
 135 // 0: no window
 136 // 1: simply an opening
 137 // 2: opening with separate cover model, for printing in clear (two colour)
 138 // 3: like 2 but one-layer window for ad-hoc multi-colour
 139
 140 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 141 initial_layer_width = 0.750; // ^ needed for mode 3 only
 142 multicolour_gap = 0.15; // each side
 143
 144 phone_cnr_rad = 6.0;
 145 phone_rim_depth = 0.80; // includes allowance for a screen protector
 146
 147 button_cutout_depth = 9;
 148
 149 phone_edge_thick = 9.0;
 150 phone_total_thick = 12.0;
 151 phone_backside_slope_inner = 1.5; // larger means shallower
 152 phone_backside_slope_outer = 1.0; // larger means shallower
 153
 154 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 155 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 156
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 led_pos = [ 13.98, 10.00 ];
 161 led_aperture = 9;
 162 led_window_ledge = 0.75; // each side
 163
 164 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 165 noisecancelmic_dia = 4.00;
 166
 167 //fingerpushhole_dias = [ 15, 18 ];
 168 fingerpushhole_dias = [];
 169
 170 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 171 rearspeaker_size   = [  3.76,  7.36 ];
 172
 173 microusb_above = 3.27 - 0.25;
 174 microusb_below = 0.0;
 175 microusb_width = 16.12 + 1.25;
 176
 177 case_th_bottom = 2.5;
 178 case_th_lid = 3.0;
 179 case_th_side = 2;
 180 case_th_lip = 1.2;
 181
 182 lid_screen_gap_extra = .66;
 183
 184 case_struts_count = 6;
 185 case_struts_solid_below = 1.00;
 186 case_struts_solid_above = 0.75;
 187 case_struts_width = 0.10;
 188
 189 keeper_th_z = 0.75;
 190 keeper_th_x = 0.75;
 191 keeper_inner_width = 2.75;
 192 keeper_inner_height = 2.75;
 193 keeper_slant_slope = 2; // larger means steeper
 194
 195 keeper_gap_z_top = 0.25;
 196 keeper_gap_z_bot = 0.75;
 197 keeper_gap_x     = 0.25;
 198 keeper_gap_x_holes = 0.75;
 199
 200 keeper_side = 0; // 0 = lhs; 1 = rhs
 201
 202 case_lip = 1.25;
 203
 204 lid_gap_x = 0.25;
 205 lid_gap_z = 0.25;
 206 lid_lip = 1.75;
 207
 208 catch_slop = 0.50;
 209
 210 foldover_gap = 0.50;
 211 foldover_lever_gap = 0.50;
 212
 213 // properties of the hinge fasteners
 214 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 215 hingescrew_shaft_len = 12;
 216 hingescrew_fasteners_extra_thick = 0.40;
 217 // ^ amount of thread protruding if everything was completely nominal
 218 //   and we are using two nuts
 219 hingescrew_nut_access_dia = 4.72 + 0.50;
 220 // ^ washer is 4.72 dia
 221 //   also, want to get pliers or tiny spanner in to do up locknut
 222 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 223 hingescrew_nut_thick = 1.93;
 224 hingescrew_head_th = 1.38 + 0.75;
 225 hingescrew_head_dia = 3.92;
 226
 227 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 228
 229 lever_cover_th = 0.75;
 230 hingemount_th = 2.5;
 231 hingemount_wd = 4.8725;
 232
 233 $fa = 5;
 234 $fs = 0.1;
 235
 236 button_l_fudge = 4.4;
 237 buttonishleg_default_l_is_fudge = 10;
 238
 239 hinge_base_slope = 1.5; // bigger is steeper
 240
 241 strut_min_at_end = 1.5;
 242
 243 hinge_x_gap = 0.125;
 244 hinge_x_postscrew_gap = 0.75;
 245 hinge_x_arms_gap = 0.35;
 246 hinge_r_arms_gap = 0.55;
 247
 248 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 249
 250 catch_len = 7.5;
 251 catch_width = 15;
 252 catch_thickness = 1.0;
 253 catch_side_gap = 0.75; // each side
 254
 255 catch_depth = 0.75;
 256 catch_height = 0.35;
 257 catch_finger_height = 1.5;
 258 catch_finger_depth = 2.5;
 259
 260 prop_recess_under = 0.50;
 261 prop_recess_slop = 0.200; // each side
 262 prop_end_dia = 0.5;
 263 prop_main_th = 3;
 264 prop_taper_len = 6;
 265 prop_main_width = 4;
 266 prop_side_gap = 0.75; // each side
 267 prop_lidrecess_behind = 0.75;
 268 prop_caserecess_behind = 0.75;
 269 prop_caserecess_taper = 0.45; // one side only
 270 prop_prop_gap = 0.5;
 271 prop_prong_heel_slope = 0.5;
 272
 273 lid_fold_clearance_antislop = 0.5;
 274
 275 // ---------- calculated ----------
 276
 277 phone_width =  (phone + bumper*2)[0];
 278 phone_height = (phone + bumper*2)[1];
 279
 280 inside_br = [phone_width, -phone_height];
 281
 282 prop_prong_h = prop_main_th;
 283
 284 //echo(camera_pos_tl + bumper,
 285 //     camera_pos_br + bumper);
 286
 287 // ----- could be changed -----
 288 lid_buttoncover_gap = lid_gap_x;
 289 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 290
 291 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 292
 293 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 294
 295 //prop_nose_len = case_th_lid - prop_recess_under;
 296 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 297 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 298
 299
 300 //lid_lip_overlap_width xxx bad name = ;
 301 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 302
 303 epp0 = [0,0];
 304 epp1 = [0, -phone_edge_thick];
 305 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 306 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 307 epp3 = epp2i + [10, 0];
 308 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 309 epp4 = epp5 + [-1,0] * case_th_side;
 310
 311 kppe = [0,0];
 312 kppd = kppe + [1,0] * keeper_inner_width;
 313 kppc = kppd + [0,1] * keeper_th_z;
 314 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 315 kppf = kppe - [0,1] * keeper_inner_height;
 316 kppa = [ kppb[0], kppf[1] ];
 317
 318 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 319 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 320
 321 lpp14 = lpp10 + [1,0] * keeper_inner_width;
 322 // exact x posn not very important; must extend past end of keeper
 323
 324 lpp15 = [ lpp14[0],
 325           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 326           + lid_screen_gap_extra ];
 327 // ^ beam theory says to maximise force before contact,
 328 //   the gap below the `beam' (the lid) must be 1/3
 329 //   the thickness (ie the lid thickness) if the beam
 330 //   is solid, or 1/2 if it has a top and bottom only.
 331 //   ours is mostly solid.
 332
 333 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 334              case_th_lip);
 335
 336 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 337 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 338
 339 case_bottom_z = epp2o[1] - case_th_bottom;
 340
 341 // button profile
 342 bppM = epp4 + [0,5];
 343 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 344 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 345 bppS = [ epp1[0], bppR[1] ];
 346 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 347 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 348 bppO = [ bppN[0], bppP[1] ];
 349 bppL = lpp10 + [5,0];
 350 bppK = [ bppL[0], bppN[1] ];
 351 bppJ = [ bppN[0], bppL[1] ];
 352 bppU = [ bppJ[0], lpp12[1] ];
 353 bppV = lpp11;
 354 bppW = lpp10;
 355
 356 // notification led aperture
 357
 358 nla_r0 = led_aperture/2;
 359 nla_r1 = nla_r0 + led_window_ledge;
 360 nla_r2 = nla_r1 + multicolour_gap;
 361 nla_t =
 362   led_window_style >= 3 ? initial_layer_thick :
 363   led_window_style >= 2 ? led_window_ledge : 0;
 364
 365
 366 // hinge plan
 367 hp_rn = hingescrew_nut_access_dia/2;
 368 hp_r2_min = hp_rn + lever_cover_th;
 369 hp_rs = hingescrew_shaft_dia/2;
 370 hp_r1_min = hp_rs + hingemount_th;
 371
 372 hp_r1 = max(hp_r1_min, hp_r2_min);
 373 hp_r2 = hp_r1;
 374
 375 hppU = lpp13;
 376 hppS = epp2o + [0,-1] * case_th_bottom;
 377 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 378
 379 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 380          0.5 * (hppU + hppS)[1] ];
 381 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 382 hppB = hppT + [0,-1] * hp_k;
 383
 384 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 385 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 386 hppE = [ hppE_x, hppE_y ];
 387
 388 // hinge elevation x coords
 389
 390 hex20 = max(epp2o[0],
 391             phone_cnr_rad,
 392             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 393 hex21 = hex20 + hingemount_wd;
 394 hex22 = hex21 + hinge_x_gap;
 395 hex27 = hex20 + hingescrew_shaft_len;
 396 hex24 = hex27 + hinge_x_postscrew_gap;
 397 hex23 = hex27 - (hingescrew_nut_thick*2
 398                  + hingescrew_fasteners_extra_thick);
 399 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 400
 401 echo(hex20, hex21, hex22, hex23, hex24);
 402 //  6, 10.8725, 10.9975, 13.74, 18.75
 403 module chk(act,exp) {
 404   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 405   else echo("ok", act);
 406 }
 407 chk(hex20, 6);
 408 chk(hex21, 10.8725);
 409 chk(hex22, 10.9975);
 410 chk(hex23, 13.74);
 411 chk(hex24, 18.75);
 412
 413 lid_fold_clearance_skew =
 414   (lpp10[1] - hppB[1]) /
 415   (lpp10[0] - hppB[0]);
 416
 417 echo("SK",lid_fold_clearance_skew);
 418
 419 // catch
 420
 421 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 422 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 423 cppB = [ epp0[0], cppA[1] ];
 424 cppP = [ epp4[0], cppJ[1] ];
 425
 426 cppS = cppJ + [0,-1] * catch_len;
 427 cppD = [ cppA[0], cppS[1] + catch_slop ];
 428 cppC = [ cppB[0], cppD[1] ];
 429 cppT = cppS + [1,0] * catch_depth;
 430 cppU = cppT + [0,-1] * catch_height;
 431 cppV = [ cppS[0], cppU[1] - catch_depth ];
 432
 433 cppR = 0.5*(cppP + cppJ);
 434
 435 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 436 cppQ = [ cppR[0],
 437          cppV[1] - (catch_finger_height - cp_rQ) ];
 438 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 439
 440 // prop recess in case
 441
 442 prop_x_pos = phone_width/2;
 443
 444 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 445
 446 prc_r1 = prop_end_dia/2;
 447 prc_r3 = prc_r1 + prop_recess_slop;
 448
 449 prcp2 = [ epp4[0] + prop_buildout_less,
 450           case_bottom_z ];
 451
 452 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 453
 454 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 455           epp2i[1] - prc_r3 - prop_recess_under];
 456
 457 // prop recess in lid
 458
 459 prl_r10 = prop_end_dia/2;
 460 prl_r10o = prl_r10 + prop_recess_slop;
 461
 462 prlp10 = lpp10 + [1,1] * prl_r10o
 463   + [1,0] * prop_lidrecess_behind
 464   + [0,1] * prop_recess_under;
 465
 466 // prop
 467
 468 $prpp10 = [0,0];
 469 $prpp11 = [0, prop_taper_len];
 470
 471 $prp_r10 = prl_r10;
 472
 473 // ---------- modules ----------
 474
 475 module AdhocMultiprintFrame(phase, z0, zs) {
 476   // from z0 to z0 + zs*layer
 477   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 478   xextra = extra + -epp4[0];
 479   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 480   yextra = extra + -epp4[0];
 481   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 482   p0 = [ xrange[0], yrange[0] ];
 483   p1 = [ xrange[1], yrange[1] ];
 484   echo(p0, p1);
 485   translate([0,0, z0])
 486     mirror([0,0, zs<0 ? 1 : 0])
 487     linear_extrude(height= initial_layer_thick)
 488     difference(){
 489       rectfromto(p0 - [1,1] * initial_layer_width,
 490                  p1 + [1,1] * initial_layer_width);
 491       rectfromto(p0, p1);
 492     }
 493 }
 494
 495 module KeeperProfile(slant=0){
 496   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 497   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 498 }
 499
 500 module EdgeProfile(){
 501   difference(){
 502     hull(){
 503       translate(epp3) square(case_th_bottom*2, center=true);
 504       circleat(epp2o, r=case_th_bottom);
 505       circleat(epp1, r=case_th_side);
 506       rectfromto(epp0, epp4);
 507     }
 508     polygon([ epp5 + [0,10],
 509               epp1,
 510               epp2i,
 511               epp3 + [10,0] ]);
 512   }
 513 }
 514
 515 module LidEdgeProfile(){
 516   polygon([ lpp10,
 517             lpp11,
 518             lpp12,
 519             lpp13,
 520             lpp13 + [10, 0],
 521             lpp15 + [10, 0],
 522             lpp15,
 523             lpp14,
 524             ]);
 525   intersection(){
 526     circleat(lpp12, r=lp_r12);
 527     rectfromto( lpp12 + [-10,   0],
 528                 lpp12 + [+10, +10] );
 529   }
 530 }
 531
 532 module LidEdgeFoldClearanceProfile(){
 533   translate([-lid_fold_clearance_antislop, 0])
 534     polygon([ lpp10,
 535               lpp11,
 536               lpp11 + [-20,  0],
 537               lpp11 + [-20, 20],
 538               lpp11 + [+20, 20],
 539               lpp10 + [+20,  0] ]);
 540 }
 541
 542 module ButtonCoverProfile(){
 543   intersection(){
 544     polygon(concat([ bppM, bppP, bppO, bppJ ],
 545                    (enable_support && !$button_suppress_over_keeper
 546                     ? [ bppU, bppV, bppW ] : []),
 547                    [ bppL, bppK ]));
 548     hull(){
 549       EdgeProfile();
 550       LidEdgeProfile();
 551     }
 552   }
 553 }
 554
 555 module ButtonPlan(l, deep, cut){
 556   epsilon =
 557     (cut  ? 0 : lid_buttoncover_gap);
 558
 559   delta =
 560     (deep ? lid_buttoncover_overlap : 0);
 561
 562   C = [0,0]; // by definition
 563   T = [ 0, epp4[1] ];
 564   G = T + [0,10];
 565
 566   B0 = C + [0,-1] * button_cutout_depth;
 567   B1 = B0 + [0,1] * epsilon;
 568
 569   r0 = 0.5 * (T[1] - B0[1]);
 570   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 571   H = A + [0,-1] * delta;
 572
 573   D = A + [-2,0] * r0;
 574   F = D + [0,10];
 575
 576   E0 = 0.5 * (D + A);
 577   E1 = E0 + [1,0] * epsilon;
 578
 579   I0 = [ E0[0], H[1] ];
 580   I1 = [ E1[0], H[1] ];
 581
 582   hull(){
 583     for (m=[0,1]) mirror([m,0])
 584       circleat(H, r0 - epsilon);
 585   }
 586   for (m=[0,1]) mirror([m,0]) {
 587     difference(){
 588       polygon([ E1,
 589                 I1,
 590                 H,
 591                 B1,
 592                 G,
 593                 F,
 594                 D
 595                 ]);
 596       circleat(D, r0 + epsilon);
 597     }
 598   }
 599 }
 600
 601 module CatchCatchProfile(){
 602   hull(){
 603     for (c=[ cppR, cppQ ])
 604       circleat(c, cp_rQ);
 605   }
 606   hull(){
 607     circleat(lpp12, lp_r12);
 608     circleat(lpp12 + [5,0], lp_r12);
 609     rectfromto(cppP, cppP + [5,0.1]);
 610   }
 611   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 612 }
 613
 614 module CatchCutProfile(){
 615   polygon([ cppB,
 616             cppA,
 617             cppD,
 618             cppF,
 619             cppF + [0,-10],
 620             cppF + [-10,-10],
 621             lpp12 + [-10,0],
 622             lpp12 + [10,0]
 623             ]);
 624 }
 625
 626 module Flip_rhs(yn=[0,1]) {
 627   for ($rhsflip=yn) {
 628     translate([phone_width/2, 0, 0])
 629       mirror([$rhsflip,0,0])
 630       translate([-phone_width/2, 0, 0])
 631       children();
 632   }
 633 }
 634
 635 module Flip_bot(yn=[0,1]) {
 636   for ($botflip=yn) {
 637     translate([0, -phone_height/2, 0])
 638       mirror([0, $botflip, 0])
 639       translate([0, phone_height/2, 0])
 640       children();
 641   }
 642 }
 643
 644 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 645   // sides
 646   Flip_rhs(){
 647     translate([0, -phone_cnr_rad, 0])
 648       rotate([90,0,0])
 649       linear_extrude(height = phone_height - phone_cnr_rad*2)
 650       children(0);
 651   }
 652   // corners
 653   Flip_rhs() Flip_bot() {
 654     translate([+1,-1] * phone_cnr_rad)
 655       intersection(){
 656         rotate_extrude()
 657           intersection(){
 658             mirror([1,0,0])
 659               translate([-1,0] * phone_cnr_rad)
 660               children(0);
 661             rectfromto([0,-20],[10,20]);
 662           }
 663         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 664           cube([10,10,40]);
 665       }
 666   }
 667   // top and bottom
 668   Flip_bot(){
 669     translate([ phone_width - phone_cnr_rad, 0,0 ])
 670       rotate([90,0,-90])
 671       linear_extrude(height = phone_width - phone_cnr_rad*2)
 672       children(0);
 673   }
 674   // fill
 675   translate([0,0, fill_zstart])
 676     mirror([0,0, fill_downwards])
 677     linear_extrude(height = fill_th)
 678     rectfromto([+1,-1] * phone_cnr_rad,
 679                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 680 }
 681
 682 module CaseAperture(pos, dia, $fn) {
 683   theta = 180/$fn;
 684   translate([ pos[0] + bumper[0],
 685               -epp2i[0],
 686               -pos[1] ])
 687     rotate([-90, theta, 0])
 688     cylinder(r = dia/2 / cos(theta),
 689              h = 60);
 690 }
 691
 692 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 693   // y_ref_sign:
 694   //   +1  measured from top    of actual phone to top    of button
 695   //   -1  measured from bottom of actual phone to bottom of button
 696   //    0  y is centre of button in coordinate system
 697   $button_l= l;
 698   $button_suppress_over_keeper= suppress_over_keeper;
 699   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 700           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 701           y;
 702   //echo(eff_y);
 703   translate([0, eff_y, 0])
 704     children();
 705 }
 706
 707 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 708   $button_leg_only = true;
 709   SideButton(y, y_ref_sign, l) children();
 710 }
 711
 712 module Buttons(){
 713   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 714   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 715   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 716   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 717 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 718 }
 719
 720 module Struts(x_start, z_min, th){
 721   // if th is negative, starts at z_min and works towards -ve z
 722   // and object should then be printed other way up
 723   for (i= [1 : 1 : case_struts_count]) {
 724     translate([0,
 725                0,
 726                z_min])
 727       mirror([0,0, th<0 ? 1 : 0])
 728       translate([0,
 729                  -phone_height * i / (case_struts_count+1),
 730                  case_struts_solid_below])
 731       linear_extrude(height= abs(th)
 732                      -(case_struts_solid_below+case_struts_solid_above))
 733       rectfromto([               x_start, -0.5 * case_struts_width ],
 734                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 735   }
 736 }
 737
 738 module OrdinaryRearAperture(rhs,bot, pos){
 739   Flip_rhs(rhs) Flip_bot(bot)
 740     linextr(-20, 20)
 741     mirror([0,1])
 742     translate(pos + bumper)
 743     children();
 744 }
 745
 746 module MicroUSB(){
 747   Flip_bot(1){
 748     rotate([90,0,0])
 749       mirror([0,0,1])
 750       linextr(-epp2i[0], 60)
 751       translate([0.5 * phone_width, 0, 0])
 752       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 753                  [+microusb_width/2, epp0[1] + -microusb_above]);
 754   }
 755 }
 756
 757 module OrdinaryRearApertures(){
 758   // rear speaker
 759   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 760     rectfromto(-rearspeaker_gap,
 761                rearspeaker_size + rearspeaker_gap);
 762
 763   // finger hole to remove phone
 764   if (len(fingerpushhole_dias))
 765     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 766                                 phone[1]/2 ])
 767     scale(fingerpushhole_dias)
 768     circle(r= 0.5 );
 769 }
 770
 771 module RearCameraAperture(){
 772   Flip_rhs(1)
 773     mirror([0, 0, 1])
 774     linear_extrude(height = 20)
 775     mirror([0, 1, 0])
 776     translate(bumper)
 777     rectfromto(camera_pos_tl, camera_pos_br);
 778 }
 779
 780 module HingeLidProfile(){
 781   hull(){
 782     circleat(hppT, hp_r1);
 783     circleat(lpp12, lp_r12);
 784     polygon([lpp10,
 785              lpp13 + [2,0],
 786              lpp12,
 787              hppT]);
 788   }
 789 }
 790
 791 module HingeBaseProfile(){
 792   difference(){
 793     hull(){
 794       circleat(hppB, hp_r1);
 795       circleat(hppE, hp_r1);
 796       circleat(epp2o, case_th_bottom);
 797       circleat(hppB + [10,0], hp_r1);
 798     }
 799     polygon([epp5, epp1, epp2i, epp3, bppL]);
 800   }
 801 }
 802
 803 module HingeLeverOuterProfile(){
 804   hull(){
 805     circleat(hppT, hp_r2);
 806     circleat(hppB, hp_r2);
 807   }
 808 }
 809
 810 module HingeLeverInnerProfile(){
 811   for (s = [-1,+1]) {
 812     c = s > 0 ? hppT : hppB;
 813     translate(c)
 814       mirror([0,0,s>0])
 815       rotate(s<0 ? -40 : 0)
 816       hull()
 817       for (x=[-20,20])
 818         for (y=[0, s * 10])
 819           translate([x,y])
 820             circle(hp_rn);
 821   }
 822 }
 823
 824 module HingeLeverNutProfile(){
 825   for (c= [hppB, hppT]) {
 826     translate(c)
 827       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 828   }
 829 }
 830
 831 module Flip_hinge(doflip=1){
 832   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 833   translate(hinge_origin)
 834     rotate([doflip*180,0,0])
 835     translate(-hinge_origin)
 836     children();
 837 }
 838
 839 module HingePortion(x0,x1){
 840   Flip_rhs() Flip_bot(1)
 841     translate([x0,0,0])
 842     mirror([1,0,0])
 843     rotate([90,0,-90])
 844     linear_extrude(height=x1-x0)
 845     children();
 846 }
 847
 848 module CatchPortion(width){
 849   translate([phone_width/2, 0,0])
 850     rotate([90,0,-90])
 851     linextr(-width/2, width/2)
 852     children(0);
 853 }
 854
 855 module CaseBase(){
 856   AroundEdges(epp3[1], case_th_bottom, 1)
 857     EdgeProfile();
 858 }
 859
 860 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 861
 862 module PropProfileAssignments(gamma){
 863   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 864   x = prop_x(gamma);
 865   p = phone_height + prlp10[0] - hppB[0];
 866   b = p + x;
 867
 868   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 869   a = q + x;
 870   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 871   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 872
 873   $prp_theta = 90 - $prp_alpha;
 874   beta = 180 - $prp_alpha - gamma;
 875   psi = 90 - beta;
 876
 877   //echo("abc", a,b,c);
 878
 879   v1 = [ [ cos(psi), -sin(psi) ],    // x
 880          [ sin(psi),  cos(psi) ] ];  // y
 881
 882   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 883
 884   $prp_r1 = prc_r1;
 885   $prp_r11 = prop_main_th/2;
 886
 887   $prpp1 = $prpp7 + [1,0] *
 888     // this is approximate, but will do
 889     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 890   $prpp3 = $prpp1 +
 891     v1[0] * -$prp_r1 +
 892     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 893   $prpp12 = $prpp3 + v1[0] *
 894     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 895   $prp_r8 = prop_main_th;
 896   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 897   $prp_r5 = $prp_r8;
 898   $prpp5 = [ $prpp12[0] - $prp_r5,
 899             $prpp3[1] - prop_prong_h + $prp_r5 ];
 900   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 901          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 902   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 903   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 904
 905   children();
 906 }
 907
 908 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 909   PropProfileAssignments(gamma){
 910
 911     //#circleat($prpp3,1);
 912     //#circleat($prpp12,1);
 913
 914     if (!cut) {
 915       hull(){
 916         translate($prpp8)
 917           intersection(){
 918             circle($prp_r8);
 919             polygon([[-20,-0], [20,20], [0,0]]);
 920           }
 921         rectfromto($prpp6, $prpp9);
 922         translate($prpp5) intersection(){
 923           circle($prp_r5);
 924           polygon([[-10,-10], [0,0], [10,0]]);
 925         }
 926         rectfromto($prpp12 + [0,-0.1], $prpp3);
 927       }
 928       hull(){
 929         circleat($prpp1, $prp_r1);
 930         rectfromto($prpp12 + [0,-0.1], $prpp3);
 931       }
 932     }
 933     // main shaft
 934     rotate([0,0, rot*-$prp_theta]){
 935       hull(){
 936         extra = cut ? prop_recess_slop : 0;
 937         rectfromto($prpp6, $prpp9);
 938         circleat($prpp11, $prp_r11 + extra);
 939         circleat($prpp10, $prp_r10 + extra);
 940       }
 941     }
 942   }
 943 }
 944
 945 module PropAggregateProfile(){
 946   for (angle = prop_angles)
 947     PropProfile(angle, 0,0);
 948 }
 949
 950 module Prop(){ ////toplevel
 951   hw = prop_main_width/2;
 952   linextr(-hw, +hw)
 953     PropAggregateProfile();
 954 }
 955
 956 module Case(){ ////toplevel
 957   difference(){
 958     union(){
 959       CaseBase();
 960
 961       // ledge (fixed keeper)
 962       Flip_rhs(1-keeper_side) intersection(){
 963         rotate([90, 0, 0])
 964           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 965           KeeperProfile(1);
 966
 967         // outline of the whole case, to stop it protruding
 968         translate([0,0, -25])
 969           linear_extrude(height = 50)
 970           hull()
 971           Flip_bot()
 972           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 973       }
 974
 975       // hinge
 976       HingePortion(hex20, hex21) HingeBaseProfile();
 977
 978       // buildout for prop recess
 979       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
 980         linextr(case_bottom_z, epp2i[1])
 981         hull() {
 982           for (dxs = [-1,+1])
 983             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
 984                        -epp2o[0] ],
 985                      r = epp2o[0] - prcp2[0]);
 986         }
 987     }
 988
 989     // slot for keeper
 990     Flip_rhs(keeper_side)
 991       translate([0, -phone_cnr_rad, 0])
 992       rotate([90, 0, 0])
 993       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 994       minkowski(){
 995         KeeperProfile();
 996         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 997                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 998       }
 999
1000     // front camera
1001     RearCameraAperture();
1002
1003     // struts (invisible, because they're buried in the case)
1004     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1005
1006     Buttons(){
1007       mirror([1,0,0])
1008         rotate([90,0,90]) {
1009           if (!($button_leg_only && enable_support))
1010           intersection(){
1011             translate([0,0,-10])
1012               linear_extrude(height= 20)
1013               ButtonPlan($button_l, 0,1);
1014             if ($button_leg_only)
1015               rotate([-90,90,0])
1016                 translate([phone_width/2, -400, kppe[1]])
1017                 mirror([1-abs($rhsflip - keeper_side),0,0])
1018                 cube([400, 800, 50]);
1019             if (enable_support && !$button_suppress_over_keeper)
1020               rotate([-90,90,0])
1021               translate([-400, -400, kppd[1]])
1022                 mirror([0,0,1])
1023                 cube([800,800,100]);
1024           }
1025           translate([0,0, -bppR[0]])
1026             linear_extrude(height= 20)
1027             ButtonPlan($button_l, 1,1);
1028         }
1029
1030     }
1031
1032     // apertures along top edge
1033     CaseAperture(jack_pos, jack_dia, 8);
1034     Flip_rhs(1)
1035       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1036
1037     OrdinaryRearApertures();
1038
1039     MicroUSB();
1040
1041     // gaps for the lid's hinge arms
1042     HingePortion(hex20 - hinge_x_arms_gap,
1043                  hex21 + hinge_x_arms_gap)
1044       minkowski(){
1045         HingeLidProfile();
1046         circle(r= hinge_r_arms_gap, $fn= 8);
1047       }
1048
1049     // screw holes in the hinge arms
1050     HingeScrews();
1051
1052     // catch striker
1053     CatchPortion(catch_width + catch_side_gap*2)
1054       CatchCutProfile();
1055
1056     // prop recess
1057     Flip_rhs(1)
1058       translate([prop_x_pos,0,0])
1059       mirror([0,1,0])
1060       rotate([90,0,90])
1061       linextr(-prop_recess_hw, +prop_recess_hw)
1062       hull(){
1063         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1064           circleat(prcp1 + 20*d,
1065                    prc_r3);
1066       }
1067   }
1068 }
1069
1070 module LidAdhocMultiprintFrame(phase){
1071   if (led_window_style >= 3) {
1072     AdhocMultiprintFrame(phase, lpp13[1], -1);
1073   }
1074 }
1075
1076 module LidAroundEdges(){
1077   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1078     children();
1079 }
1080
1081 module Lid(){ ////toplevel
1082   skew_centre = [0, lpp11[0], lpp11[1]];
1083   difference(){
1084     union(){
1085       intersection(){
1086         LidAroundEdges()
1087           LidEdgeProfile();
1088
1089         translate(skew_centre)
1090           multmatrix([[ 1, 0, 0, 0 ],
1091                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1092                       [ 0, 0, 1, 0 ],
1093                       [ 0, 0, 0, 1 ]])
1094           translate(-skew_centre)
1095           LidAroundEdges()
1096           LidEdgeFoldClearanceProfile();
1097       }
1098
1099       // button covers
1100       Buttons(){
1101         intersection(){
1102           rotate([90,0,90])
1103             translate([0,0,-10])
1104             linear_extrude(height= 20)
1105             ButtonPlan($button_l, 1,0);
1106           rotate([90,0,0])
1107              translate([0,0,-100])
1108             linear_extrude(height= 200)
1109             ButtonCoverProfile();
1110         }
1111       }
1112
1113       // hinge arms
1114       HingePortion(hex20, hex21) {
1115         LidEdgeProfile();
1116         HingeLidProfile();
1117       }
1118
1119       // catch
1120       CatchPortion(catch_width)
1121         CatchCatchProfile();
1122     }
1123     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1124
1125     // screw holes in the hinge arms
1126     HingeScrews();
1127
1128     // prop recess
1129     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1130       mirror([0,1,0])
1131       rotate([90,0,90])
1132       linextr(-prop_recess_hw, +prop_recess_hw)
1133       hull()
1134       for (pa = prop_angles)
1135         PropProfile(pa, 1,1);
1136
1137     // notification led aperture
1138     if (led_window_style)
1139       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1140         translate([0,0,-10])
1141           cylinder(r=nla_r0, h=20);
1142         if (led_window_style >= 2)
1143           translate([0,0, -nla_t])
1144             cylinder(r=nla_r2, height=20);
1145       }
1146
1147     }
1148
1149   LidAdhocMultiprintFrame(1);
1150 }
1151
1152 module HingeLever(){ ////toplevel
1153   difference() {
1154     // outer body, positive
1155     HingePortion(hex22, hex22 + phone_width/2)
1156       HingeLeverOuterProfile();
1157
1158     // space for the screws
1159     HingePortion(hex26, hex24)
1160       HingeLeverInnerProfile();
1161
1162     // recesses for the nuts
1163     HingePortion(hex23, hex26+1)
1164       HingeLeverNutProfile();
1165
1166     // bores for the screws
1167     HingeScrews();
1168
1169     // space for the charging cable
1170     MicroUSB();
1171     Flip_hinge() MicroUSB();
1172   }
1173 }
1174
1175 module LidWindow(){ ////toplevel
1176   translate([led_pos[0], -led_pos[1], lpp13[1]])
1177     mirror([0,0,1])
1178     cylinder(r= nla_r1, h=nla_t);
1179   LidAdhocMultiprintFrame(0);
1180 }
1181
1182 module LidWindowPrint(){ ////toplevel
1183   rotate([0,180,0])
1184     LidWindow();
1185 }
1186
1187 module DemoLidWindowSelect(){
1188   translate([led_pos[0], led_pos[1], -100]) {
1189     translate([0, -30, 0]) cube([400, 400, 200]);
1190   }
1191 }
1192
1193 module DemoLidWindow(){ ////toplevel
1194   %Lid();
1195   LidWindow();
1196   translate([0,40,0]){
1197     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1198     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1199   }
1200 }
1201
1202 module HingeLeverPrint(){ ////toplevel
1203   rotate([-90,0,0])
1204     translate([-phone_width/2, phone_height, 0])
1205     HingeLever();
1206 }
1207
1208 module TestSelectLength(){
1209   translate([-30, -200, -20])
1210     cube([30 + 15, 250, 40]);
1211 }
1212
1213 module TestLength(){ ////toplevel
1214   intersection(){
1215     Case();
1216     TestSelectLength();
1217   }
1218 }
1219
1220 module TestLengthRight(){ ////toplevel
1221   intersection(){
1222     Case();
1223     Flip_rhs(1)
1224       TestSelectLength();
1225   }
1226 }
1227
1228 module TestSelectWidth(){
1229   translate([-30, -(phone_height - 25), -20])
1230     mirror([0, 1, 0])
1231     cube([200, 50, 40]);
1232 }
1233
1234 module TestWidth(){ ////toplevel
1235   intersection(){
1236     Case();
1237     TestSelectWidth();
1238   }
1239 }
1240
1241 module TestLidWidthPrint(){ ////toplevel
1242   rotate([0,180.0]) intersection(){
1243     Lid();
1244     TestSelectWidth();
1245   }
1246 }
1247
1248 module TestSelectRearAperture(){
1249   minkowski(){
1250     union() children();
1251     translate([20, 0,0])
1252       cube([42, 2, 1], center=true);
1253   }
1254 }
1255
1256 module TestSelectCamera(){
1257   minkowski(){
1258     TestSelectRearAperture()
1259       RearCameraAperture();
1260     cube([0.1, 50, 0.1]);
1261   }
1262 }
1263
1264 module TestSelectOrdinaryRearApertures(){
1265   TestSelectRearAperture()
1266     OrdinaryRearApertures();
1267 }
1268
1269 module TestCamera(){ ////toplevel
1270   intersection(){
1271     Case();
1272     TestSelectCamera();
1273   }
1274 }
1275
1276 module TestLidByCamera(){ ////toplevel
1277   intersection(){
1278     Lid();
1279     TestSelectCamera();
1280   }
1281 }
1282
1283 module TestLidByCameraPrint(){ ////toplevel
1284   rotate([180,0,0]) TestLidByCamera();
1285 }
1286
1287 module DemoByCamera(){ ////toplevel
1288   color("blue") TestLidByCamera();
1289   color("red")  TestCamera();
1290 }
1291
1292 module OneKeeper(){ ////toplevel
1293   translate([0, -phone_cnr_rad, 0])
1294     rotate([90, 0, 0])
1295     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1296     KeeperProfile();
1297 }
1298
1299 module OneKeeperPrint(){ ////toplevel
1300   rotate([0,180,0])
1301     OneKeeper();
1302 }
1303
1304 module LidPrint(){ ////toplevel
1305   rotate([0,180,0])
1306     Lid();
1307 }
1308
1309 module TestSelectFrame(){
1310   include = [1,-1] * (epp2i[0] + 4);
1311
1312   difference(){
1313     cube(1000, center=true);
1314     translate([0,0, -100])
1315       linear_extrude(height=200)
1316       rectfromto(include,  inside_br - include);
1317   }
1318 }
1319
1320 module TestSelectLidFrame(){
1321   TestSelectFrame();
1322   translate([led_pos[0], -led_pos[1], -50])
1323     cylinder(r= nla_r2+3, h=100);
1324 }
1325
1326 module TestFrameCase(){ ////toplevel
1327   intersection(){
1328     Case();
1329     union(){
1330       TestSelectFrame();
1331       TestSelectCamera();
1332       TestSelectOrdinaryRearApertures();
1333     }
1334   }
1335 }
1336
1337 module TestSelectTopApertures(){
1338   translate([-100, -35, -100])
1339     cube([400, 100, 200]);
1340   LidAdhocMultiprintFrame(0);
1341   LidAdhocMultiprintFrame(1);
1342 }
1343
1344 module TestTopApertures(){ ////toplevel
1345   intersection(){
1346     Case();
1347     TestSelectFrame();
1348     TestSelectTopApertures();
1349   }
1350 }
1351
1352 module TestLidTopAperturesPrint(){ ////toplevel
1353   rotate([0,180,0]) intersection(){
1354     Lid();
1355     TestSelectLidFrame();
1356     TestSelectTopApertures();
1357   }
1358 }
1359
1360 module TestLidWindowTopAperturesPrint(){ ////toplevel
1361   rotate([0,180,0]) intersection(){
1362     LidWindow();
1363     TestSelectTopApertures();
1364   }
1365 }
1366
1367 module TestFrameLidPrint(){ ////toplevel
1368   rotate([0,180,0]) intersection(){
1369     Lid();
1370     TestSelectLidFrame();
1371   }
1372 }
1373
1374 module ButtonPlanForDemo(z, deep, cut){
1375   translate([0,0,z])
1376     ButtonPlan(8, deep, cut);
1377 }
1378
1379 module HingeScrews(){
1380   Flip_rhs() Flip_bot(1){
1381     for (c= [ hppT, hppB ])
1382       translate([ hex20,
1383                   -c[0],
1384                   c[1] ]){
1385         rotate([0,90,0])
1386           translate([0,0,-.2])
1387           cylinder( r= hingescrew_shaft_dia/2,
1388                     h = hingescrew_shaft_len+0.2 );
1389         rotate([0,-90,0])
1390           translate([0,0,+.1])
1391           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1392       }
1393   }
1394 }
1395
1396 module DemoPropAngleSelect(c){
1397   color(c) difference(){
1398     union(){ children(); }
1399     translate([ prop_x_pos, -400, -200 ])
1400       cube([ 400,800,400 ]);
1401   }
1402 }
1403
1404 module DemoPropAngle(ang){
1405   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1406   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1407
1408   translate(hL)
1409     rotate([ang/2,0,0])
1410     translate(-hL)
1411     translate(hC)
1412     rotate([ang/2,0,0])
1413     translate(-hC) {
1414       DemoPropAngleSelect("red") Case();
1415
1416       color("orange")
1417         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1418         PropProfileAssignments(ang) {
1419           echo($prpp1);
1420           rotate([-$prp_theta, 0, 0])
1421           translate([0, $prpp1[0], -$prpp1[1]])
1422           rotate([90,0,-90])
1423           Prop();
1424         }
1425     }
1426
1427   translate([0,0, -hp_k*2])
1428     DemoPropAngleSelect("blue")
1429     Lid();
1430 }
1431
1432 module DemoPropAngles(){ ////toplevel
1433   for (i=[0 : len(prop_angles)-1])
1434     translate(i * [0, -100, 100])
1435     DemoPropAngle(prop_angles[i]);
1436 }
1437
1438 module DemoHingeAngle(ang1,ang2){
1439   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1440   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1441
1442   translate(hL)
1443     rotate([ang2,0,0])
1444     translate(-hL)
1445     translate(hC)
1446     rotate([ang1,0,0])
1447     translate(-hC) {
1448       color("red") Lid();
1449     }
1450
1451   color("blue") intersection(){
1452     Case();
1453     union(){
1454       translate([bppJ[0], -400, -200])
1455         mirror([1,0,0])
1456         cube([400, 800, 400]);
1457       translate([10, -400, -200])
1458         cube([10, 800, 400]);
1459     }
1460   }
1461 }
1462
1463 module DemoHingeAngles(){ ////toplevel
1464   angles = [ 0, 4, 8, 12 ];
1465   echo("angles",angles);
1466   for (i=[0 : len(angles)-1]) {
1467     translate(i * [0, 0, 30]) {
1468       DemoHingeAngle(0,angles[i]);
1469       translate([0, 200, 0])
1470         DemoHingeAngle(angles[i],0);
1471     }
1472   }
1473 }
1474
1475 module DemoSelectAdhocLeftRight(right=0) {
1476   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1477     mirror([1-right, 0,0])
1478     cube([400, 800, 200]);
1479 }
1480
1481 module DemoLeft(){ ////toplevel
1482   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1483   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1484 }
1485
1486 module DemoFrame(){ ////toplevel
1487   color("red") TestFrameCase();
1488   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1489   color("black") HingeScrews();
1490   %HingeLever();
1491 }
1492
1493 module DemoHingedFrame(){ ///toplevel
1494   color("red") TestFrameCase();
1495   translate([0,0, -2*hp_k])
1496   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1497
1498   Flip_hinge(){
1499     color("orange") HingeLever();
1500     color("black") HingeScrews();
1501   }
1502 }
1503
1504 module DemoHinge(){ ////toplevel
1505   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1506     DemoFrame();
1507     translate([0,0, -hp_k*3])
1508       DemoHingedFrame();
1509   }
1510 }
1511
1512 module DemoProfiles(){ ////toplevel
1513   LidEdgeProfile();
1514   %EdgeProfile();
1515   KeeperProfile();
1516   translate([0,0,-1]) color("black") KeeperProfile(1);
1517
1518   translate([20,0]) {
1519     LidEdgeProfile();
1520     %EdgeProfile();
1521
1522     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1523
1524     color("blue") ButtonCoverProfile();
1525     color("red") {
1526       rectfromto(bppQ, demopoint_QR);
1527       rectfromto(bppR, demopoint_QR);
1528     }
1529   }
1530
1531   translate([-20,0]) {
1532     color("black") ButtonPlanForDemo(-2, 0,1);
1533     color("red" )  ButtonPlanForDemo(-4, 1,1);
1534     color("blue")  ButtonPlanForDemo(-6, 1,0);
1535   }
1536
1537   translate([0, -30]) {
1538     %LidEdgeProfile();
1539     %EdgeProfile();
1540     color("blue") HingeLidProfile();
1541     color("red")  HingeBaseProfile();
1542     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1543   }
1544
1545   for (f=[0,1]) {
1546     translate([-30, -60 + 30*f]) {
1547       translate([0,0,-4]) EdgeProfile();
1548       %translate([0,0,-10]) HingeBaseProfile();
1549       translate([0,-2] * f * hp_k) {
1550         translate([0,0,-4]) LidEdgeProfile();
1551         %translate([0,0,-10]) %HingeLidProfile();
1552       }
1553       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1554         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1555         translate([0,0,0]) color("red") difference(){
1556           HingeLeverOuterProfile();
1557           HingeLeverInnerProfile();
1558         }
1559         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1560       }
1561     }
1562   }
1563
1564   translate([20,-30]) {
1565     %EdgeProfile();
1566     %LidEdgeProfile();
1567     //translate([0,0,1]) CatchCutProfile();
1568     color("blue") CatchCatchProfile();
1569     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1570   }
1571
1572   translate([40,-30]) {
1573     difference(){
1574       LidEdgeProfile();
1575       translate(prlp10)
1576         PropProfile(10, 1, 0);
1577     }
1578     translate(prlp10)
1579       PropProfile(15, 0);
1580   }
1581   translate([60,-30]) {
1582     PropAggregateProfile();
1583   }
1584 }
1585
1586 //EdgeProfile();
1587 //KeeperProfile();
1588 //CaseBase();
1589 //%Case();
1590 //Keeper();
1591 //LidEdgeProfile();
1592 //KeeperProfile();
1593 //DemoProfiles();
1594 //PropRecess();