fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121
 122 phone = [ 75.0, 145.0 ];
 123
 124 prop_buildout_less = 3;
 125
 126 prop_angles = [ 15, 30, 45, 60 ];
 127
 128 bumper = [ 0.250, -0.025 ];
 129 // ^ One side.  Overall size is increased by twice this.
 130 // If no bumpers, is the gap around the phone.
 131
 132 enable_support = 1;
 133
 134 led_window_style = 3;
 135 // 0: no window
 136 // 1: simply an opening
 137 // 2: opening with separate cover model, for printing in clear (two colour)
 138 // 3: like 2 but one-layer window for ad-hoc multi-colour
 139
 140 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 141 initial_layer_width = 0.750; // ^ needed for mode 3 only
 142 multicolour_gap = 0.15; // each side
 143
 144 phone_cnr_rad = 6.0;
 145 phone_rim_depth = 0.80; // includes allowance for a screen protector
 146
 147 button_cutout_depth = 9;
 148
 149 phone_edge_thick = 9.0;
 150 phone_total_thick = 12.0;
 151 phone_backside_slope_inner = 1.5; // larger means shallower
 152 phone_backside_slope_outer = 1.0; // larger means shallower
 153
 154 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 155 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 156
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 led_pos = [ 13.98, 10.00 ];
 161 led_aperture = 9;
 162 led_window_ledge = 0.75; // each side
 163
 164 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 165 noisecancelmic_dia = 4.00;
 166
 167 //fingerpushhole_dias = [ 15, 18 ];
 168 fingerpushhole_dias = [];
 169
 170 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 171 rearspeaker_size   = [  3.76,  7.36 ];
 172
 173 microusb_above = 3.27 - 0.25;
 174 microusb_below = 0.0;
 175 microusb_width = 16.12 + 1.25;
 176
 177 case_th_bottom = 2.5;
 178 case_th_lid = 3.0;
 179 case_th_side = 2.3;
 180 case_th_lip = 1.2;
 181
 182 lid_screen_gap_extra = .66;
 183
 184 case_struts_count = 6;
 185 case_struts_solid_below = 1.00;
 186 case_struts_solid_above = 0.75;
 187 case_struts_width = 0.10;
 188
 189 keeper_th_z = 0.75;
 190 keeper_th_x = 0.75;
 191 keeper_inner_width = 2.75;
 192 keeper_inner_height = 2.75;
 193 keeper_slant_slope = 2; // larger means steeper
 194
 195 keeper_gap_z_top = 0.25;
 196 keeper_gap_z_bot = 0.75;
 197 keeper_gap_x     = 0.25;
 198 keeper_gap_x_holes = 0.75;
 199
 200 keeper_side = 0; // 0 = lhs; 1 = rhs
 201
 202 case_lip = 1.25;
 203
 204 lid_gap_x = 0.25;
 205 lid_gap_z = 0.25;
 206 lid_lip = 1.75;
 207 lid_edgepart_width = 5.0;
 208 lid_buttoncover_thick = 1.3;
 209
 210 catch_slop = 0.50;
 211
 212 foldover_gap = 0.50;
 213 foldover_lever_gap = 0.50;
 214
 215 // properties of the hinge fasteners
 216 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 217 hingescrew_shaft_len = 12;
 218 hingescrew_fasteners_extra_thick = 0.40;
 219 // ^ amount of thread protruding if everything was completely nominal
 220 //   and we are using two nuts
 221 hingescrew_nut_access_dia = 4.72 + 0.50;
 222 // ^ washer is 4.72 dia
 223 //   also, want to get pliers or tiny spanner in to do up locknut
 224 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 225 hingescrew_nut_thick = 1.93;
 226 hingescrew_head_th = 1.38 + 0.75;
 227 hingescrew_head_dia = 3.92;
 228
 229 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 230
 231 lever_cover_th = 0.75;
 232 hingemount_th = 2.5;
 233 hingemount_wd = 4.8725;
 234
 235 $fa = 5;
 236 $fs = 0.1;
 237
 238 button_l_fudge = 4.4;
 239 buttonishleg_default_l_is_fudge = 10;
 240
 241 hinge_base_slope = 1.5; // bigger is steeper
 242
 243 strut_min_at_end = 1.5;
 244
 245 hinge_x_gap = 0.125;
 246 hinge_x_postscrew_gap = 0.75;
 247 hinge_x_arms_gap = 0.35;
 248 hinge_r_arms_gap = 0.55;
 249
 250 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 251
 252 catch_len = 7.5;
 253 catch_width = 15;
 254 catch_thickness = 1.0;
 255 catch_side_gap = 0.75; // each side
 256
 257 catch_depth = 0.75;
 258 catch_height = 0.35;
 259 catch_finger_height = 1.5;
 260 catch_finger_depth = 2.5;
 261
 262 catch_topcurve_r = 5.0;
 263
 264 prop_recess_under = 0.50;
 265 prop_recess_slop = 0.200; // each side
 266 prop_end_dia = 0.5;
 267 prop_main_th = 3;
 268 prop_taper_len = 6;
 269 prop_main_width = 4;
 270 prop_side_gap = 0.75; // each side
 271 prop_lidrecess_behind = 0.75;
 272 prop_caserecess_behind = 0.75;
 273 prop_caserecess_taper = 0.45; // one side only
 274 prop_prop_gap = 0.5;
 275 prop_prong_heel_slope = 0.5;
 276
 277 lid_fold_clearance_antislop = 0.5;
 278
 279 // ---------- calculated ----------
 280
 281 phone_width =  (phone + bumper*2)[0];
 282 phone_height = (phone + bumper*2)[1];
 283
 284 inside_br = [phone_width, -phone_height];
 285
 286 prop_prong_h = prop_main_th;
 287
 288 //echo(camera_pos_tl + bumper,
 289 //     camera_pos_br + bumper);
 290
 291 // ----- could be changed -----
 292 lid_buttoncover_gap = lid_gap_x;
 293 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 294
 295 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 296
 297 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 298
 299 //prop_nose_len = case_th_lid - prop_recess_under;
 300 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 301 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 302
 303
 304 //lid_lip_overlap_width xxx bad name = ;
 305 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 306
 307 epp0 = [0,0];
 308 epp1 = [0, -phone_edge_thick];
 309 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 310 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 311 epp3 = epp2i + [10, 0];
 312 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 313 epp4 = epp5 + [-1,0] * case_th_side;
 314
 315 kppe = [0,0];
 316 kppd = kppe + [1,0] * keeper_inner_width;
 317 kppc = kppd + [0,1] * keeper_th_z;
 318 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 319 kppf = kppe - [0,1] * keeper_inner_height;
 320 kppa = [ kppb[0], kppf[1] ];
 321
 322 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 323 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 324
 325 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 326 // exact x posn not very important; must extend past end of keeper
 327
 328 lpp15 = [ lpp14[0],
 329           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 330           + lid_screen_gap_extra ];
 331 // ^ beam theory says to maximise force before contact,
 332 //   the gap below the `beam' (the lid) must be 1/3
 333 //   the thickness (ie the lid thickness) if the beam
 334 //   is solid, or 1/2 if it has a top and bottom only.
 335 //   ours is mostly solid.
 336
 337 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 338              case_th_lip);
 339
 340 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 341 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 342
 343 case_bottom_z = epp2o[1] - case_th_bottom;
 344
 345 // button profile
 346 bppM = epp4 + [0,5];
 347 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 348 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 349 bppS = [ epp1[0], bppR[1] ];
 350 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 351 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 352 bppO = [ bppN[0], bppP[1] ];
 353 bppL = lpp10 + [5,0];
 354 bppK = [ bppL[0], bppN[1] ];
 355 bppJ = [ bppN[0], bppL[1] ];
 356 bppU = [ bppJ[0], lpp12[1] ];
 357 bppV = lpp11;
 358 bppW = lpp10;
 359
 360 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 361
 362 // notification led aperture
 363
 364 nla_r0 = led_aperture/2;
 365 nla_r1 = nla_r0 + led_window_ledge;
 366 nla_r2 = nla_r1 + multicolour_gap;
 367 nla_t =
 368   led_window_style >= 3 ? initial_layer_thick :
 369   led_window_style >= 2 ? led_window_ledge : 0;
 370
 371
 372 // hinge plan
 373 hp_rn = hingescrew_nut_access_dia/2;
 374 hp_r2_min = hp_rn + lever_cover_th;
 375 hp_rs = hingescrew_shaft_dia/2;
 376 hp_r1_min = hp_rs + hingemount_th;
 377
 378 hp_r1 = max(hp_r1_min, hp_r2_min);
 379 hp_r2 = hp_r1;
 380
 381 hppU = lpp13;
 382 hppS = epp2o + [0,-1] * case_th_bottom;
 383 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 384
 385 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 386          0.5 * (hppU + hppS)[1] ];
 387 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 388 hppB = hppT + [0,-1] * hp_k;
 389
 390 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 391 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 392 hppE = [ hppE_x, hppE_y ];
 393
 394 // hinge elevation x coords
 395
 396 hex20 = max(epp2o[0],
 397             phone_cnr_rad,
 398             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 399 hex21 = hex20 + hingemount_wd;
 400 hex22 = hex21 + hinge_x_gap;
 401 hex27 = hex20 + hingescrew_shaft_len;
 402 hex24 = hex27 + hinge_x_postscrew_gap;
 403 hex23 = hex27 - (hingescrew_nut_thick*2
 404                  + hingescrew_fasteners_extra_thick);
 405 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 406
 407 echo(hex20, hex21, hex22, hex23, hex24);
 408 //  6, 10.8725, 10.9975, 13.74, 18.75
 409 module chk(act,exp) {
 410   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 411   else echo("ok", act);
 412 }
 413 chk(hex20, 6);
 414 chk(hex21, 10.8725);
 415 chk(hex22, 10.9975);
 416 chk(hex23, 13.74);
 417 chk(hex24, 18.75);
 418
 419 lid_fold_clearance_skew =
 420   (lpp10[1] - hppB[1]) /
 421   (lpp10[0] - hppB[0]);
 422
 423 echo("SK",lid_fold_clearance_skew);
 424
 425 // catch
 426
 427 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 428 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 429 cppB = [ epp0[0], cppA[1] ];
 430 cppP = [ epp4[0], cppJ[1] ];
 431
 432 cppS = cppJ + [0,-1] * catch_len;
 433 cppD = [ cppA[0], cppS[1] + catch_slop ];
 434 cppC = [ cppB[0], cppD[1] ];
 435 cppT = cppS + [1,0] * catch_depth;
 436 cppU = cppT + [0,-1] * catch_height;
 437 cppV = [ cppS[0], cppU[1] - catch_depth ];
 438
 439 cppR = 0.5*(cppP + cppJ);
 440
 441 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 442 cppQ = [ cppR[0],
 443          cppV[1] - (catch_finger_height - cp_rQ) ];
 444 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 445
 446 // prop recess in case
 447
 448 prop_x_pos = phone_width/2;
 449
 450 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 451
 452 prc_r1 = prop_end_dia/2;
 453 prc_r3 = prc_r1 + prop_recess_slop;
 454
 455 prcp2 = [ epp4[0] + prop_buildout_less,
 456           case_bottom_z ];
 457
 458 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 459
 460 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 461           epp2i[1] - prc_r3 - prop_recess_under];
 462
 463 // prop recess in lid
 464
 465 prl_r10 = prop_end_dia/2;
 466 prl_r10o = prl_r10 + prop_recess_slop;
 467
 468 prlp10 = lpp10 + [1,1] * prl_r10o
 469   + [1,0] * prop_lidrecess_behind
 470   + [0,1] * prop_recess_under;
 471
 472 // prop
 473
 474 $prpp10 = [0,0];
 475 $prpp11 = [0, prop_taper_len];
 476
 477 $prp_r10 = prl_r10;
 478
 479 // ---------- modules ----------
 480
 481 module AdhocMultiprintFrame(phase, z0, zs) {
 482   // from z0 to z0 + zs*layer
 483   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 484   xextra = extra + -epp4[0];
 485   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 486   yextra = extra + -epp4[0];
 487   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 488   p0 = [ xrange[0], yrange[0] ];
 489   p1 = [ xrange[1], yrange[1] ];
 490   echo(p0, p1);
 491   translate([0,0, z0])
 492     mirror([0,0, zs<0 ? 1 : 0])
 493     linear_extrude(height= initial_layer_thick)
 494     difference(){
 495       rectfromto(p0 - [1,1] * initial_layer_width,
 496                  p1 + [1,1] * initial_layer_width);
 497       rectfromto(p0, p1);
 498     }
 499 }
 500
 501 module KeeperProfile(slant=0){
 502   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 503   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 504 }
 505
 506 module EdgeProfile(){
 507   difference(){
 508     hull(){
 509       translate(epp3) square(case_th_bottom*2, center=true);
 510       circleat(epp2o, r=case_th_bottom);
 511       circleat(epp1, r=case_th_side);
 512       rectfromto(epp0, epp4);
 513     }
 514     polygon([ epp5 + [0,10],
 515               epp1,
 516               epp2i,
 517               epp3 + [10,0] ]);
 518   }
 519 }
 520
 521 module LidEdgeProfile(){
 522   polygon([ lpp10,
 523             lpp11,
 524             lpp12,
 525             lpp13,
 526             lpp13 + [10, 0],
 527             lpp15 + [10, 0],
 528             lpp15,
 529             lpp14,
 530             ]);
 531   intersection(){
 532     circleat(lpp12, r=lp_r12);
 533     rectfromto( lpp12 + [-10,   0],
 534                 lpp12 + [+10, +10] );
 535   }
 536 }
 537
 538 module LidEdgeFoldClearanceProfile(){
 539   translate([-lid_fold_clearance_antislop, 0])
 540     polygon([ lpp10,
 541               lpp11,
 542               lpp11 + [-20,  0],
 543               lpp11 + [-20, 20],
 544               lpp11 + [+20, 20],
 545               lpp10 + [+20,  0] ]);
 546 }
 547
 548 module ButtonCoverProfile(){
 549   intersection(){
 550     polygon(concat([ bppM, bppP, bppO, bppJ ],
 551                    (enable_support && !$button_suppress_over_keeper
 552                     ? [ bppU, bppV, bppW ] : []),
 553                    [ bppL, bppK ]));
 554     hull(){
 555       EdgeProfile();
 556       LidEdgeProfile();
 557     }
 558   }
 559 }
 560
 561 module ButtonPlan(l, deep, cut){
 562   epsilon =
 563     (cut  ? 0 : lid_buttoncover_gap);
 564
 565   delta =
 566     (deep ? lid_buttoncover_overlap : 0);
 567
 568   C = [0,0]; // by definition
 569   T = [ 0, epp4[1] ];
 570   G = T + [0,10];
 571
 572   B0 = C + [0,-1] * button_cutout_depth;
 573   B1 = B0 + [0,1] * epsilon;
 574
 575   r0 = 0.5 * (T[1] - B0[1]);
 576   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 577   H = A + [0,-1] * delta;
 578
 579   D = A + [-2,0] * r0;
 580   F = D + [0,10];
 581
 582   E0 = 0.5 * (D + A);
 583   E1 = E0 + [1,0] * epsilon;
 584
 585   I0 = [ E0[0], H[1] ];
 586   I1 = [ E1[0], H[1] ];
 587
 588   hull(){
 589     for (m=[0,1]) mirror([m,0])
 590       circleat(H, r0 - epsilon);
 591   }
 592   for (m=[0,1]) mirror([m,0]) {
 593     difference(){
 594       polygon([ E1,
 595                 I1,
 596                 H,
 597                 B1,
 598                 G,
 599                 F,
 600                 D
 601                 ]);
 602       circleat(D, r0 + epsilon);
 603     }
 604   }
 605 }
 606
 607 module CatchCatchProfile(){
 608   hull(){
 609     for (c=[ cppR, cppQ ])
 610       circleat(c, cp_rQ);
 611   }
 612   hull(){
 613     circleat(lpp12, lp_r12);
 614     circleat(lpp12 + [5,0], lp_r12);
 615     rectfromto(cppP, cppP + [5,0.1]);
 616   }
 617   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 618 }
 619
 620 module CatchCutProfile(){
 621   polygon([ cppB,
 622             cppA,
 623             cppD,
 624             cppF,
 625             cppF + [0,-10],
 626             cppF + [-10,-10],
 627             lpp12 + [-10,0],
 628             lpp12 + [10,0]
 629             ]);
 630 }
 631
 632 module Flip_rhs(yn=[0,1]) {
 633   for ($rhsflip=yn) {
 634     translate([phone_width/2, 0, 0])
 635       mirror([$rhsflip,0,0])
 636       translate([-phone_width/2, 0, 0])
 637       children();
 638   }
 639 }
 640
 641 module Flip_bot(yn=[0,1]) {
 642   for ($botflip=yn) {
 643     translate([0, -phone_height/2, 0])
 644       mirror([0, $botflip, 0])
 645       translate([0, phone_height/2, 0])
 646       children();
 647   }
 648 }
 649
 650 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 651   // sides
 652   Flip_rhs(){
 653     translate([0, -phone_cnr_rad, 0])
 654       rotate([90,0,0])
 655       linear_extrude(height = phone_height - phone_cnr_rad*2)
 656       children(0);
 657   }
 658   // corners
 659   Flip_rhs() Flip_bot() {
 660     translate([+1,-1] * phone_cnr_rad)
 661       intersection(){
 662         rotate_extrude()
 663           intersection(){
 664             mirror([1,0,0])
 665               translate([-1,0] * phone_cnr_rad)
 666               children(0);
 667             rectfromto([0,-20],[10,20]);
 668           }
 669         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 670           cube([10,10,40]);
 671       }
 672   }
 673   // top and bottom
 674   Flip_bot(){
 675     translate([ phone_width - phone_cnr_rad, 0,0 ])
 676       rotate([90,0,-90])
 677       linear_extrude(height = phone_width - phone_cnr_rad*2)
 678       children(0);
 679   }
 680   // fill
 681   translate([0,0, fill_zstart])
 682     mirror([0,0, fill_downwards])
 683     linear_extrude(height = fill_th)
 684     rectfromto([+1,-1] * phone_cnr_rad,
 685                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 686 }
 687
 688 module CaseAperture(pos, dia, $fn) {
 689   theta = 180/$fn;
 690   translate([ pos[0] + bumper[0],
 691               -epp2i[0],
 692               -pos[1] ])
 693     rotate([-90, theta, 0])
 694     cylinder(r = dia/2 / cos(theta),
 695              h = 60);
 696 }
 697
 698 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 699   // y_ref_sign:
 700   //   +1  measured from top    of actual phone to top    of button
 701   //   -1  measured from bottom of actual phone to bottom of button
 702   //    0  y is centre of button in coordinate system
 703   $button_l= l;
 704   $button_suppress_over_keeper= suppress_over_keeper;
 705   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 706           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 707           y;
 708   //echo(eff_y);
 709   translate([0, eff_y, 0])
 710     children();
 711 }
 712
 713 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 714   $button_leg_only = true;
 715   SideButton(y, y_ref_sign, l) children();
 716 }
 717
 718 module Buttons(){
 719   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 720   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 721   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 722   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 723 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 724 }
 725
 726 module Struts(x_start, z_min, th){
 727   // if th is negative, starts at z_min and works towards -ve z
 728   // and object should then be printed other way up
 729   for (i= [1 : 1 : case_struts_count]) {
 730     translate([0,
 731                0,
 732                z_min])
 733       mirror([0,0, th<0 ? 1 : 0])
 734       translate([0,
 735                  -phone_height * i / (case_struts_count+1),
 736                  case_struts_solid_below])
 737       linear_extrude(height= abs(th)
 738                      -(case_struts_solid_below+case_struts_solid_above))
 739       rectfromto([               x_start, -0.5 * case_struts_width ],
 740                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 741   }
 742 }
 743
 744 module OrdinaryRearAperture(rhs,bot, pos){
 745   Flip_rhs(rhs) Flip_bot(bot)
 746     linextr(-20, 20)
 747     mirror([0,1])
 748     translate(pos + bumper)
 749     children();
 750 }
 751
 752 module MicroUSB(){
 753   Flip_bot(1){
 754     rotate([90,0,0])
 755       mirror([0,0,1])
 756       linextr(-epp2i[0], 60)
 757       translate([0.5 * phone_width, 0, 0])
 758       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 759                  [+microusb_width/2, epp0[1] + -microusb_above]);
 760   }
 761 }
 762
 763 module OrdinaryRearApertures(){
 764   // rear speaker
 765   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 766     rectfromto(-rearspeaker_gap,
 767                rearspeaker_size + rearspeaker_gap);
 768
 769   // finger hole to remove phone
 770   if (len(fingerpushhole_dias))
 771     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 772                                 phone[1]/2 ])
 773     scale(fingerpushhole_dias)
 774     circle(r= 0.5 );
 775 }
 776
 777 module RearCameraAperture(){
 778   Flip_rhs(1)
 779     mirror([0, 0, 1])
 780     linear_extrude(height = 20)
 781     mirror([0, 1, 0])
 782     translate(bumper)
 783     rectfromto(camera_pos_tl, camera_pos_br);
 784 }
 785
 786 module HingeLidProfile(){
 787   hull(){
 788     circleat(hppT, hp_r1);
 789     circleat(lpp12, lp_r12);
 790     polygon([lpp10,
 791              lpp13 + [2,0],
 792              lpp12,
 793              hppT]);
 794   }
 795 }
 796
 797 module HingeBaseProfile(){
 798   difference(){
 799     hull(){
 800       circleat(hppB, hp_r1);
 801       circleat(hppE, hp_r1);
 802       circleat(epp2o, case_th_bottom);
 803       circleat(hppB + [10,0], hp_r1);
 804     }
 805     polygon([epp5, epp1, epp2i, epp3, bppL]);
 806   }
 807 }
 808
 809 module HingeLeverOuterProfile(){
 810   hull(){
 811     circleat(hppT, hp_r2);
 812     circleat(hppB, hp_r2);
 813   }
 814 }
 815
 816 module HingeLeverInnerProfile(){
 817   for (s = [-1,+1]) {
 818     c = s > 0 ? hppT : hppB;
 819     translate(c)
 820       mirror([0,0,s>0])
 821       rotate(s<0 ? -40 : 0)
 822       hull()
 823       for (x=[-20,20])
 824         for (y=[0, s * 10])
 825           translate([x,y])
 826             circle(hp_rn);
 827   }
 828 }
 829
 830 module HingeLeverNutProfile(){
 831   for (c= [hppB, hppT]) {
 832     translate(c)
 833       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 834   }
 835 }
 836
 837 module Flip_hinge(doflip=1){
 838   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 839   translate(hinge_origin)
 840     rotate([doflip*180,0,0])
 841     translate(-hinge_origin)
 842     children();
 843 }
 844
 845 module HingePortion(x0,x1){
 846   Flip_rhs() Flip_bot(1)
 847     translate([x0,0,0])
 848     mirror([1,0,0])
 849     rotate([90,0,-90])
 850     linear_extrude(height=x1-x0)
 851     children();
 852 }
 853
 854 module CatchPortion(xwidth, ztop){
 855   width = catch_width + xwidth;
 856   w = width + catch_topcurve_r*2 + 1;
 857   translate([phone_width/2, 0,0]){
 858     difference(){
 859       rotate([90,0,-90])
 860         linextr(-w/2, w/2)
 861         children(0);
 862       translate([0, 50, 0])
 863         rotate([90,0,0])
 864         linear_extrude(height=100){
 865         for (m=[0,1]) mirror([m,0,0]) {
 866           hull(){
 867             translate([w/2, ztop - catch_topcurve_r])
 868               circle(catch_topcurve_r);
 869             translate([w/2, -50])
 870               square(catch_topcurve_r*2, center=true);
 871           }
 872         }
 873       }
 874     }
 875   }
 876 }
 877
 878 module CaseBase(){
 879   AroundEdges(epp3[1], case_th_bottom, 1)
 880     EdgeProfile();
 881 }
 882
 883 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 884
 885 module PropProfileAssignments(gamma){
 886   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 887   x = prop_x(gamma);
 888   p = phone_height + prlp10[0] - hppB[0];
 889   b = p + x;
 890
 891   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 892   a = q + x;
 893   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 894   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 895
 896   $prp_theta = 90 - $prp_alpha;
 897   beta = 180 - $prp_alpha - gamma;
 898   psi = 90 - beta;
 899
 900   //echo("abc", a,b,c);
 901
 902   v1 = [ [ cos(psi), -sin(psi) ],    // x
 903          [ sin(psi),  cos(psi) ] ];  // y
 904
 905   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 906
 907   $prp_r1 = prc_r1;
 908   $prp_r11 = prop_main_th/2;
 909
 910   $prpp1 = $prpp7 + [1,0] *
 911     // this is approximate, but will do
 912     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 913   $prpp3 = $prpp1 +
 914     v1[0] * -$prp_r1 +
 915     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 916   $prpp12 = $prpp3 + v1[0] *
 917     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 918   $prp_r8 = prop_main_th;
 919   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 920   $prp_r5 = $prp_r8;
 921   $prpp5 = [ $prpp12[0] - $prp_r5,
 922             $prpp3[1] - prop_prong_h + $prp_r5 ];
 923   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 924          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 925   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 926   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 927
 928   children();
 929 }
 930
 931 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 932   PropProfileAssignments(gamma){
 933
 934     //#circleat($prpp3,1);
 935     //#circleat($prpp12,1);
 936
 937     if (!cut) {
 938       hull(){
 939         translate($prpp8)
 940           intersection(){
 941             circle($prp_r8);
 942             polygon([[-20,-0], [20,20], [0,0]]);
 943           }
 944         rectfromto($prpp6, $prpp9);
 945         translate($prpp5) intersection(){
 946           circle($prp_r5);
 947           polygon([[-10,-10], [0,0], [10,0]]);
 948         }
 949         rectfromto($prpp12 + [0,-0.1], $prpp3);
 950       }
 951       hull(){
 952         circleat($prpp1, $prp_r1);
 953         rectfromto($prpp12 + [0,-0.1], $prpp3);
 954       }
 955     }
 956     // main shaft
 957     rotate([0,0, rot*-$prp_theta]){
 958       hull(){
 959         extra = cut ? prop_recess_slop : 0;
 960         rectfromto($prpp6, $prpp9);
 961         circleat($prpp11, $prp_r11 + extra);
 962         circleat($prpp10, $prp_r10 + extra);
 963       }
 964     }
 965   }
 966 }
 967
 968 module PropAggregateProfile(){
 969   for (angle = prop_angles)
 970     PropProfile(angle, 0,0);
 971 }
 972
 973 module Prop(){ ////toplevel
 974   hw = prop_main_width/2;
 975   linextr(-hw, +hw)
 976     PropAggregateProfile();
 977 }
 978
 979 module Case(){ ////toplevel
 980   difference(){
 981     union(){
 982       CaseBase();
 983
 984       // ledge (fixed keeper)
 985       Flip_rhs(1-keeper_side) intersection(){
 986         rotate([90, 0, 0])
 987           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 988           KeeperProfile(1);
 989
 990         // outline of the whole case, to stop it protruding
 991         translate([0,0, -25])
 992           linear_extrude(height = 50)
 993           hull()
 994           Flip_bot()
 995           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 996       }
 997
 998       // hinge
 999       HingePortion(hex20, hex21) HingeBaseProfile();
1000
1001       // buildout for prop recess
1002       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1003         linextr(case_bottom_z, epp2i[1])
1004         hull() {
1005           for (dxs = [-1,+1])
1006             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1007                        -epp2o[0] ],
1008                      r = epp2o[0] - prcp2[0]);
1009         }
1010     }
1011
1012     // slot for keeper
1013     Flip_rhs(keeper_side)
1014       translate([0, -phone_cnr_rad, 0])
1015       rotate([90, 0, 0])
1016       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1017       minkowski(){
1018         KeeperProfile();
1019         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1020                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1021       }
1022
1023     // front camera
1024     RearCameraAperture();
1025
1026     // struts (invisible, because they're buried in the case)
1027     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1028
1029     Buttons(){
1030       mirror([1,0,0])
1031         rotate([90,0,90]) {
1032           if (!($button_leg_only && enable_support))
1033           intersection(){
1034             translate([0,0,-10])
1035               linear_extrude(height= 20)
1036               ButtonPlan($button_l, 0,1);
1037             if ($button_leg_only)
1038               rotate([-90,90,0])
1039                 translate([phone_width/2, -400, kppe[1]])
1040                 mirror([1-abs($rhsflip - keeper_side),0,0])
1041                 cube([400, 800, 50]);
1042             if (enable_support && !$button_suppress_over_keeper)
1043               rotate([-90,90,0])
1044               translate([-400, -400, kppd[1]])
1045                 mirror([0,0,1])
1046                 cube([800,800,100]);
1047           }
1048           translate([0,0, -bppR[0]])
1049             linear_extrude(height= 20)
1050             ButtonPlan($button_l, 1,1);
1051         }
1052
1053     }
1054
1055     // apertures along top edge
1056     CaseAperture(jack_pos, jack_dia, 8);
1057     Flip_rhs(1)
1058       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1059
1060     OrdinaryRearApertures();
1061
1062     MicroUSB();
1063
1064     // gaps for the lid's hinge arms
1065     HingePortion(hex20 - hinge_x_arms_gap,
1066                  hex21 + hinge_x_arms_gap)
1067       minkowski(){
1068         HingeLidProfile();
1069         circle(r= hinge_r_arms_gap, $fn= 8);
1070       }
1071
1072     // screw holes in the hinge arms
1073     HingeScrews();
1074
1075     // catch striker
1076     CatchPortion(catch_side_gap*2, epp4[1])
1077       CatchCutProfile();
1078
1079     // prop recess
1080     Flip_rhs(1)
1081       translate([prop_x_pos,0,0])
1082       mirror([0,1,0])
1083       rotate([90,0,90])
1084       linextr(-prop_recess_hw, +prop_recess_hw)
1085       hull(){
1086         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1087           circleat(prcp1 + 20*d,
1088                    prc_r3);
1089       }
1090   }
1091 }
1092
1093 module LidAdhocMultiprintFrame(phase){
1094   if (led_window_style >= 3) {
1095     AdhocMultiprintFrame(phase, lpp13[1], -1);
1096   }
1097 }
1098
1099 module LidAroundEdges(){
1100   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1101     children();
1102 }
1103
1104 module Lid(){ ////toplevel
1105   skew_centre = [0, lpp11[0], lpp11[1]];
1106   difference(){
1107     union(){
1108       intersection(){
1109         LidAroundEdges()
1110           LidEdgeProfile();
1111
1112         translate(skew_centre)
1113           multmatrix([[ 1, 0, 0, 0 ],
1114                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1115                       [ 0, 0, 1, 0 ],
1116                       [ 0, 0, 0, 1 ]])
1117           translate(-skew_centre)
1118           LidAroundEdges()
1119           LidEdgeFoldClearanceProfile();
1120       }
1121
1122       // button covers
1123       Buttons(){
1124         intersection(){
1125           rotate([90,0,90])
1126             translate([0,0,-10])
1127             linear_extrude(height= 20)
1128             ButtonPlan($button_l, 1,0);
1129           rotate([90,0,0])
1130              translate([0,0,-100])
1131             linear_extrude(height= 200)
1132             ButtonCoverProfile();
1133         }
1134       }
1135
1136       // hinge arms
1137       HingePortion(hex20, hex21) {
1138         LidEdgeProfile();
1139         HingeLidProfile();
1140       }
1141
1142       // catch
1143       CatchPortion(0, lpp12[1])
1144         CatchCatchProfile();
1145     }
1146     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1147
1148     // screw holes in the hinge arms
1149     HingeScrews();
1150
1151     // prop recess
1152     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1153       mirror([0,1,0])
1154       rotate([90,0,90])
1155       linextr(-prop_recess_hw, +prop_recess_hw)
1156       hull()
1157       for (pa = prop_angles)
1158         PropProfile(pa, 1,1);
1159
1160     // notification led aperture
1161     if (led_window_style)
1162       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1163         translate([0,0,-10])
1164           cylinder(r=nla_r0, h=20);
1165         if (led_window_style >= 2)
1166           translate([0,0, -nla_t])
1167             cylinder(r=nla_r2, height=20);
1168       }
1169
1170     }
1171
1172   LidAdhocMultiprintFrame(1);
1173 }
1174
1175 module HingeLever(){ ////toplevel
1176   difference() {
1177     // outer body, positive
1178     HingePortion(hex22, hex22 + phone_width/2)
1179       HingeLeverOuterProfile();
1180
1181     // space for the screws
1182     HingePortion(hex26, hex24)
1183       HingeLeverInnerProfile();
1184
1185     // recesses for the nuts
1186     HingePortion(hex23, hex26+1)
1187       HingeLeverNutProfile();
1188
1189     // bores for the screws
1190     HingeScrews();
1191
1192     // space for the charging cable
1193     MicroUSB();
1194     Flip_hinge() MicroUSB();
1195   }
1196 }
1197
1198 module LidWindow(){ ////toplevel
1199   translate([led_pos[0], -led_pos[1], lpp13[1]])
1200     mirror([0,0,1])
1201     cylinder(r= nla_r1, h=nla_t);
1202   LidAdhocMultiprintFrame(0);
1203 }
1204
1205 module LidWindowPrint(){ ////toplevel
1206   rotate([0,180,0])
1207     LidWindow();
1208 }
1209
1210 module DemoLidWindowSelect(){
1211   translate([led_pos[0], led_pos[1], -100]) {
1212     translate([0, -30, 0]) cube([400, 400, 200]);
1213   }
1214 }
1215
1216 module DemoLidWindow(){ ////toplevel
1217   %Lid();
1218   LidWindow();
1219   translate([0,40,0]){
1220     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1221     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1222   }
1223 }
1224
1225 module HingeLeverPrint(){ ////toplevel
1226   rotate([-90,0,0])
1227     translate([-phone_width/2, phone_height, 0])
1228     HingeLever();
1229 }
1230
1231 module TestSelectLength(){
1232   translate([-30, -200, -20])
1233     cube([30 + 15, 250, 40]);
1234 }
1235
1236 module TestLength(){ ////toplevel
1237   intersection(){
1238     Case();
1239     TestSelectLength();
1240   }
1241 }
1242
1243 module TestLengthRight(){ ////toplevel
1244   intersection(){
1245     Case();
1246     Flip_rhs(1)
1247       TestSelectLength();
1248   }
1249 }
1250
1251 module TestSelectWidth(){
1252   translate([-30, -(phone_height - 25), -20])
1253     mirror([0, 1, 0])
1254     cube([200, 50, 40]);
1255 }
1256
1257 module TestWidth(){ ////toplevel
1258   intersection(){
1259     Case();
1260     TestSelectWidth();
1261   }
1262 }
1263
1264 module TestLidWidthPrint(){ ////toplevel
1265   rotate([0,180.0]) intersection(){
1266     Lid();
1267     TestSelectWidth();
1268   }
1269 }
1270
1271 module TestSelectRearAperture(){
1272   minkowski(){
1273     union() children();
1274     translate([20, 0,0])
1275       cube([42, 2, 1], center=true);
1276   }
1277 }
1278
1279 module TestSelectCamera(){
1280   minkowski(){
1281     TestSelectRearAperture()
1282       RearCameraAperture();
1283     cube([0.1, 50, 0.1]);
1284   }
1285 }
1286
1287 module TestSelectOrdinaryRearApertures(){
1288   TestSelectRearAperture()
1289     OrdinaryRearApertures();
1290 }
1291
1292 module TestCamera(){ ////toplevel
1293   intersection(){
1294     Case();
1295     TestSelectCamera();
1296   }
1297 }
1298
1299 module TestLidByCamera(){ ////toplevel
1300   intersection(){
1301     Lid();
1302     TestSelectCamera();
1303   }
1304 }
1305
1306 module TestLidByCameraPrint(){ ////toplevel
1307   rotate([180,0,0]) TestLidByCamera();
1308 }
1309
1310 module DemoByCamera(){ ////toplevel
1311   color("blue") TestLidByCamera();
1312   color("red")  TestCamera();
1313 }
1314
1315 module OneKeeper(){ ////toplevel
1316   translate([0, -phone_cnr_rad, 0])
1317     rotate([90, 0, 0])
1318     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1319     KeeperProfile();
1320 }
1321
1322 module OneKeeperPrint(){ ////toplevel
1323   rotate([0,180,0])
1324     OneKeeper();
1325 }
1326
1327 module LidPrint(){ ////toplevel
1328   rotate([0,180,0])
1329     Lid();
1330 }
1331
1332 module TestSelectFrame(){
1333   include = [1,-1] * (epp2i[0] + 4);
1334
1335   difference(){
1336     cube(1000, center=true);
1337     translate([0,0, -100])
1338       linear_extrude(height=200)
1339       rectfromto(include,  inside_br - include);
1340   }
1341 }
1342
1343 module TestSelectLidFrame(){
1344   TestSelectFrame();
1345   translate([led_pos[0], -led_pos[1], -50])
1346     cylinder(r= nla_r2+3, h=100);
1347 }
1348
1349 module TestFrameCase(){ ////toplevel
1350   intersection(){
1351     Case();
1352     union(){
1353       TestSelectFrame();
1354       TestSelectCamera();
1355       TestSelectOrdinaryRearApertures();
1356     }
1357   }
1358 }
1359
1360 module TestSelectTopApertures(){
1361   translate([-100, -35, -100])
1362     cube([400, 100, 200]);
1363   LidAdhocMultiprintFrame(0);
1364   LidAdhocMultiprintFrame(1);
1365 }
1366
1367 module TestTopApertures(){ ////toplevel
1368   intersection(){
1369     Case();
1370     TestSelectFrame();
1371     TestSelectTopApertures();
1372   }
1373 }
1374
1375 module TestLidTopAperturesPrint(){ ////toplevel
1376   rotate([0,180,0]) intersection(){
1377     Lid();
1378     TestSelectLidFrame();
1379     TestSelectTopApertures();
1380   }
1381 }
1382
1383 module TestLidWindowTopAperturesPrint(){ ////toplevel
1384   rotate([0,180,0]) intersection(){
1385     LidWindow();
1386     TestSelectTopApertures();
1387   }
1388 }
1389
1390 module TestFrameLidPrint(){ ////toplevel
1391   rotate([0,180,0]) intersection(){
1392     Lid();
1393     TestSelectLidFrame();
1394   }
1395 }
1396
1397 module ButtonPlanForDemo(z, deep, cut){
1398   translate([0,0,z])
1399     ButtonPlan(8, deep, cut);
1400 }
1401
1402 module HingeScrews(){
1403   Flip_rhs() Flip_bot(1){
1404     for (c= [ hppT, hppB ])
1405       translate([ hex20,
1406                   -c[0],
1407                   c[1] ]){
1408         rotate([0,90,0])
1409           translate([0,0,-.2])
1410           cylinder( r= hingescrew_shaft_dia/2,
1411                     h = hingescrew_shaft_len+0.2 );
1412         rotate([0,-90,0])
1413           translate([0,0,+.1])
1414           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1415       }
1416   }
1417 }
1418
1419 module DemoPropAngleSelect(c){
1420   color(c) difference(){
1421     union(){ children(); }
1422     translate([ prop_x_pos, -400, -200 ])
1423       cube([ 400,800,400 ]);
1424   }
1425 }
1426
1427 module DemoPropAngle(ang){
1428   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1429   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1430
1431   translate(hL)
1432     rotate([ang/2,0,0])
1433     translate(-hL)
1434     translate(hC)
1435     rotate([ang/2,0,0])
1436     translate(-hC) {
1437       DemoPropAngleSelect("red") Case();
1438
1439       color("orange")
1440         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1441         PropProfileAssignments(ang) {
1442           echo($prpp1);
1443           rotate([-$prp_theta, 0, 0])
1444           translate([0, $prpp1[0], -$prpp1[1]])
1445           rotate([90,0,-90])
1446           Prop();
1447         }
1448     }
1449
1450   translate([0,0, -hp_k*2])
1451     DemoPropAngleSelect("blue")
1452     Lid();
1453 }
1454
1455 module DemoPropAngles(){ ////toplevel
1456   for (i=[0 : len(prop_angles)-1])
1457     translate(i * [0, -100, 100])
1458     DemoPropAngle(prop_angles[i]);
1459 }
1460
1461 module DemoHingeAngle(ang1,ang2){
1462   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1463   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1464
1465   translate(hL)
1466     rotate([ang2,0,0])
1467     translate(-hL)
1468     translate(hC)
1469     rotate([ang1,0,0])
1470     translate(-hC) {
1471       color("red") Lid();
1472     }
1473
1474   color("blue") intersection(){
1475     Case();
1476     union(){
1477       translate([bppJ[0], -400, -200])
1478         mirror([1,0,0])
1479         cube([400, 800, 400]);
1480       translate([10, -400, -200])
1481         cube([10, 800, 400]);
1482     }
1483   }
1484 }
1485
1486 module DemoHingeAngles(){ ////toplevel
1487   angles = [ 0, 4, 8, 12 ];
1488   echo("angles",angles);
1489   for (i=[0 : len(angles)-1]) {
1490     translate(i * [0, 0, 30]) {
1491       DemoHingeAngle(0,angles[i]);
1492       translate([0, 200, 0])
1493         DemoHingeAngle(angles[i],0);
1494     }
1495   }
1496 }
1497
1498 module DemoSelectAdhocLeftRight(right=0) {
1499   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1500     mirror([1-right, 0,0])
1501     cube([400, 800, 200]);
1502 }
1503
1504 module DemoLeft(){ ////toplevel
1505   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1506   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1507 }
1508
1509 module DemoFrame(){ ////toplevel
1510   color("red") TestFrameCase();
1511   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1512   color("black") HingeScrews();
1513   %HingeLever();
1514 }
1515
1516 module DemoHingedFrame(){ ///toplevel
1517   color("red") TestFrameCase();
1518   translate([0,0, -2*hp_k])
1519   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1520
1521   Flip_hinge(){
1522     color("orange") HingeLever();
1523     color("black") HingeScrews();
1524   }
1525 }
1526
1527 module DemoHinge(){ ////toplevel
1528   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1529     DemoFrame();
1530     translate([0,0, -hp_k*3])
1531       DemoHingedFrame();
1532   }
1533 }
1534
1535 module DemoProfiles(){ ////toplevel
1536   LidEdgeProfile();
1537   %EdgeProfile();
1538   KeeperProfile();
1539   translate([0,0,-1]) color("black") KeeperProfile(1);
1540
1541   translate([20,0]) {
1542     LidEdgeProfile();
1543     %EdgeProfile();
1544
1545     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1546
1547     color("blue") ButtonCoverProfile();
1548     color("red") {
1549       rectfromto(bppQ, demopoint_QR);
1550       rectfromto(bppR, demopoint_QR);
1551     }
1552   }
1553
1554   translate([-20,0]) {
1555     color("black") ButtonPlanForDemo(-2, 0,1);
1556     color("red" )  ButtonPlanForDemo(-4, 1,1);
1557     color("blue")  ButtonPlanForDemo(-6, 1,0);
1558   }
1559
1560   translate([0, -30]) {
1561     %LidEdgeProfile();
1562     %EdgeProfile();
1563     color("blue") HingeLidProfile();
1564     color("red")  HingeBaseProfile();
1565     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1566   }
1567
1568   for (f=[0,1]) {
1569     translate([-30, -60 + 30*f]) {
1570       translate([0,0,-4]) EdgeProfile();
1571       %translate([0,0,-10]) HingeBaseProfile();
1572       translate([0,-2] * f * hp_k) {
1573         translate([0,0,-4]) LidEdgeProfile();
1574         %translate([0,0,-10]) %HingeLidProfile();
1575       }
1576       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1577         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1578         translate([0,0,0]) color("red") difference(){
1579           HingeLeverOuterProfile();
1580           HingeLeverInnerProfile();
1581         }
1582         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1583       }
1584     }
1585   }
1586
1587   translate([20,-30]) {
1588     %EdgeProfile();
1589     %LidEdgeProfile();
1590     //translate([0,0,1]) CatchCutProfile();
1591     color("blue") CatchCatchProfile();
1592     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1593   }
1594
1595   translate([40,-30]) {
1596     difference(){
1597       LidEdgeProfile();
1598       translate(prlp10)
1599         PropProfile(10, 1, 0);
1600     }
1601     translate(prlp10)
1602       PropProfile(15, 0);
1603   }
1604   translate([60,-30]) {
1605     PropAggregateProfile();
1606   }
1607 }
1608
1609 //EdgeProfile();
1610 //KeeperProfile();
1611 //CaseBase();
1612 //%Case();
1613 //Keeper();
1614 //LidEdgeProfile();
1615 //KeeperProfile();
1616 //DemoProfiles();
1617 //PropRecess();