fairphone-case.scad

   1 // -*- C -*-
   2
   3 include <utils.scad>
   4
   5 phone = [ 75.0, 145.0 ];
   6
   7 bumper = [ 0.250, -0.025 ];
   8 // ^ One side.  Overall size is increased by twice this.
   9 // If no bumpers, is the gap around the phone.
  10
  11 phone_cnr_rad = 6.0;
  12
  13 button_cutout_depth = 9;
  14
  15 phone_edge_thick = 9.0;
  16 phone_total_thick = 12.0;
  17 phone_backside_slope_inner = 1.5; // larger means shallower
  18 phone_backside_slope_outer = 1.0; // larger means shallower
  19
  20 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  21 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  22
  23 jack_pos = [ 13.92, 7.96 ];
  24 jack_dia = 9.1 + .5; // some jack I had lying around
  25
  26 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  27 noisecancelmic_dia = 1.75;
  28
  29 fingerpushhole_dias = [ 15, 18 ];
  30
  31 rearspeaker_pos_bl = [ 12.64, 18.72 ];
  32 rearspeaker_size   = [  3.76,  7.36 ];
  33
  34 microusb_above = 3.27 - 0.25;
  35 microusb_below = 0.0;
  36 microusb_width = 16.12 + 0.25;
  37
  38 case_th_bottom = 2.5;
  39 case_th_lid = 2.5;
  40 case_th_side = 2;
  41 case_th_lip = 1.2;
  42
  43 case_struts_count = 6;
  44 case_struts_solid_below = 1.00;
  45 case_struts_solid_above = 0.75;
  46 case_struts_width = 0.10;
  47
  48 keeper_th_z = 0.75;
  49 keeper_th_x = 0.75;
  50 keeper_inner_width = 2.75;
  51 keeper_inner_height = 2.75;
  52 keeper_slant_slope = 2; // larger means steeper
  53
  54 keeper_gap_z_top = 0.25;
  55 keeper_gap_z_bot = 0.75;
  56 keeper_gap_x     = 0.25;
  57 keeper_gap_x_holes = 0.75;
  58
  59 keeper_side = 0; // 0 = lhs; 1 = rhs
  60
  61 case_lip = 1.25;
  62
  63 lid_gap_x = 0.25;
  64 lid_gap_z = 0.25;
  65 lid_lip = 1.75;
  66
  67 catch_slop = 0.25;
  68
  69 foldover_gap = 0.50;
  70 foldover_lever_gap = 0.50;
  71
  72 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
  73 hingescrew_shaft_len = 12;
  74 hingescrew_nut_thick = 1.93 + 0.20; // incl. washer
  75 hingescrew_nut_dia = 4.72 + 0.50; // washer, actually
  76 hingescrew_head_th = 1.38 + 0.75;
  77 hingescrew_head_dia = 3.92;
  78 lever_cover_th = 0.75;
  79 hingemount_th = 2.5;
  80
  81 $fa = 5;
  82 $fs = 0.1;
  83
  84 button_l_fudge = 4.4;
  85 buttonishleg_default_l_is_fudge = 10;
  86
  87 hinge_base_slope = 1.5; // bigger is steeper
  88
  89 strut_min_at_end = 1.5;
  90
  91 hinge_x_gap = 0.125;
  92 hinge_x_postscrew_gap = 0.75;
  93 hinge_x_arms_gap = 0.35;
  94 hinge_r_arms_gap = 0.55;
  95
  96 rearspeaker_gap    = [ 1.0, 1.0 ]; // each side
  97
  98 catch_len = 7.5;
  99 catch_width = 15;
 100 catch_thickness = 1.0;
 101 catch_side_gap = 0.75; // each side
 102
 103 catch_depth = 1.25;
 104 catch_height = 0.35;
 105 catch_finger_height = 1.5;
 106 catch_finger_depth = 2.5;
 107
 108 // ---------- calculated ----------
 109
 110 phone_width =  (phone + bumper*2)[0];
 111 phone_height = (phone + bumper*2)[1];
 112
 113 inside_br = [phone_width, -phone_height];
 114
 115 //echo(camera_pos_tl + bumper,
 116 //     camera_pos_br + bumper);
 117
 118 // ----- could be changed -----
 119 lid_buttoncover_gap = lid_gap_x;
 120 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 121
 122 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 123
 124 //lid_lip_overlap_width xxx bad name = ;
 125 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 126
 127 epp0 = [0,0];
 128 epp1 = [0, -phone_edge_thick];
 129 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 130 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 131 epp3 = epp2i + [10, 0];
 132 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 133 epp4 = epp5 + [-1,0] * case_th_side;
 134
 135 kppe = [0,0];
 136 kppd = kppe + [1,0] * keeper_inner_width;
 137 kppc = kppd + [0,1] * keeper_th_z;
 138 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 139 kppf = kppe - [0,1] * keeper_inner_height;
 140 kppa = [ kppb[0], kppf[1] ];
 141
 142 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 143 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 144
 145 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
 146
 147 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 148 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 149
 150 // button profile
 151 bppM = epp4 + [0,5];
 152 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 153 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 154 bppS = [ epp1[0], bppR[1] ];
 155 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 156 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 157 bppO = [ bppN[0], bppP[1] ];
 158 bppL = lpp10 + [5,0];
 159 bppK = [ bppL[0], bppN[1] ];
 160 bppJ = [ bppN[0], bppL[1] ];
 161
 162 // hinge plan
 163 hp_rn = hingescrew_nut_dia/2;
 164 hp_r2_min = hp_rn + lever_cover_th;
 165 hp_rs = hingescrew_shaft_dia/2;
 166 hp_r1_min = hp_rs + hingemount_th;
 167
 168 hp_r1 = max(hp_r1_min, hp_r2_min);
 169 hp_r2 = hp_r1;
 170
 171 hppU = lpp13;
 172 hppS = epp2o + [0,-1] * case_th_bottom;
 173 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 174
 175 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 176          0.5 * (hppU + hppS)[1] ];
 177 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 178 hppB = hppT + [0,-1] * hp_k;
 179
 180 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 181 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 182 hppE = [ hppE_x, hppE_y ];
 183
 184 // hinge elevation x coords
 185
 186 hingescrew_portion_len =
 187   0.5* (hingescrew_shaft_len - hingescrew_nut_thick - hinge_x_gap);
 188
 189 hex20 = max(epp2o[0],
 190             phone_cnr_rad,
 191             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 192 hex21 = hex20 + hingescrew_portion_len;
 193 hex22 = hex21 + hinge_x_gap;
 194 hex23 = hex22 + hingescrew_portion_len
 195   - hingescrew_nut_thick; // bodge, need to divvy this up more sensibly
 196 hex24 = hex20 + hingescrew_shaft_len + hinge_x_postscrew_gap;
 197 echo(hex20, hex21, hex22, hex23, hex24);
 198 echo(hingescrew_portion_len);
 199
 200 // catch
 201
 202 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 203 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 204 cppB = [ epp0[0], cppA[1] ];
 205 cppP = [ epp4[0], cppJ[1] ];
 206
 207 cppS = cppJ + [0,-1] * catch_len;
 208 cppD = [ cppA[0], cppS[1] + catch_slop ];
 209 cppC = [ cppB[0], cppD[1] ];
 210 cppT = cppS + [1,0] * catch_depth;
 211 cppU = cppT + [0,-1] * catch_height;
 212 cppV = [ cppS[0], cppU[1] - catch_depth ];
 213
 214 cppR = 0.5*(cppP + cppJ);
 215
 216 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 217 cppQ = [ cppR[0],
 218          cppV[1] - (catch_finger_height - cp_rQ) ];
 219 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 220
 221 // ---------- modules ----------
 222
 223 module KeeperProfile(slant=0){
 224   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 225   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 226 }
 227
 228 module EdgeProfile(){
 229   difference(){
 230     hull(){
 231       translate(epp3) square(case_th_bottom*2, center=true);
 232       circleat(epp2o, r=case_th_bottom);
 233       circleat(epp1, r=case_th_side);
 234       rectfromto(epp0, epp4);
 235     }
 236     polygon([ epp5 + [0,10],
 237               epp1,
 238               epp2i,
 239               epp3 + [10,0] ]);
 240   }
 241 }
 242
 243 module LidEdgeProfile(){
 244   polygon([ lpp10,
 245             lpp11,
 246             lpp12,
 247             lpp13,
 248             lpp13 + [10, 0],
 249             lpp10 + [10, 0]
 250             ]);
 251   intersection(){
 252     circleat(lpp12, r=lp_r12);
 253     rectfromto( lpp12 + [-10,   0],
 254                 lpp12 + [+10, +10] );
 255   }
 256 }
 257
 258 module ButtonCoverProfile(){
 259   intersection(){
 260     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 261     hull(){
 262       EdgeProfile();
 263       LidEdgeProfile();
 264     }
 265   }
 266 }
 267
 268 module ButtonPlan(l, deep, cut){
 269   epsilon =
 270     (cut  ? 0 : lid_buttoncover_gap);
 271
 272   delta =
 273     (deep ? lid_buttoncover_overlap : 0);
 274
 275   C = [0,0]; // by definition
 276   T = [ 0, epp4[1] ];
 277   G = T + [0,10];
 278
 279   B0 = C + [0,-1] * button_cutout_depth;
 280   B1 = B0 + [0,1] * epsilon;
 281
 282   r0 = 0.5 * (T[1] - B0[1]);
 283   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 284   H = A + [0,-1] * delta;
 285
 286   D = A + [-2,0] * r0;
 287   F = D + [0,10];
 288
 289   E0 = 0.5 * (D + A);
 290   E1 = E0 + [1,0] * epsilon;
 291
 292   I0 = [ E0[0], H[1] ];
 293   I1 = [ E1[0], H[1] ];
 294
 295   hull(){
 296     for (m=[0,1]) mirror([m,0])
 297       circleat(H, r0 - epsilon);
 298   }
 299   for (m=[0,1]) mirror([m,0]) {
 300     difference(){
 301       polygon([ E1,
 302                 I1,
 303                 H,
 304                 B1,
 305                 G,
 306                 F,
 307                 D
 308                 ]);
 309       circleat(D, r0 + epsilon);
 310     }
 311   }
 312 }
 313
 314 module CatchCatchProfile(){
 315   hull(){
 316     for (c=[ cppR, cppQ ])
 317       circleat(c, cp_rQ);
 318   }
 319   hull(){
 320     circleat(lpp12, lp_r12);
 321     circleat(lpp12 + [5,0], lp_r12);
 322     rectfromto(cppP, cppP + [5,0.1]);
 323   }
 324   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 325 }
 326
 327 module CatchCutProfile(){
 328   polygon([ cppB,
 329             cppA,
 330             cppD,
 331             cppF,
 332             cppF + [0,-10],
 333             cppF + [-10,-10],
 334             lpp12 + [-10,0],
 335             lpp12 + [10,0]
 336             ]);
 337 }
 338
 339 module Flip_rhs(yn=[0,1]) {
 340   for ($rhsflip=yn) {
 341     translate([phone_width/2, 0, 0])
 342       mirror([$rhsflip,0,0])
 343       translate([-phone_width/2, 0, 0])
 344       children();
 345   }
 346 }
 347
 348 module Flip_bot(yn=[0,1]) {
 349   for ($botflip=yn) {
 350     translate([0, -phone_height/2, 0])
 351       mirror([0, $botflip, 0])
 352       translate([0, phone_height/2, 0])
 353       children();
 354   }
 355 }
 356
 357 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 358   // sides
 359   Flip_rhs(){
 360     translate([0, -phone_cnr_rad, 0])
 361       rotate([90,0,0])
 362       linear_extrude(height = phone_height - phone_cnr_rad*2)
 363       children(0);
 364   }
 365   // corners
 366   Flip_rhs() Flip_bot() {
 367     translate([+1,-1] * phone_cnr_rad)
 368       intersection(){
 369         rotate_extrude()
 370           intersection(){
 371             mirror([1,0,0])
 372               translate([-1,0] * phone_cnr_rad)
 373               children(0);
 374             rectfromto([0,-20],[10,20]);
 375           }
 376         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 377           cube([10,10,40]);
 378       }
 379   }
 380   // top and bottom
 381   Flip_bot(){
 382     translate([ phone_width - phone_cnr_rad, 0,0 ])
 383       rotate([90,0,-90])
 384       linear_extrude(height = phone_width - phone_cnr_rad*2)
 385       children(0);
 386   }
 387   // fill
 388   translate([0,0, fill_zstart])
 389     mirror([0,0, fill_downwards])
 390     linear_extrude(height = fill_th)
 391     rectfromto([+1,-1] * phone_cnr_rad,
 392                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 393 }
 394
 395 module CaseAperture(pos, dia, $fn) {
 396   theta = 180/$fn;
 397   translate([ pos[0] + bumper[0],
 398               -epp2i[0],
 399               -pos[1] ])
 400     rotate([-90, theta, 0])
 401     cylinder(r = dia/2 / cos(theta),
 402              h = 60);
 403 }
 404
 405 module SideButton(y, y_ref_sign, l){
 406   // y_ref_sign:
 407   //   +1  measured from top    of actual phone to top    of button
 408   //   -1  measured from bottom of actual phone to bottom of button
 409   //    0  y is centre of button in coordinate system
 410   $button_l= l;
 411   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 412           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 413           y;
 414   //echo(eff_y);
 415   translate([0, eff_y, 0])
 416     children();
 417 }
 418
 419 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 420   $button_leg_only = true;
 421   SideButton(y, y_ref_sign, l) children();
 422 }
 423
 424 module Buttons(){
 425   Flip_rhs(1) SideButton(15.580, +1, 8.9) children(); // power
 426   Flip_rhs(1) SideButton(48.700, -1, 8.920) children(); // camera
 427   Flip_rhs(0) SideButton(30.800, +1, 21.96) children(); // volume
 428   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 429 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 430 }
 431
 432 module Struts(x_start, z_min, th){
 433   // if th is negative, starts at z_min and works towards -ve z
 434   // and object should then be printed other way up
 435   for (i= [1 : 1 : case_struts_count]) {
 436     translate([0,
 437                0,
 438                z_min])
 439       mirror([0,0, th<0 ? 1 : 0])
 440       translate([0,
 441                  -phone_height * i / (case_struts_count+1),
 442                  case_struts_solid_below])
 443       linear_extrude(height= abs(th)
 444                      -(case_struts_solid_below+case_struts_solid_above))
 445       rectfromto([               x_start, -0.5 * case_struts_width ],
 446                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 447   }
 448 }
 449
 450 module OrdinaryRearAperture(rhs,bot, pos){
 451   Flip_rhs(rhs) Flip_bot(bot)
 452     linextr(-20, 20)
 453     mirror([0,1])
 454     translate(pos + bumper)
 455     children();
 456 }
 457
 458 module MicroUSB(){
 459   Flip_bot(1){
 460     rotate([90,0,0])
 461       mirror([0,0,1])
 462       linextr(-epp2i[0], 60)
 463       translate([0.5 * phone_width, 0, 0])
 464       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 465                  [+microusb_width/2, epp0[1] + -microusb_above]);
 466   }
 467 }
 468
 469 module OrdinaryRearApertures(){
 470   // rear speaker
 471   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 472     rectfromto(-rearspeaker_gap,
 473                rearspeaker_size + rearspeaker_gap);
 474
 475   // finger hole to remove phone
 476   OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 477                               phone[1]/2 ])
 478     scale(fingerpushhole_dias)
 479     circle(r= 0.5 );
 480 }
 481
 482 module RearCameraAperture(){
 483   Flip_rhs(1)
 484     mirror([0, 0, 1])
 485     linear_extrude(height = 20)
 486     mirror([0, 1, 0])
 487     translate(bumper)
 488     rectfromto(camera_pos_tl, camera_pos_br);
 489 }
 490
 491 module HingeLidProfile(){
 492   hull(){
 493     circleat(hppT, hp_r1);
 494     circleat(lpp12, lp_r12);
 495     polygon([lpp10,
 496              lpp13 + [2,0],
 497              lpp12,
 498              hppT]);
 499   }
 500 }
 501
 502 module HingeBaseProfile(){
 503   difference(){
 504     hull(){
 505       circleat(hppB, hp_r1);
 506       circleat(hppE, hp_r1);
 507       circleat(epp2o, case_th_bottom);
 508       circleat(hppB + [10,0], hp_r1);
 509     }
 510     polygon([epp5, epp1, epp2i, epp3, bppL]);
 511   }
 512 }
 513
 514 module HingeLeverOuterProfile(){
 515   hull(){
 516     circleat(hppT, hp_r2);
 517     circleat(hppB, hp_r2);
 518   }
 519 }
 520
 521 module HingeLeverInnerProfile(){
 522   for (c = [hppT, hppB]) {
 523     hull()
 524       for (x=[-20,20])
 525         for (y=[0, c[1] - hppM[1]])
 526           translate([x,y])
 527             circleat(c, hp_rn);
 528   }
 529 }
 530
 531 module Flip_hinge(){
 532   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 533   translate(hinge_origin)
 534     rotate([180,0,0])
 535     translate(-hinge_origin)
 536     children();
 537 }
 538
 539 module HingePortion(x0,x1){
 540   Flip_rhs() Flip_bot(1)
 541     translate([x0,0,0])
 542     mirror([1,0,0])
 543     rotate([90,0,-90])
 544     linear_extrude(height=x1-x0)
 545     children(0);
 546 }
 547
 548 module CatchPortion(width){
 549   translate([phone_width/2, 0,0])
 550     rotate([90,0,-90])
 551     linextr(-width/2, width/2)
 552     children(0);
 553 }
 554
 555 module CaseBase(){
 556   AroundEdges(epp3[1], case_th_bottom, 1)
 557     EdgeProfile();
 558 }
 559
 560 module Case(){ ////toplevel
 561   difference(){
 562     union(){
 563       CaseBase();
 564
 565       // ledge (fixed keeper)
 566       Flip_rhs(1-keeper_side) intersection(){
 567         rotate([90, 0, 0])
 568           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 569           KeeperProfile(1);
 570
 571         // outline of the whole case, to stop it protruding
 572         translate([0,0, -25])
 573           linear_extrude(height = 50)
 574           hull()
 575           Flip_bot()
 576           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 577       }
 578
 579       // hinge
 580       HingePortion(hex20, hex21) HingeBaseProfile();
 581     }
 582
 583     // slot for keeper
 584     Flip_rhs(keeper_side)
 585       translate([0, -phone_cnr_rad, 0])
 586       rotate([90, 0, 0])
 587       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 588       minkowski(){
 589         KeeperProfile();
 590         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 591                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 592       }
 593
 594     // front camera
 595     RearCameraAperture();
 596
 597     // struts (invisible, because they're buried in the case)
 598     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 599
 600     Buttons(){
 601       mirror([1,0,0])
 602         rotate([90,0,90]) {
 603           intersection(){
 604             translate([0,0,-10])
 605               linear_extrude(height= 20)
 606               ButtonPlan($button_l, 0,1);
 607             if ($button_leg_only)
 608               rotate([-90,90,0])
 609                 translate([phone_width/2, -400, kppe[1]])
 610                 mirror([1-abs($rhsflip - keeper_side),0,0]) cube([400, 800, 50]);
 611           }
 612           translate([0,0, -bppR[0]])
 613             linear_extrude(height= 20)
 614             ButtonPlan($button_l, 1,1);
 615         }
 616     }
 617
 618     // apertures along top edge
 619     CaseAperture(jack_pos, jack_dia, 8);
 620     Flip_rhs(1)
 621       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 20);
 622
 623     OrdinaryRearApertures();
 624
 625     MicroUSB();
 626
 627     // gaps for the lid's hinge arms
 628     HingePortion(hex20 - hinge_x_arms_gap,
 629                  hex21 + hinge_x_arms_gap)
 630       minkowski(){
 631         HingeLidProfile();
 632         circle(r= hinge_r_arms_gap, $fn= 8);
 633       }
 634
 635     // screw holes in the hinge arms
 636     HingeScrews();
 637
 638     // catch striker
 639     CatchPortion(catch_width + catch_side_gap*2)
 640       CatchCutProfile();
 641   }
 642 }
 643
 644 module Lid(){ ////toplevel
 645   difference(){
 646     union(){
 647       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 648         LidEdgeProfile();
 649
 650       // button covers
 651       Buttons(){
 652         intersection(){
 653           rotate([90,0,90])
 654             translate([0,0,-10])
 655             linear_extrude(height= 20)
 656             ButtonPlan($button_l, 1,0);
 657           rotate([90,0,0])
 658              translate([0,0,-100])
 659             linear_extrude(height= 200)
 660             ButtonCoverProfile();
 661         }
 662       }
 663
 664       // hinge arms
 665       HingePortion(hex20, hex21) HingeLidProfile();
 666
 667       // catch
 668       CatchPortion(catch_width)
 669         CatchCatchProfile();
 670     }
 671     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 672
 673     // screw holes in the hinge arms
 674     HingeScrews();
 675   }
 676 }
 677
 678 module HingeLever(){ ////toplevel
 679   difference() {
 680     // outer body, positive
 681     HingePortion(hex22, hex22 + phone_width/2)
 682       HingeLeverOuterProfile();
 683
 684     // space for the screws
 685     HingePortion(hex23, hex24)
 686       HingeLeverInnerProfile();
 687
 688     // bores for the screws
 689     HingeScrews();
 690
 691     // space for the charging cable
 692     MicroUSB();
 693     Flip_hinge() MicroUSB();
 694   }
 695 }
 696
 697 module HingeLeverPrint(){ ////toplevel
 698   rotate([90,0,0])
 699     HingeLever();
 700 }
 701
 702 module TestSelectLength(){
 703   translate([-30, -200, -20])
 704     cube([30 + 15, 250, 40]);
 705 }
 706
 707 module TestLength(){ ////toplevel
 708   intersection(){
 709     Case();
 710     TestSelectLength();
 711   }
 712 }
 713
 714 module TestLengthRight(){ ////toplevel
 715   intersection(){
 716     Case();
 717     Flip_rhs(1)
 718       TestSelectLength();
 719   }
 720 }
 721
 722 module TestSelectWidth(){
 723   translate([-30, -(phone_height - 25), -20])
 724     mirror([0, 1, 0])
 725     cube([200, 50, 40]);
 726 }
 727
 728 module TestWidth(){ ////toplevel
 729   intersection(){
 730     Case();
 731     TestSelectWidth();
 732   }
 733 }
 734
 735 module TestLidWidthPrint(){ ////toplevel
 736   rotate([0,180.0]) intersection(){
 737     Lid();
 738     TestSelectWidth();
 739   }
 740 }
 741
 742 module TestSelectRearAperture(){
 743   minkowski(){
 744     union() children();
 745     translate([20, 0,0])
 746       cube([42, 2, 1], center=true);
 747   }
 748 }
 749
 750 module TestSelectCamera(){
 751   minkowski(){
 752     TestSelectRearAperture()
 753       RearCameraAperture();
 754     cube([0.1, 50, 0.1]);
 755   }
 756 }
 757
 758 module TestSelectOrdinaryRearApertures(){
 759   TestSelectRearAperture()
 760     OrdinaryRearApertures();
 761 }
 762
 763 module TestCamera(){ ////toplevel
 764   intersection(){
 765     Case();
 766     TestSelectCamera();
 767   }
 768 }
 769
 770 module TestLidByCamera(){ ////toplevel
 771   intersection(){
 772     Lid();
 773     TestSelectCamera();
 774   }
 775 }
 776
 777 module TestLidByCameraPrint(){ ////toplevel
 778   rotate([180,0,0]) TestLidByCamera();
 779 }
 780
 781 module DemoByCamera(){ ////toplevel
 782   color("blue") TestLidByCamera();
 783   color("red")  TestCamera();
 784 }
 785
 786 module OneKeeper(){ ////toplevel
 787   translate([0, -phone_cnr_rad, 0])
 788     rotate([90, 0, 0])
 789     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 790     KeeperProfile();
 791 }
 792
 793 module OneKeeperPrint(){ ////toplevel
 794   rotate([0,180,0])
 795     OneKeeper();
 796 }
 797
 798 module LidPrint(){ ////toplevel
 799   rotate([0,180,0])
 800     Lid();
 801 }
 802
 803 module TestSelectFrame(){
 804   include = [1,-1] * (epp2i[0] + 4);
 805
 806   difference(){
 807     cube(1000, center=true);
 808     translate([0,0, -100])
 809       linear_extrude(height=200)
 810       rectfromto(include,  inside_br - include);
 811   }
 812 }
 813
 814 module TestFrameCase(){ ////toplevel
 815   intersection(){
 816     Case();
 817     union(){
 818       TestSelectFrame();
 819       TestSelectCamera();
 820       TestSelectOrdinaryRearApertures();
 821     }
 822   }
 823 }
 824
 825 module TestFrameLidPrint(){ ////toplevel
 826   rotate([0,180,0]) intersection(){
 827     Lid();
 828     TestSelectFrame();
 829   }
 830 }
 831
 832 module ButtonPlanForDemo(z, deep, cut){
 833   translate([0,0,z])
 834     ButtonPlan(8, deep, cut);
 835 }
 836
 837 module HingeScrews(){
 838   Flip_rhs() Flip_bot(1){
 839     for (c= [ hppT, hppB ])
 840       translate([ hex20,
 841                   -c[0],
 842                   c[1] ]){
 843         rotate([0,90,0])
 844           translate([0,0,-.2])
 845           cylinder( r= hingescrew_shaft_dia/2,
 846                     h = hingescrew_shaft_len+0.2 );
 847         rotate([0,-90,0])
 848           translate([0,0,+.1])
 849           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
 850       }
 851   }
 852 }
 853
 854 module DemoFrame(){ ////toplevel
 855   color("red") TestFrameCase();
 856   color("blue") intersection(){ Lid(); TestSelectFrame(); }
 857   color("black") HingeScrews();
 858   %HingeLever();
 859 }
 860
 861 module DemoHingedFrame(){ ///toplevel
 862   color("red") TestFrameCase();
 863   translate([0,0, -2*hp_k])
 864   color("blue") intersection(){ Lid(); TestSelectFrame(); }
 865
 866   Flip_hinge(){
 867     color("orange") HingeLever();
 868     color("black") HingeScrews();
 869   }
 870 }
 871
 872 module DemoHinge(){ ////toplevel
 873   DemoFrame();
 874   translate([0,0, -hp_k*3])
 875     DemoHingedFrame();
 876 }
 877
 878 module DemoProfiles(){ ////toplevel
 879   LidEdgeProfile();
 880   %EdgeProfile();
 881   KeeperProfile();
 882   translate([0,0,-1]) color("black") KeeperProfile(1);
 883
 884   translate([20,0]) {
 885     LidEdgeProfile();
 886     %EdgeProfile();
 887
 888     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 889
 890     color("blue") ButtonCoverProfile();
 891     color("red") {
 892       rectfromto(bppQ, demopoint_QR);
 893       rectfromto(bppR, demopoint_QR);
 894     }
 895   }
 896
 897   translate([-20,0]) {
 898     color("black") ButtonPlanForDemo(-2, 0,1);
 899     color("red" )  ButtonPlanForDemo(-4, 1,1);
 900     color("blue")  ButtonPlanForDemo(-6, 1,0);
 901   }
 902
 903   translate([0, -30]) {
 904     %LidEdgeProfile();
 905     %EdgeProfile();
 906     color("blue") HingeLidProfile();
 907     color("red")  HingeBaseProfile();
 908     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
 909     color("orange") translate([0,0,-1]) HingeLeverInnerProfile();
 910   }
 911
 912   translate([20,-30]) {
 913     %EdgeProfile();
 914     %LidEdgeProfile();
 915     //translate([0,0,1]) CatchCutProfile();
 916     color("blue") CatchCatchProfile();
 917     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
 918   }
 919 }
 920
 921 //EdgeProfile();
 922 //KeeperProfile();
 923 //CaseBase();
 924 //%Case();
 925 //Keeper();
 926 //LidEdgeProfile();
 927 //KeeperProfile();
 928 //DemoProfiles();