fairphone-case.scad

   1 // -*- C -*-
   2
   3 phone = [ 75.0, 145.0 ];
   4
   5 bumper = [ 0.250, 0.250 ];
   6 // ^ One side.  Overall size is increased by twice this.
   7 // If no bumpers, is the gap around the phone.
   8
   9 phone_cnr_rad = 6.0;
  10
  11 button_cutout_depth = 9;
  12
  13 phone_edge_thick = 9.0;
  14 phone_total_thick = 12.0;
  15 phone_backside_slope_inner = 1.5; // larger means shallower
  16 phone_backside_slope_outer = 1.0; // larger means shallower
  17
  18 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  19 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  20
  21 jack_pos = [ 13.92, 7.96 ];
  22 jack_dia = 9.1 + .5; // some jack I had lying around
  23
  24 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  25 noisecancelmic_dia = 1.75;
  26
  27 fingerpushhole_dias = [ 14, 17 ];
  28
  29 rearspeaker_pos_bl = [ 14.92, 18.72 ];
  30 rearspeaker_size   = [  3.76,  7.36 ];
  31
  32 case_th_bottom = 2.5;
  33 case_th_lid = 2.5;
  34 case_th_side = 2;
  35 case_th_lip = 1.2;
  36
  37 case_struts_count = 6;
  38 case_struts_solid_below = 1.00;
  39 case_struts_solid_above = 0.75;
  40 case_struts_width = 0.10;
  41
  42 keeper_th_z = 0.75;
  43 keeper_th_x = 0.75;
  44 keeper_inner_width = 2.75;
  45 keeper_inner_height = 2.75;
  46 keeper_slant_slope = 2; // larger means steeper
  47
  48 keeper_gap_z_top = 0.25;
  49 keeper_gap_z_bot = 0.75;
  50 keeper_gap_x     = 0.25;
  51 keeper_gap_x_holes = 0.75;
  52
  53 case_lip = 1.25;
  54
  55 lid_gap_x = 0.25;
  56 lid_gap_z = 0.25;
  57 lid_lip = 1.75;
  58
  59 foldover_gap = 0.50;
  60 foldover_hinger_gap = 0.50;
  61
  62 hingescrew_nut_dia = 4.72 + 0.50; // washer, actually
  63 hinger_th = 2;
  64
  65 $fa = 5;
  66 $fs = 0.1;
  67
  68 button_l_fudge = 4.4;
  69 buttonishleg_default_l_is_fudge = 10;
  70
  71 strut_min_at_end = 1.5;
  72
  73 rearspeaker_gap    = [ 1.0, 1.0 ]; // each side
  74
  75 // ---------- calculated ----------
  76
  77 phone_width =  (phone + bumper*2)[0];
  78 phone_height = (phone + bumper*2)[1];
  79
  80 inside_br = [phone_width, -phone_height];
  81
  82 //echo(camera_pos_tl + bumper,
  83 //     camera_pos_br + bumper);
  84
  85 // ----- could be changed -----
  86 lid_buttoncover_gap = lid_gap_x;
  87 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
  88
  89 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
  90
  91 //lid_lip_overlap_width xxx bad name = ;
  92 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
  93
  94 epp0 = [0,0];
  95 epp1 = [0, -phone_edge_thick];
  96 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
  97 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
  98 epp3 = epp2i + [10, 0];
  99 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 100 epp4 = epp5 + [-1,0] * case_th_side;
 101
 102 kppe = [0,0];
 103 kppd = kppe + [1,0] * keeper_inner_width;
 104 kppc = kppd + [0,1] * keeper_th_z;
 105 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 106 kppf = kppe - [0,1] * keeper_inner_height;
 107 kppa = [ kppb[0], kppf[1] ];
 108
 109 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 110 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 111
 112 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
 113
 114 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 115 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 116
 117 // button profile
 118 bppM = epp4 + [0,5];
 119 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 120 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 121 bppS = [ epp1[0], bppR[1] ];
 122 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 123 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 124 bppO = [ bppN[0], bppP[1] ];
 125 bppL = lpp10 + [5,0];
 126 bppK = [ bppL[0], bppN[1] ];
 127 bppJ = [ bppN[0], bppL[1] ];
 128
 129 // hinge plan
 130 hp_rn = hingescrew_nut_dia;
 131 hp_r2 = hp_rn + hinger_th;
 132
 133 hppU = lpp13;
 134 hppS = epp2o[1] + [0,-1] * case_th_bottom;
 135 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 136
 137 hppM = [ epp4[0] - foldover_hinger_gap - hp_r2,
 138          0.5 * (hppU + hppS)[1] ];
 139 hppT = hppM + 0.5 * [0,+1] * hp_k;
 140 hppB = hppM + 0.5 * [0,-1] * hp_k;
 141
 142 module rectfromto(a,b) {
 143   ab = b - a;
 144   translate([min(a[0], b[0]), min(a[1], b[1])])
 145     square([abs(ab[0]), abs(ab[1])]);
 146 }
 147 module circleat(c,r) { translate(c) circle(r); }
 148 module linextr(z0,z1) {
 149   translate([0,0,z0])
 150     linear_extrude(height=z1-z0)
 151     children();
 152 }
 153
 154 module KeeperProfile(slant=0){
 155   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 156   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 157 }
 158
 159 module EdgeProfile(){
 160   difference(){
 161     hull(){
 162       translate(epp3) square(case_th_bottom*2, center=true);
 163       circleat(epp2o, r=case_th_bottom);
 164       circleat(epp1, r=case_th_side);
 165       rectfromto(epp0, epp4);
 166     }
 167     polygon([ epp5 + [0,10],
 168               epp1,
 169               epp2i,
 170               epp3 + [10,0] ]);
 171   }
 172 }
 173
 174 module LidEdgeProfile(){
 175   polygon([ lpp10,
 176             lpp11,
 177             lpp12,
 178             lpp13,
 179             lpp13 + [10, 0],
 180             lpp10 + [10, 0]
 181             ]);
 182   intersection(){
 183     circleat(lpp12, r=lp_r12);
 184     rectfromto( lpp12 + [-10,   0],
 185                 lpp12 + [+10, +10] );
 186   }
 187 }
 188
 189 module ButtonCoverProfile(){
 190   intersection(){
 191     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 192     hull(){
 193       EdgeProfile();
 194       LidEdgeProfile();
 195     }
 196   }
 197 }
 198
 199 module ButtonPlan(l, deep, cut){
 200   epsilon =
 201     (cut  ? 0 : lid_buttoncover_gap);
 202
 203   delta =
 204     (deep ? lid_buttoncover_overlap : 0);
 205
 206   C = [0,0]; // by definition
 207   T = [ 0, epp4[1] ];
 208   G = T + [0,10];
 209
 210   B0 = C + [0,-1] * button_cutout_depth;
 211   B1 = B0 + [0,1] * epsilon;
 212
 213   r0 = 0.5 * (T[1] - B0[1]);
 214   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 215   H = A + [0,-1] * delta;
 216
 217   D = A + [-2,0] * r0;
 218   F = D + [0,10];
 219
 220   E0 = 0.5 * (D + A);
 221   E1 = E0 + [1,0] * epsilon;
 222
 223   I0 = [ E0[0], H[1] ];
 224   I1 = [ E1[0], H[1] ];
 225
 226   hull(){
 227     for (m=[0,1]) mirror([m,0])
 228       circleat(H, r0 - epsilon);
 229   }
 230   for (m=[0,1]) mirror([m,0]) {
 231     difference(){
 232       polygon([ E1,
 233                 I1,
 234                 H,
 235                 B1,
 236                 G,
 237                 F,
 238                 D
 239                 ]);
 240       circleat(D, r0 + epsilon);
 241     }
 242   }
 243 }
 244
 245 module CaseBase_rhsflip(yn=[0,1]) {
 246   for ($rhsflip=yn) {
 247     translate([phone_width/2, 0, 0])
 248       mirror([$rhsflip,0,0])
 249       translate([-phone_width/2, 0, 0])
 250       children();
 251   }
 252 }
 253
 254 module CaseBase_botflip(yn=[0,1]) {
 255   for ($botflip=yn) {
 256     translate([0, -phone_height/2, 0])
 257       mirror([0, $botflip, 0])
 258       translate([0, phone_height/2, 0])
 259       children();
 260   }
 261 }
 262
 263 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 264   // sides
 265   CaseBase_rhsflip(){
 266     translate([0, -phone_cnr_rad, 0])
 267       rotate([90,0,0])
 268       linear_extrude(height = phone_height - phone_cnr_rad*2)
 269       children(0);
 270   }
 271   // corners
 272   CaseBase_rhsflip() CaseBase_botflip() {
 273     translate([+1,-1] * phone_cnr_rad)
 274       intersection(){
 275         rotate_extrude()
 276           intersection(){
 277             mirror([1,0,0])
 278               translate([-1,0] * phone_cnr_rad)
 279               children(0);
 280             rectfromto([0,-20],[10,20]);
 281           }
 282         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 283           cube([10,10,40]);
 284       }
 285   }
 286   // top and bottom
 287   CaseBase_botflip(){
 288     translate([ phone_width - phone_cnr_rad, 0,0 ])
 289       rotate([90,0,-90])
 290       linear_extrude(height = phone_width - phone_cnr_rad*2)
 291       children(0);
 292   }
 293   // fill
 294   translate([0,0, fill_zstart])
 295     mirror([0,0, fill_downwards])
 296     linear_extrude(height = fill_th)
 297     rectfromto([+1,-1] * phone_cnr_rad,
 298                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 299 }
 300
 301 module CaseAperture(pos, dia, $fn) {
 302   theta = 180/$fn;
 303   translate([ pos[0] + bumper[0],
 304               -epp2i[0],
 305               -pos[1] ])
 306     rotate([-90, theta, 0])
 307     cylinder(r = dia/2 / cos(theta),
 308              h = 60);
 309 }
 310
 311 module SideButton(y, y_ref_sign, l){
 312   // y_ref_sign:
 313   //   +1  measured from top    of actual phone to top    of button
 314   //   -1  measured from bottom of actual phone to bottom of button
 315   //    0  y is centre of button in coordinate system
 316   $button_l= l;
 317   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 318           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 319           y;
 320   echo(eff_y);
 321   translate([0, eff_y, 0])
 322     children();
 323 }
 324
 325 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 326   $button_leg_only = true;
 327   SideButton(y, y_ref_sign, l) children();
 328 }
 329
 330 module Buttons(){
 331   CaseBase_rhsflip([1]) SideButton(15.580, +1, 8.9) children(); // power
 332   CaseBase_rhsflip([1]) SideButton(48.700, -1, 8.920) children(); // camera
 333   CaseBase_rhsflip([0]) SideButton(30.800, +1, 21.96) children(); // volume
 334   CaseBase_rhsflip(   ) LidButtonishLeg(20, -1) children();
 335 //  CaseBase_rhsflip([0]) LidButtonishLeg(20, +1, 20) children();
 336 }
 337
 338 module Struts(x_start, z_min, th){
 339   // if th is negative, starts at z_min and works towards -ve z
 340   // and object should then be printed other way up
 341   for (i= [1 : 1 : case_struts_count]) {
 342     translate([0,
 343                0,
 344                z_min])
 345       mirror([0,0, th<0 ? 1 : 0])
 346       translate([0,
 347                  -phone_height * i / (case_struts_count+1),
 348                  case_struts_solid_below])
 349       linear_extrude(height= abs(th)
 350                      -(case_struts_solid_below+case_struts_solid_above))
 351       rectfromto([               x_start, -0.5 * case_struts_width ],
 352                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 353   }
 354 }
 355
 356 module OrdinaryRearAperture(rhs,bot, pos){
 357   CaseBase_rhsflip(rhs) CaseBase_botflip(bot)
 358     linextr(-20, 20)
 359     mirror([0,1])
 360     translate(pos + bumper)
 361     children();
 362 }
 363
 364 module OrdinaryRearApertures(){
 365   // rear speaker
 366   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 367     rectfromto(-rearspeaker_gap,
 368                rearspeaker_size + rearspeaker_gap);
 369
 370   // finger hole to remove phone
 371   OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 372                               phone[1]/2 ])
 373     scale(fingerpushhole_dias)
 374     circle(r= 0.5 );
 375 }
 376
 377 module RearCameraAperture(){
 378   CaseBase_rhsflip([1])
 379     mirror([0, 0, 1])
 380     linear_extrude(height = 20)
 381     mirror([0, 1, 0])
 382     translate(bumper)
 383     rectfromto(camera_pos_tl, camera_pos_br);
 384 }
 385
 386 module CaseBase(){
 387   AroundEdges(epp3[1], case_th_bottom, 1)
 388     EdgeProfile();
 389 }
 390
 391 module Case(){ ////toplevel
 392   difference(){
 393     union(){
 394       CaseBase();
 395
 396       // ledge (fixed keeper)
 397       intersection(){
 398         rotate([90, 0, 0])
 399           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 400           KeeperProfile(1);
 401
 402         // outline of the whole case, to stop it protruding
 403         translate([0,0, -25])
 404           linear_extrude(height = 50)
 405           hull()
 406           // CaseBase_rhsflip() // actually, we only care about the LH
 407           CaseBase_botflip()
 408           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 409       }
 410     }
 411
 412     // slot for keeper
 413     CaseBase_rhsflip(1)
 414       translate([0, -phone_cnr_rad, 0])
 415       rotate([90, 0, 0])
 416       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 417       minkowski(){
 418         KeeperProfile();
 419         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 420                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 421       }
 422
 423     // front camera
 424     RearCameraAperture();
 425
 426     // struts (invisible, because they're buried in the case)
 427     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 428
 429     Buttons(){
 430       mirror([1,0,0])
 431         rotate([90,0,90]) {
 432           intersection(){
 433             translate([0,0,-10])
 434               linear_extrude(height= 20)
 435               ButtonPlan($button_l, 0,1);
 436             if ($button_leg_only)
 437               rotate([-90,90,0])
 438                 translate([phone_width/2, -400, kppe[1]])
 439                 mirror([$rhsflip,0,0]) cube([400, 800, 50]);
 440           }
 441           translate([0,0, -bppR[0]])
 442             linear_extrude(height= 20)
 443             ButtonPlan($button_l, 1,1);
 444         }
 445     }
 446
 447     // apertures along top edge
 448     CaseAperture(jack_pos, jack_dia, 8);
 449     CaseBase_rhsflip([1])
 450       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 20);
 451
 452     OrdinaryRearApertures();
 453   }
 454 }
 455
 456 module Lid(){ ////toplevel
 457   difference(){
 458     union(){
 459       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 460         LidEdgeProfile();
 461
 462       // button covers
 463       Buttons(){
 464         intersection(){
 465           rotate([90,0,90])
 466             translate([0,0,-10])
 467             linear_extrude(height= 20)
 468             ButtonPlan($button_l, 1,0);
 469           rotate([90,0,0])
 470              translate([0,0,-100])
 471             linear_extrude(height= 200)
 472             ButtonCoverProfile();
 473         }
 474       }
 475     }
 476     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 477   }
 478 }
 479
 480 module TestLength(){ ////toplevel
 481   intersection(){
 482     Case();
 483     translate([-30, -200, -20])
 484     cube([30 + 15, 250, 40]);
 485   }
 486 }
 487
 488 module TestSelectWidth(){
 489   translate([-30, -(phone_height - 25), -20])
 490     mirror([0, 1, 0])
 491     cube([200, 50, 40]);
 492 }
 493
 494 module TestWidth(){ ////toplevel
 495   intersection(){
 496     Case();
 497     TestSelectWidth();
 498   }
 499 }
 500
 501 module TestLidWidthPrint(){ ////toplevel
 502   rotate([0,180.0]) intersection(){
 503     Lid();
 504     TestSelectWidth();
 505   }
 506 }
 507
 508 module TestSelectRearAperture(){
 509   minkowski(){
 510     union() children();
 511     translate([20, 0,0])
 512       cube([42, 2, 1], center=true);
 513   }
 514 }
 515
 516 module TestSelectCamera(){
 517   minkowski(){
 518     TestSelectRearAperture()
 519       RearCameraAperture();
 520     cube([0.1, 50, 0.1]);
 521   }
 522 }
 523
 524 module TestSelectOrdinaryRearApertures(){
 525   TestSelectRearAperture()
 526     OrdinaryRearApertures();
 527 }
 528
 529 module TestCamera(){ ////toplevel
 530   intersection(){
 531     Case();
 532     TestSelectCamera();
 533   }
 534 }
 535
 536 module TestLidByCamera(){ ////toplevel
 537   intersection(){
 538     Lid();
 539     TestSelectCamera();
 540   }
 541 }
 542
 543 module TestLidByCameraPrint(){ ////toplevel
 544   rotate([180,0,0]) TestLidByCamera();
 545 }
 546
 547 module DemoByCamera(){ ////toplevel
 548   color("blue") TestLidByCamera();
 549   color("red")  TestCamera();
 550 }
 551
 552 module OneKeeper(){ ////toplevel
 553   translate([0, -phone_cnr_rad, 0])
 554     rotate([90, 0, 0])
 555     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 556     KeeperProfile();
 557 }
 558
 559 module OneKeeperPrint(){ ////toplevel
 560   rotate([0,180,0])
 561     OneKeeper();
 562 }
 563
 564 module LidPrint(){ ////toplevel
 565   rotate([0,180,0])
 566     Lid();
 567 }
 568
 569 module TestSelectFrame(){
 570   include = [1,-1] * (epp2i[0] + 4);
 571
 572   difference(){
 573     cube(1000, center=true);
 574     translate([0,0, -100])
 575       linear_extrude(height=200)
 576       rectfromto(include,  inside_br - include);
 577   }
 578 }
 579
 580 module TestFrameCase(){ ////toplevel
 581   intersection(){
 582     Case();
 583     union(){
 584       TestSelectFrame();
 585       TestSelectCamera();
 586       TestSelectOrdinaryRearApertures();
 587     }
 588   }
 589 }
 590
 591 module TestFrameLidPrint(){ ////toplevel
 592   rotate([0,0,180]) intersection(){
 593     Lid();
 594     TestSelectFrame();
 595   }
 596 }
 597
 598 module Keeper(){ ////toplevel
 599   CaseBase_rhsflip()
 600     OneKeeper();
 601 }
 602
 603 module ButtonPlanForDemo(z, deep, cut){
 604   translate([0,0,z])
 605     ButtonPlan(8, deep, cut);
 606 }
 607
 608 module DemoProfiles(){ ////toplevel
 609   LidEdgeProfile();
 610   %EdgeProfile();
 611   KeeperProfile();
 612   translate([0,0,-1]) color("black") KeeperProfile(1);
 613
 614   translate([20,0]) {
 615     LidEdgeProfile();
 616     %EdgeProfile();
 617
 618     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 619
 620     color("blue") ButtonCoverProfile();
 621     color("red") {
 622       rectfromto(bppQ, demopoint_QR);
 623       rectfromto(bppR, demopoint_QR);
 624     }
 625   }
 626
 627   translate([-20,0]) {
 628     color("black") ButtonPlanForDemo(-2, 0,1);
 629     color("red" )  ButtonPlanForDemo(-4, 1,1);
 630     color("blue")  ButtonPlanForDemo(-6, 1,0);
 631   }
 632 }
 633
 634 //EdgeProfile();
 635 //KeeperProfile();
 636 //CaseBase();
 637 //%Case();
 638 //Keeper();
 639 //LidEdgeProfile();
 640 //KeeperProfile();
 641 //DemoProfiles();