fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172 lanyard_entry_rel_breadth = 2;
 173 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 174 rearspeaker_size   = [  3.76,  7.36 ];
 175
 176 microusb_above = 3.27 - 0.25;
 177 microusb_below = 0.0;
 178 microusb_width = 16.12 + 1.25;
 179
 180 case_th_bottom = 2.5;
 181 case_th_lid = 3.0;
 182 case_th_side = 2.3;
 183 case_th_lip = 1.2;
 184
 185 lid_screen_gap_extra = .66;
 186
 187 case_struts_count = 6;
 188 case_struts_solid_below = 1.00;
 189 case_struts_solid_above = 0.75;
 190 case_struts_width = 0.10;
 191
 192 keeper_th_z = 0.75;
 193 keeper_th_x = 0.75;
 194 keeper_inner_width = 2.75;
 195 keeper_inner_height = 2.75;
 196 keeper_slant_slope = 2; // larger means steeper
 197
 198 keeper_gap_z_top = 0.25;
 199 keeper_gap_z_bot = 0.75;
 200 keeper_gap_x     = 0.25;
 201 keeper_gap_x_holes = 0.75;
 202
 203 keeper_side = 0; // 0 = lhs; 1 = rhs
 204
 205 case_lip = 1.25;
 206
 207 lid_gap_x = 0.25;
 208 lid_gap_z = 0.25;
 209 lid_lip = 1.75;
 210 lid_edgepart_width = 5.0;
 211 lid_buttoncover_thick = 1.3;
 212
 213 catch_slop = 0.50;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // properties of the hinge fasteners
 219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 220 hingescrew_shaft_len = 12;
 221 hingescrew_fasteners_extra_thick = 0.40;
 222 // ^ amount of thread protruding if everything was completely nominal
 223 //   and we are using two nuts
 224 hingescrew_nut_access_dia = 4.72 + 0.50;
 225 // ^ washer is 4.72 dia
 226 //   also, want to get pliers or tiny spanner in to do up locknut
 227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 228 hingescrew_nut_thick = 1.93;
 229 hingescrew_head_th = 1.38 + 0.75;
 230 hingescrew_head_dia = 3.92;
 231
 232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 233
 234 lever_cover_th = 0.75;
 235 hingemount_th = 2.5;
 236 hingemount_wd = 4.8725;
 237
 238 $fa = 5;
 239 $fs = 0.1;
 240
 241 button_l_fudge = 4.4;
 242 buttonishleg_default_l_is_fudge = 10;
 243
 244 hinge_base_slope = 1.5; // bigger is steeper
 245
 246 strut_min_at_end = 1.5;
 247
 248 hinge_x_gap = 0.125;
 249 hinge_x_postscrew_gap = 0.75;
 250 hinge_x_arms_gap = 0.35;
 251 hinge_r_arms_gap = 0.55;
 252
 253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 254
 255 catch_len = 7.5;
 256 catch_width = 15;
 257 catch_thickness = 1.0;
 258 catch_side_gap = 0.75; // each side
 259
 260 catch_depth = 0.75;
 261 catch_height = 0.35;
 262 catch_finger_height = 1.5;
 263 catch_finger_depth = 2.5;
 264
 265 catch_topcurve_r = 5.0;
 266
 267 prop_recess_under = 0.50;
 268 prop_recess_slop = 0.200; // each side
 269 prop_end_dia = 0.5;
 270 prop_main_th = 3;
 271 prop_taper_len = 6;
 272 prop_main_width = 4;
 273 prop_side_gap = 0.75; // each side
 274 prop_lidrecess_behind = 0.75;
 275 prop_caserecess_behind = 0.75;
 276 prop_caserecess_taper = 0.45; // one side only
 277 prop_prop_gap = 0.5;
 278 prop_prong_heel_slope = 0.5;
 279
 280 lid_fold_clearance_antislop = 0.5;
 281
 282 // ---------- calculated ----------
 283
 284 phone_width =  (phone + bumper*2)[0];
 285 phone_height = (phone + bumper*2)[1];
 286
 287 inside_br = [phone_width, -phone_height];
 288
 289 prop_prong_h = prop_main_th;
 290
 291 //echo(camera_pos_tl + bumper,
 292 //     camera_pos_br + bumper);
 293
 294 // ----- could be changed -----
 295 lid_buttoncover_gap = lid_gap_x;
 296 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 297
 298 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 299
 300 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 301
 302 //prop_nose_len = case_th_lid - prop_recess_under;
 303 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 304 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 305
 306
 307 //lid_lip_overlap_width xxx bad name = ;
 308 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 309
 310 epp0 = [0,0];
 311 epp1 = [0, -phone_edge_thick];
 312 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 313 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 314 epp3 = epp2i + [10, 0];
 315 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 316 epp4 = epp5 + [-1,0] * case_th_side;
 317
 318 kppe = [0,0];
 319 kppd = kppe + [1,0] * keeper_inner_width;
 320 kppc = kppd + [0,1] * keeper_th_z;
 321 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 322 kppf = kppe - [0,1] * keeper_inner_height;
 323 kppa = [ kppb[0], kppf[1] ];
 324
 325 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 326 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 327
 328 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 329 // exact x posn not very important; must extend past end of keeper
 330
 331 lpp15 = [ lpp14[0],
 332           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 333           + lid_screen_gap_extra ];
 334 // ^ beam theory says to maximise force before contact,
 335 //   the gap below the `beam' (the lid) must be 1/3
 336 //   the thickness (ie the lid thickness) if the beam
 337 //   is solid, or 1/2 if it has a top and bottom only.
 338 //   ours is mostly solid.
 339
 340 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 341              case_th_lip);
 342
 343 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 344 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 345
 346 case_bottom_z = epp2o[1] - case_th_bottom;
 347
 348 // button profile
 349 bppM = epp4 + [0,5];
 350 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 351 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 352 bppS = [ epp1[0], bppR[1] ];
 353 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 354 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 355 bppO = [ bppN[0], bppP[1] ];
 356 bppL = lpp10 + [5,0];
 357 bppK = [ bppL[0], bppN[1] ];
 358 bppJ = [ bppN[0], bppL[1] ];
 359 bppU = [ bppJ[0], lpp12[1] ];
 360 bppV = lpp11;
 361 bppW = lpp10;
 362
 363 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 364
 365 // notification led aperture
 366
 367 nla_r0 = led_aperture/2;
 368 nla_r1 = nla_r0 + led_window_ledge;
 369 nla_r2 = nla_r1 + multicolour_gap;
 370 nla_t =
 371   led_window_style >= 3 ? initial_layer_thick :
 372   led_window_style >= 2 ? led_window_ledge : 0;
 373
 374
 375 // hinge plan
 376 hp_rn = hingescrew_nut_access_dia/2;
 377 hp_r2_min = hp_rn + lever_cover_th;
 378 hp_rs = hingescrew_shaft_dia/2;
 379 hp_r1_min = hp_rs + hingemount_th;
 380
 381 hp_r1 = max(hp_r1_min, hp_r2_min);
 382 hp_r2 = hp_r1;
 383
 384 hppU = lpp13;
 385 hppS = epp2o + [0,-1] * case_th_bottom;
 386 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 387
 388 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 389          0.5 * (hppU + hppS)[1] ];
 390 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 391 hppB = hppT + [0,-1] * hp_k;
 392
 393 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 394 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 395 hppE = [ hppE_x, hppE_y ];
 396
 397 // hinge elevation x coords
 398
 399 hex20 = max(epp2o[0],
 400             phone_cnr_rad,
 401             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 402 hex21 = hex20 + hingemount_wd;
 403 hex22 = hex21 + hinge_x_gap;
 404 hex27 = hex20 + hingescrew_shaft_len;
 405 hex24 = hex27 + hinge_x_postscrew_gap;
 406 hex23 = hex27 - (hingescrew_nut_thick*2
 407                  + hingescrew_fasteners_extra_thick);
 408 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 409
 410 echo(hex20, hex21, hex22, hex23, hex24);
 411 //  6, 10.8725, 10.9975, 13.74, 18.75
 412 module chk(act,exp) {
 413   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 414   else echo("ok", act);
 415 }
 416 chk(hex20, 6);
 417 chk(hex21, 10.8725);
 418 chk(hex22, 10.9975);
 419 chk(hex23, 13.74);
 420 chk(hex24, 18.75);
 421
 422 lid_fold_clearance_skew =
 423   (lpp10[1] - hppB[1]) /
 424   (lpp10[0] - hppB[0]);
 425
 426 echo("SK",lid_fold_clearance_skew);
 427
 428 // catch
 429
 430 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 431 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 432 cppB = [ epp0[0], cppA[1] ];
 433 cppP = [ epp4[0], cppJ[1] ];
 434
 435 cppS = cppJ + [0,-1] * catch_len;
 436 cppD = [ cppA[0], cppS[1] + catch_slop ];
 437 cppC = [ cppB[0], cppD[1] ];
 438 cppT = cppS + [1,0] * catch_depth;
 439 cppU = cppT + [0,-1] * catch_height;
 440 cppV = [ cppS[0], cppU[1] - catch_depth ];
 441
 442 cppR = 0.5*(cppP + cppJ);
 443
 444 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 445 cppQ = [ cppR[0],
 446          cppV[1] - (catch_finger_height - cp_rQ) ];
 447 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 448
 449 // lanyard
 450
 451 ly_r = lanyard_half_dia / 2;
 452 ly_rc = ly_r * 2;
 453 ly_re = 10; // xxx
 454
 455 // prop recess in case
 456
 457 prop_x_pos = phone_width/2;
 458
 459 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 460
 461 prc_r1 = prop_end_dia/2;
 462 prc_r3 = prc_r1 + prop_recess_slop;
 463
 464 prcp2 = [ epp4[0] + prop_buildout_less,
 465           case_bottom_z ];
 466
 467 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 468
 469 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 470           epp2i[1] - prc_r3 - prop_recess_under];
 471
 472 // prop recess in lid
 473
 474 prl_r10 = prop_end_dia/2;
 475 prl_r10o = prl_r10 + prop_recess_slop;
 476
 477 prlp10 = lpp10 + [1,1] * prl_r10o
 478   + [1,0] * prop_lidrecess_behind
 479   + [0,1] * prop_recess_under;
 480
 481 // prop
 482
 483 $prpp10 = [0,0];
 484 $prpp11 = [0, prop_taper_len];
 485
 486 $prp_r10 = prl_r10;
 487
 488 // ---------- modules ----------
 489
 490 module AdhocMultiprintFrame(phase, z0, zs) {
 491   // from z0 to z0 + zs*layer
 492   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 493   xextra = extra + -epp4[0];
 494   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 495   yextra = extra + -epp4[0];
 496   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 497   p0 = [ xrange[0], yrange[0] ];
 498   p1 = [ xrange[1], yrange[1] ];
 499   echo(p0, p1);
 500   translate([0,0, z0])
 501     mirror([0,0, zs<0 ? 1 : 0])
 502     linear_extrude(height= initial_layer_thick)
 503     difference(){
 504       rectfromto(p0 - [1,1] * initial_layer_width,
 505                  p1 + [1,1] * initial_layer_width);
 506       rectfromto(p0, p1);
 507     }
 508 }
 509
 510 module KeeperProfile(slant=0){
 511   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 512   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 513 }
 514
 515 module EdgeProfile(){
 516   difference(){
 517     hull(){
 518       translate(epp3) square(case_th_bottom*2, center=true);
 519       circleat(epp2o, r=case_th_bottom);
 520       circleat(epp1, r=case_th_side);
 521       rectfromto(epp0, epp4);
 522     }
 523     polygon([ epp5 + [0,10],
 524               epp1,
 525               epp2i,
 526               epp3 + [10,0] ]);
 527   }
 528 }
 529
 530 module LanyardLanyardProfile(entry=false){
 531   hull(){
 532     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 533       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 534         circle(r= lanyard_half_dia/2);
 535   }
 536 }
 537
 538 module LanyardCurveChannelProfile(){
 539   translate([0, -ly_r])
 540     LanyardLanyardProfile();
 541 }
 542
 543 module LanyardEntryChannelProfile(){
 544   LanyardLanyardProfile(true);
 545 }
 546
 547 module LanyardMainChannelProfile(){
 548   LanyardCurveChannelProfile();
 549   difference(){
 550     square(center=true, ly_r * [6, 2]);
 551     for (xs=[-1,+1])
 552       translate(ly_r * [3 * xs, -1])
 553         circle(r = ly_r);
 554   }
 555 }
 556
 557 module LanyardEntry(){
 558   q_z = -(ly_rc + ly_r);
 559   d_x = -ly_rc;
 560
 561   oec_y = lanyard_entry_rel_breadth * ly_r;
 562
 563   translate([d_x, 0, q_z]) {
 564     intersection(){
 565       rotate([90,0,0])
 566         rotate_extrude(convexity=10)
 567         rotate(90)
 568         translate([0, -q_z])
 569         LanyardCurveChannelProfile();
 570       translate([0,-10,0])
 571         cube([20,20,20]);
 572     }
 573   }
 574
 575   mirror([0,0,1])
 576     translate([0,0,-1])
 577     linear_extrude(height=20)
 578     rotate(-90)
 579     LanyardEntryChannelProfile();
 580
 581   translate([0, ly_r*2, 0])
 582     rotate([90,0,0])
 583     linear_extrude(height = ly_r*4){
 584     difference(){
 585       rectfromto([d_x, q_z], [ly_r, 0]);
 586       circleat([d_x, q_z], ly_rc);
 587     }
 588   }
 589
 590   for (my=[0,1])
 591     mirror([0,my,0]){
 592       translate([0, oec_y, 0]){
 593         difference(){
 594           translate(ly_re * [-1,0,-1])
 595             cube(ly_re * [2,1,1]);
 596           rotate_extrude(convexity=10)
 597             circleat([ly_re + ly_r, 0], ly_re);
 598         }
 599       }
 600     }
 601 }
 602
 603 module LanyardCutout(l){
 604   rotate([0,-90,0])
 605     linear_extrude(height=l)
 606     rotate(-90)
 607     LanyardMainChannelProfile();
 608
 609   for (ee=[0,1]){
 610     translate(ee * l * [-1,0])
 611       mirror([ee,0,0])
 612       LanyardEntry();
 613   }
 614 }
 615
 616 module LidEdgeProfile(){
 617   polygon([ lpp10,
 618             lpp11,
 619             lpp12,
 620             lpp13,
 621             lpp13 + [10, 0],
 622             lpp15 + [10, 0],
 623             lpp15,
 624             lpp14,
 625             ]);
 626   intersection(){
 627     circleat(lpp12, r=lp_r12);
 628     rectfromto( lpp12 + [-10,   0],
 629                 lpp12 + [+10, +10] );
 630   }
 631 }
 632
 633 module LidEdgeFoldClearanceProfile(){
 634   translate([-lid_fold_clearance_antislop, 0])
 635     polygon([ lpp10,
 636               lpp11,
 637               lpp11 + [-20,  0],
 638               lpp11 + [-20, 20],
 639               lpp11 + [+20, 20],
 640               lpp10 + [+20,  0] ]);
 641 }
 642
 643 module ButtonCoverProfile(){
 644   intersection(){
 645     polygon(concat([ bppM, bppP, bppO, bppJ ],
 646                    (enable_support && !$button_suppress_over_keeper
 647                     ? [ bppU, bppV, bppW ] : []),
 648                    [ bppL, bppK ]));
 649     hull(){
 650       EdgeProfile();
 651       LidEdgeProfile();
 652     }
 653   }
 654 }
 655
 656 module ButtonPlan(l, deep, cut){
 657   epsilon =
 658     (cut  ? 0 : lid_buttoncover_gap);
 659
 660   delta =
 661     (deep ? lid_buttoncover_overlap : 0);
 662
 663   C = [0,0]; // by definition
 664   T = [ 0, epp4[1] ];
 665   G = T + [0,10];
 666
 667   B0 = C + [0,-1] * button_cutout_depth;
 668   B1 = B0 + [0,1] * epsilon;
 669
 670   r0 = 0.5 * (T[1] - B0[1]);
 671   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 672   H = A + [0,-1] * delta;
 673
 674   D = A + [-2,0] * r0;
 675   F = D + [0,10];
 676
 677   E0 = 0.5 * (D + A);
 678   E1 = E0 + [1,0] * epsilon;
 679
 680   I0 = [ E0[0], H[1] ];
 681   I1 = [ E1[0], H[1] ];
 682
 683   hull(){
 684     for (m=[0,1]) mirror([m,0])
 685       circleat(H, r0 - epsilon);
 686   }
 687   for (m=[0,1]) mirror([m,0]) {
 688     difference(){
 689       polygon([ E1,
 690                 I1,
 691                 H,
 692                 B1,
 693                 G,
 694                 F,
 695                 D
 696                 ]);
 697       circleat(D, r0 + epsilon);
 698     }
 699   }
 700 }
 701
 702 module CatchCatchProfile(){
 703   hull(){
 704     for (c=[ cppR, cppQ ])
 705       circleat(c, cp_rQ);
 706   }
 707   hull(){
 708     circleat(lpp12, lp_r12);
 709     circleat(lpp12 + [5,0], lp_r12);
 710     rectfromto(cppP, cppP + [5,0.1]);
 711   }
 712   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 713 }
 714
 715 module CatchCutProfile(){
 716   polygon([ cppB,
 717             cppA,
 718             cppD,
 719             cppF,
 720             cppF + [0,-10],
 721             cppF + [-10,-10],
 722             lpp12 + [-10,0],
 723             lpp12 + [10,0]
 724             ]);
 725 }
 726
 727 module Flip_rhs(yn=[0,1]) {
 728   for ($rhsflip=yn) {
 729     translate([phone_width/2, 0, 0])
 730       mirror([$rhsflip,0,0])
 731       translate([-phone_width/2, 0, 0])
 732       children();
 733   }
 734 }
 735
 736 module Flip_bot(yn=[0,1]) {
 737   for ($botflip=yn) {
 738     translate([0, -phone_height/2, 0])
 739       mirror([0, $botflip, 0])
 740       translate([0, phone_height/2, 0])
 741       children();
 742   }
 743 }
 744
 745 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 746   // sides
 747   Flip_rhs(){
 748     translate([0, -phone_cnr_rad, 0])
 749       rotate([90,0,0])
 750       linear_extrude(height = phone_height - phone_cnr_rad*2)
 751       children(0);
 752   }
 753   // corners
 754   Flip_rhs() Flip_bot() {
 755     translate([+1,-1] * phone_cnr_rad)
 756       intersection(){
 757         rotate_extrude()
 758           intersection(){
 759             mirror([1,0,0])
 760               translate([-1,0] * phone_cnr_rad)
 761               children(0);
 762             rectfromto([0,-20],[10,20]);
 763           }
 764         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 765           cube([10,10,40]);
 766       }
 767   }
 768   // top and bottom
 769   Flip_bot(){
 770     translate([ phone_width - phone_cnr_rad, 0,0 ])
 771       rotate([90,0,-90])
 772       linear_extrude(height = phone_width - phone_cnr_rad*2)
 773       children(0);
 774   }
 775   // fill
 776   translate([0,0, fill_zstart])
 777     mirror([0,0, fill_downwards])
 778     linear_extrude(height = fill_th)
 779     rectfromto([+1,-1] * phone_cnr_rad,
 780                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 781 }
 782
 783 module CaseAperture(pos, dia, $fn) {
 784   theta = 180/$fn;
 785   translate([ pos[0] + bumper[0],
 786               -epp2i[0],
 787               -pos[1] ])
 788     rotate([-90, theta, 0])
 789     cylinder(r = dia/2 / cos(theta),
 790              h = 60);
 791 }
 792
 793 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 794   // y_ref_sign:
 795   //   +1  measured from top    of actual phone to top    of button
 796   //   -1  measured from bottom of actual phone to bottom of button
 797   //    0  y is centre of button in coordinate system
 798   $button_l= l;
 799   $button_suppress_over_keeper= suppress_over_keeper;
 800   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 801           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 802           y;
 803   //echo(eff_y);
 804   translate([0, eff_y, 0])
 805     children();
 806 }
 807
 808 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 809   $button_leg_only = true;
 810   SideButton(y, y_ref_sign, l) children();
 811 }
 812
 813 module Buttons(){
 814   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 815   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 816   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 817   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 818 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 819 }
 820
 821 module Struts(x_start, z_min, th){
 822   // if th is negative, starts at z_min and works towards -ve z
 823   // and object should then be printed other way up
 824   for (i= [1 : 1 : case_struts_count]) {
 825     translate([0,
 826                0,
 827                z_min])
 828       mirror([0,0, th<0 ? 1 : 0])
 829       translate([0,
 830                  -phone_height * i / (case_struts_count+1),
 831                  case_struts_solid_below])
 832       linear_extrude(height= abs(th)
 833                      -(case_struts_solid_below+case_struts_solid_above))
 834       rectfromto([               x_start, -0.5 * case_struts_width ],
 835                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 836   }
 837 }
 838
 839 module OrdinaryRearAperture(rhs,bot, pos){
 840   Flip_rhs(rhs) Flip_bot(bot)
 841     linextr(-20, 20)
 842     mirror([0,1])
 843     translate(pos + bumper)
 844     children();
 845 }
 846
 847 module MicroUSB(){
 848   Flip_bot(1){
 849     rotate([90,0,0])
 850       mirror([0,0,1])
 851       linextr(-epp2i[0], 60)
 852       translate([0.5 * phone_width, 0, 0])
 853       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 854                  [+microusb_width/2, epp0[1] + -microusb_above]);
 855   }
 856 }
 857
 858 module OrdinaryRearApertures(){
 859   // rear speaker
 860   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 861     rectfromto(-rearspeaker_gap,
 862                rearspeaker_size + rearspeaker_gap);
 863
 864   // finger hole to remove phone
 865   if (len(fingerpushhole_dias))
 866     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 867                                 phone[1]/2 ])
 868     scale(fingerpushhole_dias)
 869     circle(r= 0.5 );
 870 }
 871
 872 module RearCameraAperture(){
 873   Flip_rhs(1)
 874     mirror([0, 0, 1])
 875     linear_extrude(height = 20)
 876     mirror([0, 1, 0])
 877     translate(bumper)
 878     rectfromto(camera_pos_tl, camera_pos_br);
 879 }
 880
 881 module HingeLidProfile(){
 882   hull(){
 883     circleat(hppT, hp_r1);
 884     circleat(lpp12, lp_r12);
 885     polygon([lpp10,
 886              lpp13 + [2,0],
 887              lpp12,
 888              hppT]);
 889   }
 890 }
 891
 892 module HingeBaseProfile(){
 893   difference(){
 894     hull(){
 895       circleat(hppB, hp_r1);
 896       circleat(hppE, hp_r1);
 897       circleat(epp2o, case_th_bottom);
 898       circleat(hppB + [10,0], hp_r1);
 899     }
 900     polygon([epp5, epp1, epp2i, epp3, bppL]);
 901   }
 902 }
 903
 904 module HingeLeverOuterProfile(){
 905   hull(){
 906     circleat(hppT, hp_r2);
 907     circleat(hppB, hp_r2);
 908   }
 909 }
 910
 911 module HingeLeverInnerProfile(){
 912   for (s = [-1,+1]) {
 913     c = s > 0 ? hppT : hppB;
 914     translate(c)
 915       mirror([0,0,s>0])
 916       rotate(s<0 ? -40 : 0)
 917       hull()
 918       for (x=[-20,20])
 919         for (y=[0, s * 10])
 920           translate([x,y])
 921             circle(hp_rn);
 922   }
 923 }
 924
 925 module HingeLeverNutProfile(){
 926   for (c= [hppB, hppT]) {
 927     translate(c)
 928       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 929   }
 930 }
 931
 932 module Flip_hinge(doflip=1){
 933   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 934   translate(hinge_origin)
 935     rotate([doflip*180,0,0])
 936     translate(-hinge_origin)
 937     children();
 938 }
 939
 940 module HingePortion(x0,x1){
 941   Flip_rhs() Flip_bot(1)
 942     translate([x0,0,0])
 943     mirror([1,0,0])
 944     rotate([90,0,-90])
 945     linear_extrude(height=x1-x0)
 946     children();
 947 }
 948
 949 module CatchPortion(xwidth, ztop){
 950   width = catch_width + xwidth;
 951   w = width + catch_topcurve_r*2 + 1;
 952   translate([phone_width/2, 0,0]){
 953     difference(){
 954       rotate([90,0,-90])
 955         linextr(-w/2, w/2)
 956         children(0);
 957       translate([0, 50, 0])
 958         rotate([90,0,0])
 959         linear_extrude(height=100){
 960         for (m=[0,1]) mirror([m,0,0]) {
 961           hull(){
 962             translate([w/2, ztop - catch_topcurve_r])
 963               circle(catch_topcurve_r);
 964             translate([w/2, -50])
 965               square(catch_topcurve_r*2, center=true);
 966           }
 967         }
 968       }
 969     }
 970   }
 971 }
 972
 973 module CaseBase(){
 974   AroundEdges(epp3[1], case_th_bottom, 1)
 975     EdgeProfile();
 976 }
 977
 978 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 979
 980 module PropProfileAssignments(gamma){
 981   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 982   x = prop_x(gamma);
 983   p = phone_height + prlp10[0] - hppB[0];
 984   b = p + x;
 985
 986   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 987   a = q + x;
 988   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 989   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 990
 991   $prp_theta = 90 - $prp_alpha;
 992   beta = 180 - $prp_alpha - gamma;
 993   psi = 90 - beta;
 994
 995   //echo("abc", a,b,c);
 996
 997   v1 = [ [ cos(psi), -sin(psi) ],    // x
 998          [ sin(psi),  cos(psi) ] ];  // y
 999
1000   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1001
1002   $prp_r1 = prc_r1;
1003   $prp_r11 = prop_main_th/2;
1004
1005   $prpp1 = $prpp7 + [1,0] *
1006     // this is approximate, but will do
1007     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1008   $prpp3 = $prpp1 +
1009     v1[0] * -$prp_r1 +
1010     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1011   $prpp12 = $prpp3 + v1[0] *
1012     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1013   $prp_r8 = prop_main_th;
1014   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1015   $prp_r5 = $prp_r8;
1016   $prpp5 = [ $prpp12[0] - $prp_r5,
1017             $prpp3[1] - prop_prong_h + $prp_r5 ];
1018   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1019          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1020   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1021   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1022
1023   children();
1024 }
1025
1026 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
1027   PropProfileAssignments(gamma){
1028
1029     //#circleat($prpp3,1);
1030     //#circleat($prpp12,1);
1031
1032     if (!cut) {
1033       hull(){
1034         translate($prpp8)
1035           intersection(){
1036             circle($prp_r8);
1037             polygon([[-20,-0], [20,20], [0,0]]);
1038           }
1039         rectfromto($prpp6, $prpp9);
1040         translate($prpp5) intersection(){
1041           circle($prp_r5);
1042           polygon([[-10,-10], [0,0], [10,0]]);
1043         }
1044         rectfromto($prpp12 + [0,-0.1], $prpp3);
1045       }
1046       hull(){
1047         circleat($prpp1, $prp_r1);
1048         rectfromto($prpp12 + [0,-0.1], $prpp3);
1049       }
1050     }
1051     // main shaft
1052     rotate([0,0, rot*-$prp_theta]){
1053       hull(){
1054         extra = cut ? prop_recess_slop : 0;
1055         rectfromto($prpp6, $prpp9);
1056         circleat($prpp11, $prp_r11 + extra);
1057         circleat($prpp10, $prp_r10 + extra);
1058       }
1059     }
1060   }
1061 }
1062
1063 module PropAggregateProfile(){
1064   for (angle = prop_angles)
1065     PropProfile(angle, 0,0);
1066 }
1067
1068 module Prop(){ ////toplevel
1069   hw = prop_main_width/2;
1070   linextr(-hw, +hw)
1071     PropAggregateProfile();
1072 }
1073
1074 module Case(){ ////toplevel
1075   difference(){
1076     union(){
1077       CaseBase();
1078
1079       // ledge (fixed keeper)
1080       Flip_rhs(1-keeper_side) intersection(){
1081         rotate([90, 0, 0])
1082           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1083           KeeperProfile(1);
1084
1085         // outline of the whole case, to stop it protruding
1086         translate([0,0, -25])
1087           linear_extrude(height = 50)
1088           hull()
1089           Flip_bot()
1090           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1091       }
1092
1093       // hinge
1094       HingePortion(hex20, hex21) HingeBaseProfile();
1095
1096       // buildout for prop recess
1097       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1098         linextr(case_bottom_z, epp2i[1])
1099         hull() {
1100           for (dxs = [-1,+1])
1101             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1102                        -epp2o[0] ],
1103                      r = epp2o[0] - prcp2[0]);
1104         }
1105     }
1106
1107     // slot for keeper
1108     Flip_rhs(keeper_side)
1109       translate([0, -phone_cnr_rad, 0])
1110       rotate([90, 0, 0])
1111       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1112       minkowski(){
1113         KeeperProfile();
1114         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1115                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1116       }
1117
1118     // front camera
1119     RearCameraAperture();
1120
1121     // struts (invisible, because they're buried in the case)
1122     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1123
1124     Buttons(){
1125       mirror([1,0,0])
1126         rotate([90,0,90]) {
1127           if (!($button_leg_only && enable_support))
1128           intersection(){
1129             translate([0,0,-10])
1130               linear_extrude(height= 20)
1131               ButtonPlan($button_l, 0,1);
1132             if ($button_leg_only)
1133               rotate([-90,90,0])
1134                 translate([phone_width/2, -400, kppe[1]])
1135                 mirror([1-abs($rhsflip - keeper_side),0,0])
1136                 cube([400, 800, 50]);
1137             if (enable_support && !$button_suppress_over_keeper)
1138               rotate([-90,90,0])
1139               translate([-400, -400, kppd[1]])
1140                 mirror([0,0,1])
1141                 cube([800,800,100]);
1142           }
1143           translate([0,0, -bppR[0]])
1144             linear_extrude(height= 20)
1145             ButtonPlan($button_l, 1,1);
1146         }
1147
1148     }
1149
1150     // apertures along top edge
1151     CaseAperture(jack_pos, jack_dia, 8);
1152     Flip_rhs(1)
1153       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1154
1155     OrdinaryRearApertures();
1156
1157     MicroUSB();
1158
1159     // gaps for the lid's hinge arms
1160     HingePortion(hex20 - hinge_x_arms_gap,
1161                  hex21 + hinge_x_arms_gap)
1162       minkowski(){
1163         HingeLidProfile();
1164         circle(r= hinge_r_arms_gap, $fn= 8);
1165       }
1166
1167     // screw holes in the hinge arms
1168     HingeScrews();
1169
1170     // catch striker
1171     CatchPortion(catch_side_gap*2, epp4[1])
1172       CatchCutProfile();
1173
1174     // prop recess
1175     Flip_rhs(1)
1176       translate([prop_x_pos,0,0])
1177       mirror([0,1,0])
1178       rotate([90,0,90])
1179       linextr(-prop_recess_hw, +prop_recess_hw)
1180       hull(){
1181         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1182           circleat(prcp1 + 20*d,
1183                    prc_r3);
1184       }
1185   }
1186 }
1187
1188 module LidAdhocMultiprintFrame(phase){
1189   if (led_window_style >= 3) {
1190     AdhocMultiprintFrame(phase, lpp13[1], -1);
1191   }
1192 }
1193
1194 module LidAroundEdges(){
1195   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1196     children();
1197 }
1198
1199 module Lid(){ ////toplevel
1200   skew_centre = [0, lpp11[0], lpp11[1]];
1201   difference(){
1202     union(){
1203       intersection(){
1204         LidAroundEdges()
1205           LidEdgeProfile();
1206
1207         translate(skew_centre)
1208           multmatrix([[ 1, 0, 0, 0 ],
1209                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1210                       [ 0, 0, 1, 0 ],
1211                       [ 0, 0, 0, 1 ]])
1212           translate(-skew_centre)
1213           LidAroundEdges()
1214           LidEdgeFoldClearanceProfile();
1215       }
1216
1217       // button covers
1218       Buttons(){
1219         intersection(){
1220           rotate([90,0,90])
1221             translate([0,0,-10])
1222             linear_extrude(height= 20)
1223             ButtonPlan($button_l, 1,0);
1224           rotate([90,0,0])
1225              translate([0,0,-100])
1226             linear_extrude(height= 200)
1227             ButtonCoverProfile();
1228         }
1229       }
1230
1231       // hinge arms
1232       HingePortion(hex20, hex21) {
1233         LidEdgeProfile();
1234         HingeLidProfile();
1235       }
1236
1237       // catch
1238       CatchPortion(0, lpp12[1])
1239         CatchCatchProfile();
1240     }
1241     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1242
1243     // screw holes in the hinge arms
1244     HingeScrews();
1245
1246     // prop recess
1247     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1248       mirror([0,1,0])
1249       rotate([90,0,90])
1250       linextr(-prop_recess_hw, +prop_recess_hw)
1251       hull()
1252       for (pa = prop_angles)
1253         PropProfile(pa, 1,1);
1254
1255     // notification led aperture
1256     if (led_window_style)
1257       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1258         translate([0,0,-10])
1259           cylinder(r=nla_r0, h=20);
1260         if (led_window_style >= 2)
1261           translate([0,0, -nla_t])
1262             cylinder(r=nla_r2, height=20);
1263       }
1264
1265     }
1266
1267   LidAdhocMultiprintFrame(1);
1268 }
1269
1270 module HingeLever(){ ////toplevel
1271   difference() {
1272     // outer body, positive
1273     HingePortion(hex22, hex22 + phone_width/2)
1274       HingeLeverOuterProfile();
1275
1276     // space for the screws
1277     HingePortion(hex26, hex24)
1278       HingeLeverInnerProfile();
1279
1280     // recesses for the nuts
1281     HingePortion(hex23, hex26+1)
1282       HingeLeverNutProfile();
1283
1284     // bores for the screws
1285     HingeScrews();
1286
1287     // space for the charging cable
1288     MicroUSB();
1289     Flip_hinge() MicroUSB();
1290   }
1291 }
1292
1293 module LidWindow(){ ////toplevel
1294   translate([led_pos[0], -led_pos[1], lpp13[1]])
1295     mirror([0,0,1])
1296     cylinder(r= nla_r1, h=nla_t);
1297   LidAdhocMultiprintFrame(0);
1298 }
1299
1300 module LidWindowPrint(){ ////toplevel
1301   rotate([0,180,0])
1302     LidWindow();
1303 }
1304
1305 module DemoLidWindowSelect(){
1306   translate([led_pos[0], led_pos[1], -100]) {
1307     translate([0, -30, 0]) cube([400, 400, 200]);
1308   }
1309 }
1310
1311 module DemoLidWindow(){ ////toplevel
1312   %Lid();
1313   LidWindow();
1314   translate([0,40,0]){
1315     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1316     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1317   }
1318 }
1319
1320 module HingeLeverPrint(){ ////toplevel
1321   rotate([-90,0,0])
1322     translate([-phone_width/2, phone_height, 0])
1323     HingeLever();
1324 }
1325
1326 module TestSelectLength(){
1327   translate([-30, -200, -20])
1328     cube([30 + 15, 250, 40]);
1329 }
1330
1331 module TestLength(){ ////toplevel
1332   intersection(){
1333     Case();
1334     TestSelectLength();
1335   }
1336 }
1337
1338 module TestLengthRight(){ ////toplevel
1339   intersection(){
1340     Case();
1341     Flip_rhs(1)
1342       TestSelectLength();
1343   }
1344 }
1345
1346 module TestSelectWidth(){
1347   translate([-30, -(phone_height - 25), -20])
1348     mirror([0, 1, 0])
1349     cube([200, 50, 40]);
1350 }
1351
1352 module TestWidth(){ ////toplevel
1353   intersection(){
1354     Case();
1355     TestSelectWidth();
1356   }
1357 }
1358
1359 module TestLidWidthPrint(){ ////toplevel
1360   rotate([0,180.0]) intersection(){
1361     Lid();
1362     TestSelectWidth();
1363   }
1364 }
1365
1366 module TestSelectRearAperture(){
1367   minkowski(){
1368     union() children();
1369     translate([20, 0,0])
1370       cube([42, 2, 1], center=true);
1371   }
1372 }
1373
1374 module TestSelectCamera(){
1375   minkowski(){
1376     TestSelectRearAperture()
1377       RearCameraAperture();
1378     cube([0.1, 50, 0.1]);
1379   }
1380 }
1381
1382 module TestSelectOrdinaryRearApertures(){
1383   TestSelectRearAperture()
1384     OrdinaryRearApertures();
1385 }
1386
1387 module TestCamera(){ ////toplevel
1388   intersection(){
1389     Case();
1390     TestSelectCamera();
1391   }
1392 }
1393
1394 module TestLidByCamera(){ ////toplevel
1395   intersection(){
1396     Lid();
1397     TestSelectCamera();
1398   }
1399 }
1400
1401 module TestLidByCameraPrint(){ ////toplevel
1402   rotate([180,0,0]) TestLidByCamera();
1403 }
1404
1405 module DemoByCamera(){ ////toplevel
1406   color("blue") TestLidByCamera();
1407   color("red")  TestCamera();
1408 }
1409
1410 module OneKeeper(){ ////toplevel
1411   translate([0, -phone_cnr_rad, 0])
1412     rotate([90, 0, 0])
1413     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1414     KeeperProfile();
1415 }
1416
1417 module OneKeeperPrint(){ ////toplevel
1418   rotate([0,180,0])
1419     OneKeeper();
1420 }
1421
1422 module LidPrint(){ ////toplevel
1423   rotate([0,180,0])
1424     Lid();
1425 }
1426
1427 module TestSelectFrame(){
1428   include = [1,-1] * (epp2i[0] + 4);
1429
1430   difference(){
1431     cube(1000, center=true);
1432     translate([0,0, -100])
1433       linear_extrude(height=200)
1434       rectfromto(include,  inside_br - include);
1435   }
1436 }
1437
1438 module TestSelectLidFrame(){
1439   TestSelectFrame();
1440   translate([led_pos[0], -led_pos[1], -50])
1441     cylinder(r= nla_r2+3, h=100);
1442 }
1443
1444 module TestFrameCase(){ ////toplevel
1445   intersection(){
1446     Case();
1447     union(){
1448       TestSelectFrame();
1449       TestSelectCamera();
1450       TestSelectOrdinaryRearApertures();
1451     }
1452   }
1453 }
1454
1455 module TestSelectTopApertures(){
1456   translate([-100, -35, -100])
1457     cube([400, 100, 200]);
1458   LidAdhocMultiprintFrame(0);
1459   LidAdhocMultiprintFrame(1);
1460 }
1461
1462 module TestTopApertures(){ ////toplevel
1463   intersection(){
1464     Case();
1465     TestSelectFrame();
1466     TestSelectTopApertures();
1467   }
1468 }
1469
1470 module TestLidTopAperturesPrint(){ ////toplevel
1471   rotate([0,180,0]) intersection(){
1472     Lid();
1473     TestSelectLidFrame();
1474     TestSelectTopApertures();
1475   }
1476 }
1477
1478 module TestLidWindowTopAperturesPrint(){ ////toplevel
1479   rotate([0,180,0]) intersection(){
1480     LidWindow();
1481     TestSelectTopApertures();
1482   }
1483 }
1484
1485 module TestFrameLidPrint(){ ////toplevel
1486   rotate([0,180,0]) intersection(){
1487     Lid();
1488     TestSelectLidFrame();
1489   }
1490 }
1491
1492 module ButtonPlanForDemo(z, deep, cut){
1493   translate([0,0,z])
1494     ButtonPlan(8, deep, cut);
1495 }
1496
1497 module HingeScrews(){
1498   Flip_rhs() Flip_bot(1){
1499     for (c= [ hppT, hppB ])
1500       translate([ hex20,
1501                   -c[0],
1502                   c[1] ]){
1503         rotate([0,90,0])
1504           translate([0,0,-.2])
1505           cylinder( r= hingescrew_shaft_dia/2,
1506                     h = hingescrew_shaft_len+0.2 );
1507         rotate([0,-90,0])
1508           translate([0,0,+.1])
1509           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1510       }
1511   }
1512 }
1513
1514 module DemoPropAngleSelect(c){
1515   color(c) difference(){
1516     union(){ children(); }
1517     translate([ prop_x_pos, -400, -200 ])
1518       cube([ 400,800,400 ]);
1519   }
1520 }
1521
1522 module DemoPropAngle(ang){
1523   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1524   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1525
1526   translate(hL)
1527     rotate([ang/2,0,0])
1528     translate(-hL)
1529     translate(hC)
1530     rotate([ang/2,0,0])
1531     translate(-hC) {
1532       DemoPropAngleSelect("red") Case();
1533
1534       color("orange")
1535         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1536         PropProfileAssignments(ang) {
1537           echo($prpp1);
1538           rotate([-$prp_theta, 0, 0])
1539           translate([0, $prpp1[0], -$prpp1[1]])
1540           rotate([90,0,-90])
1541           Prop();
1542         }
1543     }
1544
1545   translate([0,0, -hp_k*2])
1546     DemoPropAngleSelect("blue")
1547     Lid();
1548 }
1549
1550 module DemoPropAngles(){ ////toplevel
1551   for (i=[0 : len(prop_angles)-1])
1552     translate(i * [0, -100, 100])
1553     DemoPropAngle(prop_angles[i]);
1554 }
1555
1556 module DemoHingeAngle(ang1,ang2){
1557   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1558   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1559
1560   translate(hL)
1561     rotate([ang2,0,0])
1562     translate(-hL)
1563     translate(hC)
1564     rotate([ang1,0,0])
1565     translate(-hC) {
1566       color("red") Lid();
1567     }
1568
1569   color("blue") intersection(){
1570     Case();
1571     union(){
1572       translate([bppJ[0], -400, -200])
1573         mirror([1,0,0])
1574         cube([400, 800, 400]);
1575       translate([10, -400, -200])
1576         cube([10, 800, 400]);
1577     }
1578   }
1579 }
1580
1581 module DemoHingeAngles(){ ////toplevel
1582   angles = [ 0, 4, 8, 12 ];
1583   echo("angles",angles);
1584   for (i=[0 : len(angles)-1]) {
1585     translate(i * [0, 0, 30]) {
1586       DemoHingeAngle(0,angles[i]);
1587       translate([0, 200, 0])
1588         DemoHingeAngle(angles[i],0);
1589     }
1590   }
1591 }
1592
1593 module DemoSelectAdhocLeftRight(right=0) {
1594   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1595     mirror([1-right, 0,0])
1596     cube([400, 800, 200]);
1597 }
1598
1599 module DemoLeft(){ ////toplevel
1600   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1601   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1602 }
1603
1604 module DemoFrame(){ ////toplevel
1605   color("red") TestFrameCase();
1606   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1607   color("black") HingeScrews();
1608   %HingeLever();
1609 }
1610
1611 module DemoLanyardCutout(){ ////toplevel
1612   LanyardCutout(25);
1613 }
1614
1615 module DemoHingedFrame(){ ///toplevel
1616   color("red") TestFrameCase();
1617   translate([0,0, -2*hp_k])
1618   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1619
1620   Flip_hinge(){
1621     color("orange") HingeLever();
1622     color("black") HingeScrews();
1623   }
1624 }
1625
1626 module DemoHinge(){ ////toplevel
1627   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1628     DemoFrame();
1629     translate([0,0, -hp_k*3])
1630       DemoHingedFrame();
1631   }
1632 }
1633
1634 module DemoProfiles(){ ////toplevel
1635   LidEdgeProfile();
1636   %EdgeProfile();
1637   KeeperProfile();
1638   translate([0,0,-1]) color("black") KeeperProfile(1);
1639   color("purple") translate(epp2i)
1640     rotate(atan2vector(epp2i - epp1)) {
1641     translate(lanyard_half_dia * 0.5 * [-3,-1])
1642       LanyardLanyardProfile();
1643     translate(lanyard_half_dia * 0.5 * [-3,+1])
1644       translate([0,-1] * case_th_side)
1645       LanyardLanyardProfile(true);
1646   }
1647
1648   translate([0,20]) {
1649     LanyardMainChannelProfile();
1650     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1651     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1652   }
1653
1654   translate([20,0]) {
1655     LidEdgeProfile();
1656     %EdgeProfile();
1657
1658     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1659
1660     color("blue") ButtonCoverProfile();
1661     color("red") {
1662       rectfromto(bppQ, demopoint_QR);
1663       rectfromto(bppR, demopoint_QR);
1664     }
1665   }
1666
1667   translate([-20,0]) {
1668     color("black") ButtonPlanForDemo(-2, 0,1);
1669     color("red" )  ButtonPlanForDemo(-4, 1,1);
1670     color("blue")  ButtonPlanForDemo(-6, 1,0);
1671   }
1672
1673   translate([0, -30]) {
1674     %LidEdgeProfile();
1675     %EdgeProfile();
1676     color("blue") HingeLidProfile();
1677     color("red")  HingeBaseProfile();
1678     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1679   }
1680
1681   for (f=[0,1]) {
1682     translate([-30, -60 + 30*f]) {
1683       translate([0,0,-4]) EdgeProfile();
1684       %translate([0,0,-10]) HingeBaseProfile();
1685       translate([0,-2] * f * hp_k) {
1686         translate([0,0,-4]) LidEdgeProfile();
1687         %translate([0,0,-10]) %HingeLidProfile();
1688       }
1689       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1690         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1691         translate([0,0,0]) color("red") difference(){
1692           HingeLeverOuterProfile();
1693           HingeLeverInnerProfile();
1694         }
1695         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1696       }
1697     }
1698   }
1699
1700   translate([20,-30]) {
1701     %EdgeProfile();
1702     %LidEdgeProfile();
1703     //translate([0,0,1]) CatchCutProfile();
1704     color("blue") CatchCatchProfile();
1705     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1706   }
1707
1708   translate([40,-30]) {
1709     difference(){
1710       LidEdgeProfile();
1711       translate(prlp10)
1712         PropProfile(10, 1, 0);
1713     }
1714     translate(prlp10)
1715       PropProfile(15, 0);
1716   }
1717   translate([60,-30]) {
1718     PropAggregateProfile();
1719   }
1720 }
1721
1722 //EdgeProfile();
1723 //KeeperProfile();
1724 //CaseBase();
1725 //%Case();
1726 //Keeper();
1727 //LidEdgeProfile();
1728 //KeeperProfile();
1729 //DemoProfiles();
1730 //PropRecess();