fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172 lanyard_entry_rel_breadth = 2;
 173 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 174 rearspeaker_size   = [  3.76,  7.36 ];
 175
 176 microusb_above = 3.27 - 0.25;
 177 microusb_below = 0.0;
 178 microusb_width = 16.12 + 1.25;
 179
 180 case_th_bottom = 2.5;
 181 case_th_lid = 3.0;
 182 case_th_side = 2.3;
 183 case_th_lip = 1.2;
 184
 185 lid_screen_gap_extra = .66;
 186
 187 case_struts_count = 6;
 188 case_struts_solid_below = 1.00;
 189 case_struts_solid_above = 0.75;
 190 case_struts_width = 0.10;
 191
 192 keeper_th_z = 0.75;
 193 keeper_th_x = 0.75;
 194 keeper_inner_width = 2.75;
 195 keeper_inner_height = 2.75;
 196 keeper_slant_slope = 2; // larger means steeper
 197
 198 keeper_gap_z_top = 0.25;
 199 keeper_gap_z_bot = 0.75;
 200 keeper_gap_x     = 0.25;
 201 keeper_gap_x_holes = 0.75;
 202
 203 keeper_side = 0; // 0 = lhs; 1 = rhs
 204
 205 case_lip = 1.25;
 206
 207 lid_gap_x = 0.25;
 208 lid_gap_z = 0.25;
 209 lid_lip = 1.75;
 210 lid_edgepart_width = 5.0;
 211 lid_buttoncover_thick = 1.3;
 212
 213 catch_slop = 0.50;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // properties of the hinge fasteners
 219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 220 hingescrew_shaft_len = 12;
 221 hingescrew_fasteners_extra_thick = 0.40;
 222 // ^ amount of thread protruding if everything was completely nominal
 223 //   and we are using two nuts
 224 hingescrew_nut_access_dia = 4.72 + 0.50;
 225 // ^ washer is 4.72 dia
 226 //   also, want to get pliers or tiny spanner in to do up locknut
 227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 228 hingescrew_nut_thick = 1.93;
 229 hingescrew_head_th = 1.38 + 0.75;
 230 hingescrew_head_dia = 3.92;
 231
 232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 233
 234 lever_cover_th = 0.75;
 235 hingemount_th = 2.5;
 236 hingemount_wd = 4.8725;
 237
 238 $fa = 5;
 239 $fs = 0.1;
 240
 241 button_l_fudge = 4.4;
 242 buttonishleg_default_l_is_fudge = 10;
 243
 244 hinge_base_slope = 1.5; // bigger is steeper
 245
 246 strut_min_at_end = 1.5;
 247
 248 hinge_x_gap = 0.125;
 249 hinge_x_postscrew_gap = 0.75;
 250 hinge_x_arms_gap = 0.35;
 251 hinge_r_arms_gap = 0.55;
 252
 253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 254
 255 catch_len = 7.5;
 256 catch_width = 15;
 257 catch_thickness = 1.0;
 258 catch_side_gap = 0.75; // each side
 259
 260 catch_depth = 0.75;
 261 catch_height = 0.35;
 262 catch_finger_height = 1.5;
 263 catch_finger_depth = 2.5;
 264
 265 catch_topcurve_r = 5.0;
 266
 267 prop_recess_under = 0.50;
 268 prop_recess_slop = 0.200; // each side
 269 prop_end_dia = 0.5;
 270 prop_main_th = 3;
 271 prop_taper_len = 6;
 272 prop_main_width = 4;
 273 prop_side_gap = 0.75; // each side
 274 prop_lidrecess_behind = 0.75;
 275 prop_caserecess_behind = 0.75;
 276 prop_caserecess_taper = 0.45; // one side only
 277 prop_prop_gap = 0.5;
 278 prop_prong_heel_slope = 0.5;
 279
 280 lid_fold_clearance_antislop = 0.5;
 281
 282 // ---------- calculated ----------
 283
 284 phone_width =  (phone + bumper*2)[0];
 285 phone_height = (phone + bumper*2)[1];
 286
 287 inside_br = [phone_width, -phone_height];
 288
 289 prop_prong_h = prop_main_th;
 290
 291 //echo(camera_pos_tl + bumper,
 292 //     camera_pos_br + bumper);
 293
 294 // ----- could be changed -----
 295 lid_buttoncover_gap = lid_gap_x;
 296 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 297
 298 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 299
 300 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 301
 302 //prop_nose_len = case_th_lid - prop_recess_under;
 303 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 304 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 305
 306
 307 //lid_lip_overlap_width xxx bad name = ;
 308 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 309
 310 epp0 = [0,0];
 311 epp1 = [0, -phone_edge_thick];
 312 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 313 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 314 epp3 = epp2i + [10, 0];
 315 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 316 epp4 = epp5 + [-1,0] * case_th_side;
 317
 318 kppe = [0,0];
 319 kppd = kppe + [1,0] * keeper_inner_width;
 320 kppc = kppd + [0,1] * keeper_th_z;
 321 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 322 kppf = kppe - [0,1] * keeper_inner_height;
 323 kppa = [ kppb[0], kppf[1] ];
 324
 325 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 326 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 327
 328 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 329 // exact x posn not very important; must extend past end of keeper
 330
 331 lpp15 = [ lpp14[0],
 332           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 333           + lid_screen_gap_extra ];
 334 // ^ beam theory says to maximise force before contact,
 335 //   the gap below the `beam' (the lid) must be 1/3
 336 //   the thickness (ie the lid thickness) if the beam
 337 //   is solid, or 1/2 if it has a top and bottom only.
 338 //   ours is mostly solid.
 339
 340 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 341              case_th_lip);
 342
 343 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 344 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 345
 346 case_bottom_z = epp2o[1] - case_th_bottom;
 347
 348 // button profile
 349 bppM = epp4 + [0,5];
 350 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 351 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 352 bppS = [ epp1[0], bppR[1] ];
 353 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 354 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 355 bppO = [ bppN[0], bppP[1] ];
 356 bppL = lpp10 + [5,0];
 357 bppK = [ bppL[0], bppN[1] ];
 358 bppJ = [ bppN[0], bppL[1] ];
 359 bppU = [ bppJ[0], lpp12[1] ];
 360 bppV = lpp11;
 361 bppW = lpp10;
 362
 363 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 364
 365 // notification led aperture
 366
 367 nla_r0 = led_aperture/2;
 368 nla_r1 = nla_r0 + led_window_ledge;
 369 nla_r2 = nla_r1 + multicolour_gap;
 370 nla_t =
 371   led_window_style >= 3 ? initial_layer_thick :
 372   led_window_style >= 2 ? led_window_ledge : 0;
 373
 374
 375 // hinge plan
 376 hp_rn = hingescrew_nut_access_dia/2;
 377 hp_r2_min = hp_rn + lever_cover_th;
 378 hp_rs = hingescrew_shaft_dia/2;
 379 hp_r1_min = hp_rs + hingemount_th;
 380
 381 hp_r1 = max(hp_r1_min, hp_r2_min);
 382 hp_r2 = hp_r1;
 383
 384 hppU = lpp13;
 385 hppS = epp2o + [0,-1] * case_th_bottom;
 386 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 387
 388 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 389          0.5 * (hppU + hppS)[1] ];
 390 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 391 hppB = hppT + [0,-1] * hp_k;
 392
 393 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 394 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 395 hppE = [ hppE_x, hppE_y ];
 396
 397 // hinge elevation x coords
 398
 399 hex20 = max(epp2o[0],
 400             phone_cnr_rad,
 401             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 402 hex21 = hex20 + hingemount_wd;
 403 hex22 = hex21 + hinge_x_gap;
 404 hex27 = hex20 + hingescrew_shaft_len;
 405 hex24 = hex27 + hinge_x_postscrew_gap;
 406 hex23 = hex27 - (hingescrew_nut_thick*2
 407                  + hingescrew_fasteners_extra_thick);
 408 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 409
 410 echo(hex20, hex21, hex22, hex23, hex24);
 411 //  6, 10.8725, 10.9975, 13.74, 18.75
 412 module chk(act,exp) {
 413   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 414   else echo("ok", act);
 415 }
 416 chk(hex20, 6);
 417 chk(hex21, 10.8725);
 418 chk(hex22, 10.9975);
 419 chk(hex23, 13.74);
 420 chk(hex24, 18.75);
 421
 422 lid_fold_clearance_skew =
 423   (lpp10[1] - hppB[1]) /
 424   (lpp10[0] - hppB[0]);
 425
 426 echo("SK",lid_fold_clearance_skew);
 427
 428 // catch
 429
 430 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 431 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 432 cppB = [ epp0[0], cppA[1] ];
 433 cppP = [ epp4[0], cppJ[1] ];
 434
 435 cppS = cppJ + [0,-1] * catch_len;
 436 cppD = [ cppA[0], cppS[1] + catch_slop ];
 437 cppC = [ cppB[0], cppD[1] ];
 438 cppT = cppS + [1,0] * catch_depth;
 439 cppU = cppT + [0,-1] * catch_height;
 440 cppV = [ cppS[0], cppU[1] - catch_depth ];
 441
 442 cppR = 0.5*(cppP + cppJ);
 443
 444 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 445 cppQ = [ cppR[0],
 446          cppV[1] - (catch_finger_height - cp_rQ) ];
 447 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 448
 449 // lanyard
 450
 451 ly_r = lanyard_half_dia / 2;
 452 ly_rc = ly_r * 2;
 453
 454 ly_theta = -atan2vector(epp2i - epp1);
 455 ly_o = epp2i + 3 * ly_r * unitvector2d(epp1 - epp2i);
 456
 457 max_case_bottom_edge_thickness =
 458   case_th_bottom
 459   + sin(ly_theta) * (epp2i-epp2o)[0];
 460
 461 ly_q_z = -(ly_rc + ly_r);
 462 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 463
 464 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 465
 466 // prop recess in case
 467
 468 prop_x_pos = phone_width/2;
 469
 470 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 471
 472 prc_r1 = prop_end_dia/2;
 473 prc_r3 = prc_r1 + prop_recess_slop;
 474
 475 prcp2 = [ epp4[0] + prop_buildout_less,
 476           case_bottom_z ];
 477
 478 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 479
 480 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 481           epp2i[1] - prc_r3 - prop_recess_under];
 482
 483 // prop recess in lid
 484
 485 prl_r10 = prop_end_dia/2;
 486 prl_r10o = prl_r10 + prop_recess_slop;
 487
 488 prlp10 = lpp10 + [1,1] * prl_r10o
 489   + [1,0] * prop_lidrecess_behind
 490   + [0,1] * prop_recess_under;
 491
 492 // prop
 493
 494 $prpp10 = [0,0];
 495 $prpp11 = [0, prop_taper_len];
 496
 497 $prp_r10 = prl_r10;
 498
 499 // ---------- modules ----------
 500
 501 module AdhocMultiprintFrame(phase, z0, zs) {
 502   // from z0 to z0 + zs*layer
 503   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 504   xextra = extra + -epp4[0];
 505   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 506   yextra = extra + -epp4[0];
 507   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 508   p0 = [ xrange[0], yrange[0] ];
 509   p1 = [ xrange[1], yrange[1] ];
 510   echo(p0, p1);
 511   translate([0,0, z0])
 512     mirror([0,0, zs<0 ? 1 : 0])
 513     linear_extrude(height= initial_layer_thick)
 514     difference(){
 515       rectfromto(p0 - [1,1] * initial_layer_width,
 516                  p1 + [1,1] * initial_layer_width);
 517       rectfromto(p0, p1);
 518     }
 519 }
 520
 521 module KeeperProfile(slant=0){
 522   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 523   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 524 }
 525
 526 module EdgeProfile(){
 527   difference(){
 528     hull(){
 529       translate(epp3) square(case_th_bottom*2, center=true);
 530       circleat(epp2o, r=case_th_bottom);
 531       circleat(epp1, r=case_th_side);
 532       rectfromto(epp0, epp4);
 533     }
 534     polygon([ epp5 + [0,10],
 535               epp1,
 536               epp2i,
 537               epp3 + [10,0] ]);
 538   }
 539 }
 540
 541 module LanyardLanyardProfile(entry=false){
 542   hull(){
 543     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 544       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 545         circle(r= lanyard_half_dia/2);
 546   }
 547 }
 548
 549 module LanyardCurveChannelProfile(){
 550   translate([0, -ly_r])
 551     LanyardLanyardProfile();
 552 }
 553
 554 module LanyardEntryChannelProfile(){
 555   LanyardLanyardProfile(true);
 556 }
 557
 558 module LanyardMainChannelProfile(){
 559   LanyardCurveChannelProfile();
 560   difference(){
 561     square(center=true, ly_r * [6, 2]);
 562     for (xs=[-1,+1])
 563       translate(ly_r * [3 * xs, -1])
 564         circle(r = ly_r);
 565   }
 566 }
 567
 568 module LanyardEntryOuterProfile(){
 569   circleat([ly_re + ly_r, 0], ly_re);
 570 }
 571
 572 module LanyardEntry(){
 573   q_z = ly_q_z;
 574   oec_y = ly_oec_y;
 575
 576   d_x = -ly_rc;
 577
 578   translate([d_x, 0, q_z]) {
 579     intersection(){
 580       rotate([90,0,0])
 581         rotate_extrude(convexity=10)
 582         rotate(90)
 583         translate([0, -q_z])
 584         LanyardCurveChannelProfile();
 585       translate([0,-10,0])
 586         cube([20,20,20]);
 587     }
 588   }
 589
 590   mirror([0,0,1])
 591     translate([0,0,-1])
 592     linear_extrude(height=20)
 593     rotate(-90)
 594     LanyardEntryChannelProfile();
 595
 596   translate([0, ly_r*2, 0])
 597     rotate([90,0,0])
 598     linear_extrude(height = ly_r*4){
 599     difference(){
 600       rectfromto([d_x, q_z], [ly_r, 0]);
 601       circleat([d_x, q_z], ly_rc);
 602     }
 603   }
 604
 605   translate([0,0,q_z]){
 606     for (my=[0,1])
 607       mirror([0,my,0]){
 608         translate([0, oec_y, 0]){
 609           difference(){
 610             translate(ly_re * [-1,0,-2])
 611               cube(ly_re * [2,1,2]);
 612             rotate_extrude(convexity=10)
 613               LanyardEntryOuterProfile();
 614           }
 615         }
 616       }
 617     difference(){
 618       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 619         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 620       for (mx=[0,1])
 621         mirror([mx,0,0])
 622           rotate([90,0,0])
 623           translate([0,0,-10])
 624           linear_extrude(height=20)
 625           LanyardEntryOuterProfile();
 626     }
 627   }
 628 }
 629
 630 module LanyardCutout(l){
 631   rotate([0,-90,0])
 632     linear_extrude(height=l)
 633     rotate(-90)
 634     LanyardMainChannelProfile();
 635
 636   for (ee=[0,1]){
 637     translate(ee * l * [-1,0])
 638       mirror([ee,0,0])
 639       LanyardEntry();
 640   }
 641 }
 642
 643 module LidEdgeProfile(){
 644   polygon([ lpp10,
 645             lpp11,
 646             lpp12,
 647             lpp13,
 648             lpp13 + [10, 0],
 649             lpp15 + [10, 0],
 650             lpp15,
 651             lpp14,
 652             ]);
 653   intersection(){
 654     circleat(lpp12, r=lp_r12);
 655     rectfromto( lpp12 + [-10,   0],
 656                 lpp12 + [+10, +10] );
 657   }
 658 }
 659
 660 module LidEdgeFoldClearanceProfile(){
 661   translate([-lid_fold_clearance_antislop, 0])
 662     polygon([ lpp10,
 663               lpp11,
 664               lpp11 + [-20,  0],
 665               lpp11 + [-20, 20],
 666               lpp11 + [+20, 20],
 667               lpp10 + [+20,  0] ]);
 668 }
 669
 670 module ButtonCoverProfile(){
 671   intersection(){
 672     polygon(concat([ bppM, bppP, bppO, bppJ ],
 673                    (enable_support && !$button_suppress_over_keeper
 674                     ? [ bppU, bppV, bppW ] : []),
 675                    [ bppL, bppK ]));
 676     hull(){
 677       EdgeProfile();
 678       LidEdgeProfile();
 679     }
 680   }
 681 }
 682
 683 module ButtonPlan(l, deep, cut){
 684   epsilon =
 685     (cut  ? 0 : lid_buttoncover_gap);
 686
 687   delta =
 688     (deep ? lid_buttoncover_overlap : 0);
 689
 690   C = [0,0]; // by definition
 691   T = [ 0, epp4[1] ];
 692   G = T + [0,10];
 693
 694   B0 = C + [0,-1] * button_cutout_depth;
 695   B1 = B0 + [0,1] * epsilon;
 696
 697   r0 = 0.5 * (T[1] - B0[1]);
 698   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 699   H = A + [0,-1] * delta;
 700
 701   D = A + [-2,0] * r0;
 702   F = D + [0,10];
 703
 704   E0 = 0.5 * (D + A);
 705   E1 = E0 + [1,0] * epsilon;
 706
 707   I0 = [ E0[0], H[1] ];
 708   I1 = [ E1[0], H[1] ];
 709
 710   hull(){
 711     for (m=[0,1]) mirror([m,0])
 712       circleat(H, r0 - epsilon);
 713   }
 714   for (m=[0,1]) mirror([m,0]) {
 715     difference(){
 716       polygon([ E1,
 717                 I1,
 718                 H,
 719                 B1,
 720                 G,
 721                 F,
 722                 D
 723                 ]);
 724       circleat(D, r0 + epsilon);
 725     }
 726   }
 727 }
 728
 729 module CatchCatchProfile(){
 730   hull(){
 731     for (c=[ cppR, cppQ ])
 732       circleat(c, cp_rQ);
 733   }
 734   hull(){
 735     circleat(lpp12, lp_r12);
 736     circleat(lpp12 + [5,0], lp_r12);
 737     rectfromto(cppP, cppP + [5,0.1]);
 738   }
 739   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 740 }
 741
 742 module CatchCutProfile(){
 743   polygon([ cppB,
 744             cppA,
 745             cppD,
 746             cppF,
 747             cppF + [0,-10],
 748             cppF + [-10,-10],
 749             lpp12 + [-10,0],
 750             lpp12 + [10,0]
 751             ]);
 752 }
 753
 754 module Flip_rhs(yn=[0,1]) {
 755   for ($rhsflip=yn) {
 756     translate([phone_width/2, 0, 0])
 757       mirror([$rhsflip,0,0])
 758       translate([-phone_width/2, 0, 0])
 759       children();
 760   }
 761 }
 762
 763 module Flip_bot(yn=[0,1]) {
 764   for ($botflip=yn) {
 765     translate([0, -phone_height/2, 0])
 766       mirror([0, $botflip, 0])
 767       translate([0, phone_height/2, 0])
 768       children();
 769   }
 770 }
 771
 772 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 773   // sides
 774   Flip_rhs(){
 775     translate([0, -phone_cnr_rad, 0])
 776       rotate([90,0,0])
 777       linear_extrude(height = phone_height - phone_cnr_rad*2)
 778       children(0);
 779   }
 780   // corners
 781   Flip_rhs() Flip_bot() {
 782     translate([+1,-1] * phone_cnr_rad)
 783       intersection(){
 784         rotate_extrude()
 785           intersection(){
 786             mirror([1,0,0])
 787               translate([-1,0] * phone_cnr_rad)
 788               children(0);
 789             rectfromto([0,-20],[10,20]);
 790           }
 791         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 792           cube([10,10,40]);
 793       }
 794   }
 795   // top and bottom
 796   Flip_bot(){
 797     translate([ phone_width - phone_cnr_rad, 0,0 ])
 798       rotate([90,0,-90])
 799       linear_extrude(height = phone_width - phone_cnr_rad*2)
 800       children(0);
 801   }
 802   // fill
 803   translate([0,0, fill_zstart])
 804     mirror([0,0, fill_downwards])
 805     linear_extrude(height = fill_th)
 806     rectfromto([+1,-1] * phone_cnr_rad,
 807                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 808 }
 809
 810 module CaseAperture(pos, dia, $fn) {
 811   theta = 180/$fn;
 812   translate([ pos[0] + bumper[0],
 813               -epp2i[0],
 814               -pos[1] ])
 815     rotate([-90, theta, 0])
 816     cylinder(r = dia/2 / cos(theta),
 817              h = 60);
 818 }
 819
 820 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 821   // y_ref_sign:
 822   //   +1  measured from top    of actual phone to top    of button
 823   //   -1  measured from bottom of actual phone to bottom of button
 824   //    0  y is centre of button in coordinate system
 825   $button_l= l;
 826   $button_suppress_over_keeper= suppress_over_keeper;
 827   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 828           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 829           y;
 830   //echo(eff_y);
 831   translate([0, eff_y, 0])
 832     children();
 833 }
 834
 835 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 836   $button_leg_only = true;
 837   SideButton(y, y_ref_sign, l) children();
 838 }
 839
 840 module Buttons(){
 841   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 842   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 843   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 844   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 845 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 846 }
 847
 848 module Struts(x_start, z_min, th){
 849   // if th is negative, starts at z_min and works towards -ve z
 850   // and object should then be printed other way up
 851   for (i= [1 : 1 : case_struts_count]) {
 852     translate([0,
 853                0,
 854                z_min])
 855       mirror([0,0, th<0 ? 1 : 0])
 856       translate([0,
 857                  -phone_height * i / (case_struts_count+1),
 858                  case_struts_solid_below])
 859       linear_extrude(height= abs(th)
 860                      -(case_struts_solid_below+case_struts_solid_above))
 861       rectfromto([               x_start, -0.5 * case_struts_width ],
 862                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 863   }
 864 }
 865
 866 module OrdinaryRearAperture(rhs,bot, pos){
 867   Flip_rhs(rhs) Flip_bot(bot)
 868     linextr(-20, 20)
 869     mirror([0,1])
 870     translate(pos + bumper)
 871     children();
 872 }
 873
 874 module MicroUSB(){
 875   Flip_bot(1){
 876     rotate([90,0,0])
 877       mirror([0,0,1])
 878       linextr(-epp2i[0], 60)
 879       translate([0.5 * phone_width, 0, 0])
 880       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 881                  [+microusb_width/2, epp0[1] + -microusb_above]);
 882   }
 883 }
 884
 885 module OrdinaryRearApertures(){
 886   // rear speaker
 887   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 888     rectfromto(-rearspeaker_gap,
 889                rearspeaker_size + rearspeaker_gap);
 890
 891   // finger hole to remove phone
 892   if (len(fingerpushhole_dias))
 893     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 894                                 phone[1]/2 ])
 895     scale(fingerpushhole_dias)
 896     circle(r= 0.5 );
 897 }
 898
 899 module RearCameraAperture(){
 900   Flip_rhs(1)
 901     mirror([0, 0, 1])
 902     linear_extrude(height = 20)
 903     mirror([0, 1, 0])
 904     translate(bumper)
 905     rectfromto(camera_pos_tl, camera_pos_br);
 906 }
 907
 908 module HingeLidProfile(){
 909   hull(){
 910     circleat(hppT, hp_r1);
 911     circleat(lpp12, lp_r12);
 912     polygon([lpp10,
 913              lpp13 + [2,0],
 914              lpp12,
 915              hppT]);
 916   }
 917 }
 918
 919 module HingeBaseProfile(){
 920   difference(){
 921     hull(){
 922       circleat(hppB, hp_r1);
 923       circleat(hppE, hp_r1);
 924       circleat(epp2o, case_th_bottom);
 925       circleat(hppB + [10,0], hp_r1);
 926     }
 927     polygon([epp5, epp1, epp2i, epp3, bppL]);
 928   }
 929 }
 930
 931 module HingeLeverOuterProfile(){
 932   hull(){
 933     circleat(hppT, hp_r2);
 934     circleat(hppB, hp_r2);
 935   }
 936 }
 937
 938 module HingeLeverInnerProfile(){
 939   for (s = [-1,+1]) {
 940     c = s > 0 ? hppT : hppB;
 941     translate(c)
 942       mirror([0,0,s>0])
 943       rotate(s<0 ? -40 : 0)
 944       hull()
 945       for (x=[-20,20])
 946         for (y=[0, s * 10])
 947           translate([x,y])
 948             circle(hp_rn);
 949   }
 950 }
 951
 952 module HingeLeverNutProfile(){
 953   for (c= [hppB, hppT]) {
 954     translate(c)
 955       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 956   }
 957 }
 958
 959 module Flip_hinge(doflip=1){
 960   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 961   translate(hinge_origin)
 962     rotate([doflip*180,0,0])
 963     translate(-hinge_origin)
 964     children();
 965 }
 966
 967 module HingePortion(x0,x1){
 968   Flip_rhs() Flip_bot(1)
 969     translate([x0,0,0])
 970     mirror([1,0,0])
 971     rotate([90,0,-90])
 972     linear_extrude(height=x1-x0)
 973     children();
 974 }
 975
 976 module CatchPortion(xwidth, ztop){
 977   width = catch_width + xwidth;
 978   w = width + catch_topcurve_r*2 + 1;
 979   translate([phone_width/2, 0,0]){
 980     difference(){
 981       rotate([90,0,-90])
 982         linextr(-w/2, w/2)
 983         children(0);
 984       translate([0, 50, 0])
 985         rotate([90,0,0])
 986         linear_extrude(height=100){
 987         for (m=[0,1]) mirror([m,0,0]) {
 988           hull(){
 989             translate([w/2, ztop - catch_topcurve_r])
 990               circle(catch_topcurve_r);
 991             translate([w/2, -50])
 992               square(catch_topcurve_r*2, center=true);
 993           }
 994         }
 995       }
 996     }
 997   }
 998 }
 999
1000 module CaseBase(){
1001   AroundEdges(epp3[1], case_th_bottom, 1)
1002     EdgeProfile();
1003 }
1004
1005 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
1006
1007 module PropProfileAssignments(gamma){
1008   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
1009   x = prop_x(gamma);
1010   p = phone_height + prlp10[0] - hppB[0];
1011   b = p + x;
1012
1013   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1014   a = q + x;
1015   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1016   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1017
1018   $prp_theta = 90 - $prp_alpha;
1019   beta = 180 - $prp_alpha - gamma;
1020   psi = 90 - beta;
1021
1022   //echo("abc", a,b,c);
1023
1024   v1 = [ [ cos(psi), -sin(psi) ],    // x
1025          [ sin(psi),  cos(psi) ] ];  // y
1026
1027   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1028
1029   $prp_r1 = prc_r1;
1030   $prp_r11 = prop_main_th/2;
1031
1032   $prpp1 = $prpp7 + [1,0] *
1033     // this is approximate, but will do
1034     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1035   $prpp3 = $prpp1 +
1036     v1[0] * -$prp_r1 +
1037     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1038   $prpp12 = $prpp3 + v1[0] *
1039     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1040   $prp_r8 = prop_main_th;
1041   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1042   $prp_r5 = $prp_r8;
1043   $prpp5 = [ $prpp12[0] - $prp_r5,
1044             $prpp3[1] - prop_prong_h + $prp_r5 ];
1045   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1046          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1047   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1048   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1049
1050   children();
1051 }
1052
1053 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
1054   PropProfileAssignments(gamma){
1055
1056     //#circleat($prpp3,1);
1057     //#circleat($prpp12,1);
1058
1059     if (!cut) {
1060       hull(){
1061         translate($prpp8)
1062           intersection(){
1063             circle($prp_r8);
1064             polygon([[-20,-0], [20,20], [0,0]]);
1065           }
1066         rectfromto($prpp6, $prpp9);
1067         translate($prpp5) intersection(){
1068           circle($prp_r5);
1069           polygon([[-10,-10], [0,0], [10,0]]);
1070         }
1071         rectfromto($prpp12 + [0,-0.1], $prpp3);
1072       }
1073       hull(){
1074         circleat($prpp1, $prp_r1);
1075         rectfromto($prpp12 + [0,-0.1], $prpp3);
1076       }
1077     }
1078     // main shaft
1079     rotate([0,0, rot*-$prp_theta]){
1080       hull(){
1081         extra = cut ? prop_recess_slop : 0;
1082         rectfromto($prpp6, $prpp9);
1083         circleat($prpp11, $prp_r11 + extra);
1084         circleat($prpp10, $prp_r10 + extra);
1085       }
1086     }
1087   }
1088 }
1089
1090 module PropAggregateProfile(){
1091   for (angle = prop_angles)
1092     PropProfile(angle, 0,0);
1093 }
1094
1095 module Prop(){ ////toplevel
1096   hw = prop_main_width/2;
1097   linextr(-hw, +hw)
1098     PropAggregateProfile();
1099 }
1100
1101 module Case(){ ////toplevel
1102   difference(){
1103     union(){
1104       CaseBase();
1105
1106       // ledge (fixed keeper)
1107       Flip_rhs(1-keeper_side) intersection(){
1108         rotate([90, 0, 0])
1109           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1110           KeeperProfile(1);
1111
1112         // outline of the whole case, to stop it protruding
1113         translate([0,0, -25])
1114           linear_extrude(height = 50)
1115           hull()
1116           Flip_bot()
1117           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1118       }
1119
1120       // hinge
1121       HingePortion(hex20, hex21) HingeBaseProfile();
1122
1123       // buildout for prop recess
1124       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1125         linextr(case_bottom_z, epp2i[1])
1126         hull() {
1127           for (dxs = [-1,+1])
1128             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1129                        -epp2o[0] ],
1130                      r = epp2o[0] - prcp2[0]);
1131         }
1132     }
1133
1134     // slot for keeper
1135     Flip_rhs(keeper_side)
1136       translate([0, -phone_cnr_rad, 0])
1137       rotate([90, 0, 0])
1138       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1139       minkowski(){
1140         KeeperProfile();
1141         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1142                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1143       }
1144
1145     // front camera
1146     RearCameraAperture();
1147
1148     // struts (invisible, because they're buried in the case)
1149     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1150
1151     Buttons(){
1152       mirror([1,0,0])
1153         rotate([90,0,90]) {
1154           if (!($button_leg_only && enable_support))
1155           intersection(){
1156             translate([0,0,-10])
1157               linear_extrude(height= 20)
1158               ButtonPlan($button_l, 0,1);
1159             if ($button_leg_only)
1160               rotate([-90,90,0])
1161                 translate([phone_width/2, -400, kppe[1]])
1162                 mirror([1-abs($rhsflip - keeper_side),0,0])
1163                 cube([400, 800, 50]);
1164             if (enable_support && !$button_suppress_over_keeper)
1165               rotate([-90,90,0])
1166               translate([-400, -400, kppd[1]])
1167                 mirror([0,0,1])
1168                 cube([800,800,100]);
1169           }
1170           translate([0,0, -bppR[0]])
1171             linear_extrude(height= 20)
1172             ButtonPlan($button_l, 1,1);
1173         }
1174
1175     }
1176
1177     // apertures along top edge
1178     CaseAperture(jack_pos, jack_dia, 8);
1179     Flip_rhs(1)
1180       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1181
1182     OrdinaryRearApertures();
1183
1184     MicroUSB();
1185
1186     // gaps for the lid's hinge arms
1187     HingePortion(hex20 - hinge_x_arms_gap,
1188                  hex21 + hinge_x_arms_gap)
1189       minkowski(){
1190         HingeLidProfile();
1191         circle(r= hinge_r_arms_gap, $fn= 8);
1192       }
1193
1194     // screw holes in the hinge arms
1195     HingeScrews();
1196
1197     // catch striker
1198     CatchPortion(catch_side_gap*2, epp4[1])
1199       CatchCutProfile();
1200
1201     // prop recess
1202     Flip_rhs(1)
1203       translate([prop_x_pos,0,0])
1204       mirror([0,1,0])
1205       rotate([90,0,90])
1206       linextr(-prop_recess_hw, +prop_recess_hw)
1207       hull(){
1208         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1209           circleat(prcp1 + 20*d,
1210                    prc_r3);
1211       }
1212   }
1213 }
1214
1215 module LidAdhocMultiprintFrame(phase){
1216   if (led_window_style >= 3) {
1217     AdhocMultiprintFrame(phase, lpp13[1], -1);
1218   }
1219 }
1220
1221 module LidAroundEdges(){
1222   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1223     children();
1224 }
1225
1226 module Lid(){ ////toplevel
1227   skew_centre = [0, lpp11[0], lpp11[1]];
1228   difference(){
1229     union(){
1230       intersection(){
1231         LidAroundEdges()
1232           LidEdgeProfile();
1233
1234         translate(skew_centre)
1235           multmatrix([[ 1, 0, 0, 0 ],
1236                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1237                       [ 0, 0, 1, 0 ],
1238                       [ 0, 0, 0, 1 ]])
1239           translate(-skew_centre)
1240           LidAroundEdges()
1241           LidEdgeFoldClearanceProfile();
1242       }
1243
1244       // button covers
1245       Buttons(){
1246         intersection(){
1247           rotate([90,0,90])
1248             translate([0,0,-10])
1249             linear_extrude(height= 20)
1250             ButtonPlan($button_l, 1,0);
1251           rotate([90,0,0])
1252              translate([0,0,-100])
1253             linear_extrude(height= 200)
1254             ButtonCoverProfile();
1255         }
1256       }
1257
1258       // hinge arms
1259       HingePortion(hex20, hex21) {
1260         LidEdgeProfile();
1261         HingeLidProfile();
1262       }
1263
1264       // catch
1265       CatchPortion(0, lpp12[1])
1266         CatchCatchProfile();
1267     }
1268     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1269
1270     // screw holes in the hinge arms
1271     HingeScrews();
1272
1273     // prop recess
1274     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1275       mirror([0,1,0])
1276       rotate([90,0,90])
1277       linextr(-prop_recess_hw, +prop_recess_hw)
1278       hull()
1279       for (pa = prop_angles)
1280         PropProfile(pa, 1,1);
1281
1282     // notification led aperture
1283     if (led_window_style)
1284       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1285         translate([0,0,-10])
1286           cylinder(r=nla_r0, h=20);
1287         if (led_window_style >= 2)
1288           translate([0,0, -nla_t])
1289             cylinder(r=nla_r2, height=20);
1290       }
1291
1292     }
1293
1294   LidAdhocMultiprintFrame(1);
1295 }
1296
1297 module HingeLever(){ ////toplevel
1298   difference() {
1299     // outer body, positive
1300     HingePortion(hex22, hex22 + phone_width/2)
1301       HingeLeverOuterProfile();
1302
1303     // space for the screws
1304     HingePortion(hex26, hex24)
1305       HingeLeverInnerProfile();
1306
1307     // recesses for the nuts
1308     HingePortion(hex23, hex26+1)
1309       HingeLeverNutProfile();
1310
1311     // bores for the screws
1312     HingeScrews();
1313
1314     // space for the charging cable
1315     MicroUSB();
1316     Flip_hinge() MicroUSB();
1317   }
1318 }
1319
1320 module LidWindow(){ ////toplevel
1321   translate([led_pos[0], -led_pos[1], lpp13[1]])
1322     mirror([0,0,1])
1323     cylinder(r= nla_r1, h=nla_t);
1324   LidAdhocMultiprintFrame(0);
1325 }
1326
1327 module LidWindowPrint(){ ////toplevel
1328   rotate([0,180,0])
1329     LidWindow();
1330 }
1331
1332 module DemoLidWindowSelect(){
1333   translate([led_pos[0], led_pos[1], -100]) {
1334     translate([0, -30, 0]) cube([400, 400, 200]);
1335   }
1336 }
1337
1338 module DemoLidWindow(){ ////toplevel
1339   %Lid();
1340   LidWindow();
1341   translate([0,40,0]){
1342     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1343     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1344   }
1345 }
1346
1347 module HingeLeverPrint(){ ////toplevel
1348   rotate([-90,0,0])
1349     translate([-phone_width/2, phone_height, 0])
1350     HingeLever();
1351 }
1352
1353 module TestSelectLength(){
1354   translate([-30, -200, -20])
1355     cube([30 + 15, 250, 40]);
1356 }
1357
1358 module TestLength(){ ////toplevel
1359   intersection(){
1360     Case();
1361     TestSelectLength();
1362   }
1363 }
1364
1365 module TestLengthRight(){ ////toplevel
1366   intersection(){
1367     Case();
1368     Flip_rhs(1)
1369       TestSelectLength();
1370   }
1371 }
1372
1373 module TestSelectWidth(){
1374   translate([-30, -(phone_height - 25), -20])
1375     mirror([0, 1, 0])
1376     cube([200, 50, 40]);
1377 }
1378
1379 module TestWidth(){ ////toplevel
1380   intersection(){
1381     Case();
1382     TestSelectWidth();
1383   }
1384 }
1385
1386 module TestLidWidthPrint(){ ////toplevel
1387   rotate([0,180.0]) intersection(){
1388     Lid();
1389     TestSelectWidth();
1390   }
1391 }
1392
1393 module TestSelectRearAperture(){
1394   minkowski(){
1395     union() children();
1396     translate([20, 0,0])
1397       cube([42, 2, 1], center=true);
1398   }
1399 }
1400
1401 module TestSelectCamera(){
1402   minkowski(){
1403     TestSelectRearAperture()
1404       RearCameraAperture();
1405     cube([0.1, 50, 0.1]);
1406   }
1407 }
1408
1409 module TestSelectOrdinaryRearApertures(){
1410   TestSelectRearAperture()
1411     OrdinaryRearApertures();
1412 }
1413
1414 module TestCamera(){ ////toplevel
1415   intersection(){
1416     Case();
1417     TestSelectCamera();
1418   }
1419 }
1420
1421 module TestLidByCamera(){ ////toplevel
1422   intersection(){
1423     Lid();
1424     TestSelectCamera();
1425   }
1426 }
1427
1428 module TestLidByCameraPrint(){ ////toplevel
1429   rotate([180,0,0]) TestLidByCamera();
1430 }
1431
1432 module DemoByCamera(){ ////toplevel
1433   color("blue") TestLidByCamera();
1434   color("red")  TestCamera();
1435 }
1436
1437 module OneKeeper(){ ////toplevel
1438   translate([0, -phone_cnr_rad, 0])
1439     rotate([90, 0, 0])
1440     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1441     KeeperProfile();
1442 }
1443
1444 module OneKeeperPrint(){ ////toplevel
1445   rotate([0,180,0])
1446     OneKeeper();
1447 }
1448
1449 module LidPrint(){ ////toplevel
1450   rotate([0,180,0])
1451     Lid();
1452 }
1453
1454 module TestSelectFrame(){
1455   include = [1,-1] * (epp2i[0] + 4);
1456
1457   difference(){
1458     cube(1000, center=true);
1459     translate([0,0, -100])
1460       linear_extrude(height=200)
1461       rectfromto(include,  inside_br - include);
1462   }
1463 }
1464
1465 module TestSelectLidFrame(){
1466   TestSelectFrame();
1467   translate([led_pos[0], -led_pos[1], -50])
1468     cylinder(r= nla_r2+3, h=100);
1469 }
1470
1471 module TestFrameCase(){ ////toplevel
1472   intersection(){
1473     Case();
1474     union(){
1475       TestSelectFrame();
1476       TestSelectCamera();
1477       TestSelectOrdinaryRearApertures();
1478     }
1479   }
1480 }
1481
1482 module TestSelectTopApertures(){
1483   translate([-100, -35, -100])
1484     cube([400, 100, 200]);
1485   LidAdhocMultiprintFrame(0);
1486   LidAdhocMultiprintFrame(1);
1487 }
1488
1489 module TestTopApertures(){ ////toplevel
1490   intersection(){
1491     Case();
1492     TestSelectFrame();
1493     TestSelectTopApertures();
1494   }
1495 }
1496
1497 module TestLidTopAperturesPrint(){ ////toplevel
1498   rotate([0,180,0]) intersection(){
1499     Lid();
1500     TestSelectLidFrame();
1501     TestSelectTopApertures();
1502   }
1503 }
1504
1505 module TestLidWindowTopAperturesPrint(){ ////toplevel
1506   rotate([0,180,0]) intersection(){
1507     LidWindow();
1508     TestSelectTopApertures();
1509   }
1510 }
1511
1512 module TestFrameLidPrint(){ ////toplevel
1513   rotate([0,180,0]) intersection(){
1514     Lid();
1515     TestSelectLidFrame();
1516   }
1517 }
1518
1519 module ButtonPlanForDemo(z, deep, cut){
1520   translate([0,0,z])
1521     ButtonPlan(8, deep, cut);
1522 }
1523
1524 module HingeScrews(){
1525   Flip_rhs() Flip_bot(1){
1526     for (c= [ hppT, hppB ])
1527       translate([ hex20,
1528                   -c[0],
1529                   c[1] ]){
1530         rotate([0,90,0])
1531           translate([0,0,-.2])
1532           cylinder( r= hingescrew_shaft_dia/2,
1533                     h = hingescrew_shaft_len+0.2 );
1534         rotate([0,-90,0])
1535           translate([0,0,+.1])
1536           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1537       }
1538   }
1539 }
1540
1541 module DemoPropAngleSelect(c){
1542   color(c) difference(){
1543     union(){ children(); }
1544     translate([ prop_x_pos, -400, -200 ])
1545       cube([ 400,800,400 ]);
1546   }
1547 }
1548
1549 module DemoPropAngle(ang){
1550   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1551   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1552
1553   translate(hL)
1554     rotate([ang/2,0,0])
1555     translate(-hL)
1556     translate(hC)
1557     rotate([ang/2,0,0])
1558     translate(-hC) {
1559       DemoPropAngleSelect("red") Case();
1560
1561       color("orange")
1562         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1563         PropProfileAssignments(ang) {
1564           echo($prpp1);
1565           rotate([-$prp_theta, 0, 0])
1566           translate([0, $prpp1[0], -$prpp1[1]])
1567           rotate([90,0,-90])
1568           Prop();
1569         }
1570     }
1571
1572   translate([0,0, -hp_k*2])
1573     DemoPropAngleSelect("blue")
1574     Lid();
1575 }
1576
1577 module DemoPropAngles(){ ////toplevel
1578   for (i=[0 : len(prop_angles)-1])
1579     translate(i * [0, -100, 100])
1580     DemoPropAngle(prop_angles[i]);
1581 }
1582
1583 module DemoHingeAngle(ang1,ang2){
1584   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1585   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1586
1587   translate(hL)
1588     rotate([ang2,0,0])
1589     translate(-hL)
1590     translate(hC)
1591     rotate([ang1,0,0])
1592     translate(-hC) {
1593       color("red") Lid();
1594     }
1595
1596   color("blue") intersection(){
1597     Case();
1598     union(){
1599       translate([bppJ[0], -400, -200])
1600         mirror([1,0,0])
1601         cube([400, 800, 400]);
1602       translate([10, -400, -200])
1603         cube([10, 800, 400]);
1604     }
1605   }
1606 }
1607
1608 module DemoHingeAngles(){ ////toplevel
1609   angles = [ 0, 4, 8, 12 ];
1610   echo("angles",angles);
1611   for (i=[0 : len(angles)-1]) {
1612     translate(i * [0, 0, 30]) {
1613       DemoHingeAngle(0,angles[i]);
1614       translate([0, 200, 0])
1615         DemoHingeAngle(angles[i],0);
1616     }
1617   }
1618 }
1619
1620 module DemoSelectAdhocLeftRight(right=0) {
1621   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1622     mirror([1-right, 0,0])
1623     cube([400, 800, 200]);
1624 }
1625
1626 module DemoLeft(){ ////toplevel
1627   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1628   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1629 }
1630
1631 module DemoFrame(){ ////toplevel
1632   color("red") TestFrameCase();
1633   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1634   color("black") HingeScrews();
1635   %HingeLever();
1636 }
1637
1638 module DemoLanyardCutout(){ ////toplevel
1639   LanyardCutout(25);
1640 }
1641
1642 module DemoHingedFrame(){ ///toplevel
1643   color("red") TestFrameCase();
1644   translate([0,0, -2*hp_k])
1645   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1646
1647   Flip_hinge(){
1648     color("orange") HingeLever();
1649     color("black") HingeScrews();
1650   }
1651 }
1652
1653 module DemoHinge(){ ////toplevel
1654   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1655     DemoFrame();
1656     translate([0,0, -hp_k*3])
1657       DemoHingedFrame();
1658   }
1659 }
1660
1661 module DemoProfiles(){ ////toplevel
1662   LidEdgeProfile();
1663   %EdgeProfile();
1664   KeeperProfile();
1665   translate([0,0,-1]) color("black") KeeperProfile(1);
1666   translate(ly_o){
1667     rotate(-ly_theta){
1668       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1669       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1670       translate([0, ly_q_z]){
1671         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1672         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1673       }
1674     }
1675   }
1676   translate([0,0,-5]) color("white") translate(epp2i)
1677     rotate(-ly_theta)
1678     rectfromto([-15, 0],
1679                [+15, -max_case_bottom_edge_thickness]);
1680
1681   translate([0,20]) {
1682     LanyardMainChannelProfile();
1683     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1684     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1685   }
1686
1687   translate([20,0]) {
1688     LidEdgeProfile();
1689     %EdgeProfile();
1690
1691     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1692
1693     color("blue") ButtonCoverProfile();
1694     color("red") {
1695       rectfromto(bppQ, demopoint_QR);
1696       rectfromto(bppR, demopoint_QR);
1697     }
1698   }
1699
1700   translate([-20,0]) {
1701     color("black") ButtonPlanForDemo(-2, 0,1);
1702     color("red" )  ButtonPlanForDemo(-4, 1,1);
1703     color("blue")  ButtonPlanForDemo(-6, 1,0);
1704   }
1705
1706   translate([0, -30]) {
1707     %LidEdgeProfile();
1708     %EdgeProfile();
1709     color("blue") HingeLidProfile();
1710     color("red")  HingeBaseProfile();
1711     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1712   }
1713
1714   for (f=[0,1]) {
1715     translate([-30, -60 + 30*f]) {
1716       translate([0,0,-4]) EdgeProfile();
1717       %translate([0,0,-10]) HingeBaseProfile();
1718       translate([0,-2] * f * hp_k) {
1719         translate([0,0,-4]) LidEdgeProfile();
1720         %translate([0,0,-10]) %HingeLidProfile();
1721       }
1722       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1723         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1724         translate([0,0,0]) color("red") difference(){
1725           HingeLeverOuterProfile();
1726           HingeLeverInnerProfile();
1727         }
1728         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1729       }
1730     }
1731   }
1732
1733   translate([20,-30]) {
1734     %EdgeProfile();
1735     %LidEdgeProfile();
1736     //translate([0,0,1]) CatchCutProfile();
1737     color("blue") CatchCatchProfile();
1738     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1739   }
1740
1741   translate([40,-30]) {
1742     difference(){
1743       LidEdgeProfile();
1744       translate(prlp10)
1745         PropProfile(10, 1, 0);
1746     }
1747     translate(prlp10)
1748       PropProfile(15, 0);
1749   }
1750   translate([60,-30]) {
1751     PropAggregateProfile();
1752   }
1753 }
1754
1755 //EdgeProfile();
1756 //KeeperProfile();
1757 //CaseBase();
1758 //%Case();
1759 //Keeper();
1760 //LidEdgeProfile();
1761 //KeeperProfile();
1762 //DemoProfiles();
1763 //PropRecess();