fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121
 122 phone = [ 75.0, 145.0 ];
 123
 124 prop_buildout_less = 3;
 125
 126 prop_angles = [ 15, 30, 45, 60 ];
 127
 128 bumper = [ 0.250, -0.025 ];
 129 // ^ One side.  Overall size is increased by twice this.
 130 // If no bumpers, is the gap around the phone.
 131
 132 enable_support = 1;
 133
 134 led_window_style = 3;
 135 // 0: no window
 136 // 1: simply an opening
 137 // 2: opening with separate cover model, for printing in clear (two colour)
 138 // 3: like 2 but one-layer window for ad-hoc multi-colour
 139
 140 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 141 initial_layer_width = 0.750; // ^ needed for mode 3 only
 142 multicolour_gap = 0.15; // each side
 143
 144 phone_cnr_rad = 6.0;
 145 phone_rim_depth = 0.80; // includes allowance for a screen protector
 146
 147 button_cutout_depth = 9;
 148
 149 phone_edge_thick = 9.0;
 150 phone_total_thick = 12.0;
 151 phone_backside_slope_inner = 1.5; // larger means shallower
 152 phone_backside_slope_outer = 1.0; // larger means shallower
 153
 154 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 155 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 156
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 led_pos = [ 13.98, 10.00 ];
 161 led_aperture = 9;
 162 led_window_ledge = 0.75; // each side
 163
 164 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 165 noisecancelmic_dia = 4.00;
 166
 167 //fingerpushhole_dias = [ 15, 18 ];
 168 fingerpushhole_dias = [];
 169
 170 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 171 rearspeaker_size   = [  3.76,  7.36 ];
 172
 173 microusb_above = 3.27 - 0.25;
 174 microusb_below = 0.0;
 175 microusb_width = 16.12 + 1.25;
 176
 177 case_th_bottom = 2.5;
 178 case_th_lid = 3.0;
 179 case_th_side = 2;
 180 case_th_lip = 1.2;
 181
 182 lid_screen_gap_extra = .66;
 183
 184 case_struts_count = 6;
 185 case_struts_solid_below = 1.00;
 186 case_struts_solid_above = 0.75;
 187 case_struts_width = 0.10;
 188
 189 keeper_th_z = 0.75;
 190 keeper_th_x = 0.75;
 191 keeper_inner_width = 2.75;
 192 keeper_inner_height = 2.75;
 193 keeper_slant_slope = 2; // larger means steeper
 194
 195 keeper_gap_z_top = 0.25;
 196 keeper_gap_z_bot = 0.75;
 197 keeper_gap_x     = 0.25;
 198 keeper_gap_x_holes = 0.75;
 199
 200 keeper_side = 0; // 0 = lhs; 1 = rhs
 201
 202 case_lip = 1.25;
 203
 204 lid_gap_x = 0.25;
 205 lid_gap_z = 0.25;
 206 lid_lip = 1.75;
 207
 208 catch_slop = 0.50;
 209
 210 foldover_gap = 0.50;
 211 foldover_lever_gap = 0.50;
 212
 213 // properties of the hinge fasteners
 214 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 215 hingescrew_shaft_len = 12;
 216 hingescrew_fasteners_extra_thick = 0.40;
 217 // ^ amount of thread protruding if everything was completely nominal
 218 //   and we are using two nuts
 219 hingescrew_nut_access_dia = 4.72 + 0.50;
 220 // ^ washer is 4.72 dia
 221 //   also, want to get pliers or tiny spanner in to do up locknut
 222 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 223 hingescrew_nut_thick = 1.93;
 224 hingescrew_head_th = 1.38 + 0.75;
 225 hingescrew_head_dia = 3.92;
 226
 227 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 228
 229 lever_cover_th = 0.75;
 230 hingemount_th = 2.5;
 231 hingemount_wd = 4.8725;
 232
 233 $fa = 5;
 234 $fs = 0.1;
 235
 236 button_l_fudge = 4.4;
 237 buttonishleg_default_l_is_fudge = 10;
 238
 239 hinge_base_slope = 1.5; // bigger is steeper
 240
 241 strut_min_at_end = 1.5;
 242
 243 hinge_x_gap = 0.125;
 244 hinge_x_postscrew_gap = 0.75;
 245 hinge_x_arms_gap = 0.35;
 246 hinge_r_arms_gap = 0.55;
 247
 248 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 249
 250 catch_len = 7.5;
 251 catch_width = 15;
 252 catch_thickness = 1.0;
 253 catch_side_gap = 0.75; // each side
 254
 255 catch_depth = 0.75;
 256 catch_height = 0.35;
 257 catch_finger_height = 1.5;
 258 catch_finger_depth = 2.5;
 259
 260 prop_recess_under = 0.50;
 261 prop_recess_slop = 0.200; // each side
 262 prop_end_dia = 0.5;
 263 prop_main_th = 3;
 264 prop_taper_len = 6;
 265 prop_main_width = 4;
 266 prop_side_gap = 0.75; // each side
 267 prop_lidrecess_behind = 0.75;
 268 prop_caserecess_behind = 0.75;
 269 prop_caserecess_taper = 0.45; // one side only
 270 prop_prop_gap = 0.5;
 271 prop_prong_heel_slope = 0.5;
 272
 273 // ---------- calculated ----------
 274
 275 phone_width =  (phone + bumper*2)[0];
 276 phone_height = (phone + bumper*2)[1];
 277
 278 inside_br = [phone_width, -phone_height];
 279
 280 prop_prong_h = prop_main_th;
 281
 282 //echo(camera_pos_tl + bumper,
 283 //     camera_pos_br + bumper);
 284
 285 // ----- could be changed -----
 286 lid_buttoncover_gap = lid_gap_x;
 287 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 288
 289 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 290
 291 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 292
 293 //prop_nose_len = case_th_lid - prop_recess_under;
 294 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 295 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 296
 297
 298 //lid_lip_overlap_width xxx bad name = ;
 299 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 300
 301 epp0 = [0,0];
 302 epp1 = [0, -phone_edge_thick];
 303 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 304 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 305 epp3 = epp2i + [10, 0];
 306 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 307 epp4 = epp5 + [-1,0] * case_th_side;
 308
 309 kppe = [0,0];
 310 kppd = kppe + [1,0] * keeper_inner_width;
 311 kppc = kppd + [0,1] * keeper_th_z;
 312 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 313 kppf = kppe - [0,1] * keeper_inner_height;
 314 kppa = [ kppb[0], kppf[1] ];
 315
 316 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 317 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 318
 319 lpp14 = lpp10 + [1,0] * keeper_inner_width;
 320 // exact x posn not very important; must extend past end of keeper
 321
 322 lpp15 = [ lpp14[0],
 323           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 324           + lid_screen_gap_extra ];
 325 // ^ beam theory says to maximise force before contact,
 326 //   the gap below the `beam' (the lid) must be 1/3
 327 //   the thickness (ie the lid thickness) if the beam
 328 //   is solid, or 1/2 if it has a top and bottom only.
 329 //   ours is mostly solid.
 330
 331 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 332              case_th_lip);
 333
 334 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 335 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 336
 337 case_bottom_z = epp2o[1] - case_th_bottom;
 338
 339 lid_close_clearance_skew = 1.3;
 340
 341 // button profile
 342 bppM = epp4 + [0,5];
 343 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 344 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 345 bppS = [ epp1[0], bppR[1] ];
 346 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 347 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 348 bppO = [ bppN[0], bppP[1] ];
 349 bppL = lpp10 + [5,0];
 350 bppK = [ bppL[0], bppN[1] ];
 351 bppJ = [ bppN[0], bppL[1] ];
 352 bppU = [ bppJ[0], lpp12[1] ];
 353 bppV = lpp11;
 354 bppW = lpp10;
 355
 356 // notification led aperture
 357
 358 nla_r0 = led_aperture/2;
 359 nla_r1 = nla_r0 + led_window_ledge;
 360 nla_r2 = nla_r1 + multicolour_gap;
 361 nla_t =
 362   led_window_style >= 3 ? initial_layer_thick :
 363   led_window_style >= 2 ? led_window_ledge : 0;
 364
 365
 366 // hinge plan
 367 hp_rn = hingescrew_nut_access_dia/2;
 368 hp_r2_min = hp_rn + lever_cover_th;
 369 hp_rs = hingescrew_shaft_dia/2;
 370 hp_r1_min = hp_rs + hingemount_th;
 371
 372 hp_r1 = max(hp_r1_min, hp_r2_min);
 373 hp_r2 = hp_r1;
 374
 375 hppU = lpp13;
 376 hppS = epp2o + [0,-1] * case_th_bottom;
 377 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 378
 379 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 380          0.5 * (hppU + hppS)[1] ];
 381 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 382 hppB = hppT + [0,-1] * hp_k;
 383
 384 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 385 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 386 hppE = [ hppE_x, hppE_y ];
 387
 388 // hinge elevation x coords
 389
 390 hex20 = max(epp2o[0],
 391             phone_cnr_rad,
 392             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 393 hex21 = hex20 + hingemount_wd;
 394 hex22 = hex21 + hinge_x_gap;
 395 hex27 = hex20 + hingescrew_shaft_len;
 396 hex24 = hex27 + hinge_x_postscrew_gap;
 397 hex23 = hex27 - (hingescrew_nut_thick*2
 398                  + hingescrew_fasteners_extra_thick);
 399 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 400
 401 echo(hex20, hex21, hex22, hex23, hex24);
 402 //  6, 10.8725, 10.9975, 13.74, 18.75
 403 module chk(act,exp) {
 404   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 405   else echo("ok", act);
 406 }
 407 chk(hex20, 6);
 408 chk(hex21, 10.8725);
 409 chk(hex22, 10.9975);
 410 chk(hex23, 13.74);
 411 chk(hex24, 18.75);
 412
 413 // catch
 414
 415 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 416 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 417 cppB = [ epp0[0], cppA[1] ];
 418 cppP = [ epp4[0], cppJ[1] ];
 419
 420 cppS = cppJ + [0,-1] * catch_len;
 421 cppD = [ cppA[0], cppS[1] + catch_slop ];
 422 cppC = [ cppB[0], cppD[1] ];
 423 cppT = cppS + [1,0] * catch_depth;
 424 cppU = cppT + [0,-1] * catch_height;
 425 cppV = [ cppS[0], cppU[1] - catch_depth ];
 426
 427 cppR = 0.5*(cppP + cppJ);
 428
 429 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 430 cppQ = [ cppR[0],
 431          cppV[1] - (catch_finger_height - cp_rQ) ];
 432 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 433
 434 // prop recess in case
 435
 436 prop_x_pos = phone_width/2;
 437
 438 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 439
 440 prc_r1 = prop_end_dia/2;
 441 prc_r3 = prc_r1 + prop_recess_slop;
 442
 443 prcp2 = [ epp4[0] + prop_buildout_less,
 444           case_bottom_z ];
 445
 446 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 447
 448 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 449           epp2i[1] - prc_r3 - prop_recess_under];
 450
 451 // prop recess in lid
 452
 453 prl_r10 = prop_end_dia/2;
 454 prl_r10o = prl_r10 + prop_recess_slop;
 455
 456 prlp10 = lpp10 + [1,1] * prl_r10o
 457   + [1,0] * prop_lidrecess_behind
 458   + [0,1] * prop_recess_under;
 459
 460 // prop
 461
 462 $prpp10 = [0,0];
 463 $prpp11 = [0, prop_taper_len];
 464
 465 $prp_r10 = prl_r10;
 466
 467 // ---------- modules ----------
 468
 469 module AdhocMultiprintFrame(phase, z0, zs) {
 470   // from z0 to z0 + zs*layer
 471   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 472   xextra = extra + -epp4[0];
 473   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 474   yextra = extra + -epp4[0];
 475   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 476   p0 = [ xrange[0], yrange[0] ];
 477   p1 = [ xrange[1], yrange[1] ];
 478   echo(p0, p1);
 479   translate([0,0, z0])
 480     mirror([0,0, zs<0 ? 1 : 0])
 481     linear_extrude(height= initial_layer_thick)
 482     difference(){
 483       rectfromto(p0 - [1,1] * initial_layer_width,
 484                  p1 + [1,1] * initial_layer_width);
 485       rectfromto(p0, p1);
 486     }
 487 }
 488
 489 module KeeperProfile(slant=0){
 490   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 491   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 492 }
 493
 494 module EdgeProfile(){
 495   difference(){
 496     hull(){
 497       translate(epp3) square(case_th_bottom*2, center=true);
 498       circleat(epp2o, r=case_th_bottom);
 499       circleat(epp1, r=case_th_side);
 500       rectfromto(epp0, epp4);
 501     }
 502     polygon([ epp5 + [0,10],
 503               epp1,
 504               epp2i,
 505               epp3 + [10,0] ]);
 506   }
 507 }
 508
 509 module LidEdgeProfile(){
 510   polygon([ lpp10,
 511             lpp11,
 512             lpp12,
 513             lpp13,
 514             lpp13 + [10, 0],
 515             lpp15 + [10, 0],
 516             lpp15,
 517             lpp14,
 518             ]);
 519   intersection(){
 520     circleat(lpp12, r=lp_r12);
 521     rectfromto( lpp12 + [-10,   0],
 522                 lpp12 + [+10, +10] );
 523   }
 524 }
 525
 526 module LidEdgeFoldClearanceProfile(){
 527   polygon([ lpp10,
 528             lpp11,
 529             lpp11 + [-20,  0],
 530             lpp11 + [-20, 20],
 531             lpp11 + [+20, 20],
 532             lpp10 + [+20,  0] ]);
 533 }
 534
 535 module ButtonCoverProfile(){
 536   intersection(){
 537     polygon(concat([ bppM, bppP, bppO, bppJ ],
 538                    (enable_support && !$button_suppress_over_keeper
 539                     ? [ bppU, bppV, bppW ] : []),
 540                    [ bppL, bppK ]));
 541     hull(){
 542       EdgeProfile();
 543       LidEdgeProfile();
 544     }
 545   }
 546 }
 547
 548 module ButtonPlan(l, deep, cut){
 549   epsilon =
 550     (cut  ? 0 : lid_buttoncover_gap);
 551
 552   delta =
 553     (deep ? lid_buttoncover_overlap : 0);
 554
 555   C = [0,0]; // by definition
 556   T = [ 0, epp4[1] ];
 557   G = T + [0,10];
 558
 559   B0 = C + [0,-1] * button_cutout_depth;
 560   B1 = B0 + [0,1] * epsilon;
 561
 562   r0 = 0.5 * (T[1] - B0[1]);
 563   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 564   H = A + [0,-1] * delta;
 565
 566   D = A + [-2,0] * r0;
 567   F = D + [0,10];
 568
 569   E0 = 0.5 * (D + A);
 570   E1 = E0 + [1,0] * epsilon;
 571
 572   I0 = [ E0[0], H[1] ];
 573   I1 = [ E1[0], H[1] ];
 574
 575   hull(){
 576     for (m=[0,1]) mirror([m,0])
 577       circleat(H, r0 - epsilon);
 578   }
 579   for (m=[0,1]) mirror([m,0]) {
 580     difference(){
 581       polygon([ E1,
 582                 I1,
 583                 H,
 584                 B1,
 585                 G,
 586                 F,
 587                 D
 588                 ]);
 589       circleat(D, r0 + epsilon);
 590     }
 591   }
 592 }
 593
 594 module CatchCatchProfile(){
 595   hull(){
 596     for (c=[ cppR, cppQ ])
 597       circleat(c, cp_rQ);
 598   }
 599   hull(){
 600     circleat(lpp12, lp_r12);
 601     circleat(lpp12 + [5,0], lp_r12);
 602     rectfromto(cppP, cppP + [5,0.1]);
 603   }
 604   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 605 }
 606
 607 module CatchCutProfile(){
 608   polygon([ cppB,
 609             cppA,
 610             cppD,
 611             cppF,
 612             cppF + [0,-10],
 613             cppF + [-10,-10],
 614             lpp12 + [-10,0],
 615             lpp12 + [10,0]
 616             ]);
 617 }
 618
 619 module Flip_rhs(yn=[0,1]) {
 620   for ($rhsflip=yn) {
 621     translate([phone_width/2, 0, 0])
 622       mirror([$rhsflip,0,0])
 623       translate([-phone_width/2, 0, 0])
 624       children();
 625   }
 626 }
 627
 628 module Flip_bot(yn=[0,1]) {
 629   for ($botflip=yn) {
 630     translate([0, -phone_height/2, 0])
 631       mirror([0, $botflip, 0])
 632       translate([0, phone_height/2, 0])
 633       children();
 634   }
 635 }
 636
 637 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 638   // sides
 639   Flip_rhs(){
 640     translate([0, -phone_cnr_rad, 0])
 641       rotate([90,0,0])
 642       linear_extrude(height = phone_height - phone_cnr_rad*2)
 643       children(0);
 644   }
 645   // corners
 646   Flip_rhs() Flip_bot() {
 647     translate([+1,-1] * phone_cnr_rad)
 648       intersection(){
 649         rotate_extrude()
 650           intersection(){
 651             mirror([1,0,0])
 652               translate([-1,0] * phone_cnr_rad)
 653               children(0);
 654             rectfromto([0,-20],[10,20]);
 655           }
 656         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 657           cube([10,10,40]);
 658       }
 659   }
 660   // top and bottom
 661   Flip_bot(){
 662     translate([ phone_width - phone_cnr_rad, 0,0 ])
 663       rotate([90,0,-90])
 664       linear_extrude(height = phone_width - phone_cnr_rad*2)
 665       children(0);
 666   }
 667   // fill
 668   translate([0,0, fill_zstart])
 669     mirror([0,0, fill_downwards])
 670     linear_extrude(height = fill_th)
 671     rectfromto([+1,-1] * phone_cnr_rad,
 672                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 673 }
 674
 675 module CaseAperture(pos, dia, $fn) {
 676   theta = 180/$fn;
 677   translate([ pos[0] + bumper[0],
 678               -epp2i[0],
 679               -pos[1] ])
 680     rotate([-90, theta, 0])
 681     cylinder(r = dia/2 / cos(theta),
 682              h = 60);
 683 }
 684
 685 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 686   // y_ref_sign:
 687   //   +1  measured from top    of actual phone to top    of button
 688   //   -1  measured from bottom of actual phone to bottom of button
 689   //    0  y is centre of button in coordinate system
 690   $button_l= l;
 691   $button_suppress_over_keeper= suppress_over_keeper;
 692   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 693           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 694           y;
 695   //echo(eff_y);
 696   translate([0, eff_y, 0])
 697     children();
 698 }
 699
 700 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 701   $button_leg_only = true;
 702   SideButton(y, y_ref_sign, l) children();
 703 }
 704
 705 module Buttons(){
 706   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 707   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 708   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 709   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 710 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 711 }
 712
 713 module Struts(x_start, z_min, th){
 714   // if th is negative, starts at z_min and works towards -ve z
 715   // and object should then be printed other way up
 716   for (i= [1 : 1 : case_struts_count]) {
 717     translate([0,
 718                0,
 719                z_min])
 720       mirror([0,0, th<0 ? 1 : 0])
 721       translate([0,
 722                  -phone_height * i / (case_struts_count+1),
 723                  case_struts_solid_below])
 724       linear_extrude(height= abs(th)
 725                      -(case_struts_solid_below+case_struts_solid_above))
 726       rectfromto([               x_start, -0.5 * case_struts_width ],
 727                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 728   }
 729 }
 730
 731 module OrdinaryRearAperture(rhs,bot, pos){
 732   Flip_rhs(rhs) Flip_bot(bot)
 733     linextr(-20, 20)
 734     mirror([0,1])
 735     translate(pos + bumper)
 736     children();
 737 }
 738
 739 module MicroUSB(){
 740   Flip_bot(1){
 741     rotate([90,0,0])
 742       mirror([0,0,1])
 743       linextr(-epp2i[0], 60)
 744       translate([0.5 * phone_width, 0, 0])
 745       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 746                  [+microusb_width/2, epp0[1] + -microusb_above]);
 747   }
 748 }
 749
 750 module OrdinaryRearApertures(){
 751   // rear speaker
 752   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 753     rectfromto(-rearspeaker_gap,
 754                rearspeaker_size + rearspeaker_gap);
 755
 756   // finger hole to remove phone
 757   if (len(fingerpushhole_dias))
 758     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 759                                 phone[1]/2 ])
 760     scale(fingerpushhole_dias)
 761     circle(r= 0.5 );
 762 }
 763
 764 module RearCameraAperture(){
 765   Flip_rhs(1)
 766     mirror([0, 0, 1])
 767     linear_extrude(height = 20)
 768     mirror([0, 1, 0])
 769     translate(bumper)
 770     rectfromto(camera_pos_tl, camera_pos_br);
 771 }
 772
 773 module HingeLidProfile(){
 774   hull(){
 775     circleat(hppT, hp_r1);
 776     circleat(lpp12, lp_r12);
 777     polygon([lpp10,
 778              lpp13 + [2,0],
 779              lpp12,
 780              hppT]);
 781   }
 782 }
 783
 784 module HingeBaseProfile(){
 785   difference(){
 786     hull(){
 787       circleat(hppB, hp_r1);
 788       circleat(hppE, hp_r1);
 789       circleat(epp2o, case_th_bottom);
 790       circleat(hppB + [10,0], hp_r1);
 791     }
 792     polygon([epp5, epp1, epp2i, epp3, bppL]);
 793   }
 794 }
 795
 796 module HingeLeverOuterProfile(){
 797   hull(){
 798     circleat(hppT, hp_r2);
 799     circleat(hppB, hp_r2);
 800   }
 801 }
 802
 803 module HingeLeverInnerProfile(){
 804   for (s = [-1,+1]) {
 805     c = s > 0 ? hppT : hppB;
 806     translate(c)
 807       mirror([0,0,s>0])
 808       rotate(s<0 ? -40 : 0)
 809       hull()
 810       for (x=[-20,20])
 811         for (y=[0, s * 10])
 812           translate([x,y])
 813             circle(hp_rn);
 814   }
 815 }
 816
 817 module HingeLeverNutProfile(){
 818   for (c= [hppB, hppT]) {
 819     translate(c)
 820       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 821   }
 822 }
 823
 824 module Flip_hinge(doflip=1){
 825   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 826   translate(hinge_origin)
 827     rotate([doflip*180,0,0])
 828     translate(-hinge_origin)
 829     children();
 830 }
 831
 832 module HingePortion(x0,x1){
 833   Flip_rhs() Flip_bot(1)
 834     translate([x0,0,0])
 835     mirror([1,0,0])
 836     rotate([90,0,-90])
 837     linear_extrude(height=x1-x0)
 838     children();
 839 }
 840
 841 module CatchPortion(width){
 842   translate([phone_width/2, 0,0])
 843     rotate([90,0,-90])
 844     linextr(-width/2, width/2)
 845     children(0);
 846 }
 847
 848 module CaseBase(){
 849   AroundEdges(epp3[1], case_th_bottom, 1)
 850     EdgeProfile();
 851 }
 852
 853 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 854
 855 module PropProfileAssignments(gamma){
 856   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 857   x = prop_x(gamma);
 858   p = phone_height + prlp10[0] - hppB[0];
 859   b = p + x;
 860
 861   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 862   a = q + x;
 863   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 864   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 865
 866   $prp_theta = 90 - $prp_alpha;
 867   beta = 180 - $prp_alpha - gamma;
 868   psi = 90 - beta;
 869
 870   //echo("abc", a,b,c);
 871
 872   v1 = [ [ cos(psi), -sin(psi) ],    // x
 873          [ sin(psi),  cos(psi) ] ];  // y
 874
 875   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 876
 877   $prp_r1 = prc_r1;
 878   $prp_r11 = prop_main_th/2;
 879
 880   $prpp1 = $prpp7 + [1,0] *
 881     // this is approximate, but will do
 882     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 883   $prpp3 = $prpp1 +
 884     v1[0] * -$prp_r1 +
 885     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 886   $prpp12 = $prpp3 + v1[0] *
 887     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 888   $prp_r8 = prop_main_th;
 889   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 890   $prp_r5 = $prp_r8;
 891   $prpp5 = [ $prpp12[0] - $prp_r5,
 892             $prpp3[1] - prop_prong_h + $prp_r5 ];
 893   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 894          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 895   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 896   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 897
 898   children();
 899 }
 900
 901 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 902   PropProfileAssignments(gamma){
 903
 904     //#circleat($prpp3,1);
 905     //#circleat($prpp12,1);
 906
 907     if (!cut) {
 908       hull(){
 909         translate($prpp8)
 910           intersection(){
 911             circle($prp_r8);
 912             polygon([[-20,-0], [20,20], [0,0]]);
 913           }
 914         rectfromto($prpp6, $prpp9);
 915         translate($prpp5) intersection(){
 916           circle($prp_r5);
 917           polygon([[-10,-10], [0,0], [10,0]]);
 918         }
 919         rectfromto($prpp12 + [0,-0.1], $prpp3);
 920       }
 921       hull(){
 922         circleat($prpp1, $prp_r1);
 923         rectfromto($prpp12 + [0,-0.1], $prpp3);
 924       }
 925     }
 926     // main shaft
 927     rotate([0,0, rot*-$prp_theta]){
 928       hull(){
 929         extra = cut ? prop_recess_slop : 0;
 930         rectfromto($prpp6, $prpp9);
 931         circleat($prpp11, $prp_r11 + extra);
 932         circleat($prpp10, $prp_r10 + extra);
 933       }
 934     }
 935   }
 936 }
 937
 938 module PropAggregateProfile(){
 939   for (angle = prop_angles)
 940     PropProfile(angle, 0,0);
 941 }
 942
 943 module Prop(){ ////toplevel
 944   hw = prop_main_width/2;
 945   linextr(-hw, +hw)
 946     PropAggregateProfile();
 947 }
 948
 949 module Case(){ ////toplevel
 950   difference(){
 951     union(){
 952       CaseBase();
 953
 954       // ledge (fixed keeper)
 955       Flip_rhs(1-keeper_side) intersection(){
 956         rotate([90, 0, 0])
 957           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 958           KeeperProfile(1);
 959
 960         // outline of the whole case, to stop it protruding
 961         translate([0,0, -25])
 962           linear_extrude(height = 50)
 963           hull()
 964           Flip_bot()
 965           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 966       }
 967
 968       // hinge
 969       HingePortion(hex20, hex21) HingeBaseProfile();
 970
 971       // buildout for prop recess
 972       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
 973         linextr(case_bottom_z, epp2i[1])
 974         hull() {
 975           for (dxs = [-1,+1])
 976             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
 977                        -epp2o[0] ],
 978                      r = epp2o[0] - prcp2[0]);
 979         }
 980     }
 981
 982     // slot for keeper
 983     Flip_rhs(keeper_side)
 984       translate([0, -phone_cnr_rad, 0])
 985       rotate([90, 0, 0])
 986       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 987       minkowski(){
 988         KeeperProfile();
 989         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 990                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 991       }
 992
 993     // front camera
 994     RearCameraAperture();
 995
 996     // struts (invisible, because they're buried in the case)
 997     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 998
 999     Buttons(){
1000       mirror([1,0,0])
1001         rotate([90,0,90]) {
1002           if (!($button_leg_only && enable_support))
1003           intersection(){
1004             translate([0,0,-10])
1005               linear_extrude(height= 20)
1006               ButtonPlan($button_l, 0,1);
1007             if ($button_leg_only)
1008               rotate([-90,90,0])
1009                 translate([phone_width/2, -400, kppe[1]])
1010                 mirror([1-abs($rhsflip - keeper_side),0,0])
1011                 cube([400, 800, 50]);
1012             if (enable_support && !$button_suppress_over_keeper)
1013               rotate([-90,90,0])
1014               translate([-400, -400, kppd[1]])
1015                 mirror([0,0,1])
1016                 cube([800,800,100]);
1017           }
1018           translate([0,0, -bppR[0]])
1019             linear_extrude(height= 20)
1020             ButtonPlan($button_l, 1,1);
1021         }
1022
1023     }
1024
1025     // apertures along top edge
1026     CaseAperture(jack_pos, jack_dia, 8);
1027     Flip_rhs(1)
1028       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1029
1030     OrdinaryRearApertures();
1031
1032     MicroUSB();
1033
1034     // gaps for the lid's hinge arms
1035     HingePortion(hex20 - hinge_x_arms_gap,
1036                  hex21 + hinge_x_arms_gap)
1037       minkowski(){
1038         HingeLidProfile();
1039         circle(r= hinge_r_arms_gap, $fn= 8);
1040       }
1041
1042     // screw holes in the hinge arms
1043     HingeScrews();
1044
1045     // catch striker
1046     CatchPortion(catch_width + catch_side_gap*2)
1047       CatchCutProfile();
1048
1049     // prop recess
1050     Flip_rhs(1)
1051       translate([prop_x_pos,0,0])
1052       mirror([0,1,0])
1053       rotate([90,0,90])
1054       linextr(-prop_recess_hw, +prop_recess_hw)
1055       hull(){
1056         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1057           circleat(prcp1 + 20*d,
1058                    prc_r3);
1059       }
1060   }
1061 }
1062
1063 module LidAdhocMultiprintFrame(phase){
1064   if (led_window_style >= 3) {
1065     AdhocMultiprintFrame(phase, lpp13[1], -1);
1066   }
1067 }
1068
1069 module LidAroundEdges(){
1070   AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
1071     children();
1072 }
1073
1074 module Lid(){ ////toplevel
1075   skew_centre = [0, lpp11[0], lpp11[1]];
1076   difference(){
1077     union(){
1078       intersection(){
1079         LidAroundEdges()
1080           LidEdgeProfile();
1081
1082         translate(skew_centre)
1083           multmatrix([[ 1, 0, 0, 0 ],
1084                       [ 0, 1, -lid_close_clearance_skew, 0 ],
1085                       [ 0, 0, 1, 0 ],
1086                       [ 0, 0, 0, 1 ]])
1087           translate(-skew_centre)
1088           LidAroundEdges()
1089           LidEdgeFoldClearanceProfile();
1090       }
1091
1092       // button covers
1093       Buttons(){
1094         intersection(){
1095           rotate([90,0,90])
1096             translate([0,0,-10])
1097             linear_extrude(height= 20)
1098             ButtonPlan($button_l, 1,0);
1099           rotate([90,0,0])
1100              translate([0,0,-100])
1101             linear_extrude(height= 200)
1102             ButtonCoverProfile();
1103         }
1104       }
1105
1106       // hinge arms
1107       HingePortion(hex20, hex21) {
1108         LidEdgeProfile();
1109         HingeLidProfile();
1110       }
1111
1112       // catch
1113       CatchPortion(catch_width)
1114         CatchCatchProfile();
1115     }
1116     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1117
1118     // screw holes in the hinge arms
1119     HingeScrews();
1120
1121     // prop recess
1122     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1123       mirror([0,1,0])
1124       rotate([90,0,90])
1125       linextr(-prop_recess_hw, +prop_recess_hw)
1126       hull()
1127       for (pa = prop_angles)
1128         PropProfile(pa, 1,1);
1129
1130     // notification led aperture
1131     if (led_window_style)
1132       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1133         translate([0,0,-10])
1134           cylinder(r=nla_r0, h=20);
1135         if (led_window_style >= 2)
1136           translate([0,0, -nla_t])
1137             cylinder(r=nla_r2, height=20);
1138       }
1139
1140     }
1141
1142   LidAdhocMultiprintFrame(1);
1143 }
1144
1145 module HingeLever(){ ////toplevel
1146   difference() {
1147     // outer body, positive
1148     HingePortion(hex22, hex22 + phone_width/2)
1149       HingeLeverOuterProfile();
1150
1151     // space for the screws
1152     HingePortion(hex26, hex24)
1153       HingeLeverInnerProfile();
1154
1155     // recesses for the nuts
1156     HingePortion(hex23, hex26+1)
1157       HingeLeverNutProfile();
1158
1159     // bores for the screws
1160     HingeScrews();
1161
1162     // space for the charging cable
1163     MicroUSB();
1164     Flip_hinge() MicroUSB();
1165   }
1166 }
1167
1168 module LidWindow(){ ////toplevel
1169   translate([led_pos[0], -led_pos[1], lpp13[1]])
1170     mirror([0,0,1])
1171     cylinder(r= nla_r1, h=nla_t);
1172   LidAdhocMultiprintFrame(0);
1173 }
1174
1175 module LidWindowPrint(){ ////toplevel
1176   rotate([0,180,0])
1177     LidWindow();
1178 }
1179
1180 module DemoLidWindowSelect(){
1181   translate([led_pos[0], led_pos[1], -100]) {
1182     translate([0, -30, 0]) cube([400, 400, 200]);
1183   }
1184 }
1185
1186 module DemoLidWindow(){ ////toplevel
1187   %Lid();
1188   LidWindow();
1189   translate([0,40,0]){
1190     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1191     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1192   }
1193 }
1194
1195 module HingeLeverPrint(){ ////toplevel
1196   rotate([-90,0,0])
1197     translate([-phone_width/2, phone_height, 0])
1198     HingeLever();
1199 }
1200
1201 module TestSelectLength(){
1202   translate([-30, -200, -20])
1203     cube([30 + 15, 250, 40]);
1204 }
1205
1206 module TestLength(){ ////toplevel
1207   intersection(){
1208     Case();
1209     TestSelectLength();
1210   }
1211 }
1212
1213 module TestLengthRight(){ ////toplevel
1214   intersection(){
1215     Case();
1216     Flip_rhs(1)
1217       TestSelectLength();
1218   }
1219 }
1220
1221 module TestSelectWidth(){
1222   translate([-30, -(phone_height - 25), -20])
1223     mirror([0, 1, 0])
1224     cube([200, 50, 40]);
1225 }
1226
1227 module TestWidth(){ ////toplevel
1228   intersection(){
1229     Case();
1230     TestSelectWidth();
1231   }
1232 }
1233
1234 module TestLidWidthPrint(){ ////toplevel
1235   rotate([0,180.0]) intersection(){
1236     Lid();
1237     TestSelectWidth();
1238   }
1239 }
1240
1241 module TestSelectRearAperture(){
1242   minkowski(){
1243     union() children();
1244     translate([20, 0,0])
1245       cube([42, 2, 1], center=true);
1246   }
1247 }
1248
1249 module TestSelectCamera(){
1250   minkowski(){
1251     TestSelectRearAperture()
1252       RearCameraAperture();
1253     cube([0.1, 50, 0.1]);
1254   }
1255 }
1256
1257 module TestSelectOrdinaryRearApertures(){
1258   TestSelectRearAperture()
1259     OrdinaryRearApertures();
1260 }
1261
1262 module TestCamera(){ ////toplevel
1263   intersection(){
1264     Case();
1265     TestSelectCamera();
1266   }
1267 }
1268
1269 module TestLidByCamera(){ ////toplevel
1270   intersection(){
1271     Lid();
1272     TestSelectCamera();
1273   }
1274 }
1275
1276 module TestLidByCameraPrint(){ ////toplevel
1277   rotate([180,0,0]) TestLidByCamera();
1278 }
1279
1280 module DemoByCamera(){ ////toplevel
1281   color("blue") TestLidByCamera();
1282   color("red")  TestCamera();
1283 }
1284
1285 module OneKeeper(){ ////toplevel
1286   translate([0, -phone_cnr_rad, 0])
1287     rotate([90, 0, 0])
1288     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1289     KeeperProfile();
1290 }
1291
1292 module OneKeeperPrint(){ ////toplevel
1293   rotate([0,180,0])
1294     OneKeeper();
1295 }
1296
1297 module LidPrint(){ ////toplevel
1298   rotate([0,180,0])
1299     Lid();
1300 }
1301
1302 module TestSelectFrame(){
1303   include = [1,-1] * (epp2i[0] + 4);
1304
1305   difference(){
1306     cube(1000, center=true);
1307     translate([0,0, -100])
1308       linear_extrude(height=200)
1309       rectfromto(include,  inside_br - include);
1310   }
1311 }
1312
1313 module TestSelectLidFrame(){
1314   TestSelectFrame();
1315   translate([led_pos[0], -led_pos[1], -50])
1316     cylinder(r= nla_r2+3, h=100);
1317 }
1318
1319 module TestFrameCase(){ ////toplevel
1320   intersection(){
1321     Case();
1322     union(){
1323       TestSelectFrame();
1324       TestSelectCamera();
1325       TestSelectOrdinaryRearApertures();
1326     }
1327   }
1328 }
1329
1330 module TestSelectTopApertures(){
1331   translate([-100, -35, -100])
1332     cube([400, 100, 200]);
1333   LidAdhocMultiprintFrame(0);
1334   LidAdhocMultiprintFrame(1);
1335 }
1336
1337 module TestTopApertures(){ ////toplevel
1338   intersection(){
1339     Case();
1340     TestSelectFrame();
1341     TestSelectTopApertures();
1342   }
1343 }
1344
1345 module TestLidTopAperturesPrint(){ ////toplevel
1346   rotate([0,180,0]) intersection(){
1347     Lid();
1348     TestSelectLidFrame();
1349     TestSelectTopApertures();
1350   }
1351 }
1352
1353 module TestLidWindowTopAperturesPrint(){ ////toplevel
1354   rotate([0,180,0]) intersection(){
1355     LidWindow();
1356     TestSelectTopApertures();
1357   }
1358 }
1359
1360 module TestFrameLidPrint(){ ////toplevel
1361   rotate([0,180,0]) intersection(){
1362     Lid();
1363     TestSelectLidFrame();
1364   }
1365 }
1366
1367 module ButtonPlanForDemo(z, deep, cut){
1368   translate([0,0,z])
1369     ButtonPlan(8, deep, cut);
1370 }
1371
1372 module HingeScrews(){
1373   Flip_rhs() Flip_bot(1){
1374     for (c= [ hppT, hppB ])
1375       translate([ hex20,
1376                   -c[0],
1377                   c[1] ]){
1378         rotate([0,90,0])
1379           translate([0,0,-.2])
1380           cylinder( r= hingescrew_shaft_dia/2,
1381                     h = hingescrew_shaft_len+0.2 );
1382         rotate([0,-90,0])
1383           translate([0,0,+.1])
1384           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1385       }
1386   }
1387 }
1388
1389 module DemoPropAngleSelect(c){
1390   color(c) difference(){
1391     union(){ children(); }
1392     translate([ prop_x_pos, -400, -200 ])
1393       cube([ 400,800,400 ]);
1394   }
1395 }
1396
1397 module DemoPropAngle(ang){
1398   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1399   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1400
1401   translate(hL)
1402     rotate([ang/2,0,0])
1403     translate(-hL)
1404     translate(hC)
1405     rotate([ang/2,0,0])
1406     translate(-hC) {
1407       DemoPropAngleSelect("red") Case();
1408
1409       color("orange")
1410         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1411         PropProfileAssignments(ang) {
1412           echo($prpp1);
1413           rotate([-$prp_theta, 0, 0])
1414           translate([0, $prpp1[0], -$prpp1[1]])
1415           rotate([90,0,-90])
1416           Prop();
1417         }
1418     }
1419
1420   translate([0,0, -hp_k*2])
1421     DemoPropAngleSelect("blue")
1422     Lid();
1423 }
1424
1425 module DemoPropAngles(){ ////toplevel
1426   for (i=[0 : len(prop_angles)-1])
1427     translate(i * [0, -100, 100])
1428     DemoPropAngle(prop_angles[i]);
1429 }
1430
1431 module DemoHingeAngle(ang1,ang2){
1432   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1433   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1434
1435   translate(hL)
1436     rotate([ang2,0,0])
1437     translate(-hL)
1438     translate(hC)
1439     rotate([ang1,0,0])
1440     translate(-hC) {
1441       color("red") Lid();
1442     }
1443
1444   color("blue") intersection(){
1445     Case();
1446     union(){
1447       translate([bppJ[0], -400, -200])
1448         mirror([1,0,0])
1449         cube([400, 800, 400]);
1450       translate([10, -400, -200])
1451         cube([10, 800, 400]);
1452     }
1453   }
1454 }
1455
1456 module DemoHingeAngles(){ ////toplevel
1457   angles = [ 0, 4, 8, 12 ];
1458   echo("angles",angles);
1459   for (i=[0 : len(angles)-1]) {
1460     translate(i * [0, 0, 30]) {
1461       DemoHingeAngle(0,angles[i]);
1462       translate([0, 200, 0])
1463         DemoHingeAngle(angles[i],0);
1464     }
1465   }
1466 }
1467
1468 module DemoSelectAdhocLeftRight(right=0) {
1469   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1470     mirror([1-right, 0,0])
1471     cube([400, 800, 200]);
1472 }
1473
1474 module DemoLeft(){ ////toplevel
1475   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1476   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1477 }
1478
1479 module DemoFrame(){ ////toplevel
1480   color("red") TestFrameCase();
1481   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1482   color("black") HingeScrews();
1483   %HingeLever();
1484 }
1485
1486 module DemoHingedFrame(){ ///toplevel
1487   color("red") TestFrameCase();
1488   translate([0,0, -2*hp_k])
1489   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1490
1491   Flip_hinge(){
1492     color("orange") HingeLever();
1493     color("black") HingeScrews();
1494   }
1495 }
1496
1497 module DemoHinge(){ ////toplevel
1498   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1499     DemoFrame();
1500     translate([0,0, -hp_k*3])
1501       DemoHingedFrame();
1502   }
1503 }
1504
1505 module DemoProfiles(){ ////toplevel
1506   LidEdgeProfile();
1507   %EdgeProfile();
1508   KeeperProfile();
1509   translate([0,0,-1]) color("black") KeeperProfile(1);
1510
1511   translate([20,0]) {
1512     LidEdgeProfile();
1513     %EdgeProfile();
1514
1515     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1516
1517     color("blue") ButtonCoverProfile();
1518     color("red") {
1519       rectfromto(bppQ, demopoint_QR);
1520       rectfromto(bppR, demopoint_QR);
1521     }
1522   }
1523
1524   translate([-20,0]) {
1525     color("black") ButtonPlanForDemo(-2, 0,1);
1526     color("red" )  ButtonPlanForDemo(-4, 1,1);
1527     color("blue")  ButtonPlanForDemo(-6, 1,0);
1528   }
1529
1530   translate([0, -30]) {
1531     %LidEdgeProfile();
1532     %EdgeProfile();
1533     color("blue") HingeLidProfile();
1534     color("red")  HingeBaseProfile();
1535     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1536   }
1537
1538   for (f=[0,1]) {
1539     translate([-30, -60 + 30*f]) {
1540       translate([0,0,-4]) EdgeProfile();
1541       %translate([0,0,-10]) HingeBaseProfile();
1542       translate([0,-2] * f * hp_k) {
1543         translate([0,0,-4]) LidEdgeProfile();
1544         %translate([0,0,-10]) %HingeLidProfile();
1545       }
1546       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1547         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1548         translate([0,0,0]) color("red") difference(){
1549           HingeLeverOuterProfile();
1550           HingeLeverInnerProfile();
1551         }
1552         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1553       }
1554     }
1555   }
1556
1557   translate([20,-30]) {
1558     %EdgeProfile();
1559     %LidEdgeProfile();
1560     //translate([0,0,1]) CatchCutProfile();
1561     color("blue") CatchCatchProfile();
1562     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1563   }
1564
1565   translate([40,-30]) {
1566     difference(){
1567       LidEdgeProfile();
1568       translate(prlp10)
1569         PropProfile(10, 1, 0);
1570     }
1571     translate(prlp10)
1572       PropProfile(15, 0);
1573   }
1574   translate([60,-30]) {
1575     PropAggregateProfile();
1576   }
1577 }
1578
1579 //EdgeProfile();
1580 //KeeperProfile();
1581 //CaseBase();
1582 //%Case();
1583 //Keeper();
1584 //LidEdgeProfile();
1585 //KeeperProfile();
1586 //DemoProfiles();
1587 //PropRecess();