commitid.scad.pl

   1 #!/usr/bin/perl -w
   2
   3 # commitid.scad.pl - a program for annotating solid models with commit info
   4 # Copyright (C)2016 Ian Jackson.  See below.  There is NO WARRANTY.
   5
   6
   7 # USAGE
   8 # =====
   9 #
  10 #   .../commitid.scad.pl [OPTION...] [STRING...] >commitid.scad.new \
  11 #     && mv -f commitid.scad.new commitid.scad
  12 #
  13 # Run without arguments, commitid.scad.pl will output an openscad file
  14 # which contains 2D and 3D models of the current git commit count and
  15 # commit object id (commit hash), useful for identifying printed
  16 # parts.
  17 #
  18 # See below for details.  You probably want these two sections, as a
  19 # quick starting point:
  20 #    General form of provided openscad modules
  21 #    Autoscaling modules
  22 #
  23 # We can also generate models of short mainly-numeric strings
  24 # specified on the command line.
  25 #
  26 #
  27 # Options:
  28 #
  29 #   --git    Generate git commit indications, as shown below
  30 #            (this is the default if no strings are requested with -t).
  31 #            Ie, produce the `Autoscaling modules' and `Specific layouts'.
  32 #
  33 #   --git=objid
  34 #            Generate git commit indication based on commit object only
  35 #            (ie avoid counting commits).  Ie, do not generate `Small'
  36 #            and `Full' layouts (and never select them for `Best').
  37 #
  38 #   -i       Do not generate `+' dirty indication if git-untracked files
  39 #            are present (ie, missing .gitignore entries).  The `*'
  40 #            dirty tree indication (for modified files) cannot be disabled.
  41 #
  42 #   [-t[LAYOUT]] TEXT
  43 #            Generate a layout LAYOUT containing TEXT.  TEXT can
  44 #            contain newlines (a final newline usually undesirable, as
  45 #            it will generate a blank line).  If LAYOUT is not specified,
  46 #            generates Arg0, Arg1, Arg2, etc., for successive such
  47 #            TEXTs.  The permissible character set in is TEXT is:
  48 #                 space 0-9 a-f + *
  49 #
  50 #
  51 # OPENSCAD INTERFACE
  52 # ==================
  53 #
  54 # Dynamic variables for configuration
  55 # -----------------------------------
  56 #
  57 # We honour the following variables to control various scaling factors:
  58 #
  59 #                             default value  notes
  60 #    $Commitid_pixelsz         0.8             \ multiplied together
  61 #    $Commitid_scale           1.0             /
  62 #    $Commitid_depth           pixelsz/2       \ multiplied together
  63 #    $Commitid_depth_scale     1.0             /
  64 #    $Commitid_max_best_scale  2.0             limits XY scaling in *Best*
  65 #
  66 # FYI the font is nominally 3x5 pixels, with 1-pixel inter-line and
  67 # inter-character gaps.  (It's not strictly speaking a 3x5 bitmap
  68 # font, size it contains partial pixels and diagonals.)
  69 #
  70 #
  71 # Non-`module'-specific functions
  72 # -------------------------------
  73 #
  74 # We provide the following functions (which depend on the config
  75 # variables, but not on anything else) and compute useful values:
  76 #
  77 #   function Commitid_pixelsz()   Actual size of each nominal pixel
  78 #   function Commitid_depth()     Depth to use (the amount characters
  79 #                                  should be raised or sunken)
  80 #
  81 # General form of provided openscad modules
  82 # -----------------------------------------
  83 #
  84 #   module Commitid_MODULE_2D(...)   Collection of polygons forming characters
  85 #   module Commitid_MODULE(...)      The above, extruded up and down in Z
  86 #   module Commitid_MODULE_M_2D(...) Mirror writing
  87 #   module Commitid_MODULE_M(...)    3D mirror writing
  88 #   function Commitid_MODULE_sz()    A 2-vector giving the X,Y size
  89 #
  90 # Except for *Best* modules, the XY origin is in the bottom left
  91 # corner without any margin.  Likewise Commitid_MODULE_sz does not
  92 # include any margin.
  93 #
  94 # For 3D versions, the model is 2*depth deep and the XY plane bisects
  95 # the model.  This means it's convenient to either add or subtract from
  96 # a workpiece whose face is in the XY plane.
  97 #
  98 # The _M versions are provided to avoid doing inconvenient translation
  99 # and rotation to get the flipped version in the right place.
 100 #
 101 #
 102 # Autoscaling modules
 103 # -------------------
 104 #
 105 # These modules take a specification of the available XY space, and
 106 # select and generate a suitable specific identification layout:
 107 #
 108 #   module Commitid_BestCount_2D  (max_sz, margin=Commitid_pixelsz())
 109 #   module Commitid_BestCount     (max_sz, margin=Commitid_pixelsz())
 110 #   module Commitid_BestCount_M_2D(max_sz, margin=Commitid_pixelsz())
 111 #   module Commitid_BestCount_M   (max_sz, margin=Commitid_pixelsz())
 112 #   module Commitid_BestObjid_2D  (max_sz, margin=Commitid_pixelsz())
 113 #   module Commitid_BestObjid     (max_sz, margin=Commitid_pixelsz())
 114 #   module Commitid_BestObjid_M_2D(max_sz, margin=Commitid_pixelsz())
 115 #   module Commitid_BestObjid_M   (max_sz, margin=Commitid_pixelsz())
 116 #
 117 # max_sz should be [x,y].
 118 #
 119 # BestCount includes (as much as it can of) the git commit count,
 120 # ie the result of
 121 #     git rev-list --first-parent --count HEAD
 122 # (and it may include some of the git revision ID too).
 123 #
 124 # BestObjid includes as much as it can of the git commit object hash,
 125 # and never includes any of the count.
 126 #
 127 # All of these will autoscale and autorotate the selected model, and
 128 # will include an internal margin of the specified size (by default,
 129 # one pixel around each edge).  If no margin is needed, pass margin=0.
 130 #
 131 # There are no `function Commitid_Best*_sz'.  If they existed they
 132 # would simply return max_sz.
 133 #
 134 #
 135 # Output format
 136 # -------------
 137 #
 138 # In general the output, although it may be over multiple lines,
 139 # is always in this order
 140 #     git commit object id (hash)
 141 #     dirty indicator
 142 #     git commit count
 143 #
 144 # Not all layouts have all these parts.  The commit object id may
 145 # sometimes be split over multiple lines, but the count will not be.
 146 # If both commit id and commit count appear they will be separated
 147 # by (at least) a newline, or a dirty indicator, or a space.
 148 #
 149 # The commit id is truncated to fit, from the right.
 150 #
 151 # The commit count is truncated from the _left_, leaving the least
 152 # significant decimal digits.
 153 #
 154 # The dirty indicator can be
 155 #
 156 #   *   meaning the working tree contains differences from HEAD
 157 #
 158 #   +   meaning the working tree contains untracked files
 159 #       (ie files you have failed to `git add' and also failed
 160 #       to add to gitignore).  (But see the -i option.)
 161 #
 162 #
 163 # Specific layouts
 164 # ----------------
 165 #
 166 # If you want to control the exact layout (and make space for it in
 167 # your design), you can use these:
 168 #
 169 #    module Commitid_LAYOUT_2D()
 170 #    module Commitid_LAYOUT()
 171 #    module Commitid_LAYOUT_M_2D()
 172 #    module Commitid_LAYOUT_M()
 173 #    function Commitid_LAYOUT_sz()
 174 #
 175 # Here LAYOUT is one of the following (giving for example, `module
 176 # Commitid_Full8_2D').  In the examples, we will assume that the tree
 177 # is dirty, the commit count is 123456, and the commit object id
 178 # starts abcdeffedbcaabcdef...  In the examples `_' shows where a
 179 # space would be printed.
 180 #
 181 #   Small2 Small3 ... Small9 Small10 Small12 Small14 Small16
 182 #       A single line containing as much of the count will fit, eg:
 183 #            Small5    3456*
 184 #            Small8    _*123456
 185 #       The objectid is included if more than one character of of it
 186 #       will fit without makign the output ambiguous:
 187 #            Small9    ab*123456
 188 #
 189 #   Small2S Small4S ... Small16S
 190 #   Small3T Small9T Small12T
 191 #       Same as Small but split into two lines (S)
 192 #       or three lines (T).  Eg:
 193 #            Small4S    *4       Small6T   _*
 194 #                       56                 34
 195 #                                          56
 196 #   Git2 Git3 ... Git9 Git10 Git12 Git14 Git16
 197 #   Git4S Git6S ... Git16S
 198 #   Git6T Git9T Git12T
 199 #       Just the commit object hash, in one, two (S) or three (T)
 200 #       lines.  E.g.:
 201 #            Git5    abcd*
 202 #
 203 #   Full4 Full6 ... Full20:
 204 #       The commit object hash plus the commit count, on
 205 #       separate lines, eg:
 206 #            Full12   abcdef     Full16    abcdeffe
 207 #                     *23456               _*123456
 208 #
 209 #   Full6T Full9T ... Full30T
 210 #       As Full but the commit object id is split over two lines
 211 #       producing a 3-line layout, eg:
 212 #            Full9T    abc       Full21T   abcdeff
 213 #                      de*                 edbcaa*
 214 #                      456                 _123456
 215 #
 216 # Other LAYOUTs
 217 # -------------
 218 #
 219 #   FontDemo
 220 #
 221 #       A demonstration of the built-in 18-character font
 222 #
 223 #   Arg0 Arg1, ...
 224 #
 225 #       Strings passed on command line (without -t, or bare -t,
 226 #       rather than with -tLAYOUT).
 227 #
 228 #   LAYOUT
 229 #
 230 #       Generated by passing -tLAYOUT on the command line.
 231 #
 232
 233
 234 # COPYRIGHT, LICENCE AND LACK-OF-WARRANTY INFORMATION
 235 # ===================================================
 236 #
 237 # This program is Free Software and a Free Cultural Work.
 238 #
 239 #   You can redistribute it and/or modify it under the terms of the
 240 #   GNU General Public License as published by the Free Software
 241 #   Foundation, either version 3 of the License, or (at your option)
 242 #   any later version.
 243 #
 244 #   This program is distributed in the hope that it will be useful,
 245 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
 246 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 247 #   GNU General Public License for more details.
 248 #
 249 #   You should have received a copy of the GNU General Public License
 250 #   along with this program.  If not, see <http://www.gnu.org/licenses/>.
 251 #
 252 # Alternatively, at your option:
 253 #
 254 #   This work is licensed under the Creative Commons
 255 #   Attribution-ShareAlike 4.0 International License.
 256 #
 257 #   There is NO WARRANTY.
 258
 259
 260 use strict;
 261
 262 $SIG{__WARN__} = sub { die @_; };
 263
 264 our $debug=0;
 265
 266 if (@ARGV && $ARGV[0] =~ m/^-(D+)$/) {
 267     $debug = length $1;
 268     shift @ARGV;
 269 }
 270
 271 sub p { print @_ or die $!; }
 272
 273 sub p_debug { print STDERR @_ if $debug; }
 274
 275 p <<'END';
 276 // *** AUTOGENERATED - DO NOT EDIT *** //
 277 function Commitid_pixelsz() =
 278   ($Commitid_pixelsz       ? $Commitid_pixelsz       : 0.8) *
 279   ($Commitid_scale         ? $Commitid_scale         : 1.0);
 280 function Commitid_depth() =
 281   ($Commitid_depth         ? $Commitid_depth         : Commitid_pixelsz()/2) *
 282   ($Commitid_depth_scale   ? $Commitid_depth_scale   : 1.0);
 283 function Commitid__scale() =
 284   Commitid_pixelsz() / 0.2;
 285 END
 286
 287 sub chrmodname ($) {
 288     my ($chr) = @_;
 289     my $chrx = sprintf '%#x', ord $chr;
 290     return "Commitid__chr_$chrx";
 291 }
 292
 293 our $gtm_demo_i = -1;
 294 our $gtm_demo_j;
 295 our @gtm_demo_o;
 296
 297 sub gentextmodule_demo_start_batch () {
 298     $gtm_demo_j = 0;
 299     $gtm_demo_i++;
 300 }
 301
 302 sub argl_formal (@) { join ', ', @_; }
 303 sub argl_actual (@) { join ',', map { m/=/ ? $` : $_ } @_; }
 304
 305 sub gen3dmodule ($@) {
 306     my ($modb,$size,@argl) = (@_);
 307     $size ||= "${modb}_sz()";
 308     p "module ${modb}_M_2D(".argl_formal(@argl)."){\n";
 309     p "  translate([${size}[0],0])\n";
 310     p "    mirror([1,0,0])\n";
 311     p "    ${modb}_2D(".argl_actual(@argl).");\n";
 312     p "};\n";
 313     foreach my $mir ('','_M') {
 314         my $mm = "${modb}${mir}";
 315         p "module ${mm}(".argl_formal(@argl)."){\n";
 316         p " d=Commitid_depth();\n";
 317         p " translate([0,0,-d]) linear_extrude(height=d*2)\n";
 318         p "  ${mm}_2D(".argl_actual(@argl).");\n";
 319         p "}\n";
 320     }
 321 }
 322
 323 sub gentextmodule ($@) {
 324     my ($form, @lines) = @_;
 325     my $modb = "Commitid_$form";
 326     p "module ${modb}_2D(){\n";
 327     p " // |$_|\n" foreach @lines;
 328     p " scale(Commitid__scale()){\n";
 329     my $y = @lines;
 330     my $cols = 1;
 331     foreach my $line (@lines) {
 332         $y--;
 333         my $x = 0;
 334         foreach my $chr (split //, $line) {
 335             p sprintf "  translate([%d * 0.8, %d * 1.2]) %s();\n",
 336                 $x, $y, chrmodname $chr
 337                 if $chr =~ m/\S/;
 338             $x++;
 339         }
 340         $cols = $x if $x > $cols;
 341     }
 342     p " }\n";
 343     p "}\n";
 344     gen3dmodule($modb,'');
 345
 346     p sprintf "function %s_sz() = Commitid__scale() * 0.1 * [ %d, %d ];\n",
 347         $modb, 2 * ($cols * 4 - 1), 2 * (@lines * 6 - 1);
 348
 349     push @gtm_demo_o, <<END;
 350  translate([$gtm_demo_i * st[0], $gtm_demo_j * st[1]]) {
 351   difference(){
 352    color("blue") translate([-e,-e]) square(${modb}_sz() + 2*[e,e]);
 353    square(${modb}_sz());
 354   }
 355   ${modb}_2D();
 356 }
 357 END
 358     $gtm_demo_j++;
 359 }
 360
 361 our @demo;
 362
 363 sub parsefont () {
 364     my %cellmap;
 365     for (;;) {
 366         $_ = <DATA> // die;
 367         last if %cellmap && !m/\S/;
 368         next unless m/\S/;
 369         chomp;
 370         s{^(.) }{};
 371         $cellmap{$1} = $_;
 372     }
 373     my %chrpolys;
 374     # $chrs{$chr}[$poly] = $poly
 375     # $poly->{E} = [ "012345012345", ... ]
 376     while (<DATA>) {
 377         next unless m/\S/;
 378         chomp;
 379         my @chrs = split / /, $_;
 380         <DATA> !~ m/\S/ or die;
 381         foreach my $row (reverse 0..4) {
 382             $_ = <DATA>;
 383             chomp;
 384             s{^}{ };
 385             $_ .= ' ' x 8;
 386             m{\S/\S} and die;
 387             s{/(?=\s)}{L}g;
 388             s{/(?=\S)}{r}g;
 389             s{\\(?=\s)}{l}g;
 390             s{\\(?=\S)}{R}g;
 391             p "// $_\n";
 392             foreach my $chr (@chrs) {
 393                 s{^ }{} or die "$chr $_ ?";
 394                 foreach my $col (0..2) {
 395                     my @verts;
 396                     if (s{^ }{}) {
 397                     } elsif (s{^\S}{}) {
 398                         my $f = $cellmap{$&};
 399                         die unless $f;
 400                         $f =~ s/\b\d/ sprintf '%05d', $col*2000 + $&*1025 /ge;
 401                         $f =~ s/\d\b/ sprintf '%05d', $row*2000 + $&*1025 /ge;
 402                         push @{ $chrpolys{$chr} }, { E => [ split / /, $f ] };
 403                     } else {
 404                         die "$_ ?";
 405                     }
 406                 }
 407             }
 408             die "$_ ?" if m{\S};
 409         }
 410     }
 411
 412     my $demo = '';
 413     my $democols = 6;
 414     foreach my $chr (sort keys %chrpolys) {
 415         my $mod = chrmodname $chr;
 416         p "module $mod () {\n";
 417         foreach my $poly (@{ $chrpolys{$chr} }) {
 418             p " polygon([";
 419             my $delim = "";
 420             foreach my $pt (@{ $poly->{E} }) {
 421                 p $delim;
 422                 $pt =~ s{\d{5}}{$&,};
 423                 $pt =~ s{\b\d}{$&.}g;
 424                 p "[$pt]";
 425                 $delim = ',';
 426             }
 427             p "]);\n";
 428         }
 429         p "}\n";
 430         $demo .= $chr;
 431     }
 432     @demo = reverse $demo =~ m{.{1,$democols}}go;
 433 }
 434
 435 parsefont();
 436
 437 our $do_git; # contains may chars 'c' (count) and/or 'o' (object)
 438 our $do_git_untracked = 1;
 439 our $argcounter;
 440
 441 our @forms;
 442 our %included; # 0 = not at all; 1 = truncated; 2 = full
 443
 444 sub rjustt ($$$;$) {
 445     # right justify and truncate (ie, pad and truncate at left)
 446     # always includes prefix
 447     # sets $included{$what}
 448     my ($sz, $what, $whole, $prefix) = @_;
 449     $prefix //= '';
 450     my $lw = length $whole;
 451     my $spare = $sz - $lw - (length $prefix);
 452     $included{$what}= 1 + ($spare > 0);
 453     return
 454         ($spare > 0 ? (' ' x $spare) : '').
 455         $prefix.
 456         substr($whole, ($spare < 0 ? -$spare : 0));
 457 }
 458
 459 sub ljustt ($$$;$) {
 460     my ($sz, $what, $whole, $suffix) = @_;
 461     $suffix //= '';
 462     $sz -= length $suffix;
 463     $included{$what} = 1 + ($sz >= length $whole);
 464     return sprintf "%-${sz}.${sz}s%s", $whole, $suffix;
 465 }
 466
 467 sub genform_prep() {
 468     $included{$_}=0 foreach qw(Objid Count);
 469 }
 470
 471 sub genform ($@) {
 472     my ($form, @lines) = @_;
 473     gentextmodule($form, @lines);
 474     my $f = {
 475         Form => $form,
 476         Chars => (length join '', @lines),
 477         Lines => (scalar @lines),
 478         Ambiguous => ($form =~ m/Full/ && !grep { m/\W/ } @lines),
 479         Included => { %included },
 480     };
 481     push @forms, $f;
 482 }
 483
 484 sub genform_q ($$$) {
 485     my ($form, $s, $lines) = @_;
 486     $gtm_demo_j++;
 487     my $l = length $s;
 488     return if $l % $lines;
 489     my $e = $l/$lines;
 490     return if $e < 2;
 491     $gtm_demo_j--;
 492     genform($form, $s =~ m/.{$e}/g);
 493 }
 494
 495 sub genform_plusq ($$) {
 496     my ($form, $s) = @_;
 497     genform($form, $s);
 498     genform_q("${form}S", $s, 2);
 499     genform_q("${form}T", $s, 3);
 500 }
 501
 502 our @gcmd;
 503
 504 sub gitrun_start () {
 505     open F, "-|", @gcmd or die "$gcmd[0]: start: $!";
 506 }
 507
 508 sub gitrun_done (;$) {
 509     my ($errok) = @_;
 510     $?=0; $!=0;
 511     return if close F;
 512     return if $errok;
 513     die $! if $!;
 514     die "@gcmd failed ($?)\n";
 515 }
 516
 517 sub gitoutput (@) {
 518     (@gcmd) = (qw(git), @_);
 519     gitrun_start;
 520     $_ = <F>;
 521     gitrun_done;
 522     defined or die "@gcmd produced no output";
 523     chomp or die "@gcmd produced no final newline";
 524     $_;
 525 }
 526
 527 sub do_git () {
 528     return unless $do_git;
 529
 530     @gcmd = qw(git status --porcelain);
 531     push @gcmd, qw(--untracked=no) unless $do_git_untracked;
 532
 533     my $git_dirty = '';
 534     gitrun_start;
 535     while (<F>) {
 536         if (m/^\?\?/ && $do_git_untracked) {
 537             $git_dirty = '+';
 538             next;
 539         }
 540         $git_dirty = '*';
 541         last;
 542     }
 543     gitrun_done($git_dirty eq '*');
 544
 545     my $git_count;
 546     my $git_object;
 547
 548     if ($do_git =~ m/c/) {
 549         $git_count = gitoutput qw(rev-list --first-parent --count HEAD);
 550     }
 551     if ($do_git =~ m/o/) {
 552         $git_object = gitoutput qw(rev-parse HEAD);
 553     }
 554     print STDERR join ' ', map { $_ // '?' }
 555         "-- commitid", $git_object, $git_dirty, $git_count, "--\n";
 556
 557     foreach my $sz (2..10, qw(12 14 16)) {
 558         gentextmodule_demo_start_batch();
 559
 560         if (defined($git_count)) {
 561             genform_prep();
 562             my $smallstr = rjustt($sz, 'Count', $git_count, $git_dirty);
 563             my $forgitobj = $sz - length($git_count) - 1;
 564             if (defined($git_object) && $forgitobj >= 2) {
 565                 $smallstr = ljustt($forgitobj, 'Objid', $git_object).
 566                     ($git_dirty || ' ').
 567                     $git_count;
 568             }
 569             genform_plusq("Small$sz", $smallstr);
 570         }
 571
 572         genform_prep();
 573         genform_plusq("Git$sz", ljustt($sz, 'Objid', $git_object, $git_dirty))
 574             if defined $git_object;
 575
 576         if (defined $git_count && defined $git_object && $sz<=10) {
 577             genform_prep();
 578             genform("Full".($sz*2),
 579                     ljustt($sz, 'Objid', $git_object),
 580                     rjustt($sz, 'Count', $git_count, $git_dirty));
 581
 582             genform_prep();
 583             my $e = $sz;
 584             genform("Full".($e*3)."T",
 585                     ljustt($e*2, 'Objid', $git_object, $git_dirty)
 586                     =~ m/.{$e}/g,
 587                     rjustt($e, 'Count', $git_count));
 588         }
 589     }
 590 }
 591
 592 sub do_some_best ($$) {
 593     my ($bestwhat, $formre) = @_;
 594     my $modname = "Best$bestwhat";
 595     my $fullmodname = "Commitid_${modname}_2D";
 596     my @argl = qw(max_sz margin=Commitid_pixelsz());
 597     p "module $fullmodname(".argl_formal(@argl).") {\n";
 598     my $mbs = '$Commitid_max_best_scale';
 599     p " sc_max = $mbs ? $mbs : 2;\n";
 600     p " sz = max_sz - 2*[margin,margin];\n";
 601     my @do;
 602     foreach my $f (
 603         sort {
 604             $b->{Included}{$bestwhat} <=> $a->{Included}{$bestwhat} or
 605             $b->{Chars} <=> $a->{Chars} or
 606             $a->{Lines} <=> $b->{Chars}
 607         }
 608         grep {
 609             $_->{Form} =~ m/$formre/ &&
 610             !$_->{Ambiguous}
 611         }
 612         @forms
 613     ) {
 614         my $form = $f->{Form};
 615         p " sz_$form = Commitid_${form}_sz();\n";
 616         foreach my $rot (qw(0 1)) {
 617             my $id = "${form}_r${rot}";
 618             p " sc_$id = min(sc_max";
 619             foreach my $xy (qw(0 1)) {
 620                 p ",sz[$xy]/sz_$form","[",(($xy xor $rot)+0),"]";
 621             }
 622             p ");\n";
 623             push @do, " if (sc_$id >= 1.0";
 624             push @do, " && sc_$id >= sc_${form}_r1" if !$rot;
 625             push @do, ") {\n";
 626             push @do, "  translate([margin,margin]) scale(sc_$id)\n";
 627             push @do, "   rotate(90) translate([0,-sz_$form"."[1]])\n" if $rot;
 628             push @do, "   Commitid_${form}_2D();\n";
 629             push @do, " } else";
 630         }
 631     }
 632     push @do, <<END;
 633  {
 634   echo("$fullmodname could not fit anything in", max_sz);
 635  }
 636 END
 637     p $_ foreach @do;
 638     p "}\n";
 639
 640     gen3dmodule "Commitid_$modname", 'max_sz', @argl;
 641 }
 642
 643 sub do_git_best () {
 644     return unless $do_git;
 645
 646     # Auto-computer for `best fit'
 647     #
 648     # We have two best fit approaches: with count, and git-object-id-only
 649     #
 650     # For `with count', we only ever include the git object id if the
 651     # result would be unambigous.  That means that at least one space
 652     # or punctuation was generated.
 653     #
 654     # We sort the options by firstly number of characters
 655     # (decreasing), and then by number of lines (increasing) and
 656     # try each one both ways round.
 657
 658     do_some_best('Count', 'Small|Full') if $do_git =~ m/c/;
 659     do_some_best('Objid', 'Git|Full') if $do_git =~ m/o/;
 660 }
 661
 662 while (@ARGV) {
 663     $_ = shift;
 664     if (m/^--(no)?-git$/) {
 665         $do_git = $1 ? '' : 'co';
 666     } elsif (m/^---git=objid$/i) {
 667         $do_git = 'o';
 668     } elsif (m/^-i$/) {
 669         $do_git_untracked = 0;
 670     } elsif (m/^-t(.*)$/) {
 671         my $form = $1;
 672         die "bad usage: -t needs string argument\n";
 673         $_ = shift;
 674         gentextmodule($form, split /\n/, $_);
 675         $argcounter //= 0;
 676     } elsif (m/^[^-]/) {
 677         gentextmodule("Arg$argcounter", $_);
 678         $argcounter++;
 679     } else {
 680         die "bad usage: unknown option \`$_'\n";
 681     }
 682 }
 683
 684 $do_git //= defined($argcounter) ? '' : 'co';
 685
 686 gentextmodule_demo_start_batch();
 687 gentextmodule('FontDemo', @demo);
 688
 689 do_git();
 690 do_git_best();
 691
 692 p "module Commitid_2DDemo(){\n";
 693 p " st = Commitid__scale() * [ 10, 5 ];\n";
 694 p " e  = Commitid_pixelsz();\n";
 695 p $_ foreach @gtm_demo_o;
 696 p "}\n";
 697
 698 flush STDOUT or die $!;
 699 close STDOUT or die $!;
 700
 701 __DATA__
 702
 703 # 00 20 22 02
 704 l 00 20 02
 705 r 00 20 22
 706 L 00 22 02
 707 R 20 22 02
 708 > 00 20 22 02 11
 709 < 00 20 11 22 02
 710
 711 0 1 2 3 4 5 6 7 8 9
 712
 713 /#\  r  /#\ ##\ # # ### /#/ ### /#\ /#\
 714 # # /#    #   # # # #   #     # # # # #
 715 # #  #  /#/ ##< \## ##\ ##\  // >#< \##
 716 # #  #  #     #   #   # # #  #  # #   #
 717 \#/ /#\ ### ##/   # ##/ \#/  #  \#/ ##/
 718
 719 a b c d e f
 720
 721     #         #     /##
 722     #   /##   # /#\ #
 723 /## ##\ #   /## #r# ###
 724 # # # # #   # # #/  #
 725 \## ##/ \## \## \#/ #
 726
 727 + *
 728
 729     # #
 730  #  \#/
 731 ### ###
 732  #  /#\
 733     # #