commitid.scad.pl

   1 #!/usr/bin/perl -w
   2
   3 # commitid.scad.pl - a program for annotating solid models with commit info
   4 # Copyright (C)2016 Ian Jackson.  See below.  There is NO WARRANTY.
   5
   6
   7 # USAGE
   8 # =====
   9 #
  10 #   .../commitid.scad.pl [OPTION...] [STRING...] >commitid.scad.new \
  11 #     && mv -f commitid.scad.new commitid.scad
  12 #
  13 # Run without arguments, commitid.scad.pl will output an openscad file
  14 # which contains 2D and 3D models of the current git commit count and
  15 # commit object id (commit hash), useful for identifying printed
  16 # parts.
  17 #
  18 # See below for details.  You probably want these two sections, as a
  19 # quick starting point:
  20 #    General form of provided openscad modules
  21 #    Autoscaling modules
  22 #
  23 # We can also generate models of short mainly-numeric strings
  24 # specified on the command line.
  25 #
  26 #
  27 # Options:
  28 #
  29 #   --git    Generate git commit indications, as shown below
  30 #            (this is the default if no strings are requested with -t).
  31 #            Ie, produce the `Autoscaling modules' and `Specific layouts'.
  32 #
  33 #   --git=objid
  34 #            Generate git commit indication based on commit object only
  35 #            (ie avoid counting commits).  Ie, do not generate `Small'
  36 #            and `Full' layouts (and never select them for `Best').
  37 #
  38 #   -i       Do not generate `+' dirty indication if git-untracked files
  39 #            are present (ie, missing .gitignore entries).  The `*'
  40 #            dirty tree indication (for modified files) cannot be disabled.
  41 #
  42 #   [-t[LAYOUT]] TEXT
  43 #            Generate a layout LAYOUT containing TEXT.  TEXT can
  44 #            contain newlines (a final newline usually undesirable, as
  45 #            it will generate a blank line).  If LAYOUT is not specified,
  46 #            generates Arg0, Arg1, Arg2, etc., for successive such
  47 #            TEXTs.  The permissible character set in is TEXT is:
  48 #                 space 0-9 a-f + *
  49 #
  50 #
  51 # OPENSCAD INTERFACE
  52 # ==================
  53 #
  54 # Dynamic variables for configuration
  55 # -----------------------------------
  56 #
  57 # We honour the following variables to control various scaling factors:
  58 #
  59 #                             default value  notes
  60 #    $Commitid_pixelsz         0.8             \ multiplied together
  61 #    $Commitid_scale           1.0             /
  62 #    $Commitid_depth           pixelsz/2       \ multiplied together
  63 #    $Commitid_depth_scale     1.0             /
  64 #    $Commitid_max_best_scale  2.0             limits XY scaling in *Best*
  65 #
  66 # FYI the font is nominally 3x5 pixels, with 1-pixel inter-line and
  67 # inter-character gaps.  (It's not strictly speaking a 3x5 bitmap
  68 # font, size it contains partial pixels and diagonals.)
  69 #
  70 #
  71 # Non-`module'-specific functions
  72 # -------------------------------
  73 #
  74 # We provide the following functions (which depend on the config
  75 # variables, but not on anything else) and compute useful values:
  76 #
  77 #   function Commitid_pixelsz()   Actual size of each nominal pixel
  78 #   function Commitid_depth()     Depth to use (the amount characters
  79 #                                  should be raised or sunken)
  80 #
  81 # General form of provided openscad modules
  82 # -----------------------------------------
  83 #
  84 #   module Commitid_MODULE_2D(...)   Collection of polygons forming characters
  85 #   module Commitid_MODULE(...)      The above, extruded up and down in Z
  86 #   module Commitid_MODULE_M_2D(...) Mirror writing
  87 #   module Commitid_MODULE_M(...)    3D mirror writing
  88 #   function Commitid_MODULE_sz()    A 2-vector giving the X,Y size
  89 #
  90 # Except for *Best* modules, the XY origin is in the bottom left
  91 # corner without any margin.  Likewise Commitid_MODULE_sz does not
  92 # include any margin.
  93 #
  94 # For 3D versions, the model is 2*depth deep and the XY plane bisects
  95 # the model.  This means it's convenient to either add or subtract from
  96 # a workpiece whose face is in the XY plane.
  97 #
  98 # The _M versions are provided to avoid doing inconvenient translation
  99 # and rotation to get the flipped version in the right place.
 100 #
 101 #
 102 # Autoscaling modules
 103 # -------------------
 104 #
 105 # These modules take a specification of the available XY space, and
 106 # select and generate a suitable specific identification layout:
 107 #
 108 #   module Commitid_BestCount_2D  (max_sz, margin=Commitid_pixelsz())
 109 #   module Commitid_BestCount     (max_sz, margin=Commitid_pixelsz())
 110 #   module Commitid_BestCount_M_2D(max_sz, margin=Commitid_pixelsz())
 111 #   module Commitid_BestCount_M   (max_sz, margin=Commitid_pixelsz())
 112 #   module Commitid_BestObjid_2D  (max_sz, margin=Commitid_pixelsz())
 113 #   module Commitid_BestObjid     (max_sz, margin=Commitid_pixelsz())
 114 #   module Commitid_BestObjid_M_2D(max_sz, margin=Commitid_pixelsz())
 115 #   module Commitid_BestObjid_M   (max_sz, margin=Commitid_pixelsz())
 116 #
 117 # max_sz should be [x,y].
 118 #
 119 # BestCount includes (as much as it can of) the git commit count,
 120 # ie the result of
 121 #     git rev-list --first-parent --count HEAD
 122 # (and it may include some of the git revision ID too).
 123 #
 124 # BestObjid includes as much as it can of the git commit object hash,
 125 # and never includes any of the count.
 126 #
 127 # All of these will autoscale and autorotate the selected model, and
 128 # will include an internal margin of the specified size (by default,
 129 # one pixel around each edge).  If no margin is needed, pass margin=0.
 130 #
 131 # There are no `function Commitid_Best*_sz'.  If they existed they
 132 # would simply return max_sz.
 133 #
 134 #
 135 # Output format
 136 # -------------
 137 #
 138 # In general the output, although it may be over multiple lines,
 139 # is always in this order
 140 #     git commit object id (hash)
 141 #     dirty indicator
 142 #     git commit count
 143 #
 144 # Not all layouts have all these parts.  The commit object id may
 145 # sometimes be split over multiple lines, but the count will not be.
 146 # If both commit id and commit count appear they will be separated
 147 # by (at least) a newline, or a dirty indicator, or a space.
 148 #
 149 # The commit id is truncated to fit, from the right.
 150 #
 151 # The commit count is truncated from the _left_, leaving the least
 152 # significant decimal digits.
 153 #
 154 # The dirty indicator can be
 155 #
 156 #   *   meaning the working tree contains differences from HEAD
 157 #
 158 #   +   meaning the working tree contains untracked files
 159 #       (ie files you have failed to `git add' and also failed
 160 #       to add to gitignore).  (But see the -i option.)
 161 #
 162 #
 163 # Specific layouts
 164 # ----------------
 165 #
 166 # If you want to control the exact layout (and make space for it in
 167 # your design), you can use these:
 168 #
 169 #    module Commitid_LAYOUT_2D()
 170 #    module Commitid_LAYOUT()
 171 #    module Commitid_LAYOUT_M_2D()
 172 #    module Commitid_LAYOUT_M()
 173 #    function Commitid_LAYOUT_sz()
 174 #
 175 # Here LAYOUT is one of the following (giving for example, `module
 176 # Commitid_Full8_2D').  In the examples, we will assume that the tree
 177 # is dirty, the commit count is 123456, and the commit object id
 178 # starts abcdeffedbcaabcdef...  In the examples `_' shows where a
 179 # space would be printed.
 180 #
 181 #   Small2 Small3 ... Small9 Small10 Small12 Small14 Small16
 182 #       A single line containing as much of the count will fit, eg:
 183 #            Small5    3456*
 184 #            Small8    _*123456
 185 #       The objectid is included if more than one character of of it
 186 #       will fit without makign the output ambiguous:
 187 #            Small9    ab*123456
 188 #
 189 #   Small2S Small4S ... Small16S
 190 #   Small3T Small9T Small12T
 191 #       Same as Small but split into two lines (S)
 192 #       or three lines (T).  Eg:
 193 #            Small4S    *4       Small6T   _*
 194 #                       56                 34
 195 #                                          56
 196 #   Git2 Git3 ... Git9 Git10 Git12 Git14 Git16
 197 #   Git4S Git6S ... Git16S
 198 #   Git6T Git9T Git12T
 199 #       Just the commit object hash, in one, two (S) or three (T)
 200 #       lines.  E.g.:
 201 #            Git5    abcd*
 202 #
 203 #   Full4 Full6 ... Full20:
 204 #       The commit object hash plus the commit count, on
 205 #       separate lines, eg:
 206 #            Full12   abcdef     Full16    abcdeffe
 207 #                     *23456               _*123456
 208 #
 209 #   Full6T Full9T ... Full30T
 210 #       As Full but the commit object id is split over two lines
 211 #       producing a 3-line layout, eg:
 212 #            Full9T    abc       Full21T   abcdeff
 213 #                      de*                 edbcaa*
 214 #                      456                 _123456
 215 #
 216 # Other LAYOUTs
 217 # -------------
 218 #
 219 #   FontDemo
 220 #
 221 #       A demonstration of the built-in 18-character font
 222 #
 223 #   Arg0 Arg1, ...
 224 #
 225 #       Strings passed on command line (without -t, or bare -t,
 226 #       rather than with -tLAYOUT).
 227 #
 228 #   LAYOUT
 229 #
 230 #       Generated by passing -tLAYOUT on the command line.
 231 #
 232
 233
 234 # COPYRIGHT, LICENCE AND LACK-OF-WARRANTY INFORMATION
 235 # ===================================================
 236 #
 237 # This program is Free Software and a Free Cultural Work.
 238 #
 239 #   You can redistribute it and/or modify it under the terms of the
 240 #   GNU General Public License as published by the Free Software
 241 #   Foundation, either version 3 of the License, or (at your option)
 242 #   any later version.
 243 #
 244 #   This program is distributed in the hope that it will be useful,
 245 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
 246 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 247 #   GNU General Public License for more details.
 248 #
 249 #   You should have received a copy of the GNU General Public License
 250 #   along with this program.  If not, see <http://www.gnu.org/licenses/>.
 251 #
 252 # Alternatively, at your option:
 253 #
 254 #   This work is licensed under the Creative Commons
 255 #   Attribution-ShareAlike 4.0 International License.
 256 #
 257 #   There is NO WARRANTY.
 258
 259
 260 use strict;
 261
 262 $SIG{__WARN__} = sub { die @_; };
 263
 264 our $debug=0;
 265
 266 if (@ARGV && $ARGV[0] =~ m/^-(D+)$/) {
 267     $debug = length $1;
 268     shift @ARGV;
 269 }
 270
 271 sub p { print @_ or die $!; }
 272
 273 sub p_debug { print STDERR @_ if $debug; }
 274
 275 p <<'END';
 276 // *** AUTOGENERATED - DO NOT EDIT *** //
 277 function Commitid_pixelsz() =
 278   ($Commitid_pixelsz       ? $Commitid_pixelsz       : 0.8) *
 279   ($Commitid_scale         ? $Commitid_scale         : 1.0);
 280 function Commitid_depth() =
 281   ($Commitid_depth         ? $Commitid_depth         : Commitid_pixelsz()/2) *
 282   ($Commitid_depth_scale   ? $Commitid_depth_scale   : 1.0);
 283 function Commitid__scale() =
 284   Commitid_pixelsz() / 0.2;
 285 END
 286
 287 sub chrmodname ($) {
 288     my ($chr) = @_;
 289     my $chrx = sprintf '%#x', ord $chr;
 290     return "Commitid__chr_$chrx";
 291 }
 292
 293 our $gtm_demo_i = -1;
 294 our $gtm_demo_j;
 295 our @gtm_demo_o;
 296
 297 sub gentextmodule_demo_start_batch () {
 298     $gtm_demo_j = 0;
 299     $gtm_demo_i++;
 300 }
 301
 302 sub argl_formal (@) { join ', ', @_; }
 303 sub argl_actual (@) { join ',', map { m/=/ ? $` : $_ } @_; }
 304
 305 sub gen3dmodule ($@) {
 306     my ($modb,$size,@argl) = (@_);
 307     $size ||= "${modb}_sz()";
 308     p "module ${modb}_M_2D(".argl_formal(@argl)."){\n";
 309     p "  translate([${size}[0],0])\n";
 310     p "    mirror([1,0,0])\n";
 311     p "    ${modb}_2D(".argl_actual(@argl).");\n";
 312     p "};\n";
 313     foreach my $mir ('','_M') {
 314         my $mm = "${modb}${mir}";
 315         p "module ${mm}(".argl_formal(@argl)."){\n";
 316         p " d=Commitid_depth();\n";
 317         p " translate([0,0,-d]) linear_extrude(height=d*2)\n";
 318         p "  ${mm}_2D(".argl_actual(@argl).");\n";
 319         p "}\n";
 320     }
 321 }
 322
 323 sub gentextmodule ($@) {
 324     my ($form, @lines) = @_;
 325     my $modb = "Commitid_$form";
 326     p "module ${modb}_2D(){\n";
 327     p " // |$_|\n" foreach @lines;
 328     p " scale(Commitid__scale()){\n";
 329     my $y = @lines;
 330     my $cols = 1;
 331     foreach my $line (@lines) {
 332         $y--;
 333         my $x = 0;
 334         foreach my $chr (split //, $line) {
 335             p sprintf "  translate([%d * 0.8, %d * 1.2]) %s();\n",
 336                 $x, $y, chrmodname $chr
 337                 if $chr =~ m/\S/;
 338             $x++;
 339         }
 340         $cols = $x if $x > $cols;
 341     }
 342     p " }\n";
 343     p "}\n";
 344     gen3dmodule($modb,'');
 345
 346     p sprintf "function %s_sz() = Commitid__scale() * 0.1 * [ %d, %d ];\n",
 347         $modb, 2 * ($cols * 4 - 1), 2 * (@lines * 6 - 1);
 348
 349     push @gtm_demo_o, <<END;
 350  translate([$gtm_demo_i * st[0], $gtm_demo_j * st[1]]) {
 351   difference(){
 352    color("blue") translate([-e,-e]) square(${modb}_sz() + 2*[e,e]);
 353    square(${modb}_sz());
 354   }
 355   ${modb}_2D();
 356 }
 357 END
 358     $gtm_demo_j++;
 359 }
 360
 361 our @demo;
 362
 363 sub parsefont () {
 364     my %cellmap;
 365     for (;;) {
 366         $_ = <DATA> // die;
 367         last if %cellmap && !m/\S/;
 368         next unless m/\S/;
 369         chomp;
 370         s{^(.) }{};
 371         $cellmap{$1} = $_;
 372     }
 373     my %chrpolys;
 374     while (<DATA>) {
 375         next unless m/\S/;
 376         chomp;
 377         my @chrs = split / /, $_;
 378         <DATA> !~ m/\S/ or die;
 379         foreach my $row (reverse 0..4) {
 380             $_ = <DATA>;
 381             chomp;
 382             s{^}{ };
 383             $_ .= ' ' x 8;
 384             m{\S/\S} and die;
 385             s{/(?=\s)}{L}g;
 386             s{/(?=\S)}{r}g;
 387             s{\\(?=\s)}{l}g;
 388             s{\\(?=\S)}{R}g;
 389             p "// $_\n";
 390             foreach my $chr (@chrs) {
 391                 s{^ }{} or die "$chr $_ ?";
 392                 foreach my $col (0..2) {
 393                     my @verts;
 394                     if (s{^ }{}) {
 395                     } elsif (s{^\S}{}) {
 396                         my $f = $cellmap{$&};
 397                         die unless $f;
 398                         $f =~ s/\b\d/ sprintf '%05d', $col*2000 + $&*1025 /ge;
 399                         $f =~ s/\d\b/ sprintf '%05d', $row*2000 + $&*1025 /ge;
 400                         push @{ $chrpolys{$chr} }, [ split / /, $f ];
 401                     } else {
 402                         die "$_ ?";
 403                     }
 404                 }
 405             }
 406             die "$_ ?" if m{\S};
 407         }
 408     }
 409
 410     my $demo = '';
 411     my $democols = 6;
 412     foreach my $chr (sort keys %chrpolys) {
 413         my $mod = chrmodname $chr;
 414         p "module $mod () {\n";
 415         foreach my $poly (@{ $chrpolys{$chr} }) {
 416             p " polygon([";
 417             my $delim = "";
 418             foreach my $pt (@$poly) {
 419                 p $delim;
 420                 $pt =~ s{\d{5}}{$&,};
 421                 $pt =~ s{\b\d}{$&.}g;
 422                 p "[$pt]";
 423                 $delim = ',';
 424             }
 425             p "]);\n";
 426         }
 427         p "}\n";
 428         $demo .= $chr;
 429     }
 430     @demo = reverse $demo =~ m{.{1,$democols}}go;
 431 }
 432
 433 parsefont();
 434
 435 our $do_git; # contains may chars 'c' (count) and/or 'o' (object)
 436 our $do_git_untracked = 1;
 437 our $argcounter;
 438
 439 our @forms;
 440 our %included; # 0 = not at all; 1 = truncated; 2 = full
 441
 442 sub rjustt ($$$;$) {
 443     # right justify and truncate (ie, pad and truncate at left)
 444     # always includes prefix
 445     # sets $included{$what}
 446     my ($sz, $what, $whole, $prefix) = @_;
 447     $prefix //= '';
 448     my $lw = length $whole;
 449     my $spare = $sz - $lw - (length $prefix);
 450     $included{$what}= 1 + ($spare > 0);
 451     return
 452         ($spare > 0 ? (' ' x $spare) : '').
 453         $prefix.
 454         substr($whole, ($spare < 0 ? -$spare : 0));
 455 }
 456
 457 sub ljustt ($$$;$) {
 458     my ($sz, $what, $whole, $suffix) = @_;
 459     $suffix //= '';
 460     $sz -= length $suffix;
 461     $included{$what} = 1 + ($sz >= length $whole);
 462     return sprintf "%-${sz}.${sz}s%s", $whole, $suffix;
 463 }
 464
 465 sub genform_prep() {
 466     $included{$_}=0 foreach qw(Objid Count);
 467 }
 468
 469 sub genform ($@) {
 470     my ($form, @lines) = @_;
 471     gentextmodule($form, @lines);
 472     my $f = {
 473         Form => $form,
 474         Chars => (length join '', @lines),
 475         Lines => (scalar @lines),
 476         Ambiguous => ($form =~ m/Full/ && !grep { m/\W/ } @lines),
 477         Included => { %included },
 478     };
 479     push @forms, $f;
 480 }
 481
 482 sub genform_q ($$$) {
 483     my ($form, $s, $lines) = @_;
 484     $gtm_demo_j++;
 485     my $l = length $s;
 486     return if $l % $lines;
 487     my $e = $l/$lines;
 488     return if $e < 2;
 489     $gtm_demo_j--;
 490     genform($form, $s =~ m/.{$e}/g);
 491 }
 492
 493 sub genform_plusq ($$) {
 494     my ($form, $s) = @_;
 495     genform($form, $s);
 496     genform_q("${form}S", $s, 2);
 497     genform_q("${form}T", $s, 3);
 498 }
 499
 500 our @gcmd;
 501
 502 sub gitrun_start () {
 503     open F, "-|", @gcmd or die "$gcmd[0]: start: $!";
 504 }
 505
 506 sub gitrun_done (;$) {
 507     my ($errok) = @_;
 508     $?=0; $!=0;
 509     return if close F;
 510     return if $errok;
 511     die $! if $!;
 512     die "@gcmd failed ($?)\n";
 513 }
 514
 515 sub gitoutput (@) {
 516     (@gcmd) = (qw(git), @_);
 517     gitrun_start;
 518     $_ = <F>;
 519     gitrun_done;
 520     defined or die "@gcmd produced no output";
 521     chomp or die "@gcmd produced no final newline";
 522     $_;
 523 }
 524
 525 sub do_git () {
 526     return unless $do_git;
 527
 528     @gcmd = qw(git status --porcelain);
 529     push @gcmd, qw(--untracked=no) unless $do_git_untracked;
 530
 531     my $git_dirty = '';
 532     gitrun_start;
 533     while (<F>) {
 534         if (m/^\?\?/ && $do_git_untracked) {
 535             $git_dirty = '+';
 536             next;
 537         }
 538         $git_dirty = '*';
 539         last;
 540     }
 541     gitrun_done($git_dirty eq '*');
 542
 543     my $git_count;
 544     my $git_object;
 545
 546     if ($do_git =~ m/c/) {
 547         $git_count = gitoutput qw(rev-list --first-parent --count HEAD);
 548     }
 549     if ($do_git =~ m/o/) {
 550         $git_object = gitoutput qw(rev-parse HEAD);
 551     }
 552     print STDERR join ' ', map { $_ // '?' }
 553         "-- commitid", $git_object, $git_dirty, $git_count, "--\n";
 554
 555     foreach my $sz (2..10, qw(12 14 16)) {
 556         gentextmodule_demo_start_batch();
 557
 558         if (defined($git_count)) {
 559             genform_prep();
 560             my $smallstr = rjustt($sz, 'Count', $git_count, $git_dirty);
 561             my $forgitobj = $sz - length($git_count) - 1;
 562             if (defined($git_object) && $forgitobj >= 2) {
 563                 $smallstr = ljustt($forgitobj, 'Objid', $git_object).
 564                     ($git_dirty || ' ').
 565                     $git_count;
 566             }
 567             genform_plusq("Small$sz", $smallstr);
 568         }
 569
 570         genform_prep();
 571         genform_plusq("Git$sz", ljustt($sz, 'Objid', $git_object, $git_dirty))
 572             if defined $git_object;
 573
 574         if (defined $git_count && defined $git_object && $sz<=10) {
 575             genform_prep();
 576             genform("Full".($sz*2),
 577                     ljustt($sz, 'Objid', $git_object),
 578                     rjustt($sz, 'Count', $git_count, $git_dirty));
 579
 580             genform_prep();
 581             my $e = $sz;
 582             genform("Full".($e*3)."T",
 583                     ljustt($e*2, 'Objid', $git_object, $git_dirty)
 584                     =~ m/.{$e}/g,
 585                     rjustt($e, 'Count', $git_count));
 586         }
 587     }
 588 }
 589
 590 sub do_some_best ($$) {
 591     my ($bestwhat, $formre) = @_;
 592     my $modname = "Best$bestwhat";
 593     my $fullmodname = "Commitid_${modname}_2D";
 594     my @argl = qw(max_sz margin=Commitid_pixelsz());
 595     p "module $fullmodname(".argl_formal(@argl).") {\n";
 596     my $mbs = '$Commitid_max_best_scale';
 597     p " sc_max = $mbs ? $mbs : 2;\n";
 598     p " sz = max_sz - 2*[margin,margin];\n";
 599     my @do;
 600     foreach my $f (
 601         sort {
 602             $b->{Included}{$bestwhat} <=> $a->{Included}{$bestwhat} or
 603             $b->{Chars} <=> $a->{Chars} or
 604             $a->{Lines} <=> $b->{Chars}
 605         }
 606         grep {
 607             $_->{Form} =~ m/$formre/ &&
 608             !$_->{Ambiguous}
 609         }
 610         @forms
 611     ) {
 612         my $form = $f->{Form};
 613         p " sz_$form = Commitid_${form}_sz();\n";
 614         foreach my $rot (qw(0 1)) {
 615             my $id = "${form}_r${rot}";
 616             p " sc_$id = min(sc_max";
 617             foreach my $xy (qw(0 1)) {
 618                 p ",sz[$xy]/sz_$form","[",(($xy xor $rot)+0),"]";
 619             }
 620             p ");\n";
 621             push @do, " if (sc_$id >= 1.0";
 622             push @do, " && sc_$id >= sc_${form}_r1" if !$rot;
 623             push @do, ") {\n";
 624             push @do, "  translate([margin,margin]) scale(sc_$id)\n";
 625             push @do, "   rotate(90) translate([0,-sz_$form"."[1]])\n" if $rot;
 626             push @do, "   Commitid_${form}_2D();\n";
 627             push @do, " } else";
 628         }
 629     }
 630     push @do, <<END;
 631  {
 632   echo("$fullmodname could not fit anything in", max_sz);
 633  }
 634 END
 635     p $_ foreach @do;
 636     p "}\n";
 637
 638     gen3dmodule "Commitid_$modname", 'max_sz', @argl;
 639 }
 640
 641 sub do_git_best () {
 642     return unless $do_git;
 643
 644     # Auto-computer for `best fit'
 645     #
 646     # We have two best fit approaches: with count, and git-object-id-only
 647     #
 648     # For `with count', we only ever include the git object id if the
 649     # result would be unambigous.  That means that at least one space
 650     # or punctuation was generated.
 651     #
 652     # We sort the options by firstly number of characters
 653     # (decreasing), and then by number of lines (increasing) and
 654     # try each one both ways round.
 655
 656     do_some_best('Count', 'Small|Full') if $do_git =~ m/c/;
 657     do_some_best('Objid', 'Git|Full') if $do_git =~ m/o/;
 658 }
 659
 660 while (@ARGV) {
 661     $_ = shift;
 662     if (m/^--(no)?-git$/) {
 663         $do_git = $1 ? '' : 'co';
 664     } elsif (m/^---git=objid$/i) {
 665         $do_git = 'o';
 666     } elsif (m/^-i$/) {
 667         $do_git_untracked = 0;
 668     } elsif (m/^-t(.*)$/) {
 669         my $form = $1;
 670         die "bad usage: -t needs string argument\n";
 671         $_ = shift;
 672         gentextmodule($form, split /\n/, $_);
 673         $argcounter //= 0;
 674     } elsif (m/^[^-]/) {
 675         gentextmodule("Arg$argcounter", $_);
 676         $argcounter++;
 677     } else {
 678         die "bad usage: unknown option \`$_'\n";
 679     }
 680 }
 681
 682 $do_git //= defined($argcounter) ? '' : 'co';
 683
 684 gentextmodule_demo_start_batch();
 685 gentextmodule('FontDemo', @demo);
 686
 687 do_git();
 688 do_git_best();
 689
 690 p "module Commitid_2DDemo(){\n";
 691 p " st = Commitid__scale() * [ 10, 5 ];\n";
 692 p " e  = Commitid_pixelsz();\n";
 693 p $_ foreach @gtm_demo_o;
 694 p "}\n";
 695
 696 flush STDOUT or die $!;
 697 close STDOUT or die $!;
 698
 699 __DATA__
 700
 701 # 00 20 22 02
 702 l 00 20 02
 703 r 00 20 22
 704 L 00 22 02
 705 R 20 22 02
 706 > 00 20 22 02 11
 707 < 00 20 11 22 02
 708
 709 0 1 2 3 4 5 6 7 8 9
 710
 711 /#\  r  /#\ ##\ # # ### /#/ ### /#\ /#\
 712 # # /#    #   # # # #   #     # # # # #
 713 # #  #  /#/ ##< \## ##\ ##\  // >#< \##
 714 # #  #  #     #   #   # # #  #  # #   #
 715 \#/ /#\ ### ##/   # ##/ \#/  #  \#/ ##/
 716
 717 a b c d e f
 718
 719     #         #     /##
 720     #   /##   # /#\ #
 721 /## ##\ #   /## #r# ###
 722 # # # # #   # # #/  #
 723 \## ##/ \## \## \#/ #
 724
 725 + *
 726
 727     # #
 728  #  \#/
 729 ### ###
 730  #  /#\
 731     # #