belt-slot-cut-jig.scad

   1 // -*- C -*-
   2
   3 // todo
   4 //  various registration marks
   5 //   protrustions at ends at strap width and middle
   6 //   grooves on top face at 1/4,1/2,3/4 length and 1/2 width
   7
   8 crewpunch_slop = 0.3;
   9
  10 holder_min_wall = 2;
  11 holder_attach_near_wall = 3;
  12
  13 holder_attach_xsz = 5;
  14 holder_ctie_width = 4.0 + 0.5;
  15 holder_ctie_thick = 3.0 + 0.5;
  16 holder_attach_walls = 3;
  17 holder_attach_roof = 2.5;
  18
  19 jig_interval = 25;
  20 strap_width = 26.75 + 0.7;
  21 strap_thick = 3;
  22 edgewall_width = 3;
  23
  24 punch_travel = 8;
  25
  26 main_slop = 0.5;
  27
  28 jig_max_len = 160; // print diagonally
  29 //jig_max_len = 30;
  30
  31 registrationgroove_width = 0.8;
  32 registrationgroove_depth = 1.2;
  33
  34 registrationprotrusion_poke = 3;
  35 registrationprotrusion_slope = 0.75;
  36
  37 jig_overlap = 1;
  38
  39 // from careful measurement
  40
  41 crewpunch_shape =
  42   [[  6, [0.6, 6.0], [1.6, 12.3] ],
  43    [  8, [1.1, 6.2], [1.9, 12.5] ],
  44    [ 10, [1.6, 6.5], [2.1, 12.8] ],
  45    [ 12, [1.8, 6.6], [2.3, 12.7] ],
  46    [ 14, [2.1, 6.8], [2.6, 13.0] ],
  47    [ 16, [2.4, 6.9], [2.7, 13.2] ],
  48    [ 18, [2.5, 7.0], [2.9, 13.3] ],
  49    [ 22, [3.1, 7.1], [3.2, 13.4] ],
  50    [ 26, [3.3, 7.2], [3.5, 13.6] ],
  51    ];
  52
  53 crewpunch_shaft_max_y = 3.5;
  54
  55 crewpunch_systematic_size_error = +0.36;
  56
  57 crewpunch_smallest_shape = crewpunch_shape[0];
  58 crewpunch_biggest_shape = crewpunch_shape[len(crewpunch_shape)-1];
  59
  60 crewpunch_skew_angle = 3.5; //degrees
  61 crewpunch_skew_yoff = -1.1; //mm
  62
  63 // computed
  64
  65 attach_ysz = holder_attach_walls*2 + holder_ctie_width;
  66
  67 holder_block_zsz = crewpunch_biggest_shape[0] - crewpunch_smallest_shape[0];
  68 holder_xsz = crewpunch_biggest_shape[2][0] + crewpunch_biggest_shape[2][1] +
  69   holder_min_wall*2;
  70
  71 holder_front_all = crewpunch_shaft_max_y - crewpunch_biggest_shape[1][0]
  72   + attach_ysz + crewpunch_systematic_size_error + crewpunch_skew_yoff
  73   + holder_xsz/2 * sin(abs(crewpunch_skew_angle));
  74
  75 crewpunch_biggest_y =
  76   crewpunch_biggest_shape[1][0] + crewpunch_biggest_shape[1][1];
  77 holder_ysz = crewpunch_biggest_y + holder_min_wall + holder_front_all
  78   + max(0, -crewpunch_skew_yoff);
  79
  80 attach_offset = 0.5 * (holder_front_all - holder_attach_near_wall);
  81
  82 jig_main_zsz = holder_block_zsz + punch_travel;
  83
  84 jig_ends_extra = 2;
  85
  86 //jig_iters = (jig_max_len - jig_ends_extra) / jig_interval;
  87 jig_iters=2;
  88 echo(jig_iters);
  89
  90 // objects
  91
  92 module CrewPunch(){
  93   ourslop = crewpunch_slop - crewpunch_systematic_size_error;
  94   hull(){
  95     for(layer=crewpunch_shape){
  96       translate([0,0, layer[0]]){
  97         for(xind=[0,1]) //translate([xind?0:1,0,0])
  98           for(yind=[0,1]) //translate([0,yind?0.5:0,0])
  99             mirror([xind?1:0,0,0]) mirror([0,yind?0:1,0]){
 100               translate([-0.1,-0.1,-0.1])
 101                 cube([0.1 + layer[2][xind] + ourslop,
 102                       0.1 + layer[1][1-yind] + ourslop,
 103                       0.2]);
 104             }
 105       }
 106     }
 107   }
 108 }
 109
 110 module PunchHolder(cutouts=true){
 111   translations=[-holder_xsz/2,
 112                 -holder_ysz + holder_min_wall + crewpunch_biggest_y/2,
 113                 0];
 114   translate(translations){
 115     difference(){
 116       translate([0,attach_offset,0])
 117         cube([holder_xsz, holder_ysz - attach_offset, holder_block_zsz]);
 118       if (cutouts)
 119         translate([0,-crewpunch_skew_yoff])
 120         translate(-translations)
 121         rotate([0,0,-crewpunch_skew_angle])
 122         translate(translations)
 123         translate([crewpunch_biggest_shape[2][1] + holder_min_wall,
 124                    crewpunch_biggest_shape[1][1] + holder_front_all,
 125                    -crewpunch_smallest_shape[0]])
 126           CrewPunch();
 127     }
 128     difference(){
 129       translate([holder_xsz/2 - holder_attach_xsz/2, 0, 0])
 130         cube([holder_attach_xsz,
 131               attach_ysz,
 132               holder_block_zsz + punch_travel
 133               + holder_ctie_thick + holder_attach_roof + 1]);
 134       if (cutouts)
 135         translate([-30,
 136                    holder_attach_walls,
 137                    holder_block_zsz + punch_travel])
 138           cube([60, holder_ctie_width, holder_ctie_thick]);
 139     }
 140   }
 141 }
 142
 143 module RegistrationGroove(l){
 144   // runs along the +ve X axis for length l but at correct z pos
 145   translate([0, 0, jig_main_zsz + 0.1]) {
 146     rotate([90,0,90])
 147       linear_extrude(height=l)
 148       polygon([[-registrationgroove_width/2, 0],
 149                [ +registrationgroove_width/2, 0],
 150                [ 0, -registrationgroove_depth ]]);
 151   }
 152 }
 153
 154 module OneJig(){
 155   difference(){
 156     translate([-(jig_interval/2 + jig_overlap),
 157                -(strap_width/2 + edgewall_width) - attach_offset,
 158                -strap_thick])
 159       cube([jig_interval + 2,
 160             strap_width + edgewall_width*2 + attach_offset,
 161             jig_main_zsz + strap_thick]);
 162     minkowski(){
 163       cube([main_slop*2, main_slop*2, 50], center=true);
 164       PunchHolder(false);
 165     }
 166     translate([-100, -strap_width/2, -10])
 167       cube([200, strap_width, 10]);
 168    translate([-100,0,0])
 169      RegistrationGroove(200);
 170    for (xfrac=[-1/4,0,+1/4])
 171      translate([jig_interval * xfrac, -100, 0])
 172        rotate([0,0,90])
 173        RegistrationGroove(200);
 174   }
 175 }
 176
 177 module RegistrationProtrusion(){
 178   // points towards the positive x axis
 179   xsz = registrationprotrusion_poke;
 180   ysz = registrationprotrusion_poke;
 181   diag_sz = xsz * sqrt(2);
 182   zsz = diag_sz / registrationprotrusion_slope;
 183   hull(){
 184     translate([0, 0, 0.1]){
 185       linear_extrude(height=0.1)
 186         polygon([[   0, -ysz ],
 187                  [ xsz,    0 ],
 188                  [   0,  ysz ]]);
 189       translate([-0.1, 0, zsz ])
 190         rotate([0,0,45])
 191         cube(0.1);
 192     }
 193   }
 194 }
 195
 196 module Jig(){
 197   for(end=[0,1]){
 198     for(yfrac=[-1/2, 0, 1/2]){
 199       translate([ end
 200                   ? jig_interval * (jig_iters - 0.5)
 201                   : -jig_interval/2,
 202                  yfrac * strap_width,
 203                  0])
 204         rotate([0,0, end ? 0 : 180])
 205         translate([ jig_overlap, 0, 0 ])
 206         RegistrationProtrusion();
 207     }
 208   }
 209   for (i=[0:jig_iters-1]) {
 210     translate([jig_interval * i, 0, 0])
 211       OneJig();
 212   }
 213 }
 214
 215 module JigT(){ ////toplevel
 216   translate([0,0,jig_main_zsz])
 217     rotate([180,0,0])
 218     Jig();
 219 }
 220
 221 module PunchHolderT(){ ////toplevel
 222   PunchHolder(true);
 223 }
 224
 225 module Demo(){ ////toplevel
 226   %PunchHolder();
 227   Jig();
 228 }
 229
 230 module Kit(){ ////toplevel
 231   rotate([0,0,-45]){
 232     JigT();
 233     translate([(jig_iters-1)*jig_interval/2,
 234                -strap_width,
 235                0])
 236       PunchHolder();
 237   }
 238 }
 239
 240 //CrewPunch();
 241 //PunchHolder();
 242 //PunchHolder(false);
 243 //OneJig();
 244 //Jig();
 245 Demo();
 246 //JigT();
 247 //RegistrationProtrusion();
 248 //PunchHolderT();
 249 //Kit();