belt-slot-cut-jig.scad

   1 // -*- C -*-
   2
   3 // todo
   4 //  various registration marks
   5 //   protrustions at ends at strap width and middle
   6 //   grooves on top face at 1/4,1/2,3/4 length and 1/2 width
   7
   8 crewpunch_slop = 0.3;
   9
  10 holder_min_wall = 2;
  11 holder_attach_near_wall = 5;
  12
  13 holder_attach_xsz = 5;
  14 holder_ctie_width = 4.0 + 0.5;
  15 holder_ctie_thick = 3.0 + 0.5;
  16 holder_attach_walls = 3;
  17 holder_attach_roof = 2.5;
  18
  19 jig_interval = 25;
  20 strap_width = 26.75 + 0.7;
  21 strap_thick = 3;
  22 edgewall_width = 3;
  23
  24 punch_travel = 8;
  25
  26 main_slop = 0.5;
  27
  28 jig_max_len = 160; // print diagonally
  29 //jig_max_len = 30;
  30
  31 registrationgroove_width = 0.8;
  32 registrationgroove_depth = 1.2;
  33
  34 registrationprotrusion_poke = 3;
  35 registrationprotrusion_slope = 0.75;
  36
  37 jig_overlap = 1;
  38
  39 // from careful measurement
  40
  41 crewpunch_shape =
  42   [[  6, [0.6, 6.0], [1.6, 12.3] ],
  43    [  8, [1.1, 6.2], [1.9, 12.5] ],
  44    [ 10, [1.6, 6.5], [2.1, 12.8] ],
  45    [ 12, [1.8, 6.6], [2.3, 12.7] ],
  46    [ 14, [2.1, 6.8], [2.6, 13.0] ],
  47    [ 16, [2.4, 6.9], [2.7, 13.2] ],
  48    [ 18, [2.5, 7.0], [2.9, 13.3] ],
  49    [ 22, [3.1, 7.1], [3.2, 13.4] ],
  50    [ 26, [3.3, 7.2], [3.5, 13.6] ],
  51    ];
  52
  53 crewpunch_shaft_max_y = 7.5;
  54
  55 crewpunch_systematic_size_error = +0.36;
  56
  57 crewpunch_smallest_shape = crewpunch_shape[0];
  58 crewpunch_biggest_shape = crewpunch_shape[len(crewpunch_shape)-1];
  59
  60 crewpunch_skew_angle = 3.5; //degrees
  61 crewpunch_skew_yoff = +1.1; //mm
  62
  63 // computed
  64
  65 punch_dx = 0.5 * (-crewpunch_biggest_shape[2][0]
  66                   +crewpunch_biggest_shape[2][1]);
  67 punch_dy = 0.5 * (+crewpunch_biggest_shape[1][1]
  68                   -crewpunch_biggest_shape[1][0]) + crewpunch_skew_yoff;
  69
  70 attach_ysz = holder_attach_walls*2 + holder_ctie_width;
  71
  72 holder_block_zsz = crewpunch_biggest_shape[0] - crewpunch_smallest_shape[0];
  73 holder_xsz = crewpunch_biggest_shape[2][0] + crewpunch_biggest_shape[2][1] +
  74   holder_min_wall*2;
  75
  76 holder_skewangle_yextra = holder_xsz/2 * sin(abs(crewpunch_skew_angle));
  77
  78 holder_max_y = punch_dy + crewpunch_biggest_shape[1][0] + holder_min_wall
  79   + crewpunch_systematic_size_error + holder_skewangle_yextra;
  80
  81 holder_attach_max_y = punch_dy
  82   - max(crewpunch_biggest_shape[1][1], crewpunch_shaft_max_y)
  83   - crewpunch_systematic_size_error - holder_skewangle_yextra;
  84
  85 holder_block_min_y = punch_dy
  86   - crewpunch_biggest_shape[1][1] - holder_attach_near_wall +
  87   - crewpunch_systematic_size_error - holder_skewangle_yextra;
  88
  89 holder_all_min_y = holder_attach_max_y - attach_ysz;
  90
  91 jig_max_y = max(holder_max_y + main_slop, strap_width/2) + edgewall_width;
  92 jig_min_y = min(holder_all_min_y - main_slop, -strap_width/2) - edgewall_width;
  93
  94 jig_main_zsz = holder_block_zsz + punch_travel;
  95
  96 jig_ends_extra = 2;
  97
  98 //jig_iters = (jig_max_len - jig_ends_extra) / jig_interval;
  99 jig_iters=2;
 100 echo(jig_iters);
 101
 102 // objects
 103
 104 module CrewPunch(){
 105   ourslop = crewpunch_slop - crewpunch_systematic_size_error;
 106   hull(){
 107     for(layer=crewpunch_shape){
 108       translate([0,0, layer[0]]){
 109         for(xind=[0,1]) //translate([xind?0:1,0,0])
 110           for(yind=[0,1]) //translate([0,yind?0.5:0,0])
 111             mirror([xind?1:0,0,0]) mirror([0,yind?0:1,0]){
 112               translate([-0.1,-0.1,-0.1])
 113                 cube([0.1 + layer[2][xind] + ourslop,
 114                       0.1 + layer[1][1-yind] + ourslop,
 115                       0.2]);
 116             }
 117       }
 118     }
 119   }
 120 }
 121
 122 module PunchHolder(cutouts=true){
 123     difference(){
 124       translate([-holder_xsz/2, holder_block_min_y, 0])
 125         cube([holder_xsz,
 126               holder_max_y - holder_block_min_y,
 127               holder_block_zsz]);
 128       if (cutouts)
 129         rotate([0,0,-crewpunch_skew_angle])
 130         translate([punch_dx,
 131                    punch_dy,
 132                    -crewpunch_smallest_shape[0]])
 133           CrewPunch();
 134     }
 135     difference(){
 136       translate([-holder_attach_xsz/2, holder_all_min_y, 0])
 137         cube([holder_attach_xsz,
 138               attach_ysz,
 139               holder_block_zsz + punch_travel
 140               + holder_ctie_thick + holder_attach_roof + 1]);
 141       if (cutouts)
 142         translate([-30,
 143                    holder_attach_walls,
 144                    holder_block_zsz + punch_travel])
 145           cube([60, holder_ctie_width, holder_ctie_thick]);
 146     }
 147 }
 148
 149 module RegistrationGroove(l){
 150   // runs along the +ve X axis for length l but at correct z pos
 151   translate([0, 0, jig_main_zsz + 0.1]) {
 152     rotate([90,0,90])
 153       linear_extrude(height=l)
 154       polygon([[-registrationgroove_width/2, 0],
 155                [ +registrationgroove_width/2, 0],
 156                [ 0, -registrationgroove_depth ]]);
 157   }
 158 }
 159
 160 module OneJig(){
 161   difference(){
 162     translate([-(jig_interval/2 + jig_overlap),
 163                jig_min_y,
 164                -strap_thick])
 165       cube([jig_interval + 2,
 166             jig_max_y - jig_min_y,
 167             jig_main_zsz + strap_thick]);
 168     minkowski(){
 169       cube([main_slop*2, main_slop*2, 50], center=true);
 170       PunchHolder(false);
 171     }
 172     translate([-100, -strap_width/2, -10])
 173       cube([200, strap_width, 10]);
 174    translate([-100,0,0])
 175      RegistrationGroove(200);
 176    for (xfrac=[-1/4,0,+1/4])
 177      translate([jig_interval * xfrac, -100, 0])
 178        rotate([0,0,90])
 179        RegistrationGroove(200);
 180   }
 181 }
 182
 183 module RegistrationProtrusion(){
 184   // points towards the positive x axis
 185   xsz = registrationprotrusion_poke;
 186   ysz = registrationprotrusion_poke;
 187   diag_sz = xsz * sqrt(2);
 188   zsz = diag_sz / registrationprotrusion_slope;
 189   hull(){
 190     translate([0, 0, 0.1]){
 191       linear_extrude(height=0.1)
 192         polygon([[   0, -ysz ],
 193                  [ xsz,    0 ],
 194                  [   0,  ysz ]]);
 195       translate([-0.1, 0, zsz ])
 196         rotate([0,0,45])
 197         cube(0.1);
 198     }
 199   }
 200 }
 201
 202 module Jig(){
 203   for(end=[0,1]){
 204     for(yfrac=[-1/2, 0, 1/2]){
 205       translate([ end
 206                   ? jig_interval * (jig_iters - 0.5)
 207                   : -jig_interval/2,
 208                  yfrac * strap_width,
 209                  0])
 210         rotate([0,0, end ? 0 : 180])
 211         translate([ jig_overlap, 0, 0 ])
 212         RegistrationProtrusion();
 213     }
 214   }
 215   for (i=[0:jig_iters-1]) {
 216     translate([jig_interval * i, 0, 0])
 217       OneJig();
 218   }
 219 }
 220
 221 module JigT(){ ////toplevel
 222   translate([0,0,jig_main_zsz])
 223     rotate([180,0,0])
 224     Jig();
 225 }
 226
 227 module PunchHolderT(){ ////toplevel
 228   PunchHolder(true);
 229 }
 230
 231 module Demo(){ ////toplevel
 232   %PunchHolder();
 233   Jig();
 234 }
 235
 236 module Kit(){ ////toplevel
 237   rotate([0,0,-45]){
 238     JigT();
 239     translate([(jig_iters-1)*jig_interval/2,
 240                -strap_width,
 241                0])
 242       PunchHolder();
 243   }
 244 }
 245
 246 //CrewPunch();
 247 //PunchHolder();
 248 //PunchHolder(false);
 249 //OneJig();
 250 //Jig();
 251 Demo();
 252 //JigT();
 253 //RegistrationProtrusion();
 254 //PunchHolderT();
 255 //Kit();