belt-slot-cut-jig.scad

   1 // -*- C -*-
   2
   3 // todo
   4 //  various registration marks
   5 //   protrustions at ends at strap width and middle
   6 //   grooves on top face at 1/4,1/2,3/4 length and 1/2 width
   7
   8 crewpunch_slop = 0.3;
   9
  10 holder_min_wall = 2;
  11 holder_attach_near_wall = 3;
  12
  13 holder_attach_xsz = 5;
  14 holder_ctie_width = 4.0 + 0.5;
  15 holder_ctie_thick = 3.0 + 0.5;
  16 holder_attach_walls = 3;
  17 holder_attach_roof = 2.5;
  18
  19 jig_interval = 25;
  20 strap_width = 26.75 + 0.7;
  21 strap_thick = 3;
  22 edgewall_width = 3;
  23
  24 punch_travel = 8;
  25
  26 main_slop = 0.5;
  27
  28 jig_max_len = 160; // print diagonally
  29 //jig_max_len = 30;
  30
  31 registrationgroove_width = 0.8;
  32 registrationgroove_depth = 1.2;
  33
  34 registrationprotrusion_poke = 3;
  35 registrationprotrusion_slope = 0.75;
  36
  37 jig_overlap = 1;
  38
  39 // from careful measurement
  40
  41 crewpunch_shape =
  42   [[  6, [0.6, 6.0], [1.6, 12.3] ],
  43    [  8, [1.1, 6.2], [1.9, 12.5] ],
  44    [ 10, [1.6, 6.5], [2.1, 12.8] ],
  45    [ 12, [1.8, 6.6], [2.3, 12.7] ],
  46    [ 14, [2.1, 6.8], [2.6, 13.0] ],
  47    [ 16, [2.4, 6.9], [2.7, 13.2] ],
  48    [ 18, [2.5, 7.0], [2.9, 13.3] ],
  49    [ 22, [3.1, 7.1], [3.2, 13.4] ],
  50    [ 26, [3.3, 7.2], [3.5, 13.6] ],
  51    ];
  52
  53 crewpunch_shaft_max_y = 3.5;
  54
  55 crewpunch_systematic_size_error = +0.36;
  56
  57 crewpunch_smallest_shape = crewpunch_shape[0];
  58 crewpunch_biggest_shape = crewpunch_shape[len(crewpunch_shape)-1];
  59
  60 crewpunch_skew_angle = 3.5; //degrees
  61 crewpunch_skew_yoff_broken = 0; //mm
  62 crewpunch_skew_yoff = -1.1; //mm
  63
  64 // computed
  65
  66 attach_ysz = holder_attach_walls*2 + holder_ctie_width;
  67
  68 holder_block_zsz = crewpunch_biggest_shape[0] - crewpunch_smallest_shape[0];
  69 holder_xsz = crewpunch_biggest_shape[2][0] + crewpunch_biggest_shape[2][1] +
  70   holder_min_wall*2;
  71
  72 holder_skewangle_yextra = holder_xsz/2 * sin(abs(crewpunch_skew_angle));
  73
  74 holder_max_y = crewpunch_biggest_shape[1][1] + holder_min_wall
  75   + crewpunch_systematic_size_error + holder_skewangle_yextra;
  76
  77 holder_block_min_y = crewpunch_biggest_shape[1][0] - holder_attach_near_wall +
  78   - crewpunch_systematic_size_error - holder_skewangle_yextra;
  79
  80 holder_all_min_y = holder_block_min_y - attach_ysz;
  81 holder_front_all = abs(holder_all_min_y);
  82
  83 crewpunch_biggest_y =
  84   crewpunch_biggest_shape[1][0] + crewpunch_biggest_shape[1][1];
  85 holder_ysz = crewpunch_biggest_y + holder_min_wall + holder_front_all
  86   + max(0, -crewpunch_skew_yoff_broken);
  87
  88 attach_offset = 0.5 * (holder_front_all - holder_attach_near_wall);
  89
  90 jig_main_zsz = holder_block_zsz + punch_travel;
  91
  92 jig_ends_extra = 2;
  93
  94 //jig_iters = (jig_max_len - jig_ends_extra) / jig_interval;
  95 jig_iters=2;
  96 echo(jig_iters);
  97
  98 // objects
  99
 100 module CrewPunch(){
 101   ourslop = crewpunch_slop - crewpunch_systematic_size_error;
 102   hull(){
 103     for(layer=crewpunch_shape){
 104       translate([0,0, layer[0]]){
 105         for(xind=[0,1]) //translate([xind?0:1,0,0])
 106           for(yind=[0,1]) //translate([0,yind?0.5:0,0])
 107             mirror([xind?1:0,0,0]) mirror([0,yind?0:1,0]){
 108               translate([-0.1,-0.1,-0.1])
 109                 cube([0.1 + layer[2][xind] + ourslop,
 110                       0.1 + layer[1][1-yind] + ourslop,
 111                       0.2]);
 112             }
 113       }
 114     }
 115   }
 116 }
 117
 118 module PunchHolder(cutouts=true){
 119   translations=[-holder_xsz/2,
 120                 -holder_ysz + holder_min_wall + crewpunch_biggest_y/2,
 121                 0];
 122   translate(translations){
 123     difference(){
 124       translate([0,attach_offset,0])
 125         cube([holder_xsz, holder_ysz - attach_offset, holder_block_zsz]);
 126       if (cutouts)
 127         translate([0,-crewpunch_skew_yoff_broken])
 128         translate(-translations)
 129         rotate([0,0,-crewpunch_skew_angle])
 130         translate(translations)
 131         translate([crewpunch_biggest_shape[2][1] + holder_min_wall,
 132                    crewpunch_biggest_shape[1][1] + holder_front_all,
 133                    -crewpunch_smallest_shape[0]])
 134           CrewPunch();
 135     }
 136     difference(){
 137       translate([holder_xsz/2 - holder_attach_xsz/2, 0, 0])
 138         cube([holder_attach_xsz,
 139               attach_ysz,
 140               holder_block_zsz + punch_travel
 141               + holder_ctie_thick + holder_attach_roof + 1]);
 142       if (cutouts)
 143         translate([-30,
 144                    holder_attach_walls,
 145                    holder_block_zsz + punch_travel])
 146           cube([60, holder_ctie_width, holder_ctie_thick]);
 147     }
 148   }
 149 }
 150
 151 module RegistrationGroove(l){
 152   // runs along the +ve X axis for length l but at correct z pos
 153   translate([0, 0, jig_main_zsz + 0.1]) {
 154     rotate([90,0,90])
 155       linear_extrude(height=l)
 156       polygon([[-registrationgroove_width/2, 0],
 157                [ +registrationgroove_width/2, 0],
 158                [ 0, -registrationgroove_depth ]]);
 159   }
 160 }
 161
 162 module OneJig(){
 163   difference(){
 164     translate([-(jig_interval/2 + jig_overlap),
 165                -(strap_width/2 + edgewall_width) - attach_offset,
 166                -strap_thick])
 167       cube([jig_interval + 2,
 168             strap_width + edgewall_width*2 + attach_offset,
 169             jig_main_zsz + strap_thick]);
 170     minkowski(){
 171       cube([main_slop*2, main_slop*2, 50], center=true);
 172       PunchHolder(false);
 173     }
 174     translate([-100, -strap_width/2, -10])
 175       cube([200, strap_width, 10]);
 176    translate([-100,0,0])
 177      RegistrationGroove(200);
 178    for (xfrac=[-1/4,0,+1/4])
 179      translate([jig_interval * xfrac, -100, 0])
 180        rotate([0,0,90])
 181        RegistrationGroove(200);
 182   }
 183 }
 184
 185 module RegistrationProtrusion(){
 186   // points towards the positive x axis
 187   xsz = registrationprotrusion_poke;
 188   ysz = registrationprotrusion_poke;
 189   diag_sz = xsz * sqrt(2);
 190   zsz = diag_sz / registrationprotrusion_slope;
 191   hull(){
 192     translate([0, 0, 0.1]){
 193       linear_extrude(height=0.1)
 194         polygon([[   0, -ysz ],
 195                  [ xsz,    0 ],
 196                  [   0,  ysz ]]);
 197       translate([-0.1, 0, zsz ])
 198         rotate([0,0,45])
 199         cube(0.1);
 200     }
 201   }
 202 }
 203
 204 module Jig(){
 205   for(end=[0,1]){
 206     for(yfrac=[-1/2, 0, 1/2]){
 207       translate([ end
 208                   ? jig_interval * (jig_iters - 0.5)
 209                   : -jig_interval/2,
 210                  yfrac * strap_width,
 211                  0])
 212         rotate([0,0, end ? 0 : 180])
 213         translate([ jig_overlap, 0, 0 ])
 214         RegistrationProtrusion();
 215     }
 216   }
 217   for (i=[0:jig_iters-1]) {
 218     translate([jig_interval * i, 0, 0])
 219       OneJig();
 220   }
 221 }
 222
 223 module JigT(){ ////toplevel
 224   translate([0,0,jig_main_zsz])
 225     rotate([180,0,0])
 226     Jig();
 227 }
 228
 229 module PunchHolderT(){ ////toplevel
 230   PunchHolder(true);
 231 }
 232
 233 module Demo(){ ////toplevel
 234   %PunchHolder();
 235   Jig();
 236 }
 237
 238 module Kit(){ ////toplevel
 239   rotate([0,0,-45]){
 240     JigT();
 241     translate([(jig_iters-1)*jig_interval/2,
 242                -strap_width,
 243                0])
 244       PunchHolder();
 245   }
 246 }
 247
 248 //CrewPunch();
 249 //PunchHolder();
 250 //PunchHolder(false);
 251 //OneJig();
 252 //Jig();
 253 Demo();
 254 //JigT();
 255 //RegistrationProtrusion();
 256 //PunchHolderT();
 257 //Kit();