belt-slot-cut-jig.scad

   1 // -*- C -*-
   2
   3 // todo
   4 //  various registration marks
   5 //   protrustions at ends at strap width and middle
   6 //   grooves on top face at 1/4,1/2,3/4 length and 1/2 width
   7
   8 crewpunch_slop = 0.3;
   9
  10 holder_min_wall = 2;
  11 holder_attach_near_wall = 3;
  12
  13 holder_attach_xsz = 5;
  14 holder_ctie_width = 4.0 + 0.5;
  15 holder_ctie_thick = 3.0 + 0.5;
  16 holder_attach_walls = 3;
  17 holder_attach_roof = 2.5;
  18
  19 jig_interval = 25;
  20 strap_width = 26.75 + 0.7;
  21 strap_thick = 3;
  22 edgewall_width = 3;
  23
  24 punch_travel = 8;
  25
  26 main_slop = 0.5;
  27
  28 jig_max_len = 160; // print diagonally
  29 //jig_max_len = 30;
  30
  31 registrationgroove_width = 0.8;
  32 registrationgroove_depth = 1.2;
  33
  34 registrationprotrusion_poke = 3;
  35 registrationprotrusion_slope = 0.75;
  36
  37 jig_overlap = 1;
  38
  39 // from careful measurement
  40
  41 crewpunch_shape =
  42   [[  6, [0.6, 6.0], [1.6, 12.3] ],
  43    [  8, [1.1, 6.2], [1.9, 12.5] ],
  44    [ 10, [1.6, 6.5], [2.1, 12.8] ],
  45    [ 12, [1.8, 6.6], [2.3, 12.7] ],
  46    [ 14, [2.1, 6.8], [2.6, 13.0] ],
  47    [ 16, [2.4, 6.9], [2.7, 13.2] ],
  48    [ 18, [2.5, 7.0], [2.9, 13.3] ],
  49    [ 22, [3.1, 7.1], [3.2, 13.4] ],
  50    [ 26, [3.3, 7.2], [3.5, 13.6] ],
  51    ];
  52
  53 crewpunch_shaft_max_y = 3.5;
  54
  55 crewpunch_systematic_size_error = +0.36;
  56
  57 crewpunch_min_y = 4.7 - crewpunch_systematic_size_error;
  58
  59 crewpunch_smallest_shape = crewpunch_shape[0];
  60 crewpunch_biggest_shape = crewpunch_shape[len(crewpunch_shape)-1];
  61
  62 crewpunch_skew_angle = 2.0; //degrees
  63 crewpunch_skew_yoff = -0.6; //mm
  64
  65 // computed
  66
  67 attach_ysz = holder_attach_walls*2 + holder_ctie_width;
  68
  69 holder_block_zsz = crewpunch_biggest_shape[0] - crewpunch_smallest_shape[0];
  70 holder_xsz = crewpunch_biggest_shape[2][0] + crewpunch_biggest_shape[2][1] +
  71   holder_min_wall*2;
  72
  73 holder_front_all = crewpunch_shaft_max_y - crewpunch_biggest_shape[1][0]
  74   + attach_ysz + crewpunch_systematic_size_error + crewpunch_skew_yoff
  75   + holder_xsz/2 * sin(abs(crewpunch_skew_angle));
  76
  77 crewpunch_biggest_y =
  78   crewpunch_biggest_shape[1][0] + crewpunch_biggest_shape[1][1];
  79 holder_ysz = crewpunch_biggest_y + holder_min_wall + holder_front_all;
  80
  81 attach_offset = 0.5 * (holder_front_all - holder_attach_near_wall);
  82
  83 jig_main_zsz = holder_block_zsz + punch_travel;
  84
  85 jig_ends_extra = 2;
  86
  87 //jig_iters = (jig_max_len - jig_ends_extra) / jig_interval;
  88 jig_iters=2;
  89 echo(jig_iters);
  90
  91 // objects
  92
  93 module CrewPunch(){
  94   ourslop = crewpunch_slop - crewpunch_systematic_size_error;
  95   hull(){
  96     for(layer=crewpunch_shape){
  97       translate([0,0, layer[0]]){
  98         for(xind=[0,1]) //translate([xind?0:1,0,0])
  99           for(yind=[0,1]) //translate([0,yind?0.5:0,0])
 100             mirror([xind?1:0,0,0]) mirror([0,yind?0:1,0]){
 101               translate([-0.1,-0.1,-0.1])
 102                 cube([0.1 + layer[2][xind] + ourslop,
 103                       0.1 + layer[1][1-yind] + ourslop,
 104                       0.2]);
 105             }
 106       }
 107     }
 108   }
 109 }
 110
 111 module PunchHolder(cutouts=true){
 112   translations=[-holder_xsz/2,
 113                 -holder_ysz + holder_min_wall + crewpunch_biggest_y/2,
 114                 0];
 115   translate(translations){
 116     difference(){
 117       translate([0,attach_offset,0])
 118         cube([holder_xsz, holder_ysz - attach_offset, holder_block_zsz]);
 119       if (cutouts)
 120         translate([0,-crewpunch_skew_yoff])
 121         translate(-translations)
 122         rotate([0,0,-crewpunch_skew_angle])
 123         translate(translations)
 124         translate([crewpunch_biggest_shape[2][1] + holder_min_wall,
 125                    crewpunch_biggest_shape[1][1] + holder_front_all,
 126                    -crewpunch_smallest_shape[0]])
 127           CrewPunch();
 128     }
 129     difference(){
 130       translate([holder_xsz/2 - holder_attach_xsz/2, 0, 0])
 131         cube([holder_attach_xsz,
 132               attach_ysz,
 133               holder_block_zsz + punch_travel
 134               + holder_ctie_thick + holder_attach_roof + 1]);
 135       if (cutouts)
 136         translate([-30,
 137                    holder_attach_walls,
 138                    holder_block_zsz + punch_travel])
 139           cube([60, holder_ctie_width, holder_ctie_thick]);
 140     }
 141   }
 142 }
 143
 144 module RegistrationGroove(l){
 145   // runs along the +ve X axis for length l but at correct z pos
 146   translate([0, 0, jig_main_zsz + 0.1]) {
 147     rotate([90,0,90])
 148       linear_extrude(height=l)
 149       polygon([[-registrationgroove_width/2, 0],
 150                [ +registrationgroove_width/2, 0],
 151                [ 0, -registrationgroove_depth ]]);
 152   }
 153 }
 154
 155 module OneJig(){
 156   difference(){
 157     translate([-(jig_interval/2 + jig_overlap),
 158                -(strap_width/2 + edgewall_width) - attach_offset,
 159                -strap_thick])
 160       cube([jig_interval + 2,
 161             strap_width + edgewall_width*2 + attach_offset,
 162             jig_main_zsz + strap_thick]);
 163     minkowski(){
 164       cube([main_slop*2, main_slop*2, 50], center=true);
 165       PunchHolder(false);
 166     }
 167     translate([-100, -strap_width/2, -10])
 168       cube([200, strap_width, 10]);
 169    translate([-100,0,0])
 170      RegistrationGroove(200);
 171    for (xfrac=[-1/4,0,+1/4])
 172      translate([jig_interval * xfrac, -100, 0])
 173        rotate([0,0,90])
 174        RegistrationGroove(200);
 175   }
 176 }
 177
 178 module RegistrationProtrusion(){
 179   // points towards the positive x axis
 180   xsz = registrationprotrusion_poke;
 181   ysz = registrationprotrusion_poke;
 182   diag_sz = xsz * sqrt(2);
 183   zsz = diag_sz / registrationprotrusion_slope;
 184   hull(){
 185     translate([0, 0, 0.1]){
 186       linear_extrude(height=0.1)
 187         polygon([[   0, -ysz ],
 188                  [ xsz,    0 ],
 189                  [   0,  ysz ]]);
 190       translate([-0.1, 0, zsz ])
 191         rotate([0,0,45])
 192         cube(0.1);
 193     }
 194   }
 195 }
 196
 197 module Jig(){
 198   for(end=[0,1]){
 199     for(yfrac=[-1/2, 0, 1/2]){
 200       translate([ end
 201                   ? jig_interval * (jig_iters - 0.5)
 202                   : -jig_interval/2,
 203                  yfrac * strap_width,
 204                  0])
 205         rotate([0,0, end ? 0 : 180])
 206         translate([ jig_overlap, 0, 0 ])
 207         RegistrationProtrusion();
 208     }
 209   }
 210   for (i=[0:jig_iters-1]) {
 211     translate([jig_interval * i, 0, 0])
 212       OneJig();
 213   }
 214 }
 215
 216 module JigT(){ ////toplevel
 217   translate([0,0,jig_main_zsz])
 218     rotate([180,0,0])
 219     Jig();
 220 }
 221
 222 module PunchHolderT(){ ////toplevel
 223   PunchHolder(true);
 224 }
 225
 226 module Demo(){ ////toplevel
 227   %PunchHolder();
 228   Jig();
 229 }
 230
 231 module Kit(){ ////toplevel
 232   rotate([0,0,-45]){
 233     JigT();
 234     translate([(jig_iters-1)*jig_interval/2,
 235                -strap_width,
 236                0])
 237       PunchHolder();
 238   }
 239 }
 240
 241 //CrewPunch();
 242 //PunchHolder();
 243 //PunchHolder(false);
 244 //OneJig();
 245 //Jig();
 246 //Demo();
 247 //JigT();
 248 //RegistrationProtrusion();
 249 //PunchHolderT();
 250 //Kit();