belt-slot-cut-jig.scad

   1 // -*- C -*-
   2
   3 // todo
   4 //  various registration marks
   5 //   protrustions at ends at strap width and middle
   6 //   grooves on top face at 1/4,1/2,3/4 length and 1/2 width
   7
   8 crewpunch_slop = 0.3;
   9
  10 holder_min_wall = 2;
  11 holder_attach_near_wall = 3;
  12
  13 holder_attach_xsz = 5;
  14 holder_ctie_width = 4.0 + 0.5;
  15 holder_ctie_thick = 3.0 + 0.5;
  16 holder_attach_walls = 3;
  17 holder_attach_roof = 2.5;
  18
  19 jig_interval = 25;
  20 strap_width = 26.75 + 0.7;
  21 strap_thick = 3;
  22 edgewall_width = 3;
  23
  24 punch_travel = 8;
  25
  26 main_slop = 0.5;
  27
  28 jig_max_len = 160; // print diagonally
  29 //jig_max_len = 30;
  30
  31 registrationgroove_width = 0.8;
  32 registrationgroove_depth = 1.2;
  33
  34 registrationprotrusion_poke = 3;
  35 registrationprotrusion_slope = 0.75;
  36
  37 jig_overlap = 1;
  38
  39 // from careful measurement
  40
  41 crewpunch_shape =
  42   [[  6, [0.6, 6.0], [1.6, 12.3] ],
  43    [  8, [1.1, 6.2], [1.9, 12.5] ],
  44    [ 10, [1.6, 6.5], [2.1, 12.8] ],
  45    [ 12, [1.8, 6.6], [2.3, 12.7] ],
  46    [ 14, [2.1, 6.8], [2.6, 13.0] ],
  47    [ 16, [2.4, 6.9], [2.7, 13.2] ],
  48    [ 18, [2.5, 7.0], [2.9, 13.3] ],
  49    [ 22, [3.1, 7.1], [3.2, 13.4] ],
  50    [ 26, [3.3, 7.2], [3.5, 13.6] ],
  51    ];
  52
  53 crewpunch_shaft_max_y = 7.5;
  54
  55 crewpunch_systematic_size_error = +0.36;
  56
  57 crewpunch_min_y = 4.7 - crewpunch_systematic_size_error;
  58
  59 crewpunch_smallest_shape = crewpunch_shape[0];
  60 crewpunch_biggest_shape = crewpunch_shape[len(crewpunch_shape)-1];
  61
  62 // computed
  63
  64 attach_ysz = holder_attach_walls*2 + holder_ctie_width;
  65 holder_front_all = crewpunch_shaft_max_y - crewpunch_biggest_shape[1][1]
  66   + attach_ysz;
  67
  68 holder_block_zsz = crewpunch_biggest_shape[0] - crewpunch_smallest_shape[0];
  69 holder_xsz = crewpunch_biggest_shape[2][1] + crewpunch_biggest_shape[2][0] +
  70   holder_min_wall*2;
  71 crewpunch_biggest_y =
  72   crewpunch_biggest_shape[1][0] + crewpunch_biggest_shape[1][1];
  73 holder_ysz = crewpunch_biggest_y + holder_min_wall + holder_front_all;
  74
  75 attach_offset = 0.5 * (holder_front_all - holder_attach_near_wall);
  76
  77 jig_main_zsz = holder_block_zsz + punch_travel;
  78
  79 jig_ends_extra = 2;
  80
  81 //jig_iters = (jig_max_len - jig_ends_extra) / jig_interval;
  82 jig_iters=2;
  83 echo(jig_iters);
  84
  85 // objects
  86
  87 module CrewPunch(){
  88   ourslop = crewpunch_slop - crewpunch_systematic_size_error;
  89   hull(){
  90     for(layer=crewpunch_shape){
  91       translate([0,0, layer[0]]){
  92         for(xind=[0,1]) //translate([xind?0:1,0,0])
  93           for(yind=[0,1]) //translate([0,yind?0.5:0,0])
  94             mirror([xind?1:0,0,0]) mirror([0,yind?0:1,0]){
  95               translate([-0.1,-0.1,-0.1])
  96                 cube([0.1 + layer[2][1-xind] + ourslop,
  97                       0.1 + layer[1][yind] + ourslop,
  98                       0.2]);
  99             }
 100       }
 101     }
 102   }
 103 }
 104
 105 module PunchHolder(cutouts=true){
 106   translations=[-holder_xsz/2,
 107                 -holder_ysz + holder_min_wall + crewpunch_biggest_y/2,
 108                 0];
 109   translate(translations){
 110     difference(){
 111       translate([0,attach_offset,0])
 112         cube([holder_xsz, holder_ysz - attach_offset, holder_block_zsz]);
 113       if (cutouts)
 114         translate([crewpunch_biggest_shape[2][0] + holder_min_wall,
 115                    crewpunch_biggest_shape[1][0] + holder_front_all,
 116                    -crewpunch_smallest_shape[0]])
 117           CrewPunch();
 118     }
 119     difference(){
 120       translate([holder_xsz/2 - holder_attach_xsz/2, 0, 0])
 121         cube([holder_attach_xsz,
 122               attach_ysz,
 123               holder_block_zsz + punch_travel
 124               + holder_ctie_thick + holder_attach_roof + 1]);
 125       if (cutouts)
 126         translate([-30,
 127                    holder_attach_walls,
 128                    holder_block_zsz + punch_travel])
 129           cube([60, holder_ctie_width, holder_ctie_thick]);
 130     }
 131   }
 132 }
 133
 134 module RegistrationGroove(l){
 135   // runs along the +ve X axis for length l but at correct z pos
 136   translate([0, 0, jig_main_zsz + 0.1]) {
 137     rotate([90,0,90])
 138       linear_extrude(height=l)
 139       polygon([[-registrationgroove_width/2, 0],
 140                [ +registrationgroove_width/2, 0],
 141                [ 0, -registrationgroove_depth ]]);
 142   }
 143 }
 144
 145 module OneJig(){
 146   difference(){
 147     translate([-(jig_interval/2 + jig_overlap),
 148                -(strap_width/2 + edgewall_width) - attach_offset,
 149                -strap_thick])
 150       cube([jig_interval + 2,
 151             strap_width + edgewall_width*2 + attach_offset,
 152             jig_main_zsz + strap_thick]);
 153     minkowski(){
 154       cube([main_slop*2, main_slop*2, 50], center=true);
 155       PunchHolder(false);
 156     }
 157     translate([-100, -strap_width/2, -10])
 158       cube([200, strap_width, 10]);
 159    translate([-100,0,0])
 160      RegistrationGroove(200);
 161    for (xfrac=[-1/4,0,+1/4])
 162      translate([jig_interval * xfrac, -100, 0])
 163        rotate([0,0,90])
 164        RegistrationGroove(200);
 165   }
 166 }
 167
 168 module RegistrationProtrusion(){
 169   // points towards the positive x axis
 170   xsz = registrationprotrusion_poke;
 171   ysz = registrationprotrusion_poke;
 172   diag_sz = xsz * sqrt(2);
 173   zsz = diag_sz / registrationprotrusion_slope;
 174   hull(){
 175     translate([0, 0, 0.1]){
 176       linear_extrude(height=0.1)
 177         polygon([[   0, -ysz ],
 178                  [ xsz,    0 ],
 179                  [   0,  ysz ]]);
 180       translate([-0.1, 0, zsz ])
 181         rotate([0,0,45])
 182         cube(0.1);
 183     }
 184   }
 185 }
 186
 187 module Jig(){
 188   for(end=[0,1]){
 189     for(yfrac=[-1/2, 0, 1/2]){
 190       translate([ end
 191                   ? jig_interval * (jig_iters - 0.5)
 192                   : -jig_interval/2,
 193                  yfrac * strap_width,
 194                  0])
 195         rotate([0,0, end ? 0 : 180])
 196         translate([ jig_overlap, 0, 0 ])
 197         RegistrationProtrusion();
 198     }
 199   }
 200   for (i=[0:jig_iters-1]) {
 201     translate([jig_interval * i, 0, 0])
 202       OneJig();
 203   }
 204 }
 205
 206 module JigT(){ ////toplevel
 207   rotate([180,0,0])
 208     Jig();
 209 }
 210
 211 module PunchHolderT(){ ////toplevel
 212   PunchHolder(true);
 213 }
 214
 215 module Demo(){
 216   %PunchHolder();
 217   Jig();
 218 }
 219
 220 //CrewPunch();
 221 //PunchHolder();
 222 //PunchHolder(false);
 223 //OneJig();
 224 //Jig();
 225 //Demo();
 226 //JigT();
 227 //RegistrationProtrusion();
 228 //PunchHolderT();