belt-slot-cut-jig.scad

   1 // -*- C -*-
   2
   3 // todo
   4 //  various registration marks
   5 //   protrustions at ends at strap width and middle
   6 //   grooves on top face at 1/4,1/2,3/4 length and 1/2 width
   7
   8 crewpunch_slop = 0.3;
   9
  10 holder_min_wall = 2;
  11 holder_attach_near_wall = 3;
  12
  13 holder_attach_xsz = 5;
  14 holder_ctie_width = 4.0 + 0.5;
  15 holder_ctie_thick = 3.0 + 0.5;
  16 holder_attach_walls = 3;
  17 holder_attach_roof = 2.5;
  18
  19 jig_interval = 25;
  20 strap_width = 26.75 + 0.7;
  21 strap_thick = 3;
  22 edgewall_width = 3;
  23
  24 punch_travel = 8;
  25
  26 main_slop = 0.5;
  27
  28 jig_max_len = 160; // print diagonally
  29 //jig_max_len = 30;
  30
  31 registrationgroove_width = 0.8;
  32 registrationgroove_depth = 1.2;
  33
  34 registrationprotrusion_poke = 3;
  35 registrationprotrusion_slope = 0.75;
  36
  37 jig_overlap = 1;
  38
  39 // from careful measurement
  40
  41 crewpunch_shape =
  42   [[  6, [0.6, 6.0], [1.6, 12.3] ],
  43    [  8, [1.1, 6.2], [1.9, 12.5] ],
  44    [ 10, [1.6, 6.5], [2.1, 12.8] ],
  45    [ 12, [1.8, 6.6], [2.3, 12.7] ],
  46    [ 14, [2.1, 6.8], [2.6, 13.0] ],
  47    [ 16, [2.4, 6.9], [2.7, 13.2] ],
  48    [ 18, [2.5, 7.0], [2.9, 13.3] ],
  49    [ 22, [3.1, 7.1], [3.2, 13.4] ],
  50    [ 26, [3.3, 7.2], [3.5, 13.6] ],
  51    ];
  52
  53 crewpunch_shaft_max_y = 7.5;
  54
  55 crewpunch_systematic_size_error = +0.36;
  56
  57 crewpunch_min_y = 4.7 - crewpunch_systematic_size_error;
  58
  59 crewpunch_smallest_shape = crewpunch_shape[0];
  60 crewpunch_biggest_shape = crewpunch_shape[len(crewpunch_shape)-1];
  61
  62 // computed
  63
  64 attach_ysz = holder_attach_walls*2 + holder_ctie_width;
  65 holder_front_all = crewpunch_shaft_max_y - crewpunch_biggest_shape[1][1]
  66   + attach_ysz;
  67
  68 holder_block_zsz = crewpunch_biggest_shape[0] - crewpunch_smallest_shape[0];
  69 holder_xsz = crewpunch_biggest_shape[2][0] + crewpunch_biggest_shape[2][1] +
  70   holder_min_wall*2;
  71 crewpunch_biggest_y =
  72   crewpunch_biggest_shape[1][0] + crewpunch_biggest_shape[1][1];
  73 holder_ysz = crewpunch_biggest_y + holder_min_wall + holder_front_all;
  74
  75 attach_offset = 0.5 * (holder_front_all - holder_attach_near_wall);
  76
  77 jig_main_zsz = holder_block_zsz + punch_travel;
  78
  79 jig_ends_extra = 2;
  80
  81 //jig_iters = (jig_max_len - jig_ends_extra) / jig_interval;
  82 jig_iters=2;
  83 echo(jig_iters);
  84
  85 // objects
  86
  87 module CrewPunch(){
  88   ourslop = crewpunch_slop - crewpunch_systematic_size_error;
  89   hull(){
  90     for(layer=crewpunch_shape){
  91       translate([0,0, layer[0]]){
  92         for(xind=[0,1]) //translate([xind?0:1,0,0])
  93           for(yind=[0,1]) //translate([0,yind?0.5:0,0])
  94             mirror([xind?1:0,0,0]) mirror([0,yind?0:1,0]){
  95               translate([-0.1,-0.1,-0.1])
  96                 cube([0.1 + layer[2][xind] + ourslop,
  97                       0.1 + layer[1][yind] + ourslop,
  98                       0.2]);
  99             }
 100       }
 101     }
 102   }
 103 }
 104
 105 module PunchHolder(cutouts=true){
 106   translate([-holder_xsz/2,
 107              -holder_ysz + holder_min_wall + crewpunch_biggest_y/2,
 108              0]){
 109     difference(){
 110       translate([0,attach_offset,0])
 111         cube([holder_xsz, holder_ysz - attach_offset, holder_block_zsz]);
 112       if (cutouts)
 113         translate([crewpunch_biggest_shape[2][1] + holder_min_wall,
 114                    crewpunch_biggest_shape[1][0] + holder_front_all,
 115                    -crewpunch_smallest_shape[0]])
 116           CrewPunch();
 117     }
 118     difference(){
 119       translate([holder_xsz/2 - holder_attach_xsz/2, 0, 0])
 120         cube([holder_attach_xsz,
 121               attach_ysz,
 122               holder_block_zsz + punch_travel
 123               + holder_ctie_thick + holder_attach_roof + 1]);
 124       if (cutouts)
 125         translate([-30,
 126                    holder_attach_walls,
 127                    holder_block_zsz + punch_travel])
 128           cube([60, holder_ctie_width, holder_ctie_thick]);
 129     }
 130   }
 131 }
 132
 133 module RegistrationGroove(l){
 134   // runs along the +ve X axis for length l but at correct z pos
 135   translate([0, 0, jig_main_zsz + 0.1]) {
 136     rotate([90,0,90])
 137       linear_extrude(height=l)
 138       polygon([[-registrationgroove_width/2, 0],
 139                [ +registrationgroove_width/2, 0],
 140                [ 0, -registrationgroove_depth ]]);
 141   }
 142 }
 143
 144 module OneJig(){
 145   difference(){
 146     translate([-(jig_interval/2 + jig_overlap),
 147                -(strap_width/2 + edgewall_width) - attach_offset,
 148                -strap_thick])
 149       cube([jig_interval + 2,
 150             strap_width + edgewall_width*2 + attach_offset,
 151             jig_main_zsz + strap_thick]);
 152     minkowski(){
 153       cube([main_slop*2, main_slop*2, 50], center=true);
 154       PunchHolder(false);
 155     }
 156     translate([-100, -strap_width/2, -10])
 157       cube([200, strap_width, 10]);
 158    translate([-100,0,0])
 159      RegistrationGroove(200);
 160    for (xfrac=[-1/4,0,+1/4])
 161      translate([jig_interval * xfrac, -100, 0])
 162        rotate([0,0,90])
 163        RegistrationGroove(200);
 164   }
 165 }
 166
 167 module RegistrationProtrusion(){
 168   // points towards the positive x axis
 169   xsz = registrationprotrusion_poke;
 170   ysz = registrationprotrusion_poke;
 171   diag_sz = xsz * sqrt(2);
 172   zsz = diag_sz / registrationprotrusion_slope;
 173   hull(){
 174     translate([0, 0, 0.1]){
 175       linear_extrude(height=0.1)
 176         polygon([[   0, -ysz ],
 177                  [ xsz,    0 ],
 178                  [   0,  ysz ]]);
 179       translate([-0.1, 0, zsz ])
 180         rotate([0,0,45])
 181         cube(0.1);
 182     }
 183   }
 184 }
 185
 186 module Jig(){
 187   for(end=[0,1]){
 188     for(yfrac=[-1/2, 0, 1/2]){
 189       translate([ end
 190                   ? jig_interval * (jig_iters - 0.5)
 191                   : -jig_interval/2,
 192                  yfrac * strap_width,
 193                  0])
 194         rotate([0,0, end ? 0 : 180])
 195         translate([ jig_overlap, 0, 0 ])
 196         RegistrationProtrusion();
 197     }
 198   }
 199   for (i=[0:jig_iters-1]) {
 200     translate([jig_interval * i, 0, 0])
 201       OneJig();
 202   }
 203 }
 204
 205 module JigT(){ ////toplevel
 206   rotate([180,0,0])
 207     Jig();
 208 }
 209
 210 module PunchHolderT(){ ////toplevel
 211   PunchHolder(true);
 212 }
 213
 214 module Demo(){
 215   %PunchHolder();
 216   Jig();
 217 }
 218
 219 //CrewPunch();
 220 //PunchHolder();
 221 //PunchHolder(false);
 222 //OneJig();
 223 //Jig();
 224 //Demo();
 225 //JigT();
 226 //RegistrationProtrusion();
 227 //PunchHolderT();