anke-gps-bracket.scad

   1 // -*- C -*-
   2
   3 // todo
   4 // nestlecube does not fit
   5 // nestlecube doveclip at wrong angle
   6
   7 include <doveclip.scad>
   8
   9 // Dimensions of the main GPS body
  10 outerw = 120;
  11 outerh =  75;
  12 outert =  15;
  13 outerbackbevel = 3;
  14
  15 // Dimensions for the holder
  16 holder_outerw = outerw - 0.0;
  17 holder_outerh = outerh + 0.0;
  18 holder_outert = outert + 0.0;
  19
  20 // Dimensions for the model
  21 model_outerw = outerw + 2.5;
  22 model_outerh = outerh - 0.2;
  23 model_outert = outert - 1.0;
  24
  25 // Dimensions of the bezel area round the edges
  26 bezelw =    11 - 0.5;
  27 bezelboth = 11 - 0.5;
  28 bezeltoph =  7 - 0.5;
  29
  30 // Dimensions of the speaker at the back
  31 spkrdia =  22;
  32 spkr2bot = 19;
  33 spkr2rhs = 25;
  34
  35 // Dimensions of the plug and wire
  36 plugw =      12;
  37 plugh =       9;
  38 plug2bot =   11;
  39 plug2lhs =   11;
  40 plugtotald = 15;
  41 pluggapd =    5;
  42
  43 // Dimensions of the hole in the tray
  44 //   width and height (vertical) at the top
  45 nestleh = 53;
  46 nestlew = 55.4 - 0.5;
  47 //   depths (back to front distance):
  48 nestledl = 38.8 - 0.5;
  49 nestledr = 42.7 - 0.5;
  50 //   differences in width, depth, at bottom:
  51 nestledwl = 3.0;
  52 nestledwr = 2.4;
  53 nestleddf = 4.0;
  54 nestleddbl = 3.3;
  55 nestleddbr = 3.6;
  56
  57 nestlewallmin = 4;
  58 nestleceilmin = 4;
  59
  60 // Adjustment for the GPS attitude
  61 gpsazimuth = 45;
  62 gpselevation = 40;
  63 gpsrightwardoffset = 5;
  64 gpsrearwardoffset = 2;
  65
  66 // Amount of wire protrusion to allow for
  67 plugwiremoreh = 25;
  68
  69 // Slops and steps etc.
  70 plugslop = 0.5;
  71 plughstep = 1.5;
  72 bodylhsrhsslop = 0.5;
  73 holderhgap = 5;
  74 holderbezelmore = 2;
  75
  76 // Dimensions for strength only
  77 screent = 1.0;
  78 plugstrutw = 4;
  79 plugstrutt = min(model_outert, 5);
  80 nestledoveclipw = 20;
  81 holderh = model_outerh * 0.5;
  82 holderwallt = 2.5;
  83 holderbackt = 2.8;
  84 holderdccount = 2;
  85 holderdoveclipl = 15;
  86 chassish = 13;
  87 chassist = 13;
  88
  89 // Consequential values
  90 holderdcw = DoveClipPairSane_width(holderdccount);
  91
  92 module GpsPlugPlug(slop){
  93   effhslop = slop - plughstep;
  94   effplugw = plugw + slop*2;
  95   effplugh = plugh + effhslop*2;
  96   translate([plug2lhs-slop, plug2bot-effhslop, -1])
  97     cube([effplugw, effplugh, model_outert+2]);
  98 }
  99
 100 module GpsBodyOuterBevel(len){
 101   translate([0,-1,0]) {
 102     rotate([-90,0,0]) {
 103       linear_extrude(height=len+2) {
 104         polygon([[-outerbackbevel, 0],
 105                  [ 0, outerbackbevel],
 106                  [outerbackbevel, 0],
 107                  [ 0, -outerbackbevel]]);
 108       }
 109     }
 110   }
 111 }
 112
 113 module GpsBody() { ////toplevel
 114   difference(){
 115     union(){
 116       difference(){
 117         cube([model_outerw, model_outerh, model_outert]);
 118         translate([bezelw, bezelboth, screent])
 119           cube([model_outerw-bezelw*2,
 120                 model_outerh-bezelboth-bezeltoph,
 121                 model_outert]);
 122         translate([model_outerw-spkr2rhs, spkr2bot, -1])
 123           cylinder(r=spkrdia/2, h=model_outert+2);
 124       }
 125       translate([plug2lhs+plugw/2, plug2bot+plugh/2, 0])
 126         cylinder(r=(plugw+plugh)/2, h=model_outert);
 127       for (x=[plug2lhs-plugstrutw, plug2lhs+plugw])
 128         translate([x, 0.1, 0])
 129           cube([plugstrutw, model_outerh-0.2, plugstrutt-0.10]);
 130     }
 131     GpsPlugPlug(0);
 132     for (x=[0,model_outerw]) translate([x,0,0]) GpsBodyOuterBevel(model_outerh);
 133     for (y=[0,model_outerh]) translate([0,y,0])
 134       rotate([0,0,-90]) GpsBodyOuterBevel(model_outerw);
 135   }
 136 }
 137
 138 module GpsPlug() {
 139   plugwireh = plug2bot + plugwiremoreh;
 140   translate([-plugslop,0,0]) GpsPlugPlug(-plugslop);
 141   mirror([0,0,1]) translate([plug2lhs, plug2bot, 0]) {
 142     cube([plugw, plugh, plugtotald-0.05]);
 143     translate([0, -plugwireh, pluggapd])
 144       cube([plugw, plugwireh+0.05, plugtotald-pluggapd]);
 145   }
 146 }
 147
 148 lhsteethu = 2;
 149
 150 module GpsLHSMask(xslop=0){
 151   translate([plug2lhs + plugw+plugh+plugstrutw,
 152              0,
 153              -50]) {
 154     for (iter=[-100/lhsteethu : 100/lhsteethu]) {
 155       translate([0, iter*lhsteethu*2, 0]) {
 156         linear_extrude(height=100) {
 157           polygon([[-300,     0],
 158                    [   0,     0],
 159                    [lhsteethu,lhsteethu],
 160                    [   0,     lhsteethu*2],
 161                    [-300,     lhsteethu*2+0.1]]);
 162         }
 163       }
 164     }
 165   }
 166 }
 167
 168 module GpsAssembled(){ ////toplevel
 169   GpsBody();
 170   GpsPlug();
 171 }
 172
 173 module GpsBodyLT(){
 174   intersection(){
 175     GpsBody();
 176     GpsLHSMask();
 177   }
 178 }
 179
 180 module GpsBodyRT(){
 181   difference(){
 182     GpsBody();
 183     GpsLHSMask(bodylhsrhsslop);
 184   }
 185 }
 186
 187 module GpsPlugT(){ ////toplevel
 188   rotate([0,-90,0]) GpsPlug();
 189 }
 190
 191 module NestleCubeCutout(ca,cb,d){
 192   dist = cb - ca;
 193   mirror([0,1,0]){
 194     rotate([90,0,0]){
 195       linear_extrude(height=d){
 196         polygon([[ca, -nestleh-1],
 197                  [ca, -dist/2],
 198                  [(ca+cb)/2, 0],
 199                  [cb, -dist/2],
 200                  [cb, -nestleh-1]]);
 201       }
 202     }
 203   }
 204 }
 205
 206 module NestleCube(){ ////toplevel
 207   midw = nestlew/2;
 208   midd = min(nestledl,nestledr);
 209   midddb = max(nestleddbl,nestleddbr);
 210
 211   based0 = nestleddf;
 212   based1 = midd - midddb;
 213   basew0 = -nestledwr;
 214   basew1 = +nestledwl-nestlew;
 215
 216   cutd0 = based0 + nestlewallmin;
 217   cutd1 = based1 - nestlewallmin;
 218   cutw0 = basew0 - nestlewallmin;
 219   cutw1 = basew1 + nestlewallmin;
 220
 221   translate([-(basew0+basew1)/2, -(based0+based1)/2, 0]) difference(){
 222     polyhedron
 223       (points=[[          +0      ,            +0,        0], // 0
 224                [          +0      ,            +nestledr, 0], // 1
 225                [          -midw   ,            +midd,     0], // 2
 226                [          -nestlew,            +nestledl, 0], // 3
 227                [          -nestlew,            +0,        0], // 4
 228                [-nestledwr+0      , +nestleddf +0,        -nestleh], // 5
 229                [-nestledwr+0      , -nestleddbr+nestledr, -nestleh], // 6
 230                [          -midw   , -midddb    +midd,     -nestleh], // 7
 231                [+nestledwl-nestlew, -nestleddbl+nestledl, -nestleh], // 8
 232                [+nestledwl-nestlew, +nestleddf +0,        -nestleh]], // 9
 233        triangles=[[0,1,6],[6,5,0],
 234                   [1,2,7],[7,6,1],
 235                   [2,3,8],[8,7,2],
 236                   [3,4,9],[9,8,3],
 237                   [4,0,5],[5,9,4],
 238                   [4,3,2],[2,1,0],[0,4,2],
 239                   [7,8,9],[5,6,7],[7,9,5]],
 240        convexity=3);
 241     intersection(){
 242       NestleCubeCutout(cutw1, cutw0, max(nestledl,nestledr));
 243       rotate([0,0,90]) NestleCubeCutout(cutd0, cutd1, nestlew);
 244     }
 245   }
 246
 247   translate([gpsrightwardoffset,-gpsrearwardoffset,0])
 248     rotate([0,0,gpsazimuth])
 249     translate([nestledoveclipw/2,0,DoveClip_depth()-0.5])
 250     rotate([0,-90,0])
 251     DoveClipPairSane(count=3, h=nestledoveclipw);
 252 }
 253
 254 module NestleCubePin(){ ////toplevel
 255   DoveClipPin(nestledoveclipw*0.4);
 256 }
 257
 258 module HolderSideL(){ ////toplevel
 259   minz = -(bezelw - holderbezelmore) - holderbackt;
 260   holdert = holder_outert + holderwallt*2;
 261   cylr = 0.5*sqrt(holderdcw*holderdcw + holderdoveclipl*holderdoveclipl);
 262   difference(){
 263     translate([-holderh,
 264                -holderwallt,
 265                minz]) {
 266       cube([holderh + holderhgap + cylr,
 267             holdert,
 268             -minz]);
 269       translate([holderh + holderhgap + cylr, holdert/2, 0]) {
 270         cylinder(r=cylr, h=-minz);
 271         rotate([0,0,gpselevation])
 272           translate([0, -holderdoveclipl/2, -minz + DoveClip_depth()])
 273           rotate([0,-90,-90])
 274           DoveClipPairSane(count=holderdccount, h=holderdoveclipl);
 275       }
 276     }
 277     translate([-holderh-1,
 278                0,
 279                minz + holderbackt])
 280       cube([holderh+1,
 281             holder_outert,
 282             bezelw]);
 283   }
 284 }
 285
 286 module HolderSideR(){ ////toplevel
 287   mirror([0,1,0]) HolderSideL();
 288 }
 289
 290 module ChassisBar(){ ////toplevel
 291   dist = holder_outerw - 2*((bezelw - holderbezelmore) + DoveClip_depth());
 292   cliph = holderdcw;
 293   for (mir=[0,1]) {
 294     mirror([mir,0,0]) {
 295       translate([dist/2, cliph/2, 0])
 296         DoveClipPairSane(h=holderdoveclipl, count=holderdccount);
 297       translate([-1, 0, 0])
 298         cube([dist/2 - DoveClip_depth() + 1.1, chassish, chassist]);
 299     }
 300   }
 301   translate([0, -DoveClip_depth(), 0])
 302     rotate([0,0,-90])
 303     DoveClipPairSane(h=nestledoveclipw, count=3,
 304                      baseextend=chassist/2);
 305 }
 306
 307 module HolderSidePin(){ ////toplevel
 308   DoveClipPin(holderdoveclipl*0.5);
 309 }
 310
 311 module Pins(){ ///toplevel
 312   for (i=[1:4*holderdccount]) {
 313     translate([i*10, 0, 0]) HolderSidePin();
 314   }
 315   for (i=[1:6]) {
 316     translate([i*10, 20, 0]) NestleCubePin();
 317   }
 318 }
 319
 320 //GpsPlugT();
 321 //GpsAssembled();
 322 //GpsBody();
 323 //NestleCube();
 324 //NestleCubePin();
 325 //HolderSideL();
 326 //HolderSideR();
 327 //HolderSidePin();
 328 //ChassisBar();
 329 //Pins();