X-Git-Url: http://www.chiark.greenend.org.uk/ucgi/~ianmdlvl/git?p=elogind.git;a=blobdiff_plain;f=configure.ac;h=95456cd0bc9ba41235ec3b9256ecebba9de9d39a;hp=052164991605712434d5998efab9a4718913c87a;hb=d7c114c00030309435fc56c77c8578a25d228ebe;hpb=ac8cfcf56c5d7b3eaeec64e94f6c4659e82a2b10

diff --git a/configure.ac b/configure.ac
index 052164991..95456cd0b 100644
--- a/configure.ac
+++ b/configure.ac
@@ -76,4 +76,81 @@ AC_SUBST(CGROUP_LIBS)
 AM_PROG_VALAC()
 AC_SUBST(VAPIDIR)
 
+AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, or none]))
+if test "z$with_distro" = "z"; then
+        if test "$cross_compiling" = yes; then
+                AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
+        else
+                AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
+                AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
+                AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
+                AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
+        fi
+        if test "z$with_distro" = "z"; then
+                with_distro=`uname -s`
+        fi
+fi
+with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
+
+case $with_distro in
+        fedora)
+                SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
+                SYSTEM_SYSVRCND_PATH=/etc/rc.d
+                special_dbus_service=messagebus.service
+                special_syslog_service=rsyslog.service
+                AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
+                ;;
+        suse)
+                SYSTEM_SYSVINIT_PATH=/etc/init.d
+                SYSTEM_SYSVRCND_PATH=/etc/init.d
+                special_dbus_service=dbus.service
+                special_syslog_service=syslog.service
+                AC_DEFINE(TARGET_SUSE, [], [Target is OpenSUSE/SLES])
+                ;;
+        debian)
+                SYSTEM_SYSVINIT_PATH=/etc/init.d
+                SYSTEM_SYSVRCND_PATH=/etc
+                special_dbus_service=dbus.service
+                special_syslog_service=sysklogd.service
+                AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian/Ubuntu])
+                ;;
+        arch)
+                SYSTEM_SYSVINIT_PATH=/etc/rc.d
+                SYSTEM_SYSVRCND_PATH=/etc
+                special_dbus_service=dbus.service
+                special_syslog_service=syslog-ng.service
+                AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
+                ;;
+        none)
+                SYSTEM_SYSVINIT_PATH=/fix/the/configure/script
+                SYSTEM_SYSVRCND_PATH=/fix/the/configure/script
+                special_dbus_service=fix-the-configure-script.service
+                special_syslog_service=fix-the-configure-script.service
+                ;;
+        *)
+                AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=none to skip this check])
+                ;;
+esac
+
+AC_SUBST(SYSTEM_SYSVINIT_PATH)
+AC_SUBST(SYSTEM_SYSVRCND_PATH)
+
+AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
+AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
+AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
+AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
+
+AC_DEFINE_UNQUOTED(SPECIAL_DBUS_SERVICE, ["$special_dbus_service"], [D-Bus service name])
+AC_DEFINE_UNQUOTED(SPECIAL_SYSLOG_SERVICE, ["$special_syslog_service"], [syslog service name])
+
 AC_OUTPUT([Makefile])
+
+echo "
+        $PACKAGE_NAME $VERSION
+
+        Distribution:            ${with_distro}
+        SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
+        SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
+        Syslog service:          ${special_syslog_service}
+        D-Bus service:           ${special_dbus_service}
+"