klibc/klibc/arch/cris/setjmp.S

   1 #
   2 # arch/cris/setjmp.S
   3 #
   4 # setjmp/longjmp for the cris architecture
   5 #
   6
   7 #
   8 # The jmp_buf is assumed to contain the following, in order:
   9 #       $r8..$r0        (in that order)
  10 #       $sp     ($r14)
  11 #       return address
  12 #
  13
  14         .text
  15         .balign 4
  16         .globl  setjmp
  17         .type   setjmp, @function
  18 setjmp:
  19         movem   $r8,[$r10+]             /* Save $r8..$r0 at $r10... */
  20         move.d  $sp,[$r10+]
  21         move    $srp,[$r10]
  22         ret
  23           moveq 0,$r10
  24
  25         .size setjmp,.-setjmp
  26
  27         .text
  28         .balign 4
  29         .globl  longjmp
  30         .type   longjmp, @function
  31 longjmp:
  32         movem   [$r10+],$r8             /* Load $r8..$r0 from $r10... */
  33         move.d  [$r10+],$sp
  34         jump    [$r10]
  35         move.d $r11,$r10
  36
  37         .size longjmp,.-longjmp