configure.ac

   1 AC_PREREQ(2.60)
   2 AC_INIT([udev],
   3         [175],
   4         [linux-hotplug@vger.kernel.org],
   5         [udev],
   6         [http://www.kernel.org/pub/linux/utils/kernel/hotplug/udev.html])
   7 AC_CONFIG_SRCDIR([udev/udevd.c])
   8 AC_CONFIG_AUX_DIR([build-aux])
   9 AM_INIT_AUTOMAKE([check-news foreign 1.11 -Wall -Wno-portability silent-rules tar-pax dist-xz subdir-objects])
  10 AC_USE_SYSTEM_EXTENSIONS
  11 AC_SYS_LARGEFILE
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AM_SILENT_RULES([yes])
  14 LT_INIT([disable-static])
  15 AC_PROG_AWK
  16 AC_PROG_SED
  17 AC_PROG_MKDIR_P
  18 GTK_DOC_CHECK(1.10)
  19 AC_PREFIX_DEFAULT([/usr])
  20 AC_PATH_PROG([XSLTPROC], [xsltproc])
  21
  22 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([POSIX RT library not found])])
  23
  24 AC_ARG_WITH([rootlibdir],
  25         AS_HELP_STRING([--with-rootlibdir=DIR], [rootfs directory to install shared libraries]),
  26         [], [with_rootlibdir=$libdir])
  27 AC_SUBST([rootlib_execdir], [$with_rootlibdir])
  28
  29 AC_ARG_WITH([selinux],
  30         AS_HELP_STRING([--with-selinux], [enable SELinux support]),
  31         [], [with_selinux=no])
  32 AS_IF([test "x$with_selinux" = "xyes"], [
  33         LIBS_save=$LIBS
  34         AC_CHECK_LIB(selinux, getprevcon,
  35                 [],
  36                 AC_MSG_ERROR([SELinux selected but libselinux not found]))
  37         LIBS=$LIBS_save
  38         SELINUX_LIBS="-lselinux -lsepol"
  39         AC_DEFINE(WITH_SELINUX, [1] ,[SELinux support.])
  40 ])
  41 AC_SUBST([SELINUX_LIBS])
  42 AM_CONDITIONAL(WITH_SELINUX, [test "x$with_selinux" = "xyes"])
  43
  44 AC_ARG_ENABLE([debug],
  45         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
  46         [], [enable_debug=no])
  47 AS_IF([test "x$enable_debug" = "xyes"], [ AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.]) ])
  48
  49 AC_ARG_ENABLE([logging],
  50         AS_HELP_STRING([--disable-logging], [disable system logging @<:@default=enabled@:>@]),
  51         [], enable_logging=yes)
  52 AS_IF([test "x$enable_logging" = "xyes"], [ AC_DEFINE(ENABLE_LOGGING, [1], [System logging.]) ])
  53
  54 AC_ARG_WITH(firmware-path,
  55         AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
  56            [Firmware search path (default=/lib/firmware/updates:/lib/firmware)]),
  57         [], [with_firmware_path="/lib/firmware/updates:/lib/firmware"])
  58 OLD_IFS=$IFS
  59 IFS=:
  60 for i in $with_firmware_path; do
  61         if test "x${FIRMWARE_PATH}" = "x"; then
  62                 FIRMWARE_PATH="\\\"${i}/\\\""
  63         else
  64                 FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
  65         fi
  66 done
  67 IFS=$OLD_IFS
  68 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
  69
  70 AC_ARG_WITH([systemdsystemunitdir],
  71         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
  72         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
  73 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [ AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir]) ])
  74 AM_CONDITIONAL(WITH_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != "xno" ])
  75
  76 # ------------------------------------------------------------------------------
  77 # GUdev - libudev gobject interface
  78 # ------------------------------------------------------------------------------
  79 AC_ARG_ENABLE([gudev],
  80         AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
  81         [], [enable_gudev=yes])
  82 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0]) ])
  83
  84 AC_ARG_ENABLE([introspection],
  85         AS_HELP_STRING([--disable-introspection], [disable GObject introspection @<:@default=enabled@:>@]),
  86         [], [enable_introspection=yes])
  87 AS_IF([test "x$enable_introspection" = "xyes"], [
  88         PKG_CHECK_MODULES([INTROSPECTION], [gobject-introspection-1.0 >= 0.6.2])
  89         AC_DEFINE([ENABLE_INTROSPECTION], [1], [enable GObject introspection support])
  90         AC_SUBST([G_IR_SCANNER], [$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)])
  91         AC_SUBST([G_IR_COMPILER], [$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)])
  92         AC_SUBST([G_IR_GENERATE], [$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)])
  93         AC_SUBST([GIRDIR], [$($PKG_CONFIG --define-variable=datadir=${datadir} --variable=girdir gobject-introspection-1.0)])
  94         AC_SUBST([GIRTYPELIBDIR], [$($PKG_CONFIG --define-variable=libdir=${libdir} --variable=typelibdir gobject-introspection-1.0)])
  95 ])
  96 AM_CONDITIONAL([ENABLE_INTROSPECTION], [test "x$enable_introspection" = "xyes"])
  97 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
  98
  99 # ------------------------------------------------------------------------------
 100 # usb/pci-db - read vendor/device string database
 101 # ------------------------------------------------------------------------------
 102 AC_ARG_ENABLE([hwdb],
 103         AS_HELP_STRING([--disable-hwdb], [disable hardware database support @<:@default=enabled@:>@]),
 104         [], [enable_hwdb=yes])
 105 AS_IF([test "x$enable_hwdb" = "xyes"], [
 106         if test "x$cross_compiling" = "xno" ; then
 107                 AC_CHECK_FILES([/usr/share/pci.ids], [pciids=/usr/share/pci.ids])
 108                 AC_CHECK_FILES([/usr/share/hwdata/pci.ids], [pciids=/usr/share/hwdata/pci.ids])
 109                 AC_CHECK_FILES([/usr/share/misc/pci.ids], [pciids=/usr/share/misc/pci.ids])
 110         fi
 111
 112         AC_ARG_WITH(usb-ids-path,
 113                 [AS_HELP_STRING([--with-usb-ids-path=DIR], [Path to usb.ids file])],
 114                 [USB_DATABASE=${withval}],
 115                 [if test -n "$usbids" ; then
 116                         USB_DATABASE="$usbids"
 117                 else
 118                         PKG_CHECK_MODULES(USBUTILS, usbutils >= 0.82)
 119                         AC_SUBST([USB_DATABASE], [$($PKG_CONFIG --variable=usbids usbutils)])
 120                 fi])
 121         AC_MSG_CHECKING([for USB database location])
 122         AC_MSG_RESULT([$USB_DATABASE])
 123         AC_SUBST(USB_DATABASE)
 124
 125         AC_ARG_WITH(pci-ids-path,
 126                 [AS_HELP_STRING([--with-pci-ids-path=DIR], [Path to pci.ids file])],
 127                 [PCI_DATABASE=${withval}],
 128                 [if test -n "$pciids" ; then
 129                         PCI_DATABASE="$pciids"
 130                 else
 131                         AC_MSG_ERROR([pci.ids not found, try --with-pci-ids-path=])
 132                 fi])
 133         AC_MSG_CHECKING([for PCI database location])
 134         AC_MSG_RESULT([$PCI_DATABASE])
 135         AC_SUBST(PCI_DATABASE)
 136 ])
 137 AM_CONDITIONAL([ENABLE_HWDB], [test "x$enable_hwdb" = "xyes"])
 138
 139 # ------------------------------------------------------------------------------
 140 # keymap - map custom hardware's multimedia keys
 141 # ------------------------------------------------------------------------------
 142 AC_ARG_ENABLE([keymap],
 143         AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 144         [], [enable_keymap=yes])
 145 AS_IF([test "x$enable_keymap" = "xyes"], [
 146         AC_PATH_PROG([GPERF], [gperf])
 147         if test -z "$GPERF"; then
 148                 AC_MSG_ERROR([gperf is needed])
 149         fi
 150
 151         AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 152         AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 153 ])
 154 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 155
 156 # ------------------------------------------------------------------------------
 157 # mtd_probe - autoloads FTL module for mtd devices
 158 # ------------------------------------------------------------------------------
 159 AC_ARG_ENABLE([mtd_probe],
 160         AS_HELP_STRING([--disable-mtd_probe], [disable MTD support @<:@default=enabled@:>@]),
 161         [], [enable_mtd_probe=yes])
 162 AM_CONDITIONAL([ENABLE_MTD_PROBE], [test "x$enable_mtd_probe" = "xyes"])
 163
 164 # ------------------------------------------------------------------------------
 165 # rule_generator - persistent network and optical device rule generator
 166 # ------------------------------------------------------------------------------
 167 AC_ARG_ENABLE([rule_generator],
 168         AS_HELP_STRING([--enable-rule_generator], [enable persistent network + cdrom links support @<:@default=disabled@:>@]),
 169         [], [enable_rule_generator=no])
 170 AM_CONDITIONAL([ENABLE_RULE_GENERATOR], [test "x$enable_rule_generator" = "xyes"])
 171
 172 # ------------------------------------------------------------------------------
 173 # udev_acl - apply ACLs for users with local forground sessions
 174 # ------------------------------------------------------------------------------
 175 AC_ARG_ENABLE([udev_acl],
 176         AS_HELP_STRING([--enable-udev_acl], [enable local user acl permissions support @<:@default=disabled@:>@]),
 177         [], [enable_udev_acl=no])
 178 AS_IF([test "x$enable_udev_acl" = "xyes"], [
 179         AC_CHECK_LIB([acl], [acl_init], [:], AC_MSG_ERROR([libacl not found]))
 180         AC_CHECK_HEADER([acl/libacl.h], [:], AC_MSG_ERROR([libacl header not found]))
 181
 182         PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0])
 183 ])
 184 AM_CONDITIONAL([ENABLE_UDEV_ACL], [test "x$enable_udev_acl" = "xyes"])
 185
 186 # ------------------------------------------------------------------------------
 187 # create_floppy_devices - historical floppy kernel device nodes (/dev/fd0h1440, ...)
 188 # ------------------------------------------------------------------------------
 189 AC_ARG_ENABLE([floppy],
 190         AS_HELP_STRING([--enable-floppy], [enable legacy floppy support @<:@default=disabled@:>@]),
 191         [], [enable_floppy=no])
 192 AM_CONDITIONAL([ENABLE_FLOPPY], [test "x$enable_floppy" = "xyes"])
 193
 194 # ------------------------------------------------------------------------------
 195 # edd_id - create /dev/disk/by-id/edd-* links for BIOS EDD data
 196 # ------------------------------------------------------------------------------
 197 AC_ARG_ENABLE([edd],
 198         AS_HELP_STRING([--enable-edd], [enable disk edd support @<:@default=disabled@:>@]),
 199         [], [enable_edd=no])
 200 AM_CONDITIONAL([ENABLE_EDD], [test "x$enable_edd" = "xyes"])
 201
 202 AC_CONFIG_HEADERS(config.h)
 203 AC_CONFIG_FILES([
 204         Makefile
 205         libudev/docs/Makefile
 206         libudev/docs/version.xml
 207         extras/gudev/docs/Makefile
 208         extras/gudev/docs/version.xml
 209 ])
 210
 211 AC_OUTPUT
 212 AC_MSG_RESULT([
 213         $PACKAGE $VERSION
 214         ========
 215
 216         prefix:                 ${prefix}
 217         sysconfdir:             ${sysconfdir}
 218         bindir:                 ${bindir}
 219         sbindir:                ${sbindir}
 220         libdir:                 ${libdir}
 221         rootlibdir:             ${rootlib_execdir}
 222         libexecdir:             ${libexecdir}
 223         datarootdir:            ${datarootdir}
 224         mandir:                 ${mandir}
 225         includedir:             ${includedir}
 226         include_prefix:         ${INCLUDE_PREFIX}
 227         systemdsystemunitdir:   ${systemdsystemunitdir}
 228         firmware path:          ${FIRMWARE_PATH}
 229
 230         compiler:               ${CC}
 231         cflags:                 ${CFLAGS}
 232         ldflags:                ${LDFLAGS}
 233         xsltproc:               ${XSLTPROC}
 234         gperf:                  ${GPERF}
 235
 236         logging:                ${enable_logging}
 237         debug:                  ${enable_debug}
 238         selinux:                ${with_selinux}
 239
 240         gudev:                  ${enable_gudev}
 241         gintrospection:         ${enable_introspection}
 242         keymap:                 ${enable_keymap}
 243         hwdb:                   ${enable_hwdb}
 244           usb.ids:              ${USB_DATABASE}
 245           pci.ids:              ${PCI_DATABASE}
 246         mtd_probe:              ${enable_mtd_probe}
 247         rule_generator:         ${enable_rule_generator}
 248         udev_acl:               ${enable_udev_acl}
 249         floppy:                 ${enable_floppy}
 250         edd:                    ${enable_edd}
 251 ])