configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([elogind],
  23         [219.14],
  24         [https://github.com/wingo/elogind/issues],
  25         [elogind],
  26         [https://github.com/wingo/elogind])
  27
  28 AC_CONFIG_SRCDIR([src/login/logind.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41 LT_PREREQ(2.2)
  42 LT_INIT([disable-static])
  43
  44 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by elogind])])
  45 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by elogind])])
  46
  47 SET_ARCH(X86_64, x86_64*)
  48 SET_ARCH(IA32, i*86*)
  49 SET_ARCH(MIPS, mips*)
  50
  51 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  52 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  53 AS_IF([test x"$intltool_found" != xyes],
  54       [AS_IF([test x"$enable_nls" = xyes],
  55              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  56              [AS_IF([test x"$enable_nls" != xno],
  57                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  58                      enable_nls=no])
  59              ])
  60       ])
  61
  62 AM_NLS
  63 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  64     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  65 IT_PROG_INTLTOOL([0.40.0])
  66 ])
  67
  68 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  69     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  70     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  71     AC_SUBST(INTLTOOL_POLICY_RULE)
  72 ])
  73
  74 GETTEXT_PACKAGE=elogind
  75 AC_SUBST(GETTEXT_PACKAGE)
  76 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [elogind])
  77
  78 AC_PROG_MKDIR_P
  79 AC_PROG_LN_S
  80 AC_PROG_SED
  81 AC_PROG_GREP
  82 AC_PROG_AWK
  83
  84 AC_PROG_CC_C99
  85
  86 AC_PATH_PROG([M4], [m4])
  87 AC_PATH_PROG([XSLTPROC], [xsltproc])
  88
  89 AC_PATH_PROG([HALT], [halt], [halt])
  90 AC_PATH_PROG([REBOOT], [reboot], [reboot])
  91 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
  92
  93 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
  94
  95 M4_DEFINES=
  96
  97 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  98 m4_ifdef([GTK_DOC_CHECK], [
  99 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
 100          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
 101           enable_gtk_doc=no])
 102
 103 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
 104         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
 105 ])
 106
 107 AC_CHECK_TOOL(GPERF, gperf)
 108 if test -z "$GPERF" ; then
 109         AC_MSG_ERROR([*** gperf not found])
 110 fi
 111
 112 # ------------------------------------------------------------------------------
 113 address_sanitizer_cflags=
 114 address_sanitizer_cppflags=
 115 address_sanitizer_ldflags=
 116 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 117 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 118             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 119             AS_IF([test -z "$with_as_cflags"],
 120                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 121             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 122             address_sanitizer_cppflags="-DVALGRIND=1"
 123             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 124       ])
 125
 126 undefined_sanitizer_cflags=
 127 undefined_sanitizer_cppflags=
 128 undefined_sanitizer_ldflags=
 129 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 130 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 131             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 132             AS_IF([test -z "$with_us_cflags"],
 133                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 134             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 135             undefined_sanitizer_cppflags="-DVALGRIND=1"
 136             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 137       ])
 138
 139 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 140 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 141 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 142
 143 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 144         -pipe \
 145         -Wall \
 146         -Wextra \
 147         -Wno-inline \
 148         -Wundef \
 149         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 150         -Wlogical-op \
 151         -Wsign-compare \
 152         -Wmissing-include-dirs \
 153         -Wold-style-definition \
 154         -Wpointer-arith \
 155         -Winit-self \
 156         -Wdeclaration-after-statement \
 157         -Wfloat-equal \
 158         -Wsuggest-attribute=noreturn \
 159         -Wmissing-prototypes \
 160         -Wstrict-prototypes \
 161         -Wredundant-decls \
 162         -Wmissing-declarations \
 163         -Wmissing-noreturn \
 164         -Wshadow \
 165         -Wendif-labels \
 166         -Wstrict-aliasing=2 \
 167         -Wwrite-strings \
 168         -Wno-long-long \
 169         -Wno-overlength-strings \
 170         -Wno-unused-parameter \
 171         -Wno-missing-field-initializers \
 172         -Wno-unused-result \
 173         -Wno-format-signedness \
 174         -Werror=overflow \
 175         -Wdate-time \
 176         -Wnested-externs \
 177         -ffast-math \
 178         -fno-common \
 179         -fdiagnostics-show-option \
 180         -fno-strict-aliasing \
 181         -fvisibility=hidden \
 182         -ffunction-sections \
 183         -fdata-sections \
 184         -fstack-protector \
 185         -fstack-protector-strong \
 186         -fPIE \
 187         --param=ssp-buffer-size=4])
 188
 189 AS_CASE([$CC], [*clang*],
 190         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 191                -Wno-typedef-redefinition \
 192                -Wno-gnu-variable-sized-type-not-at-end \
 193         ])])
 194
 195 dnl AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 196 dnl         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 197 dnl                -flto -ffat-lto-objects])],
 198 dnl         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 199 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 200
 201 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 202         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 203                -Wp,-D_FORTIFY_SOURCE=2])],
 204         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 205 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 206
 207 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 208         -Wl,--as-needed \
 209         -Wl,--no-undefined \
 210         -Wl,--gc-sections \
 211         -Wl,-z,relro \
 212         -Wl,-z,now \
 213         -pie \
 214         -Wl,-fuse-ld=gold])
 215 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 216
 217 AC_CHECK_SIZEOF(pid_t)
 218 AC_CHECK_SIZEOF(uid_t)
 219 AC_CHECK_SIZEOF(gid_t)
 220 AC_CHECK_SIZEOF(time_t)
 221 AC_CHECK_SIZEOF(dev_t)
 222 AC_CHECK_SIZEOF(rlim_t,,[
 223        #include <sys/time.h>
 224        #include <sys/resource.h>
 225 ])
 226
 227 # ------------------------------------------------------------------------------
 228
 229 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 230 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 231 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 232
 233 # unconditionally pull-in librt with old glibc versions
 234 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 235 AC_SEARCH_LIBS([mq_unlink], [rt], [], [])
 236
 237 AC_ARG_WITH([libcap],
 238             AS_HELP_STRING([--with-libcap=DIR], [Prefix for libcap]),
 239             [CAP_LDFLAGS="-L$with_libcap/lib"],
 240             [CAP_LDFLAGS=""])
 241 save_LIBS="$LIBS"
 242 save_LDFLAGS="$LDFLAGS"
 243 LIBS=
 244 LDFLAGS="$LDFLAGS $CAP_LDFLAGS"
 245 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 246 CAP_LIBS="$LIBS"
 247 AC_SUBST(CAP_LIBS)
 248 AC_SUBST(CAP_LDFLAGS)
 249 LIBS="$save_LIBS"
 250 LDFLAGS="$save_LDFLAGS"
 251
 252 AC_CHECK_FUNCS([memfd_create])
 253 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 254 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns, getrandom, renameat2, kcmp, LO_FLAGS_PARTSCAN],
 255                [], [], [[
 256 #include <sys/types.h>
 257 #include <unistd.h>
 258 #include <sys/mount.h>
 259 #include <fcntl.h>
 260 #include <sched.h>
 261 #include <linux/loop.h>
 262 #include <linux/random.h>
 263 ]])
 264
 265 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 266                 IFLA_MACVLAN_FLAGS,
 267                 IFLA_IPVLAN_MODE,
 268                 IFLA_VTI_REMOTE,
 269                 IFLA_PHYS_PORT_ID,
 270                 IFLA_BOND_AD_INFO,
 271                 IFLA_VLAN_PROTOCOL,
 272                 IFLA_VXLAN_LOCAL6,
 273                 IFLA_IPTUN_6RD_RELAY_PREFIXLEN,
 274                 IFLA_BRIDGE_VLAN_INFO,
 275                 IFLA_BRPORT_UNICAST_FLOOD,
 276                 NDA_IFINDEX],
 277 [], [], [[
 278 #include <inttypes.h>
 279 #include <netinet/in.h>
 280 #include <netinet/ether.h>
 281 #include <linux/rtnetlink.h>
 282 #include <net/if.h>
 283 #include <linux/ip.h>
 284 #include <linux/if_tunnel.h>
 285 #include <linux/if_link.h>
 286 #include <linux/if_bridge.h>
 287 #include <linux/neighbour.h>
 288 ]])
 289
 290 # This makes sure pkg.m4 is available.
 291 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 292
 293 # ------------------------------------------------------------------------------
 294 have_dbus=no
 295 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 296 AS_IF([test "x$enable_dbus" != "xno"], [
 297         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 298                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 299                 [have_dbus=no])
 300         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 301                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 302 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 303
 304 # ------------------------------------------------------------------------------
 305 PKG_CHECK_MODULES(UDEV, [libudev])
 306
 307 AC_ARG_WITH([udevrulesdir],
 308             AS_HELP_STRING([--with-udevrulesdir=DIR], [Directory for udev rules files]),
 309             [],
 310             [with_udevrulesdir=$($PKG_CONFIG --variable=udevdir udev)/rules.d])
 311 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 312 AC_SUBST([udevbindir], [$($PKG_CONFIG --variable=udevdir udev)/../bin])
 313
 314 # ------------------------------------------------------------------------------
 315 have_coverage=no
 316 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 317 if test "x$enable_coverage" = "xyes" ; then
 318         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 319         if test "x$lcov_found" = xno ; then
 320                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 321         else
 322                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 323                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 324                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 325                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 326                 else
 327                         have_coverage=yes
 328                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 329                         -fprofile-arcs \
 330                         -ftest-coverage])
 331                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 332                 fi
 333         fi
 334 fi
 335 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 336
 337 # ------------------------------------------------------------------------------
 338 have_blkid=no
 339 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 340 if test "x$enable_blkid" != "xno"; then
 341         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 342                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 343         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 344                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 345         fi
 346 fi
 347 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 348
 349 # ------------------------------------------------------------------------------
 350 have_seccomp=no
 351 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 352 if test "x$enable_seccomp" != "xno"; then
 353         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 354                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 355                 have_seccomp=yes
 356                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 357                [have_seccomp=no])
 358         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 359                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 360         fi
 361 fi
 362 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 363
 364 # ------------------------------------------------------------------------------
 365 have_selinux=no
 366 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 367 if test "x$enable_selinux" != "xno"; then
 368         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 369                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 370                  have_selinux=yes
 371                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 372                 [have_selinux=no])
 373         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 374                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 375         fi
 376 fi
 377 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 378
 379 have_apparmor=no
 380 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 381 if test "x$enable_apparmor" != "xno"; then
 382         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 383                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 384                  have_apparmor=yes
 385                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 386                 [have_apparmor=no])
 387         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 388                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 389         fi
 390 fi
 391 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 392
 393 # ------------------------------------------------------------------------------
 394 AC_ARG_ENABLE([pam],
 395         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 396                 [case "${enableval}" in
 397                         yes) have_pam=yes ;;
 398                         no) have_pam=no ;;
 399                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 400                 esac],
 401                 [have_pam=auto])
 402
 403 if test "x${have_pam}" != xno ; then
 404         AC_CHECK_HEADERS(
 405                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 406                 [have_pam=yes],
 407                 [if test "x$have_pam" = xyes ; then
 408                         AC_MSG_ERROR([*** PAM headers not found.])
 409                 fi])
 410
 411         AC_CHECK_LIB(
 412                 [pam],
 413                 [pam_syslog],
 414                 [have_pam=yes],
 415                 [if test "x$have_pam" = xyes ; then
 416                         AC_MSG_ERROR([*** libpam not found.])
 417                 fi])
 418
 419         if test "x$have_pam" = xyes ; then
 420                 PAM_LIBS="-lpam -lpam_misc"
 421                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 422                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 423         else
 424                 have_pam=no
 425         fi
 426 else
 427         PAM_LIBS=
 428 fi
 429 AC_SUBST(PAM_LIBS)
 430 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 431
 432 # ------------------------------------------------------------------------------
 433 AC_ARG_ENABLE([acl],
 434         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 435                 [case "${enableval}" in
 436                         yes) have_acl=yes ;;
 437                         no) have_acl=no ;;
 438                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 439                 esac],
 440                 [have_acl=auto])
 441
 442 if test "x${have_acl}" != xno ; then
 443         AC_CHECK_HEADERS(
 444                 [sys/acl.h acl/libacl.h],
 445                 [have_acl=yes],
 446                 [if test "x$have_acl" = xyes ; then
 447                         AC_MSG_ERROR([*** ACL headers not found.])
 448                 fi])
 449
 450         AC_CHECK_LIB(
 451                 [acl],
 452                 [acl_get_file],
 453                 [have_acl=yes],
 454                 [if test "x$have_acl" = xyes ; then
 455                         AC_MSG_ERROR([*** libacl not found.])
 456                 fi])
 457
 458         if test "x$have_acl" = xyes ; then
 459                 ACL_LIBS="-lacl"
 460                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 461                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 462         else
 463                 have_acl=no
 464         fi
 465 else
 466         ACL_LIBS=
 467 fi
 468 AC_SUBST(ACL_LIBS)
 469 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 470
 471 # ------------------------------------------------------------------------------
 472 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 473                 [case "${enableval}" in
 474                         yes) have_smack=yes ;;
 475                         no) have_smack=no ;;
 476                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 477                 esac],
 478                 [have_smack=auto])
 479
 480 if test "x${have_smack}" = xauto; then
 481         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 482         have_smack=yes
 483 fi
 484
 485 AC_ARG_WITH(smack-run-label,
 486 AS_HELP_STRING([--with-smack-run-label=STRING],
 487         [run systemd --system with a specific SMACK label]),
 488         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run with a smack label])],
 489         [])
 490
 491 if test "x${have_smack}" = xyes ; then
 492         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 493 fi
 494
 495 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 496
 497 # ------------------------------------------------------------------------------
 498 AC_ARG_WITH(system-uid-max,
 499         AS_HELP_STRING([--with-system-uid-max=UID]
 500                 [Maximum UID for system users]),
 501         [SYSTEM_UID_MAX="$withval"],
 502         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
 503
 504 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
 505 AC_SUBST(SYSTEM_UID_MAX)
 506
 507 # ------------------------------------------------------------------------------
 508 AC_ARG_WITH(system-gid-max,
 509         AS_HELP_STRING([--with-system-gid-max=GID]
 510                 [Maximum GID for system groups]),
 511         [SYSTEM_GID_MAX="$withval"],
 512         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
 513
 514 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
 515 AC_SUBST(SYSTEM_GID_MAX)
 516
 517 # ------------------------------------------------------------------------------
 518 have_polkit=no
 519 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 520 if test "x$enable_polkit" != "xno"; then
 521         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 522         have_polkit=yes
 523 fi
 524 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 525
 526 # ------------------------------------------------------------------------------
 527 have_kdbus=no
 528 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--enable-kdbus], [do connect to kdbus by default]))
 529 if test "x$enable_kdbus" = "xyes"; then
 530         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus support is to be enabled])
 531         have_kdbus=yes
 532         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
 533 fi
 534 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
 535
 536 # ------------------------------------------------------------------------------
 537 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
 538
 539 # ------------------------------------------------------------------------------
 540 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0],
 541                   [have_glib=yes], [have_glib=no])
 542 AS_IF([test "x$have_glib" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 543
 544 # ------------------------------------------------------------------------------
 545 have_manpages=no
 546 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 547 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
 548 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 549
 550 # ------------------------------------------------------------------------------
 551 AC_SUBST(M4_DEFINES)
 552
 553 AC_ARG_WITH([dbuspolicydir],
 554         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 555         [],
 556         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
 557
 558 AC_ARG_WITH([dbussessionservicedir],
 559         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 560         [],
 561         [with_dbussessionservicedir=${datadir}/dbus-1/services])
 562
 563 AC_ARG_WITH([dbussystemservicedir],
 564         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 565         [],
 566         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
 567
 568 AC_ARG_WITH([bashcompletiondir],
 569         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 570         [],
 571         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 572                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 573         ] , [
 574                 with_bashcompletiondir=${datadir}/bash-completion/completions
 575         ])])
 576
 577 AC_ARG_WITH([zshcompletiondir],
 578         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
 579         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
 580
 581 AC_ARG_WITH([rootlibdir],
 582         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 583         [],
 584         [with_rootlibdir=${libdir}])
 585
 586 AC_ARG_WITH([pamlibdir],
 587         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 588         [],
 589         [with_pamlibdir=${with_rootlibdir}/security])
 590
 591 AC_ARG_WITH([pamconfdir],
 592         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
 593         [],
 594         [with_pamconfdir=${sysconfdir}/pam.d])
 595
 596 AC_ARG_ENABLE([split-usr],
 597         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 598         [],
 599         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 600                 enable_split_usr=yes
 601         ], [
 602                 enable_split_usr=no
 603         ])])
 604
 605 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 606         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 607 ])
 608
 609 # Work around intltoolize and gtk-doc problems in VPATH builds
 610 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 611                                        [Define to do gtk-doc tests])
 612 AS_IF([test "x$0" != "x./configure"], [
 613         AC_SUBST([INTLTOOL_UPDATE], [/usr/bin/env true])
 614 ])
 615
 616 AC_ARG_ENABLE(tests,
 617         [AC_HELP_STRING([--disable-tests], [disable tests])],
 618         enable_tests=$enableval, enable_tests=yes)
 619 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 620
 621 AC_ARG_ENABLE(debug,
 622         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
 623         [if test "x$enableval" = "xyes"; then
 624                 enableval="hashmap,mmap-cache"
 625         fi
 626         saved_ifs="$IFS"
 627         IFS="$IFS$PATH_SEPARATOR,"
 628         for name in $enableval; do
 629                 case $name in
 630                 hashmap)
 631                         enable_debug_hashmap=yes
 632                         ;;
 633                 mmap-cache)
 634                         enable_debug_mmap_cache=yes
 635                         ;;
 636                 esac
 637         done
 638         IFS="$saved_ifs"],[])
 639
 640 enable_debug=""
 641 AS_IF([test x$enable_debug_hashmap = xyes], [
 642         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
 643         enable_debug="hashmap $enable_debug"
 644 ])
 645 AS_IF([test x$enable_debug_mmap_cache = xyes], [
 646         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
 647         enable_debug="mmap-cache $enable_debug"
 648 ])
 649 test -z "$enable_debug" && enable_debug="none"
 650
 651 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 652 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 653 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 654 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 655 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
 656 AC_SUBST([pamlibdir], [$with_pamlibdir])
 657 AC_SUBST([pamconfdir], [$with_pamconfdir])
 658 AC_SUBST([rootlibdir], [$with_rootlibdir])
 659
 660 AC_CONFIG_FILES([
 661         Makefile po/Makefile.in
 662 ])
 663
 664 AC_OUTPUT
 665 AC_MSG_RESULT([
 666         $PACKAGE_NAME $VERSION
 667
 668         PAM:                     ${have_pam}
 669         AppArmor:                ${have_apparmor}
 670         SELinux:                 ${have_selinux}
 671         SECCOMP:                 ${have_seccomp}
 672         SMACK:                   ${have_smack}
 673         ACL:                     ${have_acl}
 674         polkit:                  ${have_polkit}
 675         blkid:                   ${have_blkid}
 676         dbus:                    ${have_dbus}
 677         kdbus:                   ${have_kdbus}
 678         man pages:               ${have_manpages}
 679         gtk-doc:                 ${enable_gtk_doc}
 680         test coverage:           ${have_coverage}
 681         Split /usr:              ${enable_split_usr}
 682         extra debugging:         ${enable_debug}
 683
 684         prefix:                  ${prefix}
 685         sysconf dir:             ${sysconfdir}
 686         datarootdir:             ${datarootdir}
 687         includedir:              ${includedir}
 688         lib dir:                 ${libdir}
 689         rootlib dir:             ${with_rootlibdir}
 690         PAM modules dir:         ${with_pamlibdir}
 691         PAM configuration dir:   ${with_pamconfdir}
 692         D-Bus policy dir:        ${with_dbuspolicydir}
 693         D-Bus session dir:       ${with_dbussessionservicedir}
 694         D-Bus system dir:        ${with_dbussystemservicedir}
 695         Bash completions dir:    ${with_bashcompletiondir}
 696         Zsh completions dir:     ${with_zshcompletiondir}
 697         Maximum System UID:      ${SYSTEM_UID_MAX}
 698         Maximum System GID:      ${SYSTEM_GID_MAX}
 699
 700         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 701         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
 702         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 703 ])