chiark / gitweb /
manager: introduce IgnoreOnIsolate flag so that we can keep systemd-logger around...
[elogind.git] / configure.ac
1 #  This file is part of systemd.
2 #
3 #  Copyright 2010 Lennart Poettering
4 #
5 #  systemd is free software; you can redistribute it and/or modify it
6 #  under the terms of the GNU General Public License as published by
7 #  the Free Software Foundation; either version 2 of the License, or
8 #  (at your option) any later version.
9 #
10 #  systemd is distributed in the hope that it will be useful, but
11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 #  General Public License for more details.
14 #
15 #  You should have received a copy of the GNU General Public License
16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
17
18 AC_PREREQ(2.63)
19
20 AC_INIT([systemd],[24],[systemd-devel@lists.freedesktop.org])
21 AC_CONFIG_SRCDIR([src/main.c])
22 AC_CONFIG_MACRO_DIR([m4])
23 AC_CONFIG_HEADERS([config.h])
24
25 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects dist-bzip2])
26
27 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
28
29 AC_CANONICAL_HOST
30 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
31 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
32        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
33       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
34
35 AM_SILENT_RULES([yes])
36
37 AC_CHECK_PROG([STOW], [stow], [yes], [no])
38
39 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
40         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
41         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
42 ])
43
44 AC_PROG_MKDIR_P
45 AC_PROG_LN_S
46 AC_PROG_SED
47
48 AC_PROG_CC
49 AC_PROG_CC_C99
50 AM_PROG_CC_C_O
51 AC_PROG_GCC_TRADITIONAL
52 AC_USE_SYSTEM_EXTENSIONS
53
54 AC_CHECK_TOOL(OBJCOPY, objcopy)
55 AC_CHECK_TOOL(STRINGS, strings)
56
57 CC_CHECK_CFLAGS_APPEND([ \
58         -pipe \
59         -Wall \
60         -W \
61         -Wextra \
62         -Wno-inline \
63         -Wvla \
64         -Wundef \
65         -Wformat=2 \
66         -Wlogical-op \
67         -Wsign-compare \
68         -Wformat-security \
69         -Wmissing-include-dirs \
70         -Wformat-nonliteral \
71         -Wold-style-definition \
72         -Wpointer-arith \
73         -Winit-self \
74         -Wdeclaration-after-statement \
75         -Wfloat-equal \
76         -Wmissing-prototypes \
77         -Wstrict-prototypes \
78         -Wredundant-decls \
79         -Wmissing-declarations \
80         -Wmissing-noreturn \
81         -Wshadow \
82         -Wendif-labels \
83         -Wcast-align \
84         -Wstrict-aliasing=2 \
85         -Wwrite-strings \
86         -Wno-long-long \
87         -Wno-overlength-strings \
88         -Wno-unused-parameter \
89         -Wno-missing-field-initializers \
90         -Wno-unused-result \
91         -Wp,-D_FORTIFY_SOURCE=2 \
92         -ffast-math \
93         -fno-common \
94         -fdiagnostics-show-option \
95         -fno-strict-aliasing \
96         -fvisibility=hidden \
97         -ffunction-sections \
98         -fdata-sections \
99         -Wl,--as-needed \
100         -Wl,--gc-sections])
101
102 LT_PREREQ(2.2)
103 LT_INIT
104
105 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
106 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
107 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
108 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
109
110 # This makes sure pkg.m4 is available.
111 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
112
113 PKG_CHECK_MODULES(UDEV, [ libudev >= 160 ])
114 AC_SUBST(UDEV_CFLAGS)
115 AC_SUBST(UDEV_LIBS)
116
117 PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.2 ])
118 AC_SUBST(DBUS_CFLAGS)
119 AC_SUBST(DBUS_LIBS)
120
121 have_selinux=no
122 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
123 if test "x$enable_selinux" != "xno"; then
124         PKG_CHECK_MODULES(SELINUX, [ libselinux ],
125                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
126         AC_SUBST(SELINUX_CFLAGS)
127         AC_SUBST(SELINUX_LIBS)
128         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
129                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
130         fi
131 fi
132 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
133
134 AC_ARG_ENABLE([tcpwrap],
135         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
136                 [case "${enableval}" in
137                         yes) have_tcpwrap=yes ;;
138                         no) have_tcpwrap=no ;;
139                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
140                 esac],
141                 [have_tcpwrap=auto])
142
143 if test "x${have_tcpwrap}" != xno ; then
144         ACX_LIBWRAP
145         if test "x${LIBWRAP_LIBS}" = x ; then
146                 if test "x$have_tcpwrap" = xyes ; then
147                         AC_MSG_ERROR([*** TCP wrappers support not found.])
148                 fi
149                 have_tcpwrap=no
150         else
151                 have_tcpwrap=yes
152         fi
153 else
154         LIBWRAP_LIBS=
155 fi
156 AC_SUBST(LIBWRAP_LIBS)
157
158 AC_ARG_ENABLE([pam],
159         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
160                 [case "${enableval}" in
161                         yes) have_pam=yes ;;
162                         no) have_pam=no ;;
163                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
164                 esac],
165                 [have_pam=auto])
166
167 if test "x${have_pam}" != xno ; then
168         AC_CHECK_HEADERS(
169                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
170                 [have_pam=yes],
171                 [if test "x$have_pam" = xyes ; then
172                         AC_MSG_ERROR([*** PAM headers not found.])
173                 fi])
174
175         AC_CHECK_LIB(
176                 [pam],
177                 [pam_syslog],
178                 [have_pam=yes],
179                 [if test "x$have_pam" = xyes ; then
180                         AC_MSG_ERROR([*** libpam not found.])
181                 fi])
182
183         if test "x$have_pam" = xyes ; then
184                 PAM_LIBS="-lpam -lpam_misc"
185                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
186         else
187                 have_pam=no
188         fi
189 else
190         PAM_LIBS=
191 fi
192 AC_SUBST(PAM_LIBS)
193 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
194
195 AC_ARG_ENABLE([audit],
196         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
197                 [case "${enableval}" in
198                         yes) have_audit=yes ;;
199                         no) have_audit=no ;;
200                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
201                 esac],
202                 [have_audit=auto])
203
204 if test "x${have_audit}" != xno ; then
205         AC_CHECK_HEADERS(
206                 [libaudit.h],
207                 [have_audit=yes],
208                 [if test "x$have_audit" = xyes ; then
209                         AC_MSG_ERROR([*** AUDIT headers not found.])
210                 fi])
211
212         AC_CHECK_LIB(
213                 [audit],
214                 [audit_open],
215                 [have_audit=yes],
216                 [if test "x$have_audit" = xyes ; then
217                         AC_MSG_ERROR([*** libaudit not found.])
218                 fi])
219
220         if test "x$have_audit" = xyes ; then
221                 AUDIT_LIBS="-laudit"
222                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
223         else
224                 have_audit=no
225         fi
226 else
227         AUDIT_LIBS=
228 fi
229 AC_SUBST(AUDIT_LIBS)
230
231 have_libcryptsetup=no
232 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
233 if test "x$enable_libcryptsetup" != "xno"; then
234         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup ],
235                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
236         AC_SUBST(LIBCRYPTSETUP_CFLAGS)
237         AC_SUBST(LIBCRYPTSETUP_LIBS)
238         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
239                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
240         fi
241 fi
242 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
243
244 have_gtk=no
245 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
246 if test "x$enable_gtk" != "xno"; then
247         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 glib-2.0 > 2.26 gio-unix-2.0 ],
248                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
249         AC_SUBST(GTK_CFLAGS)
250         AC_SUBST(GTK_LIBS)
251         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
252                 AC_MSG_ERROR([*** gtk support requested but libraries not found])
253         fi
254 fi
255 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
256
257 if test "$have_gtk" = "yes"; then
258         PKG_CHECK_MODULES(LIBNOTIFY, [ libnotify ])
259         PKG_CHECK_EXISTS([ libnotify >= 0.7.0 ], [ libnotify07=yes ])
260
261         AC_SUBST(LIBNOTIFY_CFLAGS)
262         AC_SUBST(LIBNOTIFY_LIBS)
263 fi
264 AM_CONDITIONAL(LIBNOTIFY07, [ test "$libnotify07" = "yes" ])
265
266 AM_PROG_VALAC([0.10])
267 AC_SUBST(VAPIDIR)
268 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
269
270 AC_PATH_PROG([XSLTPROC], [xsltproc])
271 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
272
273 AC_PATH_PROG([M4], [m4])
274
275 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux or other]))
276 if test "z$with_distro" = "z"; then
277         if test "$cross_compiling" = yes; then
278                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
279         else
280                 test -f "/etc/redhat-release" && with_distro="fedora"
281                 test -f "/etc/SuSE-release" && with_distro="suse"
282                 test -f "/etc/debian_version" &&  with_distro="debian"
283                 test -f "/etc/arch-release" && with_distro="arch"
284                 test -f "/etc/gentoo-release" && with_distro="gentoo"
285                 test -f "/etc/slackware-version" && with_distro="slackware"
286                 test -f "/etc/frugalware-release" && with_distro="frugalware"
287                 test -f "/etc/altlinux-release" && with_distro="altlinux"
288                 test -f "/etc/mandriva-release" && with_distro="mandriva"
289                 if test "x`lsb_release -is 2>/dev/null`" = "xUbuntu"; then
290                         with_distro="ubuntu"
291                 fi
292         fi
293         if test "z$with_distro" = "z"; then
294                 with_distro=`uname -s`
295         fi
296 fi
297 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
298 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
299
300 # Location of the init scripts as mandated by LSB
301 SYSTEM_SYSVINIT_PATH=/etc/init.d
302 SYSTEM_SYSVRCND_PATH=/etc/rc.d
303
304 M4_DISTRO_FLAG=
305
306 case $with_distro in
307         fedora)
308                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
309                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
310                 M4_DISTRO_FLAG=-DTARGET_FEDORA=1
311                 have_plymouth=true
312                 ;;
313         suse)
314                 SYSTEM_SYSVRCND_PATH=/etc/init.d
315                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
316                 M4_DISTRO_FLAG=-DTARGET_SUSE=1
317                 have_plymouth=true
318                 ;;
319         debian)
320                 SYSTEM_SYSVRCND_PATH=/etc
321                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
322                 M4_DISTRO_FLAG=-DTARGET_DEBIAN=1
323                 ;;
324         ubuntu)
325                 SYSTEM_SYSVRCND_PATH=/etc
326                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
327                 M4_DISTRO_FLAG=-DTARGET_UBUNTU=1
328                 ;;
329         arch)
330                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
331                 SYSTEM_SYSVRCND_PATH=/etc
332                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
333                 M4_DISTRO_FLAG=-DTARGET_ARCH=1
334                 ;;
335         gentoo)
336                 SYSTEM_SYSVINIT_PATH=
337                 SYSTEM_SYSVRCND_PATH=
338                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
339                 M4_DISTRO_FLAG=-DTARGET_GENTOO=1
340                 ;;
341         slackware)
342                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
343                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
344                 M4_DISTRO_FLAG=-DTARGET_SLACKWARE=1
345                 ;;
346         frugalware)
347                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
348                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
349                 M4_DISTRO_FLAG=-DTARGET_FRUGALWARE=1
350                 ;;
351         altlinux)
352                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
353                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
354                 M4_DISTRO_FLAG=-DTARGET_ALTLINUX=1
355                 have_plymouth=true
356                 ;;
357         mandriva)
358                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
359                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
360                 M4_DISTRO_FLAG=-DTARGET_MANDRIVA=1
361                 have_plymouth=true
362                 ;;
363         other)
364                 ;;
365         *)
366                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
367                 ;;
368 esac
369
370 AC_ARG_WITH([sysvinit-path],
371         [AS_HELP_STRING([--with-sysvinit-path=PATH],
372                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
373         [SYSTEM_SYSVINIT_PATH="$withval"],
374         [])
375
376 AC_ARG_WITH([sysvrcd-path],
377         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
378                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
379         [SYSTEM_SYSVRCND_PATH="$withval"],
380         [])
381
382 AC_SUBST(SYSTEM_SYSVINIT_PATH)
383 AC_SUBST(SYSTEM_SYSVRCND_PATH)
384 AC_SUBST(M4_DISTRO_FLAG)
385
386 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
387         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
388         SYSTEM_SYSV_COMPAT="yes"
389 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
390         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
391 else
392         SYSTEM_SYSV_COMPAT="no"
393 fi
394
395 AC_ARG_WITH([tty-gid],
396         [AS_HELP_STRING([--with-tty-gid=GID],
397                 [Specify the numeric GID of the 'tty' group])],
398         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
399         [])
400
401 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
402 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
403 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
404 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
405 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
406 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
407 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
408 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
409 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
410 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
411 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
412
413 AM_CONDITIONAL(HAVE_PLYMOUTH, test -n "$have_plymouth")
414 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
415
416 AC_ARG_WITH([dbuspolicydir],
417         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
418         [],
419         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
420
421 AC_ARG_WITH([dbussessionservicedir],
422         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
423         [],
424         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
425
426 AC_ARG_WITH([dbussystemservicedir],
427         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
428         [],
429         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
430
431 AC_ARG_WITH([dbusinterfacedir],
432         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
433         [],
434         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
435
436 AC_ARG_WITH([udevrulesdir],
437         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
438         [],
439         [with_udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d])
440
441 AC_ARG_WITH([pamlibdir],
442         AS_HELP_STRING([--with-pamlibdir=DIR], [Diectory for PAM modules]),
443         [],
444         [with_pamlibdir=/lib/`$CC -print-multi-os-directory`/security])
445
446 AC_ARG_WITH([rootdir],
447         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
448         [],
449         [with_rootdir=${ac_default_prefix}])
450
451 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
452 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
453 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
454 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
455 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
456 AC_SUBST([pamlibdir], [$with_pamlibdir])
457 AC_SUBST([rootdir], [$with_rootdir])
458
459 AC_CONFIG_FILES([Makefile])
460 AC_OUTPUT
461
462 echo "
463         $PACKAGE_NAME $VERSION
464
465         Distribution:            ${with_distro}
466         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
467         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
468         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
469         Gtk:                     ${have_gtk}
470         libcryptsetup:           ${have_libcryptsetup}
471         tcpwrap:                 ${have_tcpwrap}
472         PAM:                     ${have_pam}
473         AUDIT:                   ${have_audit}
474         SELinux:                 ${have_selinux}
475         prefix:                  ${prefix}
476         root dir:                ${with_rootdir}
477         udev rules dir:          ${with_udevrulesdir}
478         pam modules dir:         ${with_pamlibdir}
479         dbus policy dir:         ${with_dbuspolicydir}
480         dbus session dir:        ${with_dbussessionservicedir}
481         dbus system dir:         ${with_dbussystemservicedir}
482         dbus interfaces dir:     ${with_dbusinterfacedir}
483 "