chiark / gitweb /
unit: make ignoring in snapshots a per unit property, instead of a per unit type...
[elogind.git] / configure.ac
1 #  This file is part of systemd.
2 #
3 #  Copyright 2010 Lennart Poettering
4 #
5 #  systemd is free software; you can redistribute it and/or modify it
6 #  under the terms of the GNU General Public License as published by
7 #  the Free Software Foundation; either version 2 of the License, or
8 #  (at your option) any later version.
9 #
10 #  systemd is distributed in the hope that it will be useful, but
11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 #  General Public License for more details.
14 #
15 #  You should have received a copy of the GNU General Public License
16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
17
18 AC_PREREQ(2.63)
19
20 AC_INIT([systemd],[26],[systemd-devel@lists.freedesktop.org])
21 AC_CONFIG_SRCDIR([src/main.c])
22 AC_CONFIG_MACRO_DIR([m4])
23 AC_CONFIG_HEADERS([config.h])
24 AC_USE_SYSTEM_EXTENSIONS
25 AC_SYS_LARGEFILE
26
27 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects dist-bzip2])
28
29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
30
31 AC_CANONICAL_HOST
32 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
33 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
34        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
35       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
36
37 AM_SILENT_RULES([yes])
38
39 AC_CHECK_PROG([STOW], [stow], [yes], [no])
40
41 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
42         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
43         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
44 ])
45
46 AC_PROG_MKDIR_P
47 AC_PROG_LN_S
48 AC_PROG_SED
49
50 AC_PROG_CC
51 AC_PROG_CC_C99
52 AM_PROG_CC_C_O
53 AC_PROG_GCC_TRADITIONAL
54
55 AC_CHECK_TOOL(OBJCOPY, objcopy)
56 AC_CHECK_TOOL(STRINGS, strings)
57
58 CC_CHECK_CFLAGS_APPEND([ \
59         -pipe \
60         -Wall \
61         -W \
62         -Wextra \
63         -Wno-inline \
64         -Wvla \
65         -Wundef \
66         -Wformat=2 \
67         -Wlogical-op \
68         -Wsign-compare \
69         -Wformat-security \
70         -Wmissing-include-dirs \
71         -Wformat-nonliteral \
72         -Wold-style-definition \
73         -Wpointer-arith \
74         -Winit-self \
75         -Wdeclaration-after-statement \
76         -Wfloat-equal \
77         -Wmissing-prototypes \
78         -Wstrict-prototypes \
79         -Wredundant-decls \
80         -Wmissing-declarations \
81         -Wmissing-noreturn \
82         -Wshadow \
83         -Wendif-labels \
84         -Wcast-align \
85         -Wstrict-aliasing=2 \
86         -Wwrite-strings \
87         -Wno-long-long \
88         -Wno-overlength-strings \
89         -Wno-unused-parameter \
90         -Wno-missing-field-initializers \
91         -Wno-unused-result \
92         -Wp,-D_FORTIFY_SOURCE=2 \
93         -ffast-math \
94         -fno-common \
95         -fdiagnostics-show-option \
96         -fno-strict-aliasing \
97         -fvisibility=hidden \
98         -ffunction-sections \
99         -fdata-sections \
100         -Wl,--as-needed \
101         -Wl,--gc-sections])
102
103 LT_PREREQ(2.2)
104 LT_INIT
105
106 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
107 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
108 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
109 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
110
111 # This makes sure pkg.m4 is available.
112 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
113
114 PKG_CHECK_MODULES(UDEV, [ libudev >= 160 ])
115 AC_SUBST(UDEV_CFLAGS)
116 AC_SUBST(UDEV_LIBS)
117
118 PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.2 ])
119 AC_SUBST(DBUS_CFLAGS)
120 AC_SUBST(DBUS_LIBS)
121
122 have_selinux=no
123 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
124 if test "x$enable_selinux" != "xno"; then
125         PKG_CHECK_MODULES(SELINUX, [ libselinux ],
126                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
127         AC_SUBST(SELINUX_CFLAGS)
128         AC_SUBST(SELINUX_LIBS)
129         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
130                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
131         fi
132 fi
133 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
134
135 AC_ARG_ENABLE([tcpwrap],
136         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
137                 [case "${enableval}" in
138                         yes) have_tcpwrap=yes ;;
139                         no) have_tcpwrap=no ;;
140                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
141                 esac],
142                 [have_tcpwrap=auto])
143
144 if test "x${have_tcpwrap}" != xno ; then
145         ACX_LIBWRAP
146         if test "x${LIBWRAP_LIBS}" = x ; then
147                 if test "x$have_tcpwrap" = xyes ; then
148                         AC_MSG_ERROR([*** TCP wrappers support not found.])
149                 fi
150                 have_tcpwrap=no
151         else
152                 have_tcpwrap=yes
153         fi
154 else
155         LIBWRAP_LIBS=
156 fi
157 AC_SUBST(LIBWRAP_LIBS)
158
159 AC_ARG_ENABLE([pam],
160         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
161                 [case "${enableval}" in
162                         yes) have_pam=yes ;;
163                         no) have_pam=no ;;
164                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
165                 esac],
166                 [have_pam=auto])
167
168 if test "x${have_pam}" != xno ; then
169         AC_CHECK_HEADERS(
170                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
171                 [have_pam=yes],
172                 [if test "x$have_pam" = xyes ; then
173                         AC_MSG_ERROR([*** PAM headers not found.])
174                 fi])
175
176         AC_CHECK_LIB(
177                 [pam],
178                 [pam_syslog],
179                 [have_pam=yes],
180                 [if test "x$have_pam" = xyes ; then
181                         AC_MSG_ERROR([*** libpam not found.])
182                 fi])
183
184         if test "x$have_pam" = xyes ; then
185                 PAM_LIBS="-lpam -lpam_misc"
186                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
187         else
188                 have_pam=no
189         fi
190 else
191         PAM_LIBS=
192 fi
193 AC_SUBST(PAM_LIBS)
194 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
195
196 AC_ARG_ENABLE([audit],
197         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
198                 [case "${enableval}" in
199                         yes) have_audit=yes ;;
200                         no) have_audit=no ;;
201                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
202                 esac],
203                 [have_audit=auto])
204
205 if test "x${have_audit}" != xno ; then
206         AC_CHECK_HEADERS(
207                 [libaudit.h],
208                 [have_audit=yes],
209                 [if test "x$have_audit" = xyes ; then
210                         AC_MSG_ERROR([*** AUDIT headers not found.])
211                 fi])
212
213         AC_CHECK_LIB(
214                 [audit],
215                 [audit_open],
216                 [have_audit=yes],
217                 [if test "x$have_audit" = xyes ; then
218                         AC_MSG_ERROR([*** libaudit not found.])
219                 fi])
220
221         if test "x$have_audit" = xyes ; then
222                 AUDIT_LIBS="-laudit"
223                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
224         else
225                 have_audit=no
226         fi
227 else
228         AUDIT_LIBS=
229 fi
230 AC_SUBST(AUDIT_LIBS)
231
232 have_libcryptsetup=no
233 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
234 if test "x$enable_libcryptsetup" != "xno"; then
235         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup ],
236                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
237         AC_SUBST(LIBCRYPTSETUP_CFLAGS)
238         AC_SUBST(LIBCRYPTSETUP_LIBS)
239         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
240                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
241         fi
242 fi
243 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
244
245 have_binfmt=no
246 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
247 if test "x$enable_binfmt" != "xno"; then
248         have_binfmt=yes
249 fi
250 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
251
252 have_gtk=no
253 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
254 if test "x$enable_gtk" != "xno"; then
255         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 glib-2.0 > 2.26 gio-unix-2.0 ],
256                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
257         AC_SUBST(GTK_CFLAGS)
258         AC_SUBST(GTK_LIBS)
259         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
260                 AC_MSG_ERROR([*** gtk support requested but libraries not found])
261         fi
262 fi
263 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
264
265 if test "$have_gtk" = "yes"; then
266         PKG_CHECK_MODULES(LIBNOTIFY, [ libnotify ])
267         PKG_CHECK_EXISTS([ libnotify >= 0.7.0 ], [ libnotify07=yes ])
268
269         AC_SUBST(LIBNOTIFY_CFLAGS)
270         AC_SUBST(LIBNOTIFY_LIBS)
271 fi
272 AM_CONDITIONAL(LIBNOTIFY07, [ test "$libnotify07" = "yes" ])
273
274 AM_PROG_VALAC([0.10])
275 AC_SUBST(VAPIDIR)
276 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
277
278 AC_PATH_PROG([XSLTPROC], [xsltproc])
279 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
280
281 AC_PATH_PROG([M4], [m4])
282
283 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux or other]))
284 if test "z$with_distro" = "z"; then
285         if test "$cross_compiling" = yes; then
286                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
287         else
288                 test -f "/etc/redhat-release" && with_distro="fedora"
289                 test -f "/etc/SuSE-release" && with_distro="suse"
290                 test -f "/etc/debian_version" &&  with_distro="debian"
291                 test -f "/etc/arch-release" && with_distro="arch"
292                 test -f "/etc/gentoo-release" && with_distro="gentoo"
293                 test -f "/etc/slackware-version" && with_distro="slackware"
294                 test -f "/etc/frugalware-release" && with_distro="frugalware"
295                 test -f "/etc/altlinux-release" && with_distro="altlinux"
296                 test -f "/etc/mandriva-release" && with_distro="mandriva"
297                 test -f "/etc/meego-release" && with_distro="meego"
298                 if test "x`lsb_release -is 2>/dev/null`" = "xUbuntu"; then
299                         with_distro="ubuntu"
300                 fi
301         fi
302         if test "z$with_distro" = "z"; then
303                 with_distro=`uname -s`
304         fi
305 fi
306 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
307 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
308
309 # Location of the init scripts as mandated by LSB
310 SYSTEM_SYSVINIT_PATH=/etc/init.d
311 SYSTEM_SYSVRCND_PATH=/etc/rc.d
312
313 M4_DISTRO_FLAG=
314
315 case $with_distro in
316         fedora)
317                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
318                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
319                 M4_DISTRO_FLAG=-DTARGET_FEDORA=1
320                 have_plymouth=true
321                 ;;
322         suse)
323                 SYSTEM_SYSVRCND_PATH=/etc/init.d
324                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
325                 M4_DISTRO_FLAG=-DTARGET_SUSE=1
326                 have_plymouth=true
327                 ;;
328         debian)
329                 SYSTEM_SYSVRCND_PATH=/etc
330                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
331                 M4_DISTRO_FLAG=-DTARGET_DEBIAN=1
332                 ;;
333         ubuntu)
334                 SYSTEM_SYSVRCND_PATH=/etc
335                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
336                 M4_DISTRO_FLAG=-DTARGET_UBUNTU=1
337                 ;;
338         arch)
339                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
340                 SYSTEM_SYSVRCND_PATH=/etc
341                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
342                 M4_DISTRO_FLAG=-DTARGET_ARCH=1
343                 ;;
344         gentoo)
345                 SYSTEM_SYSVINIT_PATH=
346                 SYSTEM_SYSVRCND_PATH=
347                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
348                 M4_DISTRO_FLAG=-DTARGET_GENTOO=1
349                 ;;
350         slackware)
351                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
352                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
353                 M4_DISTRO_FLAG=-DTARGET_SLACKWARE=1
354                 ;;
355         frugalware)
356                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
357                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
358                 M4_DISTRO_FLAG=-DTARGET_FRUGALWARE=1
359                 ;;
360         altlinux)
361                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
362                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
363                 M4_DISTRO_FLAG=-DTARGET_ALTLINUX=1
364                 have_plymouth=true
365                 ;;
366         mandriva)
367                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
368                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
369                 M4_DISTRO_FLAG=-DTARGET_MANDRIVA=1
370                 have_plymouth=true
371                 ;;
372         meego)
373                 SYSTEM_SYSVINIT_PATH=
374                 SYSTEM_SYSVRCND_PATH=
375                 AC_DEFINE(TARGET_MEEGO, [], [Target is MeeGo])
376                 M4_DISTRO_FLAG=-DTARGET_MEEGO=1
377                 ;;
378         other)
379                 ;;
380         *)
381                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
382                 ;;
383 esac
384
385 AC_ARG_WITH([sysvinit-path],
386         [AS_HELP_STRING([--with-sysvinit-path=PATH],
387                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
388         [SYSTEM_SYSVINIT_PATH="$withval"],
389         [])
390
391 AC_ARG_WITH([sysvrcd-path],
392         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
393                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
394         [SYSTEM_SYSVRCND_PATH="$withval"],
395         [])
396
397 AC_SUBST(SYSTEM_SYSVINIT_PATH)
398 AC_SUBST(SYSTEM_SYSVRCND_PATH)
399 AC_SUBST(M4_DISTRO_FLAG)
400
401 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
402         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
403         SYSTEM_SYSV_COMPAT="yes"
404 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
405         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
406 else
407         SYSTEM_SYSV_COMPAT="no"
408 fi
409
410 AC_ARG_WITH([tty-gid],
411         [AS_HELP_STRING([--with-tty-gid=GID],
412                 [Specify the numeric GID of the 'tty' group])],
413         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
414         [])
415
416 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
417 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
418 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
419 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
420 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
421 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
422 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
423 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
424 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
425 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
426 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
427 AM_CONDITIONAL(TARGET_MEEGO, test x"$with_distro" = xmeego)
428
429 AM_CONDITIONAL(HAVE_PLYMOUTH, test -n "$have_plymouth")
430 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
431
432 AC_ARG_WITH([dbuspolicydir],
433         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
434         [],
435         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
436
437 AC_ARG_WITH([dbussessionservicedir],
438         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
439         [],
440         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
441
442 AC_ARG_WITH([dbussystemservicedir],
443         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
444         [],
445         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
446
447 AC_ARG_WITH([dbusinterfacedir],
448         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
449         [],
450         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
451
452 AC_ARG_WITH([udevrulesdir],
453         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
454         [],
455         [with_udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d])
456
457 AC_ARG_WITH([pamlibdir],
458         AS_HELP_STRING([--with-pamlibdir=DIR], [Diectory for PAM modules]),
459         [],
460         [with_pamlibdir=/lib/`$CC -print-multi-os-directory`/security])
461
462 AC_ARG_WITH([rootdir],
463         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
464         [],
465         [with_rootdir=${ac_default_prefix}])
466
467 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
468 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
469 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
470 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
471 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
472 AC_SUBST([pamlibdir], [$with_pamlibdir])
473 AC_SUBST([rootdir], [$with_rootdir])
474
475 AC_CONFIG_FILES([Makefile])
476 AC_OUTPUT
477
478 echo "
479         $PACKAGE_NAME $VERSION
480
481         Distribution:            ${with_distro}
482         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
483         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
484         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
485         Gtk:                     ${have_gtk}
486         libcryptsetup:           ${have_libcryptsetup}
487         tcpwrap:                 ${have_tcpwrap}
488         PAM:                     ${have_pam}
489         AUDIT:                   ${have_audit}
490         SELinux:                 ${have_selinux}
491         binfmt:                  ${have_binfmt}
492         prefix:                  ${prefix}
493         root dir:                ${with_rootdir}
494         udev rules dir:          ${with_udevrulesdir}
495         pam modules dir:         ${with_pamlibdir}
496         dbus policy dir:         ${with_dbuspolicydir}
497         dbus session dir:        ${with_dbussessionservicedir}
498         dbus system dir:         ${with_dbussystemservicedir}
499         dbus interfaces dir:     ${with_dbusinterfacedir}
500 "