configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [218],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  42        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  43       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  44
  45 LT_PREREQ(2.2)
  46 LT_INIT([disable-static])
  47
  48 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  49 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  50
  51 # i18n stuff for the PolicyKit policy files
  52
  53 # Check whether intltool can be found, disable NLS otherwise
  54 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  55 AS_IF([test x"$intltool_found" != xyes],
  56       [AS_IF([test x"$enable_nls" = xyes],
  57              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  58              [AS_IF([test x"$enable_nls" != xno],
  59                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  60                      enable_nls=no])
  61              ])
  62       ])
  63
  64 AM_NLS
  65 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  66     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  67 IT_PROG_INTLTOOL([0.40.0])
  68 ])
  69
  70 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  71     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  72     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  73     AC_SUBST(INTLTOOL_POLICY_RULE)
  74 ])
  75
  76 GETTEXT_PACKAGE=systemd
  77 AC_SUBST(GETTEXT_PACKAGE)
  78
  79 AC_PROG_MKDIR_P
  80 AC_PROG_LN_S
  81 AC_PROG_SED
  82 AC_PROG_GREP
  83 AC_PROG_AWK
  84
  85 AC_PROG_CC_C99
  86
  87 AC_PATH_PROG([M4], [m4])
  88 AC_PATH_PROG([XSLTPROC], [xsltproc])
  89
  90 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon], [$PATH:/usr/sbin:/sbin])
  91 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck], [$PATH:/usr/sbin:/sbin])
  92
  93 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap], [$PATH:/usr/sbin:/sbin])
  94
  95 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill], [$PATH:/usr/sbin:/sbin])
  96
  97 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod], [$PATH:/usr/sbin:/sbin])
  98
  99 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
 100
 101 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
 102
 103 M4_DEFINES=
 104
 105 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
 106 m4_ifdef([GTK_DOC_CHECK], [
 107 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
 108          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
 109           enable_gtk_doc=no])
 110
 111 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
 112         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
 113 ])
 114
 115 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
 116 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 117 ], [
 118    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
 119    enable_introspection=no])
 120
 121 AC_CHECK_TOOL(STRINGS, strings)
 122 AC_CHECK_TOOL(GPERF, gperf)
 123 if test -z "$GPERF" ; then
 124         AC_MSG_ERROR([*** gperf not found])
 125 fi
 126
 127 # ------------------------------------------------------------------------------
 128 address_sanitizer_cflags=
 129 address_sanitizer_cppflags=
 130 address_sanitizer_ldflags=
 131 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 132 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 133             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 134             AS_IF([test -z "$with_as_cflags"],
 135                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 136             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 137             address_sanitizer_cppflags="-DVALGRIND=1"
 138             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 139       ])
 140
 141 undefined_sanitizer_cflags=
 142 undefined_sanitizer_cppflags=
 143 undefined_sanitizer_ldflags=
 144 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 145 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 146             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 147             AS_IF([test -z "$with_us_cflags"],
 148                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 149             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 150             undefined_sanitizer_cppflags="-DVALGRIND=1"
 151             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 152       ])
 153
 154 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 155 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 156 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 157
 158 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 159         -pipe \
 160         -Wall \
 161         -Wextra \
 162         -Wno-inline \
 163         -Wundef \
 164         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 165         -Wlogical-op \
 166         -Wsign-compare \
 167         -Wmissing-include-dirs \
 168         -Wold-style-definition \
 169         -Wpointer-arith \
 170         -Winit-self \
 171         -Wdeclaration-after-statement \
 172         -Wfloat-equal \
 173         -Wsuggest-attribute=noreturn \
 174         -Wmissing-prototypes \
 175         -Wstrict-prototypes \
 176         -Wredundant-decls \
 177         -Wmissing-declarations \
 178         -Wmissing-noreturn \
 179         -Wshadow \
 180         -Wendif-labels \
 181         -Wstrict-aliasing=2 \
 182         -Wwrite-strings \
 183         -Wno-long-long \
 184         -Wno-overlength-strings \
 185         -Wno-unused-parameter \
 186         -Wno-missing-field-initializers \
 187         -Wno-unused-result \
 188         -Werror=overflow \
 189         -Wdate-time \
 190         -Wnested-externs \
 191         -ffast-math \
 192         -fno-common \
 193         -fdiagnostics-show-option \
 194         -fno-strict-aliasing \
 195         -fvisibility=hidden \
 196         -ffunction-sections \
 197         -fdata-sections \
 198         -fstack-protector \
 199         -fstack-protector-strong \
 200         -fPIE \
 201         --param=ssp-buffer-size=4])
 202
 203 AS_CASE([$CC], [*clang*],
 204         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 205                -Wno-typedef-redefinition \
 206                -Wno-gnu-variable-sized-type-not-at-end \
 207         ])])
 208
 209 AS_CASE([$CFLAGS], [*-O[[12345\ ]]*],
 210         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 211                -flto -ffat-lto-objects])],
 212         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 213 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 214
 215 AS_CASE([$CFLAGS], [*-O[[12345\ ]]*],
 216         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 217                -Wp,-D_FORTIFY_SOURCE=2])],
 218         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 219 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 220
 221 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 222         -Wl,--as-needed \
 223         -Wl,--no-undefined \
 224         -Wl,--gc-sections \
 225         -Wl,-z,relro \
 226         -Wl,-z,now \
 227         -pie \
 228         -Wl,-fuse-ld=gold])
 229 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 230
 231 AC_CHECK_SIZEOF(pid_t)
 232 AC_CHECK_SIZEOF(uid_t)
 233 AC_CHECK_SIZEOF(gid_t)
 234 AC_CHECK_SIZEOF(time_t)
 235 AC_CHECK_SIZEOF(dev_t)
 236 AC_CHECK_SIZEOF(rlim_t,,[
 237        #include <sys/time.h>
 238        #include <sys/resource.h>
 239 ])
 240
 241 # ------------------------------------------------------------------------------
 242 # we use python to build the man page index, and for systemd-python
 243 have_python=no
 244 AC_ARG_WITH([python],
 245         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 246
 247 have_lxml=no
 248 AS_IF([test "x$with_python" != "xno"], [
 249         AM_PATH_PYTHON(,, [:])
 250         AS_IF([test "x$PYTHON" != "x:"], [
 251                 AC_MSG_CHECKING([for python lxml module])
 252                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
 253                 AC_MSG_RESULT([$have_lxml])
 254                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
 255                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
 256         ])
 257 ])
 258 AS_IF([test "$have_python" != "yes"], [
 259       AS_IF([test "$with_python" = "yes"],
 260             [AC_MSG_ERROR([*** python support requested but python support not found])])
 261       AS_IF([test "$with_python" != "no"],
 262             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
 263 ])
 264
 265 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 266 AS_IF([test "x$PYTHON_BINARY" = "x"],
 267       [AS_IF([test "x$have_python" = "xyes"],
 268              [PYTHON_BINARY="$(which "$PYTHON")"],
 269              [PYTHON_BINARY=/usr/bin/python])])
 270 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 271
 272 AS_IF([test "x$have_python" != "xyes" -a "x$enable_python_devel" = "xyes"],
 273       [AC_MSG_ERROR([*** python-devel support requires --with-python])])
 274
 275 have_python_devel=no
 276 AC_ARG_ENABLE(python_devel, AS_HELP_STRING([--disable-python-devel], [Do not build python modules]))
 277 AS_IF([test "x$have_python" = "xyes" -a "x$enable_python_devel" != "xno"], [
 278       PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}],
 279             [have_python_devel=yes],
 280             [PKG_CHECK_MODULES([PYTHON_DEVEL], [python],
 281                   [have_python_devel=yes],
 282                   [have_python_devel=no])])
 283       AS_IF([test "x$have_python_devel" = xno -a "x$enable_python_devel" = xyes],
 284             [AC_MSG_ERROR([*** python-devel support requested but libraries not found])])
 285       AC_PATH_PROGS(SPHINX_BUILD, sphinx-build-${PYTHON_VERSION} sphinx-build)
 286 ])
 287 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 288
 289 # ------------------------------------------------------------------------------
 290
 291 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 292 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 293 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 294 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 295
 296 # unconditionally pull-in librt with old glibc versions
 297 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 298
 299 save_LIBS="$LIBS"
 300 LIBS=
 301 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 302 CAP_LIBS="$LIBS"
 303 AC_SUBST(CAP_LIBS)
 304
 305 LIBS=
 306 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 307 RT_LIBS="$LIBS"
 308 AC_SUBST(RT_LIBS)
 309 LIBS="$save_LIBS"
 310
 311 AC_CHECK_FUNCS([memfd_create])
 312 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 313 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns, getrandom, renameat2, kcmp, LO_FLAGS_PARTSCAN],
 314                [], [], [[
 315 #include <sys/types.h>
 316 #include <unistd.h>
 317 #include <sys/mount.h>
 318 #include <fcntl.h>
 319 #include <sched.h>
 320 #include <linux/loop.h>
 321 #include <linux/random.h>
 322 ]])
 323
 324 AC_CHECK_DECLS([IFLA_MACVLAN_FLAGS,
 325                 IFLA_IPVLAN_MODE,
 326                 IFLA_VTI_REMOTE,
 327                 IFLA_PHYS_PORT_ID,
 328                 IFLA_BOND_AD_INFO,
 329                 IFLA_VLAN_PROTOCOL,
 330                 IFLA_VXLAN_LOCAL6,
 331                 IFLA_IPTUN_6RD_RELAY_PREFIXLEN,
 332                 IFLA_BRIDGE_VLAN_INFO,
 333                 IFLA_BRPORT_UNICAST_FLOOD],
 334 [], [], [[
 335 #include <inttypes.h>
 336 #include <netinet/in.h>
 337 #include <netinet/ether.h>
 338 #include <linux/rtnetlink.h>
 339 #include <net/if.h>
 340 #include <linux/ip.h>
 341 #include <linux/if_tunnel.h>
 342 #include <linux/if_link.h>
 343 #include <linux/if_bridge.h>
 344 ]])
 345
 346 # This makes sure pkg.m4 is available.
 347 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 348
 349 # ------------------------------------------------------------------------------
 350 have_dbus=no
 351 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 352 AS_IF([test "x$enable_dbus" != "xno"], [
 353         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 354                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 355                 [have_dbus=no])
 356         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 357                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 358 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 359
 360 # ------------------------------------------------------------------------------
 361 have_utmp=yes
 362 AC_ARG_ENABLE([utmp], AS_HELP_STRING([--disable-utmp], [disable utmp/wtmp log handling]),
 363         AS_CASE("x${enableval}",
 364                 [xyes], [have_utmp=yes],
 365                 [xno],  [have_utmp=no],
 366                 AC_MSG_ERROR(bad value ${enableval} for --enable-utmp)))
 367 AS_IF([test "x$have_utmp" = "xyes"], [AC_DEFINE(HAVE_UTMP, 1, [Define if utmp/wtmp support is enabled])])
 368 AM_CONDITIONAL([HAVE_UTMP], [test "x$have_utmp" = "xyes"])
 369
 370 # ------------------------------------------------------------------------------
 371 have_compat_libs=no
 372 AC_ARG_ENABLE([compat_libs], AS_HELP_STRING([--enable-compat-libs],[Enable creation of compatibility libraries]),
 373                 [case "${enableval}" in
 374                         yes) have_compat_libs=yes ;;
 375                         no) have_compat_libs=no ;;
 376                         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compat-libs) ;;
 377                 esac],
 378                 [have_compat_libs=no])
 379 AM_CONDITIONAL([ENABLE_COMPAT_LIBS], [test "$have_compat_libs" = "yes"])
 380
 381 # ------------------------------------------------------------------------------
 382 have_coverage=no
 383 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 384 if test "x$enable_coverage" = "xyes" ; then
 385         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 386         if test "x$lcov_found" = xno ; then
 387                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 388         else
 389                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 390                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 391                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 392                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 393                 else
 394                         have_coverage=yes
 395                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 396                         -fprofile-arcs \
 397                         -ftest-coverage])
 398                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 399                 fi
 400         fi
 401 fi
 402 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 403
 404 # ------------------------------------------------------------------------------
 405 have_kmod=no
 406 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 407 if test "x$enable_kmod" != "xno"; then
 408         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 409         if test "x$have_kmod" = "xyes"; then
 410                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 15 ],
 411                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 412                         AC_MSG_ERROR([*** kmod version >= 15 not found]))
 413         fi
 414         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 415                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 416         fi
 417 fi
 418 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 419
 420 # ------------------------------------------------------------------------------
 421 have_xkbcommon=no
 422 AC_ARG_ENABLE(xkbcommon, AS_HELP_STRING([--disable-xkbcommon], [disable xkbcommon keymap support]))
 423 if test "x$enable_xkbcommon" != "xno"; then
 424         PKG_CHECK_MODULES(XKBCOMMON, [ xkbcommon >= 0.3.0 ],
 425                 [AC_DEFINE(HAVE_XKBCOMMON, 1, [Define if libxkbcommon is available]) have_xkbcommon=yes], have_xkbcommon=no)
 426         if test "x$have_xkbcommon" = xno -a "x$enable_xkbcommon" = xyes; then
 427                 AC_MSG_ERROR([*** xkbcommon support requested but libraries not found])
 428         fi
 429 fi
 430 AM_CONDITIONAL(HAVE_XKBCOMMON, [test "$have_xkbcommon" = "yes"])
 431
 432 # ------------------------------------------------------------------------------
 433 have_blkid=no
 434 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 435 if test "x$enable_blkid" != "xno"; then
 436         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 437                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 438         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 439                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 440         fi
 441 fi
 442 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 443
 444 # ------------------------------------------------------------------------------
 445 have_libmount=no
 446 PKG_CHECK_MODULES(MOUNT, [ mount >= 2.20 ],
 447         [AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available]) have_libmount=yes], have_libmount=no)
 448 if test "x$have_libmount" = xno; then
 449         AC_MSG_ERROR([*** libmount support required but libraries not found])
 450 fi
 451 AM_CONDITIONAL(HAVE_LIBMOUNT, [test "$have_libmount" = "yes"])
 452
 453 # ------------------------------------------------------------------------------
 454 have_seccomp=no
 455 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 456 if test "x$enable_seccomp" != "xno"; then
 457         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 458                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 459                 have_seccomp=yes
 460                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 461                [have_seccomp=no])
 462         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 463                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 464         fi
 465 fi
 466 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 467
 468 # ------------------------------------------------------------------------------
 469 have_ima=yes
 470 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 471                 [case "${enableval}" in
 472                         yes) have_ima=yes ;;
 473                         no) have_ima=no ;;
 474                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 475                 esac],
 476                 [have_ima=yes])
 477
 478 if test "x${have_ima}" != xno ; then
 479         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 480 fi
 481
 482 # ------------------------------------------------------------------------------
 483 have_chkconfig=yes
 484 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 485                 [case "${enableval}" in
 486                         yes) have_chkconfig=yes ;;
 487                         no) have_chkconfig=no ;;
 488                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 489                 esac],
 490                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 491                 if test -z "$CHKCONFIG"; then
 492                         have_chkconfig=no
 493                 else
 494                         have_chkconfig=yes
 495                 fi])
 496
 497 if test "x${have_chkconfig}" != xno ; then
 498         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 499 fi
 500
 501 # ------------------------------------------------------------------------------
 502 have_selinux=no
 503 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 504 if test "x$enable_selinux" != "xno"; then
 505         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 506                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 507                  have_selinux=yes
 508                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 509                 [have_selinux=no])
 510         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 511                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 512         fi
 513 fi
 514 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 515
 516 have_apparmor=no
 517 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 518 if test "x$enable_apparmor" != "xno"; then
 519         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 520                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 521                  have_apparmor=yes
 522                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 523                 [have_apparmor=no])
 524         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 525                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 526         fi
 527 fi
 528 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 529
 530
 531 AC_ARG_WITH(debug-shell,
 532         AS_HELP_STRING([--with-debug-shell=PATH],
 533                 [Path to debug shell binary]),
 534         [SUSHELL="$withval"],[
 535         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 536
 537 AC_SUBST(SUSHELL)
 538
 539 AC_ARG_WITH([debug-tty],
 540         AS_HELP_STRING([--with-debug-tty=PATH],
 541                 [Specify the tty device for debug shell]),
 542         [DEBUGTTY="$withval"],
 543         [DEBUGTTY=/dev/tty9])
 544
 545 AC_SUBST(DEBUGTTY)
 546
 547 AC_ARG_WITH([certificate-root],
 548         AS_HELP_STRING([--with-certificate-root=PATH],
 549                 [Specify the prefix for TLS certificates [/etc/ssl]]),
 550         [CERTIFICATEROOT="$withval"],
 551         [CERTIFICATEROOT="/etc/ssl"])
 552
 553 AC_SUBST(CERTIFICATEROOT)
 554
 555 # ------------------------------------------------------------------------------
 556 have_xz=no
 557 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 558 if test "x$enable_xz" != "xno"; then
 559         PKG_CHECK_MODULES(XZ, [ liblzma ],
 560                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes])
 561         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 562                 AC_MSG_ERROR([*** XZ support requested but libraries not found])
 563         fi
 564 fi
 565 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 566
 567 # ------------------------------------------------------------------------------
 568 have_zlib=no
 569 AC_ARG_ENABLE(zlib, AS_HELP_STRING([--disable-zlib], [Disable optional ZLIB support]))
 570 if test "x$enable_zlib" != "xno"; then
 571         PKG_CHECK_MODULES(ZLIB, [ zlib ],
 572                 [AC_DEFINE(HAVE_ZLIB, 1, [Define if ZLIB is available]) have_zlib=yes])
 573         if test "x$have_zlib" = xno -a "x$enable_zlib" = xyes; then
 574                 AC_MSG_ERROR([*** ZLIB support requested but libraries not found])
 575         fi
 576 fi
 577 AM_CONDITIONAL(HAVE_ZLIB, [test "$have_zlib" = "yes"])
 578
 579 # ------------------------------------------------------------------------------
 580 have_lz4=no
 581 AC_ARG_ENABLE(lz4, AS_HELP_STRING([--enable-lz4], [Enable optional LZ4 support]))
 582 AS_IF([test "x$enable_lz4" = "xyes"], [
 583         AC_CHECK_HEADERS(lz4.h,
 584                [AC_DEFINE(HAVE_LZ4, 1, [Define in LZ4 is available]) have_lz4=yes],
 585                [AC_MSG_ERROR([*** LZ4 support requested but headers not found])])
 586 ])
 587 AM_CONDITIONAL(HAVE_LZ4, [test "$have_lz4" = "yes"])
 588
 589 AM_CONDITIONAL(HAVE_COMPRESSION, [test "$have_xz" = "yes" -o "$have_lz4" = "yes"])
 590
 591 # ------------------------------------------------------------------------------
 592 AC_ARG_ENABLE([pam],
 593         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 594                 [case "${enableval}" in
 595                         yes) have_pam=yes ;;
 596                         no) have_pam=no ;;
 597                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 598                 esac],
 599                 [have_pam=auto])
 600
 601 if test "x${have_pam}" != xno ; then
 602         AC_CHECK_HEADERS(
 603                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 604                 [have_pam=yes],
 605                 [if test "x$have_pam" = xyes ; then
 606                         AC_MSG_ERROR([*** PAM headers not found.])
 607                 fi])
 608
 609         AC_CHECK_LIB(
 610                 [pam],
 611                 [pam_syslog],
 612                 [have_pam=yes],
 613                 [if test "x$have_pam" = xyes ; then
 614                         AC_MSG_ERROR([*** libpam not found.])
 615                 fi])
 616
 617         if test "x$have_pam" = xyes ; then
 618                 PAM_LIBS="-lpam -lpam_misc"
 619                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 620                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 621         else
 622                 have_pam=no
 623         fi
 624 else
 625         PAM_LIBS=
 626 fi
 627 AC_SUBST(PAM_LIBS)
 628 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 629
 630 # ------------------------------------------------------------------------------
 631 AC_ARG_ENABLE([acl],
 632         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 633                 [case "${enableval}" in
 634                         yes) have_acl=yes ;;
 635                         no) have_acl=no ;;
 636                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 637                 esac],
 638                 [have_acl=auto])
 639
 640 if test "x${have_acl}" != xno ; then
 641         AC_CHECK_HEADERS(
 642                 [sys/acl.h acl/libacl.h],
 643                 [have_acl=yes],
 644                 [if test "x$have_acl" = xyes ; then
 645                         AC_MSG_ERROR([*** ACL headers not found.])
 646                 fi])
 647
 648         AC_CHECK_LIB(
 649                 [acl],
 650                 [acl_get_file],
 651                 [have_acl=yes],
 652                 [if test "x$have_acl" = xyes ; then
 653                         AC_MSG_ERROR([*** libacl not found.])
 654                 fi])
 655
 656         if test "x$have_acl" = xyes ; then
 657                 ACL_LIBS="-lacl"
 658                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 659         else
 660                 have_acl=no
 661         fi
 662 else
 663         ACL_LIBS=
 664 fi
 665 AC_SUBST(ACL_LIBS)
 666 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 667
 668 # ------------------------------------------------------------------------------
 669 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 670                 [case "${enableval}" in
 671                         yes) have_smack=yes ;;
 672                         no) have_smack=no ;;
 673                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 674                 esac],
 675                 [have_smack=auto])
 676
 677 if test "x${have_smack}" = xauto; then
 678         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 679         have_smack=yes
 680 fi
 681
 682 AC_ARG_WITH(smack-run-label,
 683 AS_HELP_STRING([--with-smack-run-label=STRING],
 684         [run systemd --system with a specific SMACK label]),
 685         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run with a smack label])],
 686         [])
 687
 688 if test "x${have_smack}" = xyes ; then
 689         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 690 fi
 691
 692 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 693
 694 # ------------------------------------------------------------------------------
 695 AC_ARG_ENABLE([gcrypt],
 696         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 697                 [case "${enableval}" in
 698                         yes) have_gcrypt=yes ;;
 699                         no) have_gcrypt=no ;;
 700                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 701                 esac],
 702                 [have_gcrypt=auto])
 703
 704 if test "x${have_gcrypt}" != xno ; then
 705         AM_PATH_LIBGCRYPT(
 706                 [1.4.5],
 707                 [have_gcrypt=yes],
 708                 [if test "x$have_gcrypt" = xyes ; then
 709                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 710                 fi])
 711
 712         if test "x$have_gcrypt" = xyes ; then
 713                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 714                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 715                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 716         else
 717                 have_gcrypt=no
 718         fi
 719 else
 720         GCRYPT_LIBS=
 721         GCRYPT_CFLAGS=
 722 fi
 723 AC_SUBST(GCRYPT_LIBS)
 724 AC_SUBST(GCRYPT_CFLAGS)
 725 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 726
 727 # ------------------------------------------------------------------------------
 728 AC_ARG_ENABLE([audit],
 729         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 730                 [case "${enableval}" in
 731                         yes) have_audit=yes ;;
 732                         no) have_audit=no ;;
 733                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 734                 esac],
 735                 [have_audit=auto])
 736
 737 if test "x${have_audit}" != xno ; then
 738         AC_CHECK_HEADERS(
 739                 [libaudit.h],
 740                 [have_audit=yes],
 741                 [if test "x$have_audit" = xyes ; then
 742                         AC_MSG_ERROR([*** AUDIT headers not found.])
 743                 fi])
 744
 745         AC_CHECK_LIB(
 746                 [audit],
 747                 [audit_open],
 748                 [have_audit=yes],
 749                 [if test "x$have_audit" = xyes ; then
 750                         AC_MSG_ERROR([*** libaudit not found.])
 751                 fi])
 752
 753         if test "x$have_audit" = xyes ; then
 754                 AUDIT_LIBS="-laudit"
 755                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 756         else
 757                 have_audit=no
 758         fi
 759 else
 760         AUDIT_LIBS=
 761 fi
 762 AC_SUBST(AUDIT_LIBS)
 763
 764 # ------------------------------------------------------------------------------
 765 AC_ARG_ENABLE([elfutils],
 766         AS_HELP_STRING([--disable-elfutils],[Disable optional ELFUTILS support]),
 767                 [case "${enableval}" in
 768                         yes) have_elfutils=yes ;;
 769                         no) have_elfutils=no ;;
 770                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-elfutils) ;;
 771                 esac],
 772                 [have_elfutils=auto])
 773
 774 if test "x${have_elfutils}" != xno ; then
 775         AC_CHECK_HEADERS(
 776                 [elfutils/libdwfl.h],
 777                 [],
 778                 [if test "x$have_elfutils" = xyes ; then
 779                         AC_MSG_ERROR([*** ELFUTILS headers not found.])
 780                 fi])
 781
 782         AC_CHECK_LIB(
 783                 [dw],
 784                 [dwfl_begin],
 785                 [],
 786                 [if test "x$have_elfutils" = xyes ; then
 787                         AC_MSG_ERROR([*** ELFUTILS libs not found.])
 788                 fi])
 789
 790         AC_CHECK_LIB(
 791                 [dw],
 792                 [dwfl_core_file_attach],
 793                 [have_elfutils=yes],
 794                 [if test "x$have_elfutils" = xyes ; then
 795                         AC_MSG_ERROR([*** ELFUTILS >= 158 is required.])
 796                 fi])
 797
 798         if test "x$have_elfutils" = xyes ; then
 799                 ELFUTILS_LIBS="-lelf -ldw"
 800                 AC_DEFINE(HAVE_ELFUTILS, 1, [ELFUTILS available])
 801         else
 802                 have_elfutils=no
 803         fi
 804 else
 805         ELFUTILS_LIBS=
 806 fi
 807 AC_SUBST(ELFUTILS_LIBS)
 808 AM_CONDITIONAL(HAVE_ELFUTILS, [test "$have_elfutils" = "yes"])
 809
 810 # ------------------------------------------------------------------------------
 811 have_libcryptsetup=no
 812 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 813 if test "x$enable_libcryptsetup" != "xno"; then
 814         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 815                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 816         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 817                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 818         fi
 819 fi
 820 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 821
 822 # ------------------------------------------------------------------------------
 823 have_qrencode=no
 824 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 825 if test "x$enable_qrencode" != "xno"; then
 826         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 827                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 828         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 829                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 830         fi
 831 fi
 832 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 833
 834 # ------------------------------------------------------------------------------
 835 have_microhttpd=no
 836 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 837 if test "x$enable_microhttpd" != "xno"; then
 838         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.33],
 839                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 840         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 841                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 842         fi
 843 fi
 844 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 845
 846 # ------------------------------------------------------------------------------
 847 have_gnutls=no
 848 AC_ARG_ENABLE(gnutls, AS_HELP_STRING([--disable-gnutls], [disable gnutls support]))
 849 if test "x$enable_gnutls" != "xno"; then
 850         PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.1.4],
 851                 [AC_DEFINE(HAVE_GNUTLS, 1, [Define if gnutls is available]) have_gnutls=yes], have_gnutls=no)
 852         if test "x$have_gnutls" = xno -a "x$enable_gnutls" = xyes; then
 853                 AC_MSG_ERROR([*** gnutls support requested but libraries not found])
 854         fi
 855 fi
 856 AM_CONDITIONAL(HAVE_GNUTLS, [test "$have_gnutls" = "yes"])
 857
 858 # ------------------------------------------------------------------------------
 859 have_libcurl=no
 860 AC_ARG_ENABLE(libcurl, AS_HELP_STRING([--disable-libcurl], [disable libcurl support]))
 861 if test "x$enable_libcurl" != "xno"; then
 862         PKG_CHECK_MODULES(LIBCURL, [libcurl],
 863                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available]) have_libcurl=yes], have_libcurl=no)
 864         if test "x$have_libcurl" = xno -a "x$enable_libcurl" = xyes; then
 865                 AC_MSG_ERROR([*** libcurl support requested but libraries not found])
 866         fi
 867 fi
 868 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
 869
 870 # ------------------------------------------------------------------------------
 871 have_libidn=no
 872 AC_ARG_ENABLE(libidn, AS_HELP_STRING([--disable-libidn], [Disable optional LIBIDN support]))
 873 if test "x$enable_libidn" != "xno"; then
 874         PKG_CHECK_MODULES(LIBIDN, [libidn],
 875                [AC_DEFINE(HAVE_LIBIDN, 1, [Define if libidn is available])
 876                 have_libidn=yes
 877                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIDN"],
 878                [have_libidn=no])
 879         if test "x$have_libidn" = "xno" -a "x$enable_libidn" = "xyes"; then
 880                 AC_MSG_ERROR([*** libidn support requested but libraries not found])
 881         fi
 882 fi
 883 AM_CONDITIONAL(HAVE_LIBIDN, [test "$have_libidn" = "yes"])
 884
 885 # ------------------------------------------------------------------------------
 886 have_libiptc=no
 887 AC_ARG_ENABLE(libiptc, AS_HELP_STRING([--disable-libiptc], [Disable optional LIBIPTC support]))
 888 if test "x$enable_libiptc" != "xno"; then
 889         PKG_CHECK_MODULES(LIBIPTC, [libiptc],
 890                [AC_DEFINE(HAVE_LIBIPTC, 1, [Define if libiptc is available])
 891                 have_libiptc=yes
 892                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIPTC"],
 893                [have_libiptc=no])
 894         if test "x$have_libiptc" = "xno" -a "x$enable_libiptc" = "xyes"; then
 895                 AC_MSG_ERROR([*** libiptc support requested but libraries not found])
 896         fi
 897 fi
 898 AM_CONDITIONAL(HAVE_LIBIPTC, [test "$have_libiptc" = "yes"])
 899
 900 # ------------------------------------------------------------------------------
 901 have_binfmt=no
 902 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 903 if test "x$enable_binfmt" != "xno"; then
 904         have_binfmt=yes
 905 fi
 906 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 907
 908 # ------------------------------------------------------------------------------
 909 have_vconsole=no
 910 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 911 if test "x$enable_vconsole" != "xno"; then
 912         have_vconsole=yes
 913 fi
 914 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 915
 916 # ------------------------------------------------------------------------------
 917 have_bootchart=no
 918 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 919 if test "x$enable_bootchart" != "xno"; then
 920         have_bootchart=yes
 921 fi
 922 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 923
 924 # ------------------------------------------------------------------------------
 925 have_quotacheck=no
 926 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 927 if test "x$enable_quotacheck" != "xno"; then
 928         have_quotacheck=yes
 929 fi
 930 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 931
 932 # ------------------------------------------------------------------------------
 933 have_tmpfiles=no
 934 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 935 if test "x$enable_tmpfiles" != "xno"; then
 936         have_tmpfiles=yes
 937 fi
 938 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 939
 940 # ------------------------------------------------------------------------------
 941 have_sysusers=no
 942 AC_ARG_ENABLE(sysusers, AS_HELP_STRING([--disable-sysusers], [disable sysusers support]))
 943 if test "x$enable_sysusers" != "xno"; then
 944         have_sysusers=yes
 945 fi
 946 AM_CONDITIONAL(ENABLE_SYSUSERS, [test "$have_sysusers" = "yes"])
 947
 948 # ------------------------------------------------------------------------------
 949 have_firstboot=no
 950 AC_ARG_ENABLE(firstboot, AS_HELP_STRING([--disable-firstboot], [disable firstboot support]))
 951 if test "x$enable_firstboot" != "xno"; then
 952         have_firstboot=yes
 953 fi
 954 AM_CONDITIONAL(ENABLE_FIRSTBOOT, [test "$have_firstboot" = "yes"])
 955
 956 # ------------------------------------------------------------------------------
 957 have_randomseed=no
 958 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 959 if test "x$enable_randomseed" != "xno"; then
 960         have_randomseed=yes
 961 fi
 962 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 963
 964 # ------------------------------------------------------------------------------
 965 have_backlight=no
 966 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
 967 if test "x$enable_backlight" != "xno"; then
 968         have_backlight=yes
 969 fi
 970 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
 971
 972 # ------------------------------------------------------------------------------
 973 have_rfkill=no
 974 AC_ARG_ENABLE(rfkill, AS_HELP_STRING([--disable-rfkill], [disable rfkill tools]))
 975 if test "x$enable_rfkill" != "xno"; then
 976         have_rfkill=yes
 977 fi
 978 AM_CONDITIONAL(ENABLE_RFKILL, [test "$have_rfkill" = "yes"])
 979
 980 # ------------------------------------------------------------------------------
 981 have_logind=no
 982 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 983 if test "x$enable_logind" != "xno"; then
 984         have_logind=yes
 985 fi
 986 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 987 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 988
 989 # ------------------------------------------------------------------------------
 990 have_machined=no
 991 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
 992 if test "x$enable_machined" != "xno"; then
 993         have_machined=yes
 994 fi
 995 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
 996 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
 997
 998 # ------------------------------------------------------------------------------
 999 have_hostnamed=no
1000 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
1001 if test "x$enable_hostnamed" != "xno"; then
1002         have_hostnamed=yes
1003 fi
1004 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
1005
1006 # ------------------------------------------------------------------------------
1007 have_timedated=no
1008 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
1009 if test "x$enable_timedated" != "xno"; then
1010         have_timedated=yes
1011 fi
1012 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
1013
1014 # ------------------------------------------------------------------------------
1015 have_timesyncd=no
1016 AC_ARG_ENABLE(timesyncd, AS_HELP_STRING([--disable-timesyncd], [disable timesync daemon]))
1017 if test "x$enable_timesyncd" != "xno"; then
1018         have_timesyncd=yes
1019         M4_DEFINES="$M4_DEFINES -DENABLE_TIMESYNCD"
1020 fi
1021 AM_CONDITIONAL(ENABLE_TIMESYNCD, [test "$have_timesyncd" = "yes"])
1022
1023 AC_ARG_WITH(ntp-servers,
1024         AS_HELP_STRING([--with-ntp-servers=NTPSERVERS],
1025                 [Space-separated list of default NTP servers]),
1026         [NTP_SERVERS="$withval"],
1027         [NTP_SERVERS="time1.google.com time2.google.com time3.google.com time4.google.com"])
1028
1029 AC_DEFINE_UNQUOTED(NTP_SERVERS, ["$NTP_SERVERS"], [Default NTP Servers])
1030 AC_SUBST(NTP_SERVERS)
1031
1032 AC_ARG_WITH(time-epoch,
1033         AS_HELP_STRING([--with-time-epoch=SECONDS],
1034                 [Time epoch for time clients]),
1035         [TIME_EPOCH="$withval"],
1036         [TIME_EPOCH="`stat -c %Y ${srcdir}/NEWS 2>/dev/null || echo 0`"])
1037
1038 AC_DEFINE_UNQUOTED(TIME_EPOCH, [$TIME_EPOCH], [Time Epoch])
1039
1040 # ------------------------------------------------------------------------------
1041 AC_ARG_WITH(system-uid-max,
1042         AS_HELP_STRING([--with-system-uid-max=UID]
1043                 [Maximum UID for system users]),
1044         [SYSTEM_UID_MAX="$withval"],
1045         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
1046
1047 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
1048 AC_SUBST(SYSTEM_UID_MAX)
1049
1050 # ------------------------------------------------------------------------------
1051 AC_ARG_WITH(system-gid-max,
1052         AS_HELP_STRING([--with-system-gid-max=GID]
1053                 [Maximum GID for system groups]),
1054         [SYSTEM_GID_MAX="$withval"],
1055         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
1056
1057 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
1058 AC_SUBST(SYSTEM_GID_MAX)
1059
1060 # ------------------------------------------------------------------------------
1061 have_localed=no
1062 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
1063 if test "x$enable_localed" != "xno"; then
1064         have_localed=yes
1065 fi
1066 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
1067
1068 # ------------------------------------------------------------------------------
1069 have_coredump=no
1070 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
1071 if test "x$enable_coredump" != "xno"; then
1072         have_coredump=yes
1073 fi
1074 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
1075
1076 # ------------------------------------------------------------------------------
1077 have_polkit=no
1078 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
1079 if test "x$enable_polkit" != "xno"; then
1080         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
1081         have_polkit=yes
1082 fi
1083 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
1084
1085 # ------------------------------------------------------------------------------
1086 have_resolved=no
1087 AC_ARG_ENABLE(resolved, AS_HELP_STRING([--disable-resolved], [disable resolve daemon]))
1088 if test "x$enable_resolved" != "xno"; then
1089         have_resolved=yes
1090         M4_DEFINES="$M4_DEFINES -DENABLE_RESOLVED"
1091 fi
1092 AM_CONDITIONAL(ENABLE_RESOLVED, [test "$have_resolved" = "yes"])
1093
1094 AC_ARG_WITH(dns-servers,
1095         AS_HELP_STRING([--with-dns-servers=DNSSERVERS],
1096                 [Space-separated list of default DNS servers]),
1097         [DNS_SERVERS="$withval"],
1098         [DNS_SERVERS="8.8.8.8 8.8.4.4 2001:4860:4860::8888 2001:4860:4860::8844"])
1099
1100 AC_DEFINE_UNQUOTED(DNS_SERVERS, ["$DNS_SERVERS"], [Default DNS Servers])
1101 AC_SUBST(DNS_SERVERS)
1102
1103 # ------------------------------------------------------------------------------
1104 have_networkd=no
1105 AC_ARG_ENABLE(networkd, AS_HELP_STRING([--disable-networkd], [disable networkd]))
1106 AS_IF([test "x$enable_networkd" != "xno"], [
1107         AC_DEFINE(ENABLE_NETWORKD, 1, [Define if networkd support is to be enabled])
1108         have_networkd=yes
1109         M4_DEFINES="$M4_DEFINES -DENABLE_NETWORKD"
1110 ])
1111 AM_CONDITIONAL(ENABLE_NETWORKD, [test "x$have_networkd" = "xyes"])
1112
1113 # ------------------------------------------------------------------------------
1114 have_efi=no
1115 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
1116 if test "x$enable_efi" != "xno"; then
1117         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
1118         have_efi=yes
1119 fi
1120 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
1121
1122 # ------------------------------------------------------------------------------
1123 have_terminal=no
1124 AC_ARG_ENABLE(terminal, AS_HELP_STRING([--enable-terminal], [enable terminal support]))
1125 if test "x$enable_terminal" = "xyes"; then
1126         PKG_CHECK_MODULES([TERMINAL], [ libevdev >= 1.2 xkbcommon >= 0.5 libdrm >= 2.4], [have_terminal=yes])
1127         AS_IF([test "x$have_terminal" != xyes -a "x$enable_terminal" = xyes],
1128               [AC_MSG_ERROR([*** terminal support requested but required dependencies not available])],
1129               [test "x$have_terminal" = xyes],
1130               [AC_DEFINE(ENABLE_TERMINAL, 1, [Define if terminal support is to be enabled])])
1131 fi
1132 AM_CONDITIONAL(ENABLE_TERMINAL, [test "x$have_terminal" = "xyes"])
1133
1134 # ------------------------------------------------------------------------------
1135 have_kdbus=no
1136 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--enable-kdbus], [do connect to kdbus by default]))
1137 if test "x$enable_kdbus" = "xyes"; then
1138         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus support is to be enabled])
1139         have_kdbus=yes
1140         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
1141 fi
1142 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
1143
1144 # ------------------------------------------------------------------------------
1145 AC_ARG_WITH(rc-local-script-path-start,
1146         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
1147                 [Path to /etc/rc.local]),
1148         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
1149         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
1150
1151 AC_ARG_WITH(rc-local-script-path-stop,
1152         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
1153                 [Path to /usr/sbin/halt.local]),
1154         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
1155         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
1156
1157 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
1158 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
1159
1160 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
1161 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
1162
1163 # ------------------------------------------------------------------------------
1164 AC_ARG_WITH(kbd-loadkeys,
1165         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
1166                 [Path to loadkeys]),
1167         [KBD_LOADKEYS="$withval"],
1168         [KBD_LOADKEYS="/usr/bin/loadkeys"])
1169
1170 AC_ARG_WITH(kbd-setfont,
1171         AS_HELP_STRING([--with-kbd-setfont=PATH],
1172                 [Path to setfont]),
1173         [KBD_SETFONT="$withval"],
1174         [KBD_SETFONT="/usr/bin/setfont"])
1175
1176 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
1177 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
1178
1179 AC_SUBST(KBD_LOADKEYS)
1180 AC_SUBST(KBD_SETFONT)
1181
1182 AC_ARG_WITH(telinit,
1183         AS_HELP_STRING([--with-telinit=PATH],
1184                 [Path to telinit]),
1185         [TELINIT="$withval"],
1186         [TELINIT="/lib/sysvinit/telinit"])
1187
1188 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
1189
1190 AC_SUBST(TELINIT)
1191
1192 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
1193
1194 # ------------------------------------------------------------------------------
1195 have_myhostname=no
1196 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
1197 if test "x$enable_myhostname" != "xno"; then
1198         AC_HEADER_STDC
1199         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
1200
1201         AC_C_CONST
1202         AC_TYPE_SIZE_T
1203         AC_HEADER_TIME
1204
1205         AC_FUNC_MALLOC
1206         AC_FUNC_SELECT_ARGTYPES
1207         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
1208
1209         have_myhostname=yes
1210 fi
1211 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
1212
1213 # ------------------------------------------------------------------------------
1214 AC_ARG_ENABLE([gudev],
1215        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
1216        [], [enable_gudev=yes])
1217 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
1218 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
1219 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
1220
1221 # ------------------------------------------------------------------------------
1222 AC_ARG_ENABLE(hwdb, [AC_HELP_STRING([--disable-hwdb], [disable hardware database support])],
1223        enable_hwdb=$enableval, enable_hwdb=yes)
1224 AM_CONDITIONAL(ENABLE_HWDB, [test x$enable_hwdb = xyes])
1225
1226 # ------------------------------------------------------------------------------
1227 have_manpages=no
1228 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
1229 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
1230 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
1231
1232 # ------------------------------------------------------------------------------
1233 AC_ARG_ENABLE(hibernate,
1234        [AC_HELP_STRING([--disable-hibernate], [disable hibernation support])],
1235        enable_hibernate=$enableval, enable_hibernate=yes)
1236 AM_CONDITIONAL(ENABLE_HIBERNATE, [test x$enable_hibernate = xyes])
1237
1238 # ------------------------------------------------------------------------------
1239 AC_ARG_ENABLE(ldconfig,
1240        [AC_HELP_STRING([--disable-ldconfig], [disable ldconfig])],
1241        enable_ldconfig=$enableval, enable_ldconfig=yes)
1242 AM_CONDITIONAL(ENABLE_LDCONFIG, [test x$enable_ldconfig = xyes])
1243
1244 # ------------------------------------------------------------------------------
1245 # Location of the init scripts as mandated by LSB
1246 SYSTEM_SYSVINIT_PATH=/etc/init.d
1247 SYSTEM_SYSVRCND_PATH=/etc/rc.d
1248
1249 AC_ARG_WITH([sysvinit-path],
1250         [AS_HELP_STRING([--with-sysvinit-path=PATH],
1251                 [Specify the path to where the SysV init scripts are located])],
1252         [SYSTEM_SYSVINIT_PATH="$withval"],
1253         [])
1254
1255 AC_ARG_WITH([sysvrcnd-path],
1256         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
1257                 [Specify the path to the base directory for the SysV rcN.d directories])],
1258         [SYSTEM_SYSVRCND_PATH="$withval"],
1259         [])
1260
1261 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1262         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
1263         SYSTEM_SYSV_COMPAT="yes"
1264         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
1265 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1266         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
1267 else
1268         SYSTEM_SYSV_COMPAT="no"
1269 fi
1270
1271 AC_SUBST(SYSTEM_SYSVINIT_PATH)
1272 AC_SUBST(SYSTEM_SYSVRCND_PATH)
1273 AC_SUBST(M4_DEFINES)
1274
1275 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
1276
1277 AC_ARG_WITH([tty-gid],
1278         [AS_HELP_STRING([--with-tty-gid=GID],
1279                 [Specify the numeric GID of the 'tty' group])],
1280         [TTY_GID="$withval"],
1281         [TTY_GID="5"])
1282
1283 AC_DEFINE_UNQUOTED(TTY_GID, [$TTY_GID], [GID of the 'tty' group])
1284 AC_SUBST(TTY_GID)
1285
1286 AC_ARG_WITH([dbuspolicydir],
1287         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
1288         [],
1289         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
1290
1291 AC_ARG_WITH([dbussessionservicedir],
1292         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
1293         [],
1294         [with_dbussessionservicedir=${datadir}/dbus-1/services])
1295
1296 AC_ARG_WITH([dbussystemservicedir],
1297         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
1298         [],
1299         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
1300
1301 AC_ARG_WITH([bashcompletiondir],
1302         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
1303         [],
1304         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
1305                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
1306         ] , [
1307                 with_bashcompletiondir=${datadir}/bash-completion/completions
1308         ])])
1309
1310 AC_ARG_WITH([zshcompletiondir],
1311         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
1312         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
1313
1314 AC_ARG_WITH([rootprefix],
1315         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
1316         [], [with_rootprefix=${ac_default_prefix}])
1317
1318 AC_ARG_WITH([rootlibdir],
1319         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
1320         [],
1321         [with_rootlibdir=${libdir}])
1322
1323 AC_ARG_WITH([pamlibdir],
1324         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
1325         [],
1326         [with_pamlibdir=${with_rootlibdir}/security])
1327
1328 AC_ARG_WITH([pamconfdir],
1329         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
1330         [],
1331         [with_pamconfdir=${sysconfdir}/pam.d])
1332
1333 AC_ARG_ENABLE([split-usr],
1334         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
1335         [],
1336         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
1337                 enable_split_usr=yes
1338         ], [
1339                 enable_split_usr=no
1340         ])])
1341
1342 AC_ARG_WITH([dkr-index-url],
1343         [AS_HELP_STRING([--dkr-index-url=URL], [Specify the default index URL to use for image downloads])],
1344         [DEFAULT_DKR_INDEX_URL="\"$withval\""],
1345         [DEFAULT_DKR_INDEX_URL="NULL"])
1346
1347 AC_DEFINE_UNQUOTED(DEFAULT_DKR_INDEX_URL, [$DEFAULT_DKR_INDEX_URL], [Default index URL to use for image downloads])
1348 AC_SUBST(DEFAULT_DKR_INDEX_URL)
1349
1350 AS_IF([test "x${enable_split_usr}" = "xyes"], [
1351         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
1352 ])
1353
1354 # Work around intltoolize and gtk-doc problems in VPATH builds
1355 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
1356                                        [Define to do gtk-doc tests])
1357 AS_IF([test "x$0" != "x./configure"], [
1358         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
1359 ])
1360
1361 AC_ARG_ENABLE(tests,
1362         [AC_HELP_STRING([--disable-tests], [disable tests])],
1363         enable_tests=$enableval, enable_tests=yes)
1364 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
1365
1366 AC_ARG_ENABLE(debug,
1367         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
1368         [if test "x$enableval" = "xyes"; then
1369                 enableval="hashmap,mmap-cache"
1370         fi
1371         saved_ifs="$IFS"
1372         IFS="$IFS$PATH_SEPARATOR,"
1373         for name in $enableval; do
1374                 case $name in
1375                 hashmap)
1376                         enable_debug_hashmap=yes
1377                         ;;
1378                 mmap-cache)
1379                         enable_debug_mmap_cache=yes
1380                         ;;
1381                 esac
1382         done
1383         IFS="$saved_ifs"],[])
1384
1385 enable_debug=""
1386 AS_IF([test x$enable_debug_hashmap = xyes], [
1387         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
1388         enable_debug="hashmap $enable_debug"
1389 ])
1390 AS_IF([test x$enable_debug_mmap_cache = xyes], [
1391         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
1392         enable_debug="mmap-cache $enable_debug"
1393 ])
1394 test -z "$enable_debug" && enable_debug="none"
1395
1396 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1397 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1398 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1399 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1400 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1401 AC_SUBST([pamlibdir], [$with_pamlibdir])
1402 AC_SUBST([pamconfdir], [$with_pamconfdir])
1403 AC_SUBST([rootprefix], [$with_rootprefix])
1404 AC_SUBST([rootlibdir], [$with_rootlibdir])
1405
1406 AC_CONFIG_FILES([
1407         Makefile po/Makefile.in
1408         docs/libudev/Makefile
1409         docs/libudev/version.xml
1410         docs/gudev/Makefile
1411         docs/gudev/version.xml
1412 ])
1413
1414 AC_OUTPUT
1415 AC_MSG_RESULT([
1416         $PACKAGE_NAME $VERSION
1417
1418         libcryptsetup:           ${have_libcryptsetup}
1419         PAM:                     ${have_pam}
1420         AUDIT:                   ${have_audit}
1421         IMA:                     ${have_ima}
1422         AppArmor:                ${have_apparmor}
1423         SELinux:                 ${have_selinux}
1424         SECCOMP:                 ${have_seccomp}
1425         SMACK:                   ${have_smack}
1426         ZLIB:                    ${have_zlib}
1427         XZ:                      ${have_xz}
1428         LZ4:                     ${have_lz4}
1429         ACL:                     ${have_acl}
1430         GCRYPT:                  ${have_gcrypt}
1431         QRENCODE:                ${have_qrencode}
1432         MICROHTTPD:              ${have_microhttpd}
1433         CHKCONFIG:               ${have_chkconfig}
1434         GNUTLS:                  ${have_gnutls}
1435         libcurl:                 ${have_libcurl}
1436         libidn:                  ${have_libidn}
1437         libiptc:                 ${have_libiptc}
1438         ELFUTILS:                ${have_elfutils}
1439         binfmt:                  ${have_binfmt}
1440         vconsole:                ${have_vconsole}
1441         bootchart:               ${have_bootchart}
1442         quotacheck:              ${have_quotacheck}
1443         tmpfiles:                ${have_tmpfiles}
1444         sysusers:                ${have_sysusers}
1445         firstboot:               ${have_firstboot}
1446         randomseed:              ${have_randomseed}
1447         backlight:               ${have_backlight}
1448         rfkill:                  ${have_rfkill}
1449         logind:                  ${have_logind}
1450         machined:                ${have_machined}
1451         hostnamed:               ${have_hostnamed}
1452         timedated:               ${have_timedated}
1453         timesyncd:               ${have_timesyncd}
1454         default NTP servers:     ${NTP_SERVERS}
1455         time epoch:              ${TIME_EPOCH}
1456         localed:                 ${have_localed}
1457         networkd:                ${have_networkd}
1458         resolved:                ${have_resolved}
1459         default DNS servers:     ${DNS_SERVERS}
1460         coredump:                ${have_coredump}
1461         polkit:                  ${have_polkit}
1462         efi:                     ${have_efi}
1463         kmod:                    ${have_kmod}
1464         xkbcommon:               ${have_xkbcommon}
1465         blkid:                   ${have_blkid}
1466         libmount:                ${have_libmount}
1467         dbus:                    ${have_dbus}
1468         nss-myhostname:          ${have_myhostname}
1469         gudev:                   ${enable_gudev}
1470         hwdb:                    ${enable_hwdb}
1471         gintrospection:          ${enable_introspection}
1472         terminal:                ${have_terminal}
1473         kdbus:                   ${have_kdbus}
1474         Python:                  ${have_python}
1475         Python Headers:          ${have_python_devel}
1476         man pages:               ${have_manpages}
1477         gtk-doc:                 ${enable_gtk_doc}
1478         test coverage:           ${have_coverage}
1479         Split /usr:              ${enable_split_usr}
1480         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1481         compatibility libraries: ${have_compat_libs}
1482         utmp/wtmp support:       ${have_utmp}
1483         ldconfig support:        ${enable_ldconfig}
1484         hibernate support:       ${enable_hibernate}
1485         extra debugging:         ${enable_debug}
1486
1487         prefix:                  ${prefix}
1488         rootprefix:              ${with_rootprefix}
1489         sysconf dir:             ${sysconfdir}
1490         datarootdir:             ${datarootdir}
1491         includedir:              ${includedir}
1492         include_prefix:          ${INCLUDE_PREFIX}
1493         lib dir:                 ${libdir}
1494         rootlib dir:             ${with_rootlibdir}
1495         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1496         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1497         Build Python:            ${PYTHON}
1498         Installation Python:     ${PYTHON_BINARY}
1499         sphinx binary:           ${SPHINX_BUILD}
1500         PAM modules dir:         ${with_pamlibdir}
1501         PAM configuration dir:   ${with_pamconfdir}
1502         D-Bus policy dir:        ${with_dbuspolicydir}
1503         D-Bus session dir:       ${with_dbussessionservicedir}
1504         D-Bus system dir:        ${with_dbussystemservicedir}
1505         Bash completions dir:    ${with_bashcompletiondir}
1506         Zsh completions dir:     ${with_zshcompletiondir}
1507         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1508         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1509         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1510         TTY GID:                 ${TTY_GID}
1511         Maximum System UID:      ${SYSTEM_UID_MAX}
1512         Maximum System GID:      ${SYSTEM_GID_MAX}
1513         Certificate root:        ${CERTIFICATEROOT}
1514         Default dkr Index        ${DEFAULT_DKR_INDEX_URL}
1515
1516         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1517         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1518         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1519         PYTHON_CFLAGS:           ${PYTHON_DEVEL_CFLAGS}
1520         PYTHON_LIBS:             ${PYTHON_DEVEL_LIBS}
1521 ])