configure.ac

   1 #
   2 #  This file is part of elogind.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  elogind is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  elogind is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([elogind],
  23         [226.2],
  24         [https://github.com/elogind/elogind/issues],
  25         [elogind],
  26         [https://github.com/elogind/elogind])
  27
  28 AC_CONFIG_SRCDIR([src/login/logind.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41
  42 AC_PROG_CC_C99
  43
  44 AX_COMPILER_VENDOR
  45 AS_IF([test "x$ax_cv_c_compiler_vendor" = "xgnu"], [
  46       AC_CHECK_TOOLS([AR], [gcc-ar ar], [:])
  47       AC_CHECK_TOOLS([NM], [gcc-nm nm], [:])
  48       AC_CHECK_TOOLS([RANLIB], [gcc-ranlib ranlib], [:])
  49 ])
  50
  51 LT_PREREQ(2.2)
  52 LT_INIT([disable-static])
  53
  54 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by elogind])])
  55 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by elogind])])
  56
  57 SET_ARCH(X86_64, x86_64*)
  58 SET_ARCH(IA32, i*86*)
  59 SET_ARCH(MIPS, mips*)
  60 SET_ARCH(AARCH64, aarch64*)
  61
  62 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  63 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  64 AS_IF([test x"$intltool_found" != xyes],
  65       [AS_IF([test x"$enable_nls" = xyes],
  66              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  67              [AS_IF([test x"$enable_nls" != xno],
  68                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  69                      enable_nls=no])
  70              ])
  71       ])
  72
  73 AM_NLS
  74 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  75     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  76 IT_PROG_INTLTOOL([0.40.0])
  77 ])
  78
  79 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  80     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  81     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  82     AC_SUBST(INTLTOOL_POLICY_RULE)
  83 ])
  84
  85 GETTEXT_PACKAGE=elogind
  86 AC_SUBST(GETTEXT_PACKAGE)
  87 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [elogind])
  88
  89 AC_PROG_MKDIR_P
  90 AC_PROG_LN_S
  91 AC_PROG_SED
  92 AC_PROG_GREP
  93 AC_PROG_AWK
  94
  95 AC_PATH_PROG([M4], [m4])
  96 AC_PATH_PROG([XSLTPROC], [xsltproc])
  97
  98 AC_PATH_PROG([HALT], [halt], [halt])
  99 AC_PATH_PROG([REBOOT], [reboot], [reboot])
 100 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
 101
 102 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
 103
 104 M4_DEFINES=
 105
 106 AC_CHECK_TOOL(OBJCOPY, objcopy)
 107 AC_CHECK_TOOL(GPERF, gperf)
 108 if test -z "$GPERF" ; then
 109         AC_MSG_ERROR([*** gperf not found])
 110 fi
 111
 112
 113 # ------------------------------------------------------------------------------
 114 # Find running cgroup controller
 115 with_cgroupctrl=
 116 AS_IF(  [test -f /proc/self/cgroup],
 117         [with_cgroupctrl=`grep "^1:name=" /proc/self/cgroup | cut -d ':' -f 2`])
 118 AS_IF(  [test -z "$with_cgroupctrl"],
 119         [with_cgroupctrl="name=elogind"])
 120
 121
 122 # ------------------------------------------------------------------------------
 123 address_sanitizer_cflags=
 124 address_sanitizer_cppflags=
 125 address_sanitizer_ldflags=
 126 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 127 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 128             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 129             AS_IF([test -z "$with_as_cflags"],
 130                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 131             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 132             address_sanitizer_cppflags="-DVALGRIND=1"
 133             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 134       ])
 135
 136 undefined_sanitizer_cflags=
 137 undefined_sanitizer_cppflags=
 138 undefined_sanitizer_ldflags=
 139 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 140 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 141             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 142             AS_IF([test -z "$with_us_cflags"],
 143                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 144             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 145             undefined_sanitizer_cppflags="-DVALGRIND=1"
 146             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 147       ])
 148
 149 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 150 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 151 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 152
 153 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 154         -pipe \
 155         -Wall \
 156         -Wextra \
 157         -Wundef \
 158         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 159         -Wlogical-op \
 160         -Wmissing-include-dirs \
 161         -Wold-style-definition \
 162         -Wpointer-arith \
 163         -Winit-self \
 164         -Wdeclaration-after-statement \
 165         -Wfloat-equal \
 166         -Wsuggest-attribute=noreturn \
 167         -Werror=missing-prototypes \
 168         -Werror=implicit-function-declaration \
 169         -Werror=missing-declarations \
 170         -Werror=return-type \
 171         -Werror=shadow \
 172         -Wstrict-prototypes \
 173         -Wredundant-decls \
 174         -Wmissing-noreturn \
 175         -Wshadow \
 176         -Wendif-labels \
 177         -Wstrict-aliasing=2 \
 178         -Wwrite-strings \
 179         -Wno-unused-parameter \
 180         -Wno-missing-field-initializers \
 181         -Wno-unused-result \
 182         -Wno-format-signedness \
 183         -Werror=overflow \
 184         -Wdate-time \
 185         -Wnested-externs \
 186         -ffast-math \
 187         -fno-common \
 188         -fdiagnostics-show-option \
 189         -fno-strict-aliasing \
 190         -fvisibility=hidden \
 191         -fstack-protector \
 192         -fstack-protector-strong \
 193         -fPIE \
 194         --param=ssp-buffer-size=4])
 195
 196 AS_CASE([$CC], [*clang*],
 197         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 198                -Wno-typedef-redefinition \
 199                -Wno-gnu-variable-sized-type-not-at-end \
 200         ])])
 201
 202 dnl AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 203 dnl         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 204 dnl                -flto])],
 205 dnl         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 206 dnl AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 207
 208 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 209         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 210                -Wp,-D_FORTIFY_SOURCE=2])],
 211         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 212 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 213
 214 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 215         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 216                -Wl,--gc-sections])],
 217         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
 218 AC_SUBST([OUR_CFLAGS], "$with_ldflags $sanitizer_cflags")
 219
 220 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 221         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 222                -ffunction-sections -fdata-sections])],
 223         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
 224 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 225
 226 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 227         -Wl,--as-needed \
 228         -Wl,--no-undefined \
 229         -Wl,-z,relro \
 230         -Wl,-z,now \
 231         -pie \
 232         -Wl,-fuse-ld=gold])
 233 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 234
 235 AC_CHECK_SIZEOF(pid_t)
 236 AC_CHECK_SIZEOF(uid_t)
 237 AC_CHECK_SIZEOF(gid_t)
 238 AC_CHECK_SIZEOF(time_t)
 239 AC_CHECK_SIZEOF(dev_t)
 240 AC_CHECK_SIZEOF(rlim_t,,[
 241        #include <sys/time.h>
 242        #include <sys/resource.h>
 243 ])
 244
 245 GPERF_TEST="$(echo foo,bar | ${GPERF} -L ANSI-C)"
 246 save_CFLAGS="$CFLAGS"
 247 CFLAGS="$CFLAGS -Wno-error"
 248 AC_COMPILE_IFELSE(
 249         [AC_LANG_PROGRAM([
 250                 #include <string.h>
 251                 const char * in_word_set(const char *, size_t);
 252                 $GPERF_TEST]
 253         )],
 254         [GPERF_LEN_TYPE=size_t],
 255         [AC_COMPILE_IFELSE(
 256                 [AC_LANG_PROGRAM([
 257                         #include <string.h>
 258                         const char * in_word_set(const char *, unsigned);
 259                         $GPERF_TEST]
 260                 )],
 261                 [GPERF_LEN_TYPE=unsigned],
 262                 [AC_MSG_ERROR([** unable to determine gperf len type])]
 263         )]
 264 )
 265 CFLAGS="$save_CFLAGS"
 266
 267 AC_DEFINE_UNQUOTED([GPERF_LEN_TYPE], [$GPERF_LEN_TYPE], [gperf len type])
 268
 269 # ------------------------------------------------------------------------------
 270 # we use python to build the man page index
 271 have_python=no
 272 AC_ARG_WITH([python],
 273         [AS_HELP_STRING([--without-python], [Disable building the man page index (default: test)])])
 274
 275 have_lxml=no
 276 AS_IF([test "x$with_python" != "xno"], [
 277         AM_PATH_PYTHON(,, [:])
 278         AS_IF([test "x$PYTHON" != "x:"], [
 279                 AC_MSG_CHECKING([for python lxml module])
 280                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
 281                 AC_MSG_RESULT([$have_lxml])
 282                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
 283                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
 284         ])
 285 ])
 286 AS_IF([test "$have_python" != "yes"], [
 287       AS_IF([test "$with_python" = "yes"],
 288             [AC_MSG_ERROR([*** python support requested but python support not found])])
 289       AS_IF([test "$with_python" != "no"],
 290             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
 291 ])
 292
 293 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 294
 295 # ------------------------------------------------------------------------------
 296
 297 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 298 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 299 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 300
 301 AC_CHECK_HEADERS([printf.h], [have_printf_h=yes], [have_printf_h=no])
 302 AS_IF([test x$have_printf_h = xyes], [
 303         AC_DEFINE(HAVE_PRINTF_H, 1, [Define if printf.h was found])
 304 ])
 305
 306
 307
 308 # unconditionally pull-in librt with old glibc versions
 309 dnl AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 310 dnl AC_SEARCH_LIBS([mq_unlink], [rt], [], [])
 311
 312 AC_ARG_WITH([libcap],
 313             AS_HELP_STRING([--with-libcap=DIR], [Prefix for libcap]),
 314             [CAP_LDFLAGS="-L$with_libcap/lib"],
 315             [CAP_LDFLAGS=""])
 316 save_LIBS="$LIBS"
 317 save_LDFLAGS="$LDFLAGS"
 318 LIBS=
 319 LDFLAGS="$LDFLAGS $CAP_LDFLAGS"
 320 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 321 CAP_LIBS="$LIBS"
 322 AC_SUBST(CAP_LIBS)
 323 AC_SUBST(CAP_LDFLAGS)
 324 LIBS="$save_LIBS"
 325 LDFLAGS="$save_LDFLAGS"
 326
 327 AC_CHECK_FUNCS([memfd_create])
 328 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 329 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns, getrandom, renameat2, kcmp, LO_FLAGS_PARTSCAN],
 330                [], [], [[
 331 #include <sys/types.h>
 332 #include <unistd.h>
 333 #include <sys/mount.h>
 334 #include <fcntl.h>
 335 #include <sched.h>
 336 #include <linux/loop.h>
 337 #include <linux/random.h>
 338 ]])
 339
 340 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 341                 IFLA_MACVLAN_FLAGS,
 342                 IFLA_IPVLAN_MODE,
 343                 IFLA_VTI_REMOTE,
 344                 IFLA_PHYS_PORT_ID,
 345                 IFLA_BOND_AD_INFO,
 346                 IFLA_VLAN_PROTOCOL,
 347                 IFLA_VXLAN_REMCSUM_NOPARTIAL,
 348                 IFLA_VXLAN_LOCAL6,
 349                 IFLA_IPTUN_ENCAP_DPORT,
 350                 IFLA_GRE_ENCAP_DPORT,
 351                 IFLA_BRIDGE_VLAN_INFO,
 352                 IFLA_BRPORT_LEARNING_SYNC,
 353                 NDA_IFINDEX,
 354                 IFA_FLAGS],
 355 [], [], [[
 356 #include <inttypes.h>
 357 #include <netinet/in.h>
 358 #include <netinet/ether.h>
 359 #include <linux/rtnetlink.h>
 360 #include <net/if.h>
 361 #include <linux/ip.h>
 362 #include <linux/if_tunnel.h>
 363 #include <linux/if_link.h>
 364 #include <linux/if_bridge.h>
 365 #include <linux/if_addr.h>
 366 #include <linux/neighbour.h>
 367 ]])
 368
 369 # This makes sure pkg.m4 is available.
 370 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 371
 372
 373 # ------------------------------------------------------------------------------
 374 PKG_CHECK_MODULES(UDEV, [libudev])
 375 dnl
 376 AC_ARG_WITH([udevrulesdir],
 377             AS_HELP_STRING([--with-udevrulesdir=DIR], [Directory for udev rules files]),
 378             [],
 379             [with_udevrulesdir=$($PKG_CONFIG --variable=udevdir udev)/rules.d])
 380 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 381
 382 AC_ARG_WITH([udevbindir],
 383             AS_HELP_STRING([--with-udevbindir=DIR], [Directory for udev binary files]),
 384             [],
 385             [with_udevbindir=$($PKG_CONFIG --variable=udevdir udev)])
 386 AC_SUBST([udevbindir], [$with_udevbindir])
 387
 388 # ------------------------------------------------------------------------------
 389 have_coverage=no
 390 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 391 if test "x$enable_coverage" = "xyes" ; then
 392         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 393         if test "x$lcov_found" = xno ; then
 394                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 395         else
 396                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 397                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 398                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 399                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 400                 else
 401                         have_coverage=yes
 402                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 403                         -fprofile-arcs \
 404                         -ftest-coverage])
 405                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 406                 fi
 407         fi
 408 fi
 409 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 410
 411 # ------------------------------------------------------------------------------
 412 have_selinux=no
 413 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 414 if test "x$enable_selinux" != "xno"; then
 415         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 416                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 417                  have_selinux=yes
 418                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 419                 [have_selinux=no])
 420         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 421                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 422         fi
 423 fi
 424 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 425
 426 # ------------------------------------------------------------------------------
 427 AC_ARG_ENABLE([pam],
 428         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 429                 [case "${enableval}" in
 430                         yes) have_pam=yes ;;
 431                         no) have_pam=no ;;
 432                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 433                 esac],
 434                 [have_pam=auto])
 435
 436 if test "x${have_pam}" != xno ; then
 437         AC_CHECK_HEADERS(
 438                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 439                 [have_pam=yes],
 440                 [if test "x$have_pam" = xyes ; then
 441                         AC_MSG_ERROR([*** PAM headers not found.])
 442                 fi])
 443
 444         AC_CHECK_LIB(
 445                 [pam],
 446                 [pam_syslog],
 447                 [have_pam=yes],
 448                 [if test "x$have_pam" = xyes ; then
 449                         AC_MSG_ERROR([*** libpam not found.])
 450                 fi])
 451
 452         if test "x$have_pam" = xyes ; then
 453                 PAM_LIBS="-lpam -lpam_misc"
 454                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 455                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 456         else
 457                 have_pam=no
 458         fi
 459 else
 460         PAM_LIBS=
 461 fi
 462 AC_SUBST(PAM_LIBS)
 463 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 464
 465 # ------------------------------------------------------------------------------
 466 AC_ARG_ENABLE([acl],
 467         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 468                 [case "${enableval}" in
 469                         yes) have_acl=yes ;;
 470                         no) have_acl=no ;;
 471                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 472                 esac],
 473                 [have_acl=auto])
 474
 475 if test "x${have_acl}" != xno ; then
 476         AC_CHECK_HEADERS(
 477                 [sys/acl.h acl/libacl.h],
 478                 [have_acl=yes],
 479                 [if test "x$have_acl" = xyes ; then
 480                         AC_MSG_ERROR([*** ACL headers not found.])
 481                 fi])
 482
 483         AC_CHECK_LIB(
 484                 [acl],
 485                 [acl_get_file],
 486                 [have_acl=yes],
 487                 [if test "x$have_acl" = xyes ; then
 488                         AC_MSG_ERROR([*** libacl not found.])
 489                 fi])
 490
 491         if test "x$have_acl" = xyes ; then
 492                 ACL_LIBS="-lacl"
 493                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 494                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 495         else
 496                 have_acl=no
 497         fi
 498 else
 499         ACL_LIBS=
 500 fi
 501 AC_SUBST(ACL_LIBS)
 502 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 503
 504 # ------------------------------------------------------------------------------
 505 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 506                 [case "${enableval}" in
 507                         yes) have_smack=yes ;;
 508                         no) have_smack=no ;;
 509                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 510                 esac],
 511                 [have_smack=auto])
 512
 513 if test "x${have_smack}" = xauto; then
 514         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 515         have_smack=yes
 516 fi
 517
 518 AC_ARG_WITH(smack-run-label,
 519 AS_HELP_STRING([--with-smack-run-label=STRING],
 520         [run elogind --system itself with a specific SMACK label]),
 521         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run elogind itself with SMACK label])],
 522         [])
 523
 524 AC_ARG_WITH(smack-default-process-label,
 525 AS_HELP_STRING([--with-smack-default-process-label=STRING],
 526         [default SMACK label for executed processes]),
 527         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
 528         [])
 529
 530 if test "x${have_smack}" = xyes ; then
 531         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 532 fi
 533
 534 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 535
 536 # ------------------------------------------------------------------------------
 537 AC_ARG_WITH(system-uid-max,
 538         AS_HELP_STRING([--with-system-uid-max=UID]
 539                 [Maximum UID for system users]),
 540         [SYSTEM_UID_MAX="$withval"],
 541         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
 542
 543 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
 544 AC_SUBST(SYSTEM_UID_MAX)
 545
 546 # ------------------------------------------------------------------------------
 547 AC_ARG_WITH(system-gid-max,
 548         AS_HELP_STRING([--with-system-gid-max=GID]
 549                 [Maximum GID for system groups]),
 550         [SYSTEM_GID_MAX="$withval"],
 551         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
 552
 553 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
 554 AC_SUBST(SYSTEM_GID_MAX)
 555
 556 # ------------------------------------------------------------------------------
 557 have_polkit=no
 558 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 559 if test "x$enable_polkit" != "xno"; then
 560         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 561         have_polkit=yes
 562 fi
 563 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 564
 565 # ------------------------------------------------------------------------------
 566 have_kdbus=no
 567 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--disable-kdbus], [do not connect to kdbus by default]))
 568 if test "x$enable_kdbus" != "xno"; then
 569         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus is to be connected to by default])
 570         have_kdbus=yes
 571         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
 572 fi
 573 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
 574
 575 # ------------------------------------------------------------------------------
 576 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
 577
 578 # ------------------------------------------------------------------------------
 579 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0],
 580                   [have_glib=yes], [have_glib=no])
 581 AS_IF([test "x$have_glib" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 582
 583 # ------------------------------------------------------------------------------
 584 have_manpages=no
 585 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 586 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
 587 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 588
 589 # ------------------------------------------------------------------------------
 590 AC_SUBST(M4_DEFINES)
 591
 592 AC_ARG_WITH([dbuspolicydir],
 593         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 594         [],
 595         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
 596 AX_NORMALIZE_PATH([with_dbuspolicydir])
 597
 598 AC_ARG_WITH([dbussystemservicedir],
 599         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 600         [],
 601         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
 602 AX_NORMALIZE_PATH([with_dbussystemservicedir])
 603
 604 AC_ARG_WITH([bashcompletiondir],
 605         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 606         [],
 607         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 608                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 609         ] , [
 610                 with_bashcompletiondir=${datadir}/bash-completion/completions
 611         ])])
 612 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, [test "$with_bashcompletiondir" != "no"])
 613 AX_NORMALIZE_PATH([with_bashcompletiondir])
 614
 615 AC_ARG_WITH([zshcompletiondir],
 616         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
 617         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
 618 AM_CONDITIONAL(ENABLE_ZSH_COMPLETION, [test "$with_zshcompletiondir" != "no"])
 619 AX_NORMALIZE_PATH([with_zshcompletiondir])
 620
 621 AC_ARG_WITH([rootprefix],
 622         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 623         [], [with_rootprefix=${ac_default_prefix}])
 624 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
 625 # defaults those to ".", solve that here for now until we can find a suitable
 626 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
 627 # See: https://github.com/systemd/systemd/issues/54
 628 if test "x${with_rootprefix}" = "x"; then
 629         with_rootprefix="/"
 630 fi
 631 AX_NORMALIZE_PATH([with_rootprefix])
 632
 633 AC_ARG_WITH([rootlibdir],
 634         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 635         [],
 636         [with_rootlibdir=${libdir}])
 637 AX_NORMALIZE_PATH([with_rootlibdir])
 638
 639 AC_ARG_WITH([pamlibdir],
 640         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 641         [],
 642         [with_pamlibdir=${with_rootlibdir}/security])
 643 AX_NORMALIZE_PATH([with_pamlibdir])
 644
 645 AC_ARG_WITH([pamconfdir],
 646         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
 647         [],
 648         [with_pamconfdir=${sysconfdir}/pam.d])
 649 AX_NORMALIZE_PATH([with_pamconfdir])
 650
 651 AC_ARG_ENABLE([split-usr],
 652         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 653         [],
 654         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 655                 enable_split_usr=yes
 656         ], [
 657                 enable_split_usr=no
 658         ])])
 659
 660 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 661         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 662 ])
 663 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
 664
 665 # work around intltool-update issues during 'make distcheck'
 666 AS_IF([test "x$0" != "x./configure"], [
 667         AC_SUBST([INTLTOOL_UPDATE], [/usr/bin/env true])
 668 ])
 669
 670 AC_ARG_ENABLE(tests,
 671         [AC_HELP_STRING([--disable-tests], [disable tests])],
 672         enable_tests=$enableval, enable_tests=yes)
 673 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 674
 675 AC_ARG_ENABLE(debug,
 676         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (elogind,hashmap,mmap-cache)])],
 677         [if test "x$enableval" = "xyes"; then
 678                 enableval="elogind,hashmap,mmap-cache"
 679         fi
 680         saved_ifs="$IFS"
 681         IFS="$IFS$PATH_SEPARATOR,"
 682         for name in $enableval; do
 683                 case $name in
 684                 elogind)
 685                         enable_debug_elogind=yes
 686                         ;;
 687                 hashmap)
 688                         enable_debug_hashmap=yes
 689                         ;;
 690                 mmap-cache)
 691                         enable_debug_mmap_cache=yes
 692                         ;;
 693                 esac
 694         done
 695         IFS="$saved_ifs"],[])
 696
 697 enable_debug=""
 698 AS_IF([test x$enable_debug_elogind = xyes], [
 699         AC_DEFINE(ENABLE_DEBUG_ELOGIND, 1, [Define if elogind debugging is to be enabled])
 700         enable_debug="elogind $enable_debug"
 701 ])
 702 AS_IF([test x$enable_debug_hashmap = xyes], [
 703         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
 704         enable_debug="hashmap $enable_debug"
 705 ])
 706 AS_IF([test x$enable_debug_mmap_cache = xyes], [
 707         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
 708         enable_debug="mmap-cache $enable_debug"
 709 ])
 710 test -z "$enable_debug" && enable_debug="none"
 711
 712 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 713 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 714 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 715 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
 716 AC_SUBST([pamlibdir], [$with_pamlibdir])
 717 AC_SUBST([pamconfdir], [$with_pamconfdir])
 718 AC_SUBST([rootprefix], [$with_rootprefix])
 719 AC_SUBST([rootlibdir], [$with_rootlibdir])
 720 AC_SUBST([cgroup_controller], [$with_cgroupctrl])
 721
 722 AC_CONFIG_FILES([
 723         Makefile
 724         po/Makefile.in
 725 ])
 726
 727 AC_OUTPUT
 728 AC_MSG_RESULT([
 729         $PACKAGE_NAME $VERSION
 730
 731         PAM:                     ${have_pam}
 732         SELinux:                 ${have_selinux}
 733         SMACK:                   ${have_smack}
 734         ACL:                     ${have_acl}
 735         polkit:                  ${have_polkit}
 736         kdbus:                   ${have_kdbus}
 737         Python:                  ${have_python}
 738         man pages:               ${have_manpages}
 739         test coverage:           ${have_coverage}
 740         Split /usr:              ${enable_split_usr}
 741         extra debugging:         ${enable_debug}
 742         cgroup controller:       ${with_cgroupctrl}
 743
 744         prefix:                  ${prefix}
 745         rootprefix:              ${with_rootprefix}
 746         sysconf dir:             ${sysconfdir}
 747         datarootdir:             ${datarootdir}
 748         includedir:              ${includedir}
 749         lib dir:                 ${libdir}
 750         rootlib dir:             ${with_rootlibdir}
 751         PAM modules dir:         ${with_pamlibdir}
 752         PAM configuration dir:   ${with_pamconfdir}
 753         D-Bus policy dir:        ${with_dbuspolicydir}
 754         D-Bus system dir:        ${with_dbussystemservicedir}
 755         Bash completions dir:    ${with_bashcompletiondir}
 756         Zsh completions dir:     ${with_zshcompletiondir}
 757         Maximum System UID:      ${SYSTEM_UID_MAX}
 758         Maximum System GID:      ${SYSTEM_GID_MAX}
 759
 760         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 761         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
 762         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 763 ])