configure.ac

   1
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [189],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT
  46
  47 # i18n stuff for the PolicyKit policy files
  48 IT_PROG_INTLTOOL([0.40.0])
  49
  50 GETTEXT_PACKAGE=systemd
  51 AC_SUBST(GETTEXT_PACKAGE)
  52
  53 AC_PROG_MKDIR_P
  54 AC_PROG_LN_S
  55 AC_PROG_SED
  56 AC_PROG_GREP
  57 AC_PROG_AWK
  58
  59 AC_PROG_CC
  60 AC_PROG_CC_C99
  61 AM_PROG_CC_C_O
  62 AC_PROG_GCC_TRADITIONAL
  63
  64 AC_PATH_PROG([M4], [m4])
  65 AC_PATH_PROG([XSLTPROC], [xsltproc])
  66
  67 AC_PATH_PROG([QUOTAON], [quotaon], [/sbin/quotaon])
  68 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/sbin/quotacheck])
  69
  70 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  71 m4_ifdef([GTK_DOC_CHECK], [
  72 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])
  73 ], [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
  74
  75 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  76         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  77 ])
  78
  79 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  80 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  81 ], [AM_CONDITIONAL([HAVE_INTROSPECTION], [false])])
  82
  83 AC_CHECK_TOOL(OBJCOPY, objcopy)
  84 AC_CHECK_TOOL(STRINGS, strings)
  85 AC_CHECK_TOOL(GPERF, gperf)
  86 if test -z "$GPERF" ; then
  87         AC_MSG_ERROR([*** gperf not found])
  88 fi
  89
  90 # we use python only to build the man page index
  91 AM_PATH_PYTHON(,, [:])
  92 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  93
  94 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
  95         -pipe \
  96         -Wall \
  97         -Wextra \
  98         -Wno-inline \
  99         -Wundef \
 100         -Wformat=2 \
 101         -Wlogical-op \
 102         -Wsign-compare \
 103         -Wformat-security \
 104         -Wmissing-include-dirs \
 105         -Wformat-nonliteral \
 106         -Wold-style-definition \
 107         -Wpointer-arith \
 108         -Winit-self \
 109         -Wdeclaration-after-statement \
 110         -Wfloat-equal \
 111         -Wmissing-prototypes \
 112         -Wstrict-prototypes \
 113         -Wredundant-decls \
 114         -Wmissing-declarations \
 115         -Wmissing-noreturn \
 116         -Wshadow \
 117         -Wendif-labels \
 118         -Wcast-align \
 119         -Wstrict-aliasing=2 \
 120         -Wwrite-strings \
 121         -Wno-long-long \
 122         -Wno-overlength-strings \
 123         -Wno-unused-parameter \
 124         -Wno-missing-field-initializers \
 125         -Wno-unused-result \
 126         -Werror=overflow \
 127         -ffast-math \
 128         -fno-common \
 129         -fdiagnostics-show-option \
 130         -fno-strict-aliasing \
 131         -fvisibility=hidden \
 132         -ffunction-sections \
 133         -fdata-sections \
 134         -fstack-protector \
 135         --param=ssp-buffer-size=4])
 136 AC_SUBST([OUR_CFLAGS], $with_cflags)
 137
 138 CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 139         -Wp,-D_FORTIFY_SOURCE=2])
 140 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 141
 142 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 143         -Wl,--as-needed \
 144         -Wl,--gc-sections \
 145         -Wl,-z,relro \
 146         -Wl,-z,now])
 147 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 148
 149 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 150 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 151
 152 save_LIBS="$LIBS"
 153 LIBS=
 154 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 155 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 156 CAP_LIBS="$LIBS"
 157 LIBS="$save_LIBS"
 158 AC_SUBST(CAP_LIBS)
 159
 160 AC_CHECK_FUNCS([fanotify_init fanotify_mark name_to_handle_at])
 161 AC_CHECK_DECLS([gettid, pivot_root], [], [], [[#include <sys/types.h>
 162 #include <unistd.h>
 163 #include <sys/mount.h>]])
 164
 165 # This makes sure pkg.m4 is available.
 166 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 167
 168 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 169 PKG_CHECK_MODULES(KMOD, [libkmod >= 5])
 170 PKG_CHECK_MODULES(BLKID,[blkid >= 2.20])
 171
 172 # ------------------------------------------------------------------------------
 173 have_ima=yes
 174 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 175                 [case "${enableval}" in
 176                         yes) have_ima=yes ;;
 177                         no) have_ima=no ;;
 178                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 179                 esac],
 180                 [have_ima=yes])
 181
 182 if test "x${have_ima}" != xno ; then
 183         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 184 fi
 185
 186 # ------------------------------------------------------------------------------
 187 have_selinux=no
 188 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 189 if test "x$enable_selinux" != "xno"; then
 190         PKG_CHECK_MODULES(SELINUX, [ libselinux ],
 191                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 192         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 193                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 194         fi
 195 fi
 196 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 197 if test "x${have_selinux}" != xno ; then
 198         sushell=/sbin/sushell
 199 else
 200         sushell=/bin/bash
 201 fi
 202 AC_SUBST(sushell)
 203
 204 # ------------------------------------------------------------------------------
 205 have_xz=no
 206 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 207 if test "x$enable_xz" != "xno"; then
 208         PKG_CHECK_MODULES(XZ, [ liblzma ],
 209                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 210         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 211                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 212         fi
 213 fi
 214 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 215
 216 # ------------------------------------------------------------------------------
 217 AC_ARG_ENABLE([tcpwrap],
 218         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 219                 [case "${enableval}" in
 220                         yes) have_tcpwrap=yes ;;
 221                         no) have_tcpwrap=no ;;
 222                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 223                 esac],
 224                 [have_tcpwrap=auto])
 225
 226 if test "x${have_tcpwrap}" != xno ; then
 227         ACX_LIBWRAP
 228         if test "x${LIBWRAP_LIBS}" = x ; then
 229                 if test "x$have_tcpwrap" = xyes ; then
 230                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 231                 fi
 232                 have_tcpwrap=no
 233         else
 234                 have_tcpwrap=yes
 235         fi
 236 else
 237         LIBWRAP_LIBS=
 238 fi
 239 AC_SUBST(LIBWRAP_LIBS)
 240
 241 # ------------------------------------------------------------------------------
 242 AC_ARG_ENABLE([pam],
 243         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 244                 [case "${enableval}" in
 245                         yes) have_pam=yes ;;
 246                         no) have_pam=no ;;
 247                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 248                 esac],
 249                 [have_pam=auto])
 250
 251 if test "x${have_pam}" != xno ; then
 252         AC_CHECK_HEADERS(
 253                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 254                 [have_pam=yes],
 255                 [if test "x$have_pam" = xyes ; then
 256                         AC_MSG_ERROR([*** PAM headers not found.])
 257                 fi])
 258
 259         AC_CHECK_LIB(
 260                 [pam],
 261                 [pam_syslog],
 262                 [have_pam=yes],
 263                 [if test "x$have_pam" = xyes ; then
 264                         AC_MSG_ERROR([*** libpam not found.])
 265                 fi])
 266
 267         if test "x$have_pam" = xyes ; then
 268                 PAM_LIBS="-lpam -lpam_misc"
 269                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 270         else
 271                 have_pam=no
 272         fi
 273 else
 274         PAM_LIBS=
 275 fi
 276 AC_SUBST(PAM_LIBS)
 277 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 278
 279 # ------------------------------------------------------------------------------
 280 AC_ARG_ENABLE([acl],
 281         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 282                 [case "${enableval}" in
 283                         yes) have_acl=yes ;;
 284                         no) have_acl=no ;;
 285                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 286                 esac],
 287                 [have_acl=auto])
 288
 289 if test "x${have_acl}" != xno ; then
 290         AC_CHECK_HEADERS(
 291                 [sys/acl.h acl/libacl.h],
 292                 [have_acl=yes],
 293                 [if test "x$have_acl" = xyes ; then
 294                         AC_MSG_ERROR([*** ACL headers not found.])
 295                 fi])
 296
 297         AC_CHECK_LIB(
 298                 [acl],
 299                 [acl_get_file],
 300                 [have_acl=yes],
 301                 [if test "x$have_acl" = xyes ; then
 302                         AC_MSG_ERROR([*** libacl not found.])
 303                 fi])
 304
 305         if test "x$have_acl" = xyes ; then
 306                 ACL_LIBS="-lacl"
 307                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 308         else
 309                 have_acl=no
 310         fi
 311 else
 312         ACL_LIBS=
 313 fi
 314 AC_SUBST(ACL_LIBS)
 315 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 316
 317 # ------------------------------------------------------------------------------
 318 AC_ARG_ENABLE([gcrypt],
 319         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 320                 [case "${enableval}" in
 321                         yes) have_gcrypt=yes ;;
 322                         no) have_gcrypt=no ;;
 323                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 324                 esac],
 325                 [have_gcrypt=auto])
 326
 327 if test "x${have_gcrypt}" != xno ; then
 328         AM_PATH_LIBGCRYPT(
 329                 [1.4.5],
 330                 [have_gcrypt=yes],
 331                 [if test "x$have_gcrypt" = xyes ; then
 332                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 333                 fi])
 334
 335         if test "x$have_gcrypt" = xyes ; then
 336                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 337                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 338                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 339         else
 340                 have_gcrypt=no
 341         fi
 342 else
 343         GCRYPT_LIBS=
 344         GCRYPT_CFLAGS=
 345 fi
 346 AC_SUBST(GCRYPT_LIBS)
 347 AC_SUBST(GCRYPT_CFLAGS)
 348 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 349
 350 # ------------------------------------------------------------------------------
 351 AC_ARG_ENABLE([audit],
 352         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 353                 [case "${enableval}" in
 354                         yes) have_audit=yes ;;
 355                         no) have_audit=no ;;
 356                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 357                 esac],
 358                 [have_audit=auto])
 359
 360 if test "x${have_audit}" != xno ; then
 361         AC_CHECK_HEADERS(
 362                 [libaudit.h],
 363                 [have_audit=yes],
 364                 [if test "x$have_audit" = xyes ; then
 365                         AC_MSG_ERROR([*** AUDIT headers not found.])
 366                 fi])
 367
 368         AC_CHECK_LIB(
 369                 [audit],
 370                 [audit_open],
 371                 [have_audit=yes],
 372                 [if test "x$have_audit" = xyes ; then
 373                         AC_MSG_ERROR([*** libaudit not found.])
 374                 fi])
 375
 376         if test "x$have_audit" = xyes ; then
 377                 AUDIT_LIBS="-laudit"
 378                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 379         else
 380                 have_audit=no
 381         fi
 382 else
 383         AUDIT_LIBS=
 384 fi
 385 AC_SUBST(AUDIT_LIBS)
 386
 387 # ------------------------------------------------------------------------------
 388 have_libcryptsetup=no
 389 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 390 if test "x$enable_libcryptsetup" != "xno"; then
 391         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.4.2 ],
 392                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 393         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 394                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 395         fi
 396 fi
 397 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 398
 399 # ------------------------------------------------------------------------------
 400 have_qrencode=no
 401 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 402 if test "x$enable_qrencode" != "xno"; then
 403         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 404                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 405         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 406                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 407         fi
 408 fi
 409 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 410
 411 # ------------------------------------------------------------------------------
 412 have_binfmt=no
 413 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 414 if test "x$enable_binfmt" != "xno"; then
 415         have_binfmt=yes
 416 fi
 417 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 418
 419 # ------------------------------------------------------------------------------
 420 have_vconsole=no
 421 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 422 if test "x$enable_vconsole" != "xno"; then
 423         have_vconsole=yes
 424 fi
 425 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 426
 427 # ------------------------------------------------------------------------------
 428 have_readahead=no
 429 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 430 if test "x$enable_readahead" != "xno"; then
 431         have_readahead=yes
 432 fi
 433 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 434
 435 # ------------------------------------------------------------------------------
 436 have_quotacheck=no
 437 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 438 if test "x$enable_quotacheck" != "xno"; then
 439         have_quotacheck=yes
 440 fi
 441 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 442
 443 # ------------------------------------------------------------------------------
 444 have_randomseed=no
 445 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 446 if test "x$enable_randomseed" != "xno"; then
 447         have_randomseed=yes
 448 fi
 449 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 450
 451 # ------------------------------------------------------------------------------
 452 have_logind=no
 453 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 454 if test "x$enable_logind" != "xno"; then
 455         have_logind=yes
 456 fi
 457 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 458 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 459
 460 # ------------------------------------------------------------------------------
 461 have_hostnamed=no
 462 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 463 if test "x$enable_hostnamed" != "xno"; then
 464         have_hostnamed=yes
 465 fi
 466 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 467
 468 # ------------------------------------------------------------------------------
 469 have_timedated=no
 470 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 471 if test "x$enable_timedated" != "xno"; then
 472         have_timedated=yes
 473 fi
 474 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 475
 476 # ------------------------------------------------------------------------------
 477 have_localed=no
 478 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 479 if test "x$enable_localed" != "xno"; then
 480         have_localed=yes
 481 fi
 482 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 483
 484 # ------------------------------------------------------------------------------
 485 have_coredump=no
 486 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 487 if test "x$enable_coredump" != "xno"; then
 488         have_coredump=yes
 489 fi
 490 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 491
 492 # ------------------------------------------------------------------------------
 493 AC_ARG_WITH(usb-ids-path,
 494         [AS_HELP_STRING([--with-usb-ids-path=DIR], [Path to usb.ids file])],
 495         [USB_DATABASE=${withval}],
 496         [if test -n "$usbids" ; then
 497                 USB_DATABASE="$usbids"
 498         else
 499                 PKG_CHECK_MODULES(USBUTILS, usbutils >= 0.82)
 500                 AC_SUBST([USB_DATABASE], [$($PKG_CONFIG --variable=usbids usbutils)])
 501         fi])
 502 AC_MSG_CHECKING([for USB database location])
 503 AC_MSG_RESULT([$USB_DATABASE])
 504 AC_SUBST(USB_DATABASE)
 505
 506 AC_ARG_WITH(pci-ids-path,
 507         [AS_HELP_STRING([--with-pci-ids-path=DIR], [Path to pci.ids file])],
 508         [PCI_DATABASE=${withval}],
 509         [if test -n "$pciids" ; then
 510                 PCI_DATABASE="$pciids"
 511         else
 512                 PKG_CHECK_MODULES(LIBPCI, libpci >= 3)
 513                 AC_SUBST([PCI_DATABASE], [$($PKG_CONFIG --variable=idsdir libpci)/pci.ids])
 514         fi])
 515 AC_MSG_CHECKING([for PCI database location])
 516 AC_MSG_RESULT([$PCI_DATABASE])
 517 AC_SUBST(PCI_DATABASE)
 518
 519 # ------------------------------------------------------------------------------
 520 AC_ARG_WITH(firmware-path,
 521        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 522           [Firmware search path (default=ROOTPREFIX/lib/firmware/updates:ROOTPREFIX/lib/firmware)]),
 523        [], [with_firmware_path="$rootprefix/lib/firmware/updates:$rootprefix/lib/firmware"])
 524 OLD_IFS=$IFS
 525 IFS=:
 526 for i in $with_firmware_path; do
 527        if test "x${FIRMWARE_PATH}" = "x"; then
 528               FIRMWARE_PATH="\\\"${i}/\\\""
 529        else
 530               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 531        fi
 532 done
 533 IFS=$OLD_IFS
 534 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
 535
 536 # ------------------------------------------------------------------------------
 537 AC_ARG_ENABLE([gudev],
 538        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 539        [], [enable_gudev=yes])
 540 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0]) ])
 541 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 542
 543 # ------------------------------------------------------------------------------
 544 AC_ARG_ENABLE([keymap],
 545        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 546        [], [enable_keymap=yes])
 547 AS_IF([test "x$enable_keymap" = "xyes"], [
 548        AC_PATH_PROG([GPERF], [gperf])
 549        if test -z "$GPERF"; then
 550               AC_MSG_ERROR([gperf is needed])
 551        fi
 552
 553        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 554        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 555 ])
 556 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 557
 558 # ------------------------------------------------------------------------------
 559 have_manpages=no
 560 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 561 AS_IF([test "x$enable_manpages" != xno], [
 562         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 563                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 564         ])
 565         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 566 ])
 567 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 568
 569 # ------------------------------------------------------------------------------
 570
 571 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux, mandriva, mageia, angstrom or other]))
 572 if test "z$with_distro" = "z"; then
 573         if test "$cross_compiling" = yes; then
 574                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 575         else
 576                 with_distro=$($GREP '^ID=' /etc/os-release 2>/dev/null | $SED 's/ID=//');
 577         fi
 578         if test "z$with_distro" = "z"; then
 579                 with_distro=other
 580         fi
 581 fi
 582 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 583 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 584
 585 # Location of the init scripts as mandated by LSB
 586 SYSTEM_SYSVINIT_PATH=/etc/init.d
 587 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 588
 589 M4_DEFINES=
 590
 591 case $with_distro in
 592         fedora)
 593                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 594                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 595                 M4_DEFINES=-DTARGET_FEDORA=1
 596                 ;;
 597         opensuse|suse)
 598                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 599                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 600                 M4_DEFINES=-DTARGET_SUSE=1
 601                 ;;
 602         debian)
 603                 SYSTEM_SYSVRCND_PATH=/etc
 604                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 605                 M4_DEFINES=-DTARGET_DEBIAN=1
 606                 ;;
 607         ubuntu)
 608                 SYSTEM_SYSVRCND_PATH=/etc
 609                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 610                 M4_DEFINES=-DTARGET_UBUNTU=1
 611                 ;;
 612         arch)
 613                 SYSTEM_SYSVINIT_PATH=
 614                 SYSTEM_SYSVRCND_PATH=
 615                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 616                 M4_DEFINES=-DTARGET_ARCH=1
 617                 ;;
 618         gentoo)
 619                 SYSTEM_SYSVINIT_PATH=
 620                 SYSTEM_SYSVRCND_PATH=
 621                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 622                 M4_DEFINES=-DTARGET_GENTOO=1
 623                 ;;
 624         slackware)
 625                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 626                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 627                 M4_DEFINES=-DTARGET_SLACKWARE=1
 628                 ;;
 629         frugalware)
 630                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 631                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 632                 M4_DEFINES=-DTARGET_FRUGALWARE=1
 633                 ;;
 634         altlinux)
 635                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 636                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
 637                 M4_DEFINES=-DTARGET_ALTLINUX=1
 638                 ;;
 639         mandriva)
 640                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 641                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
 642                 M4_DEFINES=-DTARGET_MANDRIVA=1
 643                 ;;
 644         angstrom)
 645                 SYSTEM_SYSVRCND_PATH=/etc
 646                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
 647                 M4_DEFINES=-DTARGET_ANGSTROM=1
 648                 ;;
 649         mageia)
 650                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 651                 AC_DEFINE(TARGET_MAGEIA, [], [Target is Mageia])
 652                 M4_DEFINES=-DTARGET_MAGEIA=1
 653                 ;;
 654         other)
 655                 ;;
 656         *)
 657                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 658                 ;;
 659 esac
 660
 661 AC_ARG_WITH([sysvinit-path],
 662         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 663                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 664         [SYSTEM_SYSVINIT_PATH="$withval"],
 665         [])
 666
 667 AC_ARG_WITH([sysvrcd-path],
 668         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 669                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 670         [SYSTEM_SYSVRCND_PATH="$withval"],
 671         [])
 672
 673 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 674 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 675 AC_SUBST(M4_DEFINES)
 676
 677 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 678         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 679         SYSTEM_SYSV_COMPAT="yes"
 680         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 681 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 682         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 683 else
 684         SYSTEM_SYSV_COMPAT="no"
 685 fi
 686
 687 AC_ARG_WITH([tty-gid],
 688         [AS_HELP_STRING([--with-tty-gid=GID],
 689                 [Specify the numeric GID of the 'tty' group])],
 690         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 691         [])
 692
 693 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 694 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 695 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 696 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 697 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 698 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 699 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 700 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 701 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 702 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
 703 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 704 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
 705 AM_CONDITIONAL(TARGET_MAGEIA, test x"$with_distro" = xmageia)
 706
 707 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 708
 709 AC_ARG_WITH([dbuspolicydir],
 710         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 711         [],
 712         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 713
 714 AC_ARG_WITH([dbussessionservicedir],
 715         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 716         [],
 717         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 718
 719 AC_ARG_WITH([dbussystemservicedir],
 720         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 721         [],
 722         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 723
 724 AC_ARG_WITH([dbusinterfacedir],
 725         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 726         [],
 727         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 728
 729 AC_ARG_WITH([rootprefix],
 730         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 731         [], [with_rootprefix=${ac_default_prefix}])
 732
 733 AC_ARG_WITH([rootlibdir],
 734         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 735         [],
 736         [with_rootlibdir=${libdir}])
 737
 738 AC_ARG_WITH([pamlibdir],
 739         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 740         [],
 741         [with_pamlibdir=${with_rootlibdir}/security])
 742
 743 AC_ARG_ENABLE([split-usr],
 744         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 745         [],
 746         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 747                 enable_split_usr=yes
 748         ], [
 749                 enable_split_usr=no
 750         ])])
 751
 752 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 753         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 754 ])
 755
 756 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 757 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 758 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 759 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 760 AC_SUBST([pamlibdir], [$with_pamlibdir])
 761 AC_SUBST([rootprefix], [$with_rootprefix])
 762 AC_SUBST([rootlibdir], [$with_rootlibdir])
 763
 764 AC_CONFIG_FILES([
 765         Makefile po/Makefile.in
 766         docs/libudev/Makefile
 767         docs/libudev/version.xml
 768         docs/gudev/Makefile
 769         docs/gudev/version.xml
 770 ])
 771
 772 AC_OUTPUT
 773 AC_MSG_RESULT([
 774         $PACKAGE_NAME $VERSION
 775
 776         Distribution:            ${with_distro}
 777         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 778         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 779         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 780         libcryptsetup:           ${have_libcryptsetup}
 781         tcpwrap:                 ${have_tcpwrap}
 782         PAM:                     ${have_pam}
 783         AUDIT:                   ${have_audit}
 784         IMA:                     ${have_ima}
 785         SELinux:                 ${have_selinux}
 786         XZ:                      ${have_xz}
 787         ACL:                     ${have_acl}
 788         GCRYPT:                  ${have_gcrypt}
 789         QRENCODE:                ${have_qrencode}
 790         binfmt:                  ${have_binfmt}
 791         vconsole:                ${have_vconsole}
 792         readahead:               ${have_readahead}
 793         quotacheck:              ${have_quotacheck}
 794         randomseed:              ${have_randomseed}
 795         logind:                  ${have_logind}
 796         hostnamed:               ${have_hostnamed}
 797         timedated:               ${have_timedated}
 798         localed:                 ${have_localed}
 799         coredump:                ${have_coredump}
 800         firmware path:           ${FIRMWARE_PATH}
 801         usb.ids:                 ${USB_DATABASE}
 802         pci.ids:                 ${PCI_DATABASE}
 803         gudev:                   ${enable_gudev}
 804         gintrospection:          ${enable_introspection}
 805         keymap:                  ${enable_keymap}
 806
 807         prefix:                  ${prefix}
 808         rootprefix:              ${with_rootprefix}
 809         sysconf dir:             ${sysconfdir}
 810         datarootdir:             ${datarootdir}
 811         includedir:              ${includedir}
 812         include_prefix:          ${INCLUDE_PREFIX}
 813         lib dir:                 ${libdir}
 814         rootlib dir:             ${with_rootlibdir}
 815         PAM modules dir:         ${with_pamlibdir}
 816         D-Bus policy dir:        ${with_dbuspolicydir}
 817         D-Bus session dir:       ${with_dbussessionservicedir}
 818         D-Bus system dir:        ${with_dbussystemservicedir}
 819         D-Bus interfaces dir:    ${with_dbusinterfacedir}
 820         Split /usr:              ${enable_split_usr}
 821         man pages:               ${have_manpages}
 822         gtk-doc:                 ${enable_gtk_doc}
 823
 824         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 825         CPPLAGS:                 ${OUR_CPPFLAGS} ${CPPFLAGS}
 826         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 827 ])