chiark / gitweb /
unit: make sure deserialized_job's type is known
[elogind.git] / configure.ac
1 #  This file is part of systemd.
2 #
3 #  Copyright 2010 Lennart Poettering
4 #
5 #  systemd is free software; you can redistribute it and/or modify it
6 #  under the terms of the GNU General Public License as published by
7 #  the Free Software Foundation; either version 2 of the License, or
8 #  (at your option) any later version.
9 #
10 #  systemd is distributed in the hope that it will be useful, but
11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 #  General Public License for more details.
14 #
15 #  You should have received a copy of the GNU General Public License
16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
17
18 AC_PREREQ(2.63)
19
20 AC_INIT([systemd],[0],[systemd-devel@lists.freedesktop.org])
21 AC_CONFIG_SRCDIR([src/main.c])
22 AC_CONFIG_MACRO_DIR([m4])
23 AC_CONFIG_HEADERS([config.h])
24
25 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects])
26
27 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
28
29 AC_CANONICAL_HOST
30
31 AM_SILENT_RULES([yes])
32
33 AC_CHECK_PROG([STOW], [stow], [yes], [no])
34
35 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
36         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
37         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
38 ])
39
40 AC_PROG_MKDIR_P
41 AC_PROG_LN_S
42 AC_PROG_SED
43
44 AC_PROG_CC
45 AC_PROG_CC_C99
46 AM_PROG_CC_C_O
47 AC_PROG_GCC_TRADITIONAL
48 AC_USE_SYSTEM_EXTENSIONS
49
50 CC_CHECK_CFLAGS_APPEND([ \
51         -Wall \
52         -W \
53         -Wextra \
54         -pipe \
55         -Wno-long-long \
56         -Winline \
57         -Wvla \
58         -Wno-overlength-strings \
59         -Wundef \
60         -Wformat=2 \
61         -Wlogical-op \
62         -Wsign-compare \
63         -Wformat-security \
64         -Wmissing-include-dirs \
65         -Wformat-nonliteral \
66         -Wold-style-definition \
67         -Wpointer-arith \
68         -Winit-self \
69         -Wdeclaration-after-statement \
70         -Wfloat-equal \
71         -Wmissing-prototypes \
72         -Wstrict-prototypes \
73         -Wredundant-decls \
74         -Wmissing-declarations \
75         -Wmissing-noreturn \
76         -Wshadow \
77         -Wendif-labels \
78         -Wcast-align \
79         -Wstrict-aliasing=2 \
80         -Wwrite-strings \
81         -Wno-unused-parameter \
82         -ffast-math \
83         -Wp,-D_FORTIFY_SOURCE=2 \
84         -fno-common \
85         -fdiagnostics-show-option \
86         -Wno-missing-field-initializers])
87
88 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
89 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
90 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
91
92 # This makes sure pkg.m4 is available.
93 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
94
95 PKG_CHECK_MODULES(UDEV, [ libudev >= 154 ])
96 AC_SUBST(UDEV_CFLAGS)
97 AC_SUBST(UDEV_LIBS)
98
99 PKG_CHECK_MODULES(DBUS, [ dbus-1 ])
100 AC_SUBST(DBUS_CFLAGS)
101 AC_SUBST(DBUS_LIBS)
102
103 PKG_CHECK_MODULES(DBUSGLIB, [ dbus-glib-1 ])
104 AC_SUBST(DBUSGLIB_CFLAGS)
105 AC_SUBST(DBUSGLIB_LIBS)
106
107 PKG_CHECK_MODULES(CGROUP, [ libcgroup >= 0.36 ])
108 AC_SUBST(CGROUP_CFLAGS)
109 AC_SUBST(CGROUP_LIBS)
110
111 have_gtk=no
112 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
113 if test "x$enable_gtk" != "xno"; then
114         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 ],
115                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
116         AC_SUBST(GTK_CFLAGS)
117         AC_SUBST(GTK_LIBS)
118         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
119              AC_MSG_ERROR([*** gtk support requested but libraries not found])
120         fi
121 fi
122 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
123
124 AM_PROG_VALAC([0.8])
125 AC_SUBST(VAPIDIR)
126 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
127
128 AC_PATH_PROG([XSLTPROC], [xsltproc])
129 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
130
131 AC_PATH_PROG([M4], [m4])
132
133 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, arch, gentoo, slackware or other]))
134 if test "z$with_distro" = "z"; then
135         if test "$cross_compiling" = yes; then
136                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
137         else
138                 AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
139                 AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
140                 AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
141                 AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
142                 AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
143                 AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
144         fi
145         if test "z$with_distro" = "z"; then
146                 with_distro=`uname -s`
147         fi
148 fi
149 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
150
151 # Default generic names
152 SPECIAL_DBUS_SERVICE=dbus.service
153 SPECIAL_SYSLOG_SERVICE=syslog.service
154
155 # Location of the init scripts as mandated by LSB
156 SYSTEM_SYSVINIT_PATH=/etc/init.d
157
158 M4_DISTRO_FLAG=
159
160 case $with_distro in
161         fedora)
162                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
163                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
164
165                 # A little background why we define these special unit
166                 # names here in configure.ac: SysV services currently
167                 # cannot have aliases. As long as syslog is started
168                 # via a SysV init script we hence define these names
169                 # to the actual SysV name here. Later on when SysV
170                 # init scripts are not used anymore it is advisable to
171                 # use the generic names instead and use symlinks in
172                 # the unit directories to point to the right native
173                 # unit file.
174
175                 SPECIAL_DBUS_SERVICE=messagebus.service
176                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
177                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
178                 M4_DISTRO_FLAG=-DTARGET_FEDORA=1
179                 ;;
180         suse)
181                 SYSTEM_SYSVRCND_PATH=/etc/init.d
182                 AC_DEFINE(TARGET_SUSE, [], [Target is OpenSUSE/SLE])
183                 M4_DISTRO_FLAG=-DTARGET_SUSE=1
184                 ;;
185         debian)
186                 SYSTEM_SYSVRCND_PATH=/etc
187                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
188                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian/Ubuntu])
189                 M4_DISTRO_FLAG=-DTARGET_DEBIAN=1
190                 ;;
191         arch)
192                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
193                 SYSTEM_SYSVRCND_PATH=/etc
194                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
195                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
196                 M4_DISTRO_FLAG=-DTARGET_ARCH=1
197                 ;;
198         gentoo)
199                 SYSTEM_SYSVRCND_PATH=/etc
200                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
201                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
202                 M4_DISTRO_FLAG=-DTARGET_GENTOO=1
203                 ;;
204         slackware)
205                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
206                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
207                 SPECIAL_DBUS_SERVICE=messagebus.service
208                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
209                 M4_DISTRO_FLAG=-DTARGET_SLACKWARE=1
210                 ;;
211         other)
212                 AS_IF([test "x$with_sysvinit_path" = "x"],
213                         [AC_MSG_ERROR([With --distro=other, you must pass --with-sysvinit-path= to configure])])
214                 AS_IF([test "x$with_sysvrcd_path" = "x"],
215                         [AC_MSG_ERROR([With --distro=other, you must pass --with-sysvrcd-path= to configure])])
216                 AS_IF([test "x$with_dbus_service" = "x"],
217                         [AC_MSG_ERROR([With --distro=other, you must pass --with-dbus-service= to configure])])
218                 AS_IF([test "x$with_syslog_service" = "x"],
219                         [AC_MSG_ERROR([With --distro=other, you must pass --with-syslog-service= to configure])])
220                 ;;
221         *)
222                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
223                 ;;
224 esac
225
226 AC_ARG_WITH([sysvinit-path],
227         [AS_HELP_STRING([--with-sysvinit-path=PATH],
228                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
229         [SYSTEM_SYSVINIT_PATH="$withval"],
230         [])
231
232 AC_ARG_WITH([sysvrcd-path],
233         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
234                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
235         [SYSTEM_SYSVRCND_PATH="$withval"],
236         [])
237
238 AC_ARG_WITH([dbus-service],
239         [AS_HELP_STRING([--with-dbus-service=PATH],
240                 [Specify the name of the special DBus service @<:@default=based on distro@:>@])],
241         [SPECIAL_DBUS_SERVICE="$withval"],
242         [])
243
244 AC_ARG_WITH([syslog-service],
245         [AS_HELP_STRING([--with-syslog-service=PATH],
246                 [Specify the name of the special syslog service @<:@default=based on distro@:>@])],
247         [SPECIAL_SYSLOG_SERVICE="$withval"],
248         [])
249
250 AC_SUBST(SYSTEM_SYSVINIT_PATH)
251 AC_SUBST(SYSTEM_SYSVRCND_PATH)
252 AC_SUBST(SPECIAL_DBUS_SERVICE)
253 AC_SUBST(SPECIAL_SYSLOG_SERVICE)
254 AC_SUBST(M4_DISTRO_FLAG)
255
256 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
257 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
258 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
259 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
260 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
261 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
262
263 AC_DEFINE_UNQUOTED(SPECIAL_DBUS_SERVICE, ["$SPECIAL_DBUS_SERVICE"], [D-Bus service name])
264 AC_DEFINE_UNQUOTED(SPECIAL_SYSLOG_SERVICE, ["$SPECIAL_SYSLOG_SERVICE"], [Syslog service name])
265
266 AC_ARG_WITH([udevrulesdir],
267         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
268         [],
269         [with_udevrulesdir=/lib/udev/rules.d])
270 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
271
272 AC_ARG_WITH([rootdir],
273         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
274         [],
275         [with_rootdir=${ac_default_prefix}])
276 AC_SUBST([rootdir], [$with_rootdir])
277
278 AC_CONFIG_FILES([Makefile])
279 AC_OUTPUT
280
281 echo "
282         $PACKAGE_NAME $VERSION
283
284         Distribution:            ${with_distro}
285         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
286         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
287         Syslog service:          ${SPECIAL_SYSLOG_SERVICE}
288         D-Bus service:           ${SPECIAL_DBUS_SERVICE}
289         Gtk:                     ${have_gtk}
290         prefix:                  ${prefix}
291         root dir:                ${with_rootdir}
292         udev rules dir:          ${with_udevrulesdir}
293 "