chiark / gitweb /
Prep v230: Apply missing upstream fixes and updates (3/8) src/cgroups-agent.
[elogind.git] / configure.ac
1 #
2 #  This file is part of elogind.
3 #
4 #  Copyright 2010-2012 Lennart Poettering
5 #  Copyright 2010-2012 Kay Sievers
6 #
7 #  elogind is free software; you can redistribute it and/or modify it
8 #  under the terms of the GNU Lesser General Public License as published by
9 #  the Free Software Foundation; either version 2.1 of the License, or
10 #  (at your option) any later version.
11 #
12 #  elogind is distributed in the hope that it will be useful, but
13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15 #  Lesser General Public License for more details.
16 #
17 #  You should have received a copy of the GNU Lesser General Public License
18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
19
20 AC_PREREQ([2.64])
21
22 AC_INIT([elogind],
23         [230],
24         [https://github.com/elogind/elogind/issues],
25         [elogind],
26         [https://github.com/elogind/elogind])
27
28 AC_CONFIG_SRCDIR([src/login/logind.c])
29 AC_CONFIG_MACRO_DIR([m4])
30 AC_CONFIG_HEADERS([config.h])
31 AC_CONFIG_AUX_DIR([build-aux])
32
33 AC_USE_SYSTEM_EXTENSIONS
34 AC_SYS_LARGEFILE
35 AC_PREFIX_DEFAULT([/usr])
36 AM_MAINTAINER_MODE([enable])
37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
38 AM_SILENT_RULES([yes])
39 AC_CANONICAL_HOST
40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
41
42 AC_PROG_CC_C99
43
44 AX_COMPILER_VENDOR
45 AS_IF([test "x$ax_cv_c_compiler_vendor" = "xgnu"], [
46       AC_CHECK_TOOLS([AR], [gcc-ar ar], [:])
47       AC_CHECK_TOOLS([NM], [gcc-nm nm], [:])
48       AC_CHECK_TOOLS([RANLIB], [gcc-ranlib ranlib], [:])
49 ])
50
51 LT_PREREQ(2.2)
52 LT_INIT([disable-static])
53
54 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by elogind])])
55 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by elogind])])
56
57 SET_ARCH(X86_64, x86_64*)
58 SET_ARCH(IA32, i*86*)
59 SET_ARCH(MIPS, mips*)
60 SET_ARCH(AARCH64, aarch64*)
61
62 # i18n stuff for the PolicyKit policy files, check whether intltool can be found, disable NLS otherwise
63 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
64 AS_IF([test x"$intltool_found" != xyes],
65       [AS_IF([test x"$enable_nls" = xyes],
66              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
67              [AS_IF([test x"$enable_nls" != xno],
68                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
69                      enable_nls=no])
70              ])
71       ])
72
73 AM_NLS
74 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
75     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
76 IT_PROG_INTLTOOL([0.40.0])
77 ])
78
79 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
80     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
81     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
82     AC_SUBST(INTLTOOL_POLICY_RULE)
83 ])
84
85 GETTEXT_PACKAGE=elogind
86 AC_SUBST(GETTEXT_PACKAGE)
87 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [elogind])
88
89 AC_PROG_MKDIR_P
90 AC_PROG_LN_S
91 AC_PROG_SED
92 AC_PROG_GREP
93 AC_PROG_AWK
94
95 AC_PATH_PROG([M4], [m4])
96 AC_PATH_PROG([XSLTPROC], [xsltproc])
97
98 AC_PATH_PROG([HALT], [halt], [halt])
99 AC_PATH_PROG([REBOOT], [reboot], [reboot])
100 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
101
102 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
103
104 M4_DEFINES=
105
106 AC_CHECK_TOOL(OBJCOPY, objcopy)
107 AC_CHECK_TOOL(GPERF, gperf)
108 if test -z "$GPERF" ; then
109         AC_MSG_ERROR([*** gperf not found])
110 fi
111
112
113 # ------------------------------------------------------------------------------
114 # Find running cgroup controller
115 with_cgroupctrl=
116 AS_IF(  [test -f /proc/self/cgroup], [
117         # If the init system is a cgroup controler, it will be position 1.
118         # Secondary controllers, like cgmanager, do not work.
119         with_cgroupctrl=`grep "^1:name=" /proc/self/cgroup | cut -d ':' -f 2`
120         AS_IF(  [test -z "$with_cgroupctrl"], [
121                 # Try to be our own cgroup controller
122                 with_cgroupctrl="name=elogind"
123         ])
124 ])
125 AS_IF(  [test -z "$with_cgroupctrl"],
126         AC_MSG_ERROR([No running cgroup controller found]))
127
128
129 # ------------------------------------------------------------------------------
130 address_sanitizer_cflags=
131 address_sanitizer_cppflags=
132 address_sanitizer_ldflags=
133 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
134 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
135             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
136             AS_IF([test -z "$with_as_cflags"],
137                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
138             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
139             address_sanitizer_cppflags="-DVALGRIND=1"
140             address_sanitizer_ldflags="-Wc,-fsanitize=address"
141       ])
142
143 undefined_sanitizer_cflags=
144 undefined_sanitizer_cppflags=
145 undefined_sanitizer_ldflags=
146 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
147 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
148             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
149             AS_IF([test -z "$with_us_cflags"],
150                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
151             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
152             undefined_sanitizer_cppflags="-DVALGRIND=1"
153             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
154       ])
155
156 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
157 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
158 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
159
160 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
161         -pipe \
162         -Wall \
163         -Wextra \
164         -Wundef \
165         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
166         -Wlogical-op \
167         -Wmissing-include-dirs \
168         -Wold-style-definition \
169         -Wpointer-arith \
170         -Winit-self \
171         -Wdeclaration-after-statement \
172         -Wfloat-equal \
173         -Wsuggest-attribute=noreturn \
174         -Werror=missing-prototypes \
175         -Werror=implicit-function-declaration \
176         -Werror=missing-declarations \
177         -Werror=return-type \
178         -Wstrict-prototypes \
179         -Wredundant-decls \
180         -Wmissing-noreturn \
181         -Wshadow \
182         -Wendif-labels \
183         -Wstrict-aliasing=2 \
184         -Wwrite-strings \
185         -Wno-unused-parameter \
186         -Wno-missing-field-initializers \
187         -Wno-unused-result \
188         -Wno-format-signedness \
189         -Werror=overflow \
190         -Wdate-time \
191         -Wnested-externs \
192         -ffast-math \
193         -fno-common \
194         -fdiagnostics-show-option \
195         -fno-strict-aliasing \
196         -fvisibility=hidden \
197         -fstack-protector \
198         -fstack-protector-strong \
199         -fPIE \
200         --param=ssp-buffer-size=4])
201
202 CC_CHECK_FLAG_APPEND([with_cflags], [CFLAGS], [-Werror=shadow], [
203 #include <time.h>
204 #include <inttypes.h>
205 typedef uint64_t usec_t;
206 usec_t now(clockid_t clock);
207 int main(void) {
208         struct timespec now;
209         return 0;
210 }
211 ])
212
213 AS_CASE([$CC], [*clang*],
214         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
215                -Wno-typedef-redefinition \
216                -Wno-gnu-variable-sized-type-not-at-end \
217         ])])
218
219
220 # ------------------------------------------------------------------------------
221 # On some distributions -flto, even if available, leads to linking errors.
222 # We therefore make it optional
223 have_lto=no
224 AC_ARG_ENABLE([lto],
225         [AS_HELP_STRING([--disable-lto], [Disable link time optimization (default: test)])])
226
227 AS_IF([test "x$enable_lto" != "xno"], [
228         AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
229                 [have_lto=yes],
230                 [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
231         AS_IF([test "$have_lto" != "no"],
232                 [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [-flto])]
233         )
234         AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
235 ])
236
237 # ------------------------------------------------------------------------------
238 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
239         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
240                -Wp,-D_FORTIFY_SOURCE=2])],
241         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
242 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
243
244 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
245         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
246                -Wl,--gc-sections])],
247         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
248 AC_SUBST([OUR_CFLAGS], "$with_ldflags $sanitizer_cflags")
249
250 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
251         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
252                -ffunction-sections -fdata-sections])],
253         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
254 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
255
256 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
257         -Wl,--as-needed \
258         -Wl,--no-undefined \
259         -Wl,-z,relro \
260         -Wl,-z,now \
261         -pie \
262         -Wl,-fuse-ld=gold])
263 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
264
265 AC_CHECK_SIZEOF(pid_t)
266 AC_CHECK_SIZEOF(uid_t)
267 AC_CHECK_SIZEOF(gid_t)
268 AC_CHECK_SIZEOF(time_t)
269 AC_CHECK_SIZEOF(dev_t)
270 AC_CHECK_SIZEOF(rlim_t,,[
271        #include <sys/time.h>
272        #include <sys/resource.h>
273 ])
274
275 GPERF_TEST="$(echo foo,bar | ${GPERF} -L ANSI-C)"
276 save_CFLAGS="$CFLAGS"
277 CFLAGS="$CFLAGS -Wno-error"
278 AC_COMPILE_IFELSE(
279         [AC_LANG_PROGRAM([
280                 #include <string.h>
281                 const char * in_word_set(const char *, size_t);
282                 $GPERF_TEST]
283         )],
284         [GPERF_LEN_TYPE=size_t],
285         [AC_COMPILE_IFELSE(
286                 [AC_LANG_PROGRAM([
287                         #include <string.h>
288                         const char * in_word_set(const char *, unsigned);
289                         $GPERF_TEST]
290                 )],
291                 [GPERF_LEN_TYPE=unsigned],
292                 [AC_MSG_ERROR([** unable to determine gperf len type])]
293         )]
294 )
295 CFLAGS="$save_CFLAGS"
296
297 AC_DEFINE_UNQUOTED([GPERF_LEN_TYPE], [$GPERF_LEN_TYPE], [gperf len type])
298
299 # ------------------------------------------------------------------------------
300 # we use python to build the man page index
301 have_python=no
302 AC_ARG_WITH([python],
303         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
304
305 have_lxml=no
306 AS_IF([test "x$with_python" != "xno"], [
307         AM_PATH_PYTHON(,, [:])
308         AS_IF([test "x$PYTHON" != "x:"], [
309                 AC_MSG_CHECKING([for python lxml module])
310                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
311                 AC_MSG_RESULT([$have_lxml])
312                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
313                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
314         ])
315 ])
316 AS_IF([test "$have_python" != "yes"], [
317       AS_IF([test "$with_python" = "yes"],
318             [AC_MSG_ERROR([*** python support requested but python support not found])])
319       AS_IF([test "$with_python" != "no"],
320             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
321 ])
322 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
323
324 # ------------------------------------------------------------------------------
325
326 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
327 AC_CHECK_HEADERS([linux/memfd.h], [], [])
328
329 AC_CHECK_HEADERS([printf.h], [have_printf_h=yes], [have_printf_h=no])
330 AS_IF([test x$have_printf_h = xyes], [
331         AC_DEFINE(HAVE_PRINTF_H, 1, [Define if printf.h was found])
332 ])
333
334
335
336 # unconditionally pull-in librt with old glibc versions
337 dnl AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
338 dnl AC_SEARCH_LIBS([mq_unlink], [rt], [], [])
339
340 save_LIBS="$LIBS"
341 LIBS=
342 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
343 CAP_LIBS="$LIBS"
344 AC_SUBST(CAP_LIBS)
345
346 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
347 AC_CHECK_DECLS([
348         memfd_create,
349         gettid,
350         pivot_root,
351         name_to_handle_at,
352         setns,
353         getrandom,
354         renameat2,
355         kcmp,
356         keyctl,
357         LO_FLAGS_PARTSCAN,
358         copy_file_range],
359                 [], [], [[
360 #include <sys/types.h>
361 #include <unistd.h>
362 #include <sys/mount.h>
363 #include <fcntl.h>
364 #include <sched.h>
365 #include <linux/loop.h>
366 #include <linux/random.h>
367 ]])
368
369 AC_CHECK_TYPES([char16_t, char32_t, key_serial_t],
370                [], [], [[
371 #include <uchar.h>
372 ]])
373
374 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
375                 IFLA_MACVLAN_FLAGS,
376                 IFLA_IPVLAN_MODE,
377                 IFLA_VTI_REMOTE,
378                 IFLA_PHYS_PORT_ID,
379                 IFLA_BOND_AD_INFO,
380                 IFLA_VLAN_PROTOCOL,
381                 IFLA_VXLAN_REMCSUM_NOPARTIAL,
382                 IFLA_IPTUN_ENCAP_DPORT,
383                 IFLA_GRE_ENCAP_DPORT,
384                 IFLA_BRIDGE_VLAN_INFO,
385                 IFLA_BRPORT_PROXYARP,
386                 IFLA_BRPORT_LEARNING_SYNC,
387                 IFLA_BR_VLAN_DEFAULT_PVID,
388                 NDA_IFINDEX,
389                 IFA_FLAGS],
390 [], [], [[
391 #include <inttypes.h>
392 #include <netinet/in.h>
393 #include <netinet/ether.h>
394 #include <linux/rtnetlink.h>
395 #include <net/if.h>
396 #include <linux/ip.h>
397 #include <linux/if_tunnel.h>
398 #include <linux/if_link.h>
399 #include <linux/if_bridge.h>
400 #include <linux/if_addr.h>
401 #include <linux/neighbour.h>
402 ]])
403
404 # This makes sure pkg.m4 is available.
405 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
406
407
408 # ------------------------------------------------------------------------------
409 PKG_CHECK_MODULES(UDEV, [libudev])
410 dnl
411 AC_ARG_WITH([udevrulesdir],
412             AS_HELP_STRING([--with-udevrulesdir=DIR], [Directory for udev rules files]),
413             [],
414             [with_udevrulesdir=$($PKG_CONFIG --variable=udevdir udev)/rules.d])
415 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
416
417 AC_ARG_WITH([udevbindir],
418             AS_HELP_STRING([--with-udevbindir=DIR], [Directory for udev binary files]),
419             [],
420             [with_udevbindir=$($PKG_CONFIG --variable=udevdir udev)])
421 AC_SUBST([udevbindir], [$with_udevbindir])
422
423 # ------------------------------------------------------------------------------
424 have_coverage=no
425 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
426 if test "x$enable_coverage" = "xyes" ; then
427         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
428         if test "x$lcov_found" = xno ; then
429                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
430         else
431                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
432                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
433                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
434                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
435                 else
436                         have_coverage=yes
437                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
438                         -fprofile-arcs \
439                         -ftest-coverage])
440                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
441                 fi
442         fi
443 fi
444 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
445
446 # ------------------------------------------------------------------------------
447 have_selinux=no
448 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
449 if test "x$enable_selinux" != "xno"; then
450         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
451                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
452                  have_selinux=yes
453                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
454                 [have_selinux=no])
455         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
456                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
457         fi
458 fi
459 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
460
461 # ------------------------------------------------------------------------------
462 AC_ARG_WITH([kill-user-processes],
463         [AS_HELP_STRING([--without-kill-user-processes], [Set elogind's KillUserProcesses=no by default])])
464 AS_IF([test "$with_kill_user_processes" != "no"],
465        [kill_user_processes=true
466         KILL_USER_PROCESSES=yes],
467        [kill_user_processes=false
468         KILL_USER_PROCESSES=no])
469 AC_DEFINE_UNQUOTED(KILL_USER_PROCESSES, [$kill_user_processes], [Default KillUserProcesses setting])
470 AC_SUBST(KILL_USER_PROCESSES)
471
472 # ------------------------------------------------------------------------------
473 AC_ARG_ENABLE([pam],
474         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
475                 [case "${enableval}" in
476                         yes) have_pam=yes ;;
477                         no) have_pam=no ;;
478                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
479                 esac],
480                 [have_pam=auto])
481
482 if test "x${have_pam}" != xno ; then
483         AC_CHECK_HEADERS(
484                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
485                 [have_pam=yes],
486                 [if test "x$have_pam" = xyes ; then
487                         AC_MSG_ERROR([*** PAM headers not found.])
488                 fi])
489
490         AC_CHECK_LIB(
491                 [pam],
492                 [pam_syslog],
493                 [have_pam=yes],
494                 [if test "x$have_pam" = xyes ; then
495                         AC_MSG_ERROR([*** libpam not found.])
496                 fi])
497
498         if test "x$have_pam" = xyes ; then
499                 PAM_LIBS="-lpam -lpam_misc"
500                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
501                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
502         else
503                 have_pam=no
504         fi
505 else
506         PAM_LIBS=
507 fi
508 AC_SUBST(PAM_LIBS)
509 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
510
511 # ------------------------------------------------------------------------------
512 AC_ARG_ENABLE([acl],
513         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
514                 [case "${enableval}" in
515                         yes) have_acl=yes ;;
516                         no) have_acl=no ;;
517                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
518                 esac],
519                 [have_acl=auto])
520
521 if test "x${have_acl}" != xno ; then
522         AC_CHECK_HEADERS(
523                 [sys/acl.h acl/libacl.h],
524                 [have_acl=yes],
525                 [if test "x$have_acl" = xyes ; then
526                         AC_MSG_ERROR([*** ACL headers not found.])
527                 fi])
528
529         AC_CHECK_LIB(
530                 [acl],
531                 [acl_get_file],
532                 [have_acl=yes],
533                 [if test "x$have_acl" = xyes ; then
534                         AC_MSG_ERROR([*** libacl not found.])
535                 fi])
536
537         if test "x$have_acl" = xyes ; then
538                 ACL_LIBS="-lacl"
539                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
540                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
541         else
542                 have_acl=no
543         fi
544 else
545         ACL_LIBS=
546 fi
547 AC_SUBST(ACL_LIBS)
548 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
549
550 # ------------------------------------------------------------------------------
551 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
552                 [case "${enableval}" in
553                         yes) have_smack=yes ;;
554                         no) have_smack=no ;;
555                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
556                 esac],
557                 [have_smack=auto])
558
559 if test "x${have_smack}" != xno; then
560         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
561         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
562         have_smack=yes
563 fi
564
565 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
566
567 have_smack_run_label=no
568 AC_ARG_WITH(smack-run-label,
569 AS_HELP_STRING([--with-smack-run-label=STRING],
570         [run systemd --system itself with a specific SMACK label]),
571         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run systemd itself with SMACK label]) have_smack_run_label=yes],
572         [])
573
574 if test "x${have_smack_run_label}" = xyes; then
575         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK_RUN_LABEL"
576 fi
577
578 AC_ARG_WITH(smack-default-process-label,
579 AS_HELP_STRING([--with-smack-default-process-label=STRING],
580         [default SMACK label for executed processes]),
581         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
582         [])
583
584 # ------------------------------------------------------------------------------
585 AC_ARG_WITH(system-uid-max,
586         AS_HELP_STRING([--with-system-uid-max=UID]
587                 [Maximum UID for system users]),
588         [SYSTEM_UID_MAX="$withval"],
589         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
590
591 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
592 AC_SUBST(SYSTEM_UID_MAX)
593
594 # ------------------------------------------------------------------------------
595 AC_ARG_WITH(system-gid-max,
596         AS_HELP_STRING([--with-system-gid-max=GID]
597                 [Maximum GID for system groups]),
598         [SYSTEM_GID_MAX="$withval"],
599         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
600
601 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
602 AC_SUBST(SYSTEM_GID_MAX)
603
604 # ------------------------------------------------------------------------------
605 have_polkit=no
606 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
607 if test "x$enable_polkit" != "xno"; then
608         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
609         have_polkit=yes
610 fi
611 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
612
613 # ------------------------------------------------------------------------------
614 have_kdbus=no
615 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--disable-kdbus], [do not connect to kdbus by default]))
616 if test "x$enable_kdbus" != "xno"; then
617         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus is to be connected to by default])
618         have_kdbus=yes
619         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
620 fi
621 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
622
623 # ------------------------------------------------------------------------------
624 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
625
626 # ------------------------------------------------------------------------------
627 have_manpages=no
628 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
629 AC_PATH_PROG([XSLTPROC], [xsltproc])
630 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
631 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
632
633 # ------------------------------------------------------------------------------
634 AC_SUBST(M4_DEFINES)
635
636 AC_ARG_WITH([dbuspolicydir],
637         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
638         [],
639         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
640 AX_NORMALIZE_PATH([with_dbuspolicydir])
641
642 AC_ARG_WITH([dbussystemservicedir],
643         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
644         [],
645         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
646 AX_NORMALIZE_PATH([with_dbussystemservicedir])
647
648 AC_ARG_WITH([bashcompletiondir],
649         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
650         [],
651         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
652                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
653         ] , [
654                 with_bashcompletiondir=${datadir}/bash-completion/completions
655         ])])
656 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, [test "$with_bashcompletiondir" != "no"])
657 AX_NORMALIZE_PATH([with_bashcompletiondir])
658
659 AC_ARG_WITH([zshcompletiondir],
660         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
661         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
662 AM_CONDITIONAL(ENABLE_ZSH_COMPLETION, [test "$with_zshcompletiondir" != "no"])
663 AX_NORMALIZE_PATH([with_zshcompletiondir])
664
665 AC_ARG_WITH([rootprefix],
666         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
667         [], [with_rootprefix=${ac_default_prefix}])
668 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
669 # defaults those to ".", solve that here for now until we can find a suitable
670 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
671 # See: https://github.com/systemd/systemd/issues/54
672 if test "x${with_rootprefix}" = "x"; then
673         with_rootprefix="/"
674 fi
675 AX_NORMALIZE_PATH([with_rootprefix])
676
677 AC_ARG_WITH([rootlibdir],
678         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
679         [],
680         [with_rootlibdir=${libdir}])
681 AX_NORMALIZE_PATH([with_rootlibdir])
682
683 AC_ARG_WITH([pamlibdir],
684         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
685         [],
686         [with_pamlibdir=${with_rootlibdir}/security])
687 AX_NORMALIZE_PATH([with_pamlibdir])
688
689 AC_ARG_WITH([pamconfdir],
690         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
691         [],
692         [with_pamconfdir=${sysconfdir}/pam.d])
693 AX_NORMALIZE_PATH([with_pamconfdir])
694
695 AC_ARG_ENABLE([split-usr],
696         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
697         [],
698         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
699                 enable_split_usr=yes
700         ], [
701                 enable_split_usr=no
702         ])])
703
704 AS_IF([test "x${enable_split_usr}" = "xyes"], [
705         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
706 ])
707 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
708
709 # work around intltool-update issues during 'make distcheck'
710 AS_IF([test "x$0" != "x./configure"], [
711         AC_SUBST([INTLTOOL_UPDATE], [/usr/bin/env true])
712 ])
713
714 AC_ARG_ENABLE(tests,
715         [AC_HELP_STRING([--disable-tests], [disable tests])],
716         enable_tests=$enableval, enable_tests=yes)
717 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
718
719 AC_ARG_ENABLE(debug,
720         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (elogind,hashmap,mmap-cache)])],
721         [if test "x$enableval" = "xyes"; then
722                 enableval="elogind,hashmap,mmap-cache"
723         fi
724         saved_ifs="$IFS"
725         IFS="$IFS$PATH_SEPARATOR,"
726         for name in $enableval; do
727                 case $name in
728                 elogind)
729                         enable_debug_elogind=yes
730                         ;;
731                 hashmap)
732                         enable_debug_hashmap=yes
733                         ;;
734                 mmap-cache)
735                         enable_debug_mmap_cache=yes
736                         ;;
737                 esac
738         done
739         IFS="$saved_ifs"],[])
740
741 enable_debug=""
742 AS_IF([test x$enable_debug_elogind = xyes], [
743         AC_DEFINE(ENABLE_DEBUG_ELOGIND, 1, [Define if elogind debugging is to be enabled])
744         enable_debug="elogind $enable_debug"
745 ])
746 AS_IF([test x$enable_debug_hashmap = xyes], [
747         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
748         enable_debug="hashmap $enable_debug"
749 ])
750 AS_IF([test x$enable_debug_mmap_cache = xyes], [
751         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
752         enable_debug="mmap-cache $enable_debug"
753 ])
754 test -z "$enable_debug" && enable_debug="none"
755
756 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
757 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
758 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
759 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
760 AC_SUBST([pamlibdir], [$with_pamlibdir])
761 AC_SUBST([pamconfdir], [$with_pamconfdir])
762 AC_SUBST([rootprefix], [$with_rootprefix])
763 AC_SUBST([rootlibdir], [$with_rootlibdir])
764 AC_SUBST([cgroup_controller], [$with_cgroupctrl])
765
766 AC_CONFIG_FILES([
767         Makefile
768         po/Makefile.in
769 ])
770
771 AC_OUTPUT
772 AC_MSG_RESULT([
773         $PACKAGE_NAME $VERSION
774
775         PAM:                     ${have_pam}
776         SELinux:                 ${have_selinux}
777         SMACK:                   ${have_smack}
778         ACL:                     ${have_acl}
779         KillUserProcesses default: ${KILL_USER_PROCESSES}
780         polkit:                  ${have_polkit}
781         kdbus:                   ${have_kdbus}
782         Python:                  ${have_python}
783         man pages:               ${have_manpages}
784         test coverage:           ${have_coverage}
785         Split /usr:              ${enable_split_usr}
786         Link time optimization:  ${have_lto}
787         extra debugging:         ${enable_debug}
788         cgroup controller:       ${with_cgroupctrl}
789
790         prefix:                  ${prefix}
791         rootprefix:              ${with_rootprefix}
792         sysconf dir:             ${sysconfdir}
793         datarootdir:             ${datarootdir}
794         includedir:              ${includedir}
795         lib dir:                 ${libdir}
796         rootlib dir:             ${with_rootlibdir}
797         PAM modules dir:         ${with_pamlibdir}
798         PAM configuration dir:   ${with_pamconfdir}
799         D-Bus policy dir:        ${with_dbuspolicydir}
800         D-Bus system dir:        ${with_dbussystemservicedir}
801         Bash completions dir:    ${with_bashcompletiondir}
802         Zsh completions dir:     ${with_zshcompletiondir}
803         Maximum System UID:      ${SYSTEM_UID_MAX}
804         Maximum System GID:      ${SYSTEM_GID_MAX}
805
806         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
807         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
808         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
809 ])