chiark / gitweb /
loginctl: when showing device tree of seats with no devices show something useful
[elogind.git] / configure.ac
1 #
2 #  This file is part of systemd.
3 #
4 #  Copyright 2010-2012 Lennart Poettering
5 #  Copyright 2010-2012 Kay Sievers
6 #
7 #  systemd is free software; you can redistribute it and/or modify it
8 #  under the terms of the GNU Lesser General Public License as published by
9 #  the Free Software Foundation; either version 2.1 of the License, or
10 #  (at your option) any later version.
11 #
12 #  systemd is distributed in the hope that it will be useful, but
13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15 #  Lesser General Public License for more details.
16 #
17 #  You should have received a copy of the GNU Lesser General Public License
18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
19
20 AC_PREREQ([2.64])
21
22 AC_INIT([systemd],
23         [208],
24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
25         [systemd],
26         [http://www.freedesktop.org/wiki/Software/systemd])
27
28 AC_CONFIG_SRCDIR([src/core/main.c])
29 AC_CONFIG_MACRO_DIR([m4])
30 AC_CONFIG_HEADERS([config.h])
31 AC_CONFIG_AUX_DIR([build-aux])
32
33 AC_USE_SYSTEM_EXTENSIONS
34 AC_SYS_LARGEFILE
35 AC_PREFIX_DEFAULT([/usr])
36 AM_MAINTAINER_MODE([enable])
37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
38 AM_SILENT_RULES([yes])
39 AC_CANONICAL_HOST
40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
41 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
42        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
43       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
44
45 LT_PREREQ(2.2)
46 LT_INIT([disable-static])
47
48 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
49 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
50
51 # i18n stuff for the PolicyKit policy files
52 IT_PROG_INTLTOOL([0.40.0])
53
54 GETTEXT_PACKAGE=systemd
55 AC_SUBST(GETTEXT_PACKAGE)
56
57 AC_PROG_MKDIR_P
58 AC_PROG_LN_S
59 AC_PROG_SED
60 AC_PROG_GREP
61 AC_PROG_AWK
62
63 AC_PROG_CC_C99
64
65 AC_PATH_PROG([M4], [m4])
66 AC_PATH_PROG([XSLTPROC], [xsltproc])
67
68 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
69 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
70
71 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
72
73 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
74
75 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod])
76
77 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec])
78
79 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
80 m4_ifdef([GTK_DOC_CHECK], [
81 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
82          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
83           enable_gtk_doc=no])
84
85 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
86         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
87 ])
88
89 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
90 GOBJECT_INTROSPECTION_CHECK([1.31.1])
91 ], [
92    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
93    enable_introspection=no])
94
95 AC_CHECK_TOOL(STRINGS, strings)
96 AC_CHECK_TOOL(GPERF, gperf)
97 if test -z "$GPERF" ; then
98         AC_MSG_ERROR([*** gperf not found])
99 fi
100
101 # ------------------------------------------------------------------------------
102 address_sanitizer_cflags=
103 address_sanitizer_cppflags=
104 address_sanitizer_ldflags=
105 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
106 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
107             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
108             AS_IF([test -z "$with_as_cflags"],
109                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
110             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
111             address_sanitizer_cppflags="-DVALGRIND=1"
112             address_sanitizer_ldflags="-Wc,-fsanitize=address"
113       ])
114
115 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
116         -pipe \
117         -Wall \
118         -Wextra \
119         -Wno-inline \
120         -Wundef \
121         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
122         -Wlogical-op \
123         -Wsign-compare \
124         -Wmissing-include-dirs \
125         -Wold-style-definition \
126         -Wpointer-arith \
127         -Winit-self \
128         -Wdeclaration-after-statement \
129         -Wfloat-equal \
130         -Wmissing-prototypes \
131         -Wstrict-prototypes \
132         -Wredundant-decls \
133         -Wmissing-declarations \
134         -Wmissing-noreturn \
135         -Wshadow \
136         -Wendif-labels \
137         -Wcast-align \
138         -Wstrict-aliasing=2 \
139         -Wwrite-strings \
140         -Wno-long-long \
141         -Wno-overlength-strings \
142         -Wno-unused-parameter \
143         -Wno-missing-field-initializers \
144         -Wno-unused-result \
145         -Werror=overflow \
146         -Wdate-time \
147         -ffast-math \
148         -fno-common \
149         -fdiagnostics-show-option \
150         -fdiagnostics-color \
151         -fno-strict-aliasing \
152         -fvisibility=hidden \
153         -ffunction-sections \
154         -fdata-sections \
155         -fstack-protector \
156         --param=ssp-buffer-size=4])
157 AS_CASE([$CFLAGS], [*-O[[12345\ ]]*],
158         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
159                -flto])],
160         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
161 AC_SUBST([OUR_CFLAGS], "$with_cflags $address_sanitizer_cflags")
162
163 AS_CASE([$CFLAGS], [*-O[[12345\ ]]*],
164         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
165                -Wp,-D_FORTIFY_SOURCE=2])],
166         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
167 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $address_sanitizer_cppflags")
168
169 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
170         -Wl,--as-needed \
171         -Wl,--no-undefined \
172         -Wl,--gc-sections \
173         -Wl,-z,relro \
174         -Wl,-z,now])
175 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $address_sanitizer_ldflags")
176
177 # ------------------------------------------------------------------------------
178 # we use python to build the man page index, and for systemd-python
179 have_python=no
180 AC_ARG_WITH([python],
181         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
182
183 AS_IF([test "x$with_python" != "xno"], [
184         AM_PATH_PYTHON(,, [:])
185         AS_IF([test "$PYTHON" != :], [have_python=yes])
186 ])
187 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
188 AS_IF([test "x$PYTHON_BINARY" = "x"],
189       [AS_IF([test "x$have_python" = "xyes"],
190              [PYTHON_BINARY="$(which "$PYTHON")"],
191              [PYTHON_BINARY=/usr/bin/python])])
192 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
193
194 AS_IF([test "x$have_python" != "xyes" -a "x$enable_python_devel" = "xyes"],
195       [AC_MSG_ERROR([*** python-devel support requires --with-python])])
196
197 have_python_devel=no
198 AC_ARG_ENABLE(python_devel, AS_HELP_STRING([--disable-python-devel], [Do not build python modules]))
199 AS_IF([test "x$have_python" = "xyes" -a "x$enable_python_devel" != "xno"], [
200       PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}],
201             [have_python_devel=yes],
202             [PKG_CHECK_MODULES([PYTHON_DEVEL], [python],
203                   [have_python_devel=yes],
204                   [have_python_devel=no])])
205       AS_IF([test "x$have_python_devel" = xno -a "x$enable_python_devel" = xyes],
206             [AC_MSG_ERROR([*** python-devel support requested but libraries not found])])
207       AC_PATH_PROGS(SPHINX_BUILD, sphinx-build-${PYTHON_VERSION} sphinx-build)
208 ])
209 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
210
211 # ------------------------------------------------------------------------------
212
213 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
214 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
215 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
216
217 # unconditionally pull-in librt with old glibc versions
218 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
219
220 save_LIBS="$LIBS"
221 LIBS=
222 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
223 CAP_LIBS="$LIBS"
224 AC_SUBST(CAP_LIBS)
225
226 LIBS=
227 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
228 RT_LIBS="$LIBS"
229 AC_SUBST(RT_LIBS)
230 LIBS="$save_LIBS"
231
232 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
233 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
234 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
235 #include <unistd.h>
236 #include <sys/mount.h>
237 #include <fcntl.h>]])
238
239 # This makes sure pkg.m4 is available.
240 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
241
242 # ------------------------------------------------------------------------------
243 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2], have_dbus=yes, have_dbus=no])
244 AS_IF([test "$have_dbus" = "yes"], [ AC_DEFINE(HAVE_DBUS, [1], [Define if dbus-1 is available]) ])
245 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
246
247 # ------------------------------------------------------------------------------
248 have_coverage=no
249 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
250 if test "x$enable_coverage" = "xyes" ; then
251         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
252         if test "x$lcov_found" = xno ; then
253                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
254         else
255                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
256                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
257                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
258                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
259                 else
260                         have_coverage=yes
261                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
262                         -fprofile-arcs \
263                         -ftest-coverage])
264                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
265                 fi
266         fi
267 fi
268 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
269
270 # ------------------------------------------------------------------------------
271 have_kmod=no
272 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
273 if test "x$enable_kmod" != "xno"; then
274         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
275         if test "x$have_kmod" = "xyes"; then
276                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 15 ],
277                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
278                         AC_MSG_ERROR([*** kmod version >= 15 not found]))
279         fi
280         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
281                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
282         fi
283 fi
284 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
285
286 # ------------------------------------------------------------------------------
287 have_blkid=no
288 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
289 if test "x$enable_blkid" != "xno"; then
290         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
291                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
292         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
293                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
294         fi
295 fi
296 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
297
298 # ------------------------------------------------------------------------------
299 have_ima=yes
300 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
301                 [case "${enableval}" in
302                         yes) have_ima=yes ;;
303                         no) have_ima=no ;;
304                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
305                 esac],
306                 [have_ima=yes])
307
308 if test "x${have_ima}" != xno ; then
309         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
310 fi
311
312 # ------------------------------------------------------------------------------
313 have_chkconfig=yes
314 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
315                 [case "${enableval}" in
316                         yes) have_chkconfig=yes ;;
317                         no) have_chkconfig=no ;;
318                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
319                 esac],
320                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
321                 if test -z "$CHKCONFIG"; then
322                         have_chkconfig=no
323                 else
324                         have_chkconfig=yes
325                 fi])
326
327 if test "x${have_chkconfig}" != xno ; then
328         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
329 fi
330
331 # ------------------------------------------------------------------------------
332 have_selinux=no
333 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
334 if test "x$enable_selinux" != "xno"; then
335         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
336                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
337         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
338                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
339         fi
340 fi
341 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
342
343 AC_ARG_WITH(debug-shell,
344         AS_HELP_STRING([--with-debug-shell=PATH],
345                 [Path to debug shell binary]),
346         [SUSHELL="$withval"],[
347         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
348
349 AC_SUBST(SUSHELL)
350
351 AC_ARG_WITH([debug-tty],
352         AS_HELP_STRING([--with-debug-tty=PATH],
353                 [Specify the tty device for debug shell]),
354         [DEBUGTTY="$withval"],
355         [DEBUGTTY=/dev/tty9])
356
357 AC_SUBST(DEBUGTTY)
358
359 # ------------------------------------------------------------------------------
360 have_xz=no
361 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
362 if test "x$enable_xz" != "xno"; then
363         PKG_CHECK_MODULES(XZ, [ liblzma ],
364                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
365         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
366                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
367         fi
368 fi
369 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
370
371 # ------------------------------------------------------------------------------
372 AC_ARG_ENABLE([tcpwrap],
373         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
374                 [case "${enableval}" in
375                         yes) have_tcpwrap=yes ;;
376                         no) have_tcpwrap=no ;;
377                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
378                 esac],
379                 [have_tcpwrap=auto])
380
381 if test "x${have_tcpwrap}" != xno ; then
382         ACX_LIBWRAP
383         if test "x${LIBWRAP_LIBS}" = x ; then
384                 if test "x$have_tcpwrap" = xyes ; then
385                         AC_MSG_ERROR([*** TCP wrappers support not found.])
386                 fi
387                 have_tcpwrap=no
388         else
389                 have_tcpwrap=yes
390         fi
391 else
392         LIBWRAP_LIBS=
393 fi
394 AC_SUBST(LIBWRAP_LIBS)
395
396 # ------------------------------------------------------------------------------
397 AC_ARG_ENABLE([pam],
398         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
399                 [case "${enableval}" in
400                         yes) have_pam=yes ;;
401                         no) have_pam=no ;;
402                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
403                 esac],
404                 [have_pam=auto])
405
406 if test "x${have_pam}" != xno ; then
407         AC_CHECK_HEADERS(
408                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
409                 [have_pam=yes],
410                 [if test "x$have_pam" = xyes ; then
411                         AC_MSG_ERROR([*** PAM headers not found.])
412                 fi])
413
414         AC_CHECK_LIB(
415                 [pam],
416                 [pam_syslog],
417                 [have_pam=yes],
418                 [if test "x$have_pam" = xyes ; then
419                         AC_MSG_ERROR([*** libpam not found.])
420                 fi])
421
422         if test "x$have_pam" = xyes ; then
423                 PAM_LIBS="-lpam -lpam_misc"
424                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
425         else
426                 have_pam=no
427         fi
428 else
429         PAM_LIBS=
430 fi
431 AC_SUBST(PAM_LIBS)
432 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
433
434 # ------------------------------------------------------------------------------
435 AC_ARG_ENABLE([acl],
436         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
437                 [case "${enableval}" in
438                         yes) have_acl=yes ;;
439                         no) have_acl=no ;;
440                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
441                 esac],
442                 [have_acl=auto])
443
444 if test "x${have_acl}" != xno ; then
445         AC_CHECK_HEADERS(
446                 [sys/acl.h acl/libacl.h],
447                 [have_acl=yes],
448                 [if test "x$have_acl" = xyes ; then
449                         AC_MSG_ERROR([*** ACL headers not found.])
450                 fi])
451
452         AC_CHECK_LIB(
453                 [acl],
454                 [acl_get_file],
455                 [have_acl=yes],
456                 [if test "x$have_acl" = xyes ; then
457                         AC_MSG_ERROR([*** libacl not found.])
458                 fi])
459
460         if test "x$have_acl" = xyes ; then
461                 ACL_LIBS="-lacl"
462                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
463         else
464                 have_acl=no
465         fi
466 else
467         ACL_LIBS=
468 fi
469 AC_SUBST(ACL_LIBS)
470 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
471
472 # ------------------------------------------------------------------------------
473 AC_ARG_ENABLE([xattr],
474         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
475                 [case "${enableval}" in
476                         yes) have_xattr=yes ;;
477                         no) have_xattr=no ;;
478                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
479                 esac],
480                 [have_xattr=auto])
481
482 if test "x${have_xattr}" != xno ; then
483         AC_CHECK_HEADERS(
484                 [attr/xattr.h],
485                 [have_xattr=yes],
486                 [if test "x$have_xattr" = xyes ; then
487                         AC_MSG_ERROR([*** XATTR headers not found.])
488                 fi])
489
490         AC_CHECK_LIB(
491                 [attr],
492                 [fsetxattr],
493                 [have_xattr=yes],
494                 [if test "x$have_xattr" = xyes ; then
495                         AC_MSG_ERROR([*** libattr not found.])
496                 fi])
497
498         if test "x$have_xattr" = xyes ; then
499                 XATTR_LIBS="-lattr"
500                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
501         else
502                 have_xattr=no
503         fi
504 else
505         XATTR_LIBS=
506 fi
507 AC_SUBST(XATTR_LIBS)
508 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
509
510 # ------------------------------------------------------------------------------
511 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
512                 [case "${enableval}" in
513                         yes) have_smack=yes ;;
514                         no) have_smack=no ;;
515                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
516                 esac],
517                 [have_smack=auto])
518
519 if test "x${have_xattr}" = xno; then
520         if test "x${have_smack}" = xyes; then
521                 AC_MSG_ERROR(SMACK requires xattr support)
522         else
523                 have_smack=no
524         fi
525 else
526         if test "x${have_smack}" = xauto; then
527                 have_smack=yes
528         fi
529 fi
530
531 AC_ARG_WITH(smack-run-label,
532 AS_HELP_STRING([--with-smack-run-label=STRING],
533         [run systemd --system with a specific SMACK label]),
534         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run with a smack label])],
535         [])
536
537 if test "x${have_smack}" = xyes ; then
538         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
539 fi
540
541 # ------------------------------------------------------------------------------
542 AC_ARG_ENABLE([gcrypt],
543         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
544                 [case "${enableval}" in
545                         yes) have_gcrypt=yes ;;
546                         no) have_gcrypt=no ;;
547                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
548                 esac],
549                 [have_gcrypt=auto])
550
551 if test "x${have_gcrypt}" != xno ; then
552         AM_PATH_LIBGCRYPT(
553                 [1.4.5],
554                 [have_gcrypt=yes],
555                 [if test "x$have_gcrypt" = xyes ; then
556                         AC_MSG_ERROR([*** GCRYPT headers not found.])
557                 fi])
558
559         if test "x$have_gcrypt" = xyes ; then
560                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
561                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
562                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
563         else
564                 have_gcrypt=no
565         fi
566 else
567         GCRYPT_LIBS=
568         GCRYPT_CFLAGS=
569 fi
570 AC_SUBST(GCRYPT_LIBS)
571 AC_SUBST(GCRYPT_CFLAGS)
572 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
573
574 # ------------------------------------------------------------------------------
575 AC_ARG_ENABLE([audit],
576         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
577                 [case "${enableval}" in
578                         yes) have_audit=yes ;;
579                         no) have_audit=no ;;
580                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
581                 esac],
582                 [have_audit=auto])
583
584 if test "x${have_audit}" != xno ; then
585         AC_CHECK_HEADERS(
586                 [libaudit.h],
587                 [have_audit=yes],
588                 [if test "x$have_audit" = xyes ; then
589                         AC_MSG_ERROR([*** AUDIT headers not found.])
590                 fi])
591
592         AC_CHECK_LIB(
593                 [audit],
594                 [audit_open],
595                 [have_audit=yes],
596                 [if test "x$have_audit" = xyes ; then
597                         AC_MSG_ERROR([*** libaudit not found.])
598                 fi])
599
600         if test "x$have_audit" = xyes ; then
601                 AUDIT_LIBS="-laudit"
602                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
603         else
604                 have_audit=no
605         fi
606 else
607         AUDIT_LIBS=
608 fi
609 AC_SUBST(AUDIT_LIBS)
610
611 # ------------------------------------------------------------------------------
612 have_libcryptsetup=no
613 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
614 if test "x$enable_libcryptsetup" != "xno"; then
615         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
616                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
617         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
618                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
619         fi
620 fi
621 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
622
623 # ------------------------------------------------------------------------------
624 have_qrencode=no
625 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
626 if test "x$enable_qrencode" != "xno"; then
627         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
628                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
629         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
630                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
631         fi
632 fi
633 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
634
635 # ------------------------------------------------------------------------------
636 have_microhttpd=no
637 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
638 if test "x$enable_microhttpd" != "xno"; then
639         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
640                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
641         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
642                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
643         fi
644 fi
645 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
646
647 # ------------------------------------------------------------------------------
648 have_binfmt=no
649 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
650 if test "x$enable_binfmt" != "xno"; then
651         have_binfmt=yes
652 fi
653 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
654
655 # ------------------------------------------------------------------------------
656 have_vconsole=no
657 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
658 if test "x$enable_vconsole" != "xno"; then
659         have_vconsole=yes
660 fi
661 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
662
663 # ------------------------------------------------------------------------------
664 have_readahead=no
665 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
666 if test "x$enable_readahead" != "xno"; then
667         have_readahead=yes
668 fi
669 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
670
671 # ------------------------------------------------------------------------------
672 have_bootchart=no
673 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
674 if test "x$enable_bootchart" != "xno"; then
675         have_bootchart=yes
676 fi
677 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
678
679 # ------------------------------------------------------------------------------
680 have_quotacheck=no
681 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
682 if test "x$enable_quotacheck" != "xno"; then
683         have_quotacheck=yes
684 fi
685 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
686
687 # ------------------------------------------------------------------------------
688 have_tmpfiles=no
689 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
690 if test "x$enable_tmpfiles" != "xno"; then
691         have_tmpfiles=yes
692 fi
693 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
694
695 # ------------------------------------------------------------------------------
696 have_randomseed=no
697 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
698 if test "x$enable_randomseed" != "xno"; then
699         have_randomseed=yes
700 fi
701 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
702
703 # ------------------------------------------------------------------------------
704 have_backlight=no
705 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
706 if test "x$enable_backlight" != "xno"; then
707         have_backlight=yes
708 fi
709 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
710
711 # ------------------------------------------------------------------------------
712 have_rfkill=no
713 AC_ARG_ENABLE(rfkill, AS_HELP_STRING([--disable-rfkill], [disable rfkill tools]))
714 if test "x$enable_rfkill" != "xno"; then
715         have_rfkill=yes
716 fi
717 AM_CONDITIONAL(ENABLE_RFKILL, [test "$have_rfkill" = "yes"])
718
719 # ------------------------------------------------------------------------------
720 have_logind=no
721 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
722 if test "x$enable_logind" != "xno"; then
723         have_logind=yes
724 fi
725 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
726 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
727
728 # ------------------------------------------------------------------------------
729 have_machined=no
730 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
731 if test "x$enable_machined" != "xno"; then
732         have_machined=yes
733 fi
734 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
735 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
736
737 # ------------------------------------------------------------------------------
738 have_hostnamed=no
739 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
740 if test "x$enable_hostnamed" != "xno"; then
741         have_hostnamed=yes
742 fi
743 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
744
745 # ------------------------------------------------------------------------------
746 have_timedated=no
747 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
748 if test "x$enable_timedated" != "xno"; then
749         have_timedated=yes
750 fi
751 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
752
753 # ------------------------------------------------------------------------------
754 have_localed=no
755 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
756 if test "x$enable_localed" != "xno"; then
757         have_localed=yes
758 fi
759 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
760
761 # ------------------------------------------------------------------------------
762 have_coredump=no
763 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
764 if test "x$enable_coredump" != "xno"; then
765         have_coredump=yes
766 fi
767 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
768
769 # ------------------------------------------------------------------------------
770 have_polkit=no
771 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
772 if test "x$enable_polkit" != "xno"; then
773         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
774         have_polkit=yes
775 fi
776 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
777
778 # ------------------------------------------------------------------------------
779 AC_ARG_ENABLE(networkd, AS_HELP_STRING([--disable-networkd], [disable networkd]))
780 if test "x$enable_networkd" != "xno"; then
781         AC_DEFINE(ENABLE_NETWORKD, 1, [Define if networkd support is to be enabled])
782         have_networkd=yes
783 fi
784 AM_CONDITIONAL(ENABLE_NETWORKD, [test "x$have_networkd" = "xyes"])
785
786 # ------------------------------------------------------------------------------
787 have_efi=no
788 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
789 if test "x$enable_efi" != "xno"; then
790         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
791         have_efi=yes
792 fi
793 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
794
795 # ------------------------------------------------------------------------------
796 have_multi_seat_x=no
797 AC_ARG_ENABLE(multi_seat_x, AS_HELP_STRING([--disable-multi-seat-x], [do not build multi-seat-x]))
798 if test "x$enable_multi_seat_x" != "xno"; then
799         have_multi_seat_x=yes
800 fi
801 AM_CONDITIONAL(ENABLE_MULTI_SEAT_X, [test "$have_multi_seat_x" = "yes"])
802
803 # ------------------------------------------------------------------------------
804 have_kdbus=no
805 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--enable-kdbus], [do connect to kdbus by default]))
806 if test "x$enable_kdbus" == "xyes"; then
807         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus support is to be enabled])
808         have_kdbus=yes
809 fi
810 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
811
812 # ------------------------------------------------------------------------------
813 AC_ARG_WITH(rc-local-script-path-start,
814         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
815                 [Path to /etc/rc.local]),
816         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
817         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
818
819 AC_ARG_WITH(rc-local-script-path-stop,
820         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
821                 [Path to /usr/sbin/halt.local]),
822         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
823         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
824
825 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
826 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
827
828 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
829 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
830
831 # ------------------------------------------------------------------------------
832 AC_ARG_WITH(kbd-loadkeys,
833         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
834                 [Path to loadkeys]),
835         [KBD_LOADKEYS="$withval"],
836         [KBD_LOADKEYS="/usr/bin/loadkeys"])
837
838 AC_ARG_WITH(kbd-setfont,
839         AS_HELP_STRING([--with-kbd-setfont=PATH],
840                 [Path to setfont]),
841         [KBD_SETFONT="$withval"],
842         [KBD_SETFONT="/usr/bin/setfont"])
843
844 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
845 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
846
847 AC_SUBST(KBD_LOADKEYS)
848 AC_SUBST(KBD_SETFONT)
849
850 AC_ARG_WITH(telinit,
851         AS_HELP_STRING([--with-telinit=PATH],
852                 [Path to telinit]),
853         [TELINIT="$withval"],
854         [TELINIT="/lib/sysvinit/telinit"])
855
856 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
857
858 AC_SUBST(TELINIT)
859
860 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
861
862 # ------------------------------------------------------------------------------
863 have_myhostname=no
864 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
865 if test "x$enable_myhostname" != "xno"; then
866         AC_HEADER_STDC
867         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
868
869         AC_C_CONST
870         AC_TYPE_SIZE_T
871         AC_HEADER_TIME
872
873         AC_FUNC_MALLOC
874         AC_FUNC_SELECT_ARGTYPES
875         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
876
877         have_myhostname=yes
878 fi
879 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
880
881 # ------------------------------------------------------------------------------
882 AC_ARG_WITH(firmware-path,
883        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
884           [Firmware search path (default="")]),
885        [], [with_firmware_path=""])
886 OLD_IFS=$IFS
887 IFS=:
888 for i in $with_firmware_path; do
889        if test "x${FIRMWARE_PATH}" = "x"; then
890               FIRMWARE_PATH="\\\"${i}/\\\""
891        else
892               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
893        fi
894 done
895 IFS=$OLD_IFS
896 AC_SUBST(FIRMWARE_PATH)
897 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
898 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
899
900 # ------------------------------------------------------------------------------
901 AC_ARG_ENABLE([gudev],
902        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
903        [], [enable_gudev=yes])
904 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
905 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
906 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
907
908 # ------------------------------------------------------------------------------
909 have_manpages=no
910 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
911 AS_IF([test "x$enable_manpages" != xno], [
912         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
913                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
914         ])
915         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
916 ])
917 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
918
919 # ------------------------------------------------------------------------------
920
921 # Location of the init scripts as mandated by LSB
922 SYSTEM_SYSVINIT_PATH=/etc/init.d
923 SYSTEM_SYSVRCND_PATH=/etc/rc.d
924 M4_DEFINES=
925
926 AC_ARG_WITH([sysvinit-path],
927         [AS_HELP_STRING([--with-sysvinit-path=PATH],
928                 [Specify the path to where the SysV init scripts are located])],
929         [SYSTEM_SYSVINIT_PATH="$withval"],
930         [])
931
932 AC_ARG_WITH([sysvrcnd-path],
933         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
934                 [Specify the path to the base directory for the SysV rcN.d directories])],
935         [SYSTEM_SYSVRCND_PATH="$withval"],
936         [])
937
938 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
939         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
940         SYSTEM_SYSV_COMPAT="yes"
941         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
942 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
943         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
944 else
945         SYSTEM_SYSV_COMPAT="no"
946 fi
947
948 AC_SUBST(SYSTEM_SYSVINIT_PATH)
949 AC_SUBST(SYSTEM_SYSVRCND_PATH)
950 AC_SUBST(M4_DEFINES)
951
952 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
953
954 AC_ARG_WITH([tty-gid],
955         [AS_HELP_STRING([--with-tty-gid=GID],
956                 [Specify the numeric GID of the 'tty' group])],
957         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
958         [])
959
960 AC_ARG_WITH([dbuspolicydir],
961         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
962         [],
963         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
964
965 AC_ARG_WITH([dbussessionservicedir],
966         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
967         [],
968         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
969
970 AC_ARG_WITH([dbussystemservicedir],
971         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
972         [],
973         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
974
975 AC_ARG_WITH([dbusinterfacedir],
976         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
977         [],
978         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
979
980 AC_ARG_WITH([bashcompletiondir],
981         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
982         [],
983         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
984                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
985         ] , [
986                 with_bashcompletiondir=${datadir}/bash-completion/completions
987         ])])
988
989 AC_ARG_WITH([zshcompletiondir],
990         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
991         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
992
993 AC_ARG_WITH([rootprefix],
994         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
995         [], [with_rootprefix=${ac_default_prefix}])
996
997 AC_ARG_WITH([rootlibdir],
998         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
999         [],
1000         [with_rootlibdir=${libdir}])
1001
1002 AC_ARG_WITH([pamlibdir],
1003         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
1004         [],
1005         [with_pamlibdir=${with_rootlibdir}/security])
1006
1007 AC_ARG_WITH([pamconfdir],
1008         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
1009         [],
1010         [with_pamconfdir=${sysconfdir}/pam.d])
1011
1012 AC_ARG_ENABLE([split-usr],
1013         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
1014         [],
1015         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
1016                 enable_split_usr=yes
1017         ], [
1018                 enable_split_usr=no
1019         ])])
1020
1021 AS_IF([test "x${enable_split_usr}" = "xyes"], [
1022         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
1023 ])
1024
1025 # Work around intltoolize and gtk-doc problems in VPATH builds
1026 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
1027                                        [Define to do gtk-doc tests])
1028 AS_IF([test "x$0" != "x./configure"], [
1029         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
1030 ])
1031
1032 AC_ARG_ENABLE(tests,
1033        [AC_HELP_STRING([--disable-tests], [disable tests])],
1034        enable_tests=$enableval, enable_tests=yes)
1035 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
1036
1037 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1038 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1039 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1040 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
1041 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1042 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1043 AC_SUBST([pamlibdir], [$with_pamlibdir])
1044 AC_SUBST([pamconfdir], [$with_pamconfdir])
1045 AC_SUBST([rootprefix], [$with_rootprefix])
1046 AC_SUBST([rootlibdir], [$with_rootlibdir])
1047
1048 AC_CONFIG_FILES([
1049         Makefile po/Makefile.in
1050         docs/libudev/Makefile
1051         docs/libudev/version.xml
1052         docs/gudev/Makefile
1053         docs/gudev/version.xml
1054 ])
1055
1056 AC_OUTPUT
1057 AC_MSG_RESULT([
1058         $PACKAGE_NAME $VERSION
1059
1060         libcryptsetup:           ${have_libcryptsetup}
1061         tcpwrap:                 ${have_tcpwrap}
1062         PAM:                     ${have_pam}
1063         AUDIT:                   ${have_audit}
1064         IMA:                     ${have_ima}
1065         SELinux:                 ${have_selinux}
1066         SMACK:                   ${have_smack}
1067         XZ:                      ${have_xz}
1068         ACL:                     ${have_acl}
1069         XATTR:                   ${have_xattr}
1070         GCRYPT:                  ${have_gcrypt}
1071         QRENCODE:                ${have_qrencode}
1072         MICROHTTPD:              ${have_microhttpd}
1073         CHKCONFIG:               ${have_chkconfig}
1074         binfmt:                  ${have_binfmt}
1075         vconsole:                ${have_vconsole}
1076         readahead:               ${have_readahead}
1077         bootchart:               ${have_bootchart}
1078         quotacheck:              ${have_quotacheck}
1079         tmpfiles:                ${have_tmpfiles}
1080         randomseed:              ${have_randomseed}
1081         backlight:               ${have_backlight}
1082         rfkill:                  ${have_rfkill}
1083         logind:                  ${have_logind}
1084         machined:                ${have_machined}
1085         hostnamed:               ${have_hostnamed}
1086         timedated:               ${have_timedated}
1087         localed:                 ${have_localed}
1088         coredump:                ${have_coredump}
1089         polkit:                  ${have_polkit}
1090         efi:                     ${have_efi}
1091         kmod:                    ${have_kmod}
1092         blkid:                   ${have_blkid}
1093         nss-myhostname:          ${have_myhostname}
1094         gudev:                   ${enable_gudev}
1095         gintrospection:          ${enable_introspection}
1096         multi-seat-x:            ${have_multi_seat_x}
1097         kdbus:                   ${have_kdbus}
1098         Python:                  ${have_python}
1099         Python Headers:          ${have_python_devel}
1100         man pages:               ${have_manpages}
1101         gtk-doc:                 ${enable_gtk_doc}
1102         test coverage:           ${have_coverage}
1103         Split /usr:              ${enable_split_usr}
1104         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1105
1106         prefix:                  ${prefix}
1107         rootprefix:              ${with_rootprefix}
1108         sysconf dir:             ${sysconfdir}
1109         datarootdir:             ${datarootdir}
1110         includedir:              ${includedir}
1111         include_prefix:          ${INCLUDE_PREFIX}
1112         lib dir:                 ${libdir}
1113         rootlib dir:             ${with_rootlibdir}
1114         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1115         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1116         Build Python:            ${PYTHON}
1117         Installation Python:     ${PYTHON_BINARY}
1118         sphinx binary:           ${SPHINX_BUILD}
1119         firmware path:           ${FIRMWARE_PATH}
1120         PAM modules dir:         ${with_pamlibdir}
1121         PAM configuration dir:   ${with_pamconfdir}
1122         D-Bus policy dir:        ${with_dbuspolicydir}
1123         D-Bus session dir:       ${with_dbussessionservicedir}
1124         D-Bus system dir:        ${with_dbussystemservicedir}
1125         D-Bus interfaces dir:    ${with_dbusinterfacedir}
1126         Bash completions dir:    ${with_bashcompletiondir}
1127         Zsh completions dir:     ${with_zshcompletiondir}
1128         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1129         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1130         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1131
1132         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1133         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1134         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1135         PYTHON_CFLAGS:           ${PYTHON_DEVEL_CFLAGS}
1136         PYTHON_LIBS:             ${PYTHON_DEVEL_LIBS}
1137 ])