configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 # FIXME: Update to proper web page
  23 AC_INIT([elogind],
  24         [219],
  25         [http://bugs.freedesktop.org/enter_bug.cgi?product=elogind],
  26         [elogind],
  27         [http://www.freedesktop.org/wiki/Software/elogind])
  28
  29 AC_CONFIG_SRCDIR([src/login/logind.c])
  30 AC_CONFIG_MACRO_DIR([m4])
  31 AC_CONFIG_HEADERS([config.h])
  32 AC_CONFIG_AUX_DIR([build-aux])
  33
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AC_SYS_LARGEFILE
  36 AC_PREFIX_DEFAULT([/usr])
  37 AM_MAINTAINER_MODE([enable])
  38 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  39 AM_SILENT_RULES([yes])
  40 AC_CANONICAL_HOST
  41 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  42 LT_PREREQ(2.2)
  43 LT_INIT([disable-static])
  44
  45 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by elogind])])
  46 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by elogind])])
  47
  48 SET_ARCH(X86_64, x86_64*)
  49 SET_ARCH(IA32, i*86*)
  50 SET_ARCH(MIPS, mips*)
  51
  52 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  53 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  54 AS_IF([test x"$intltool_found" != xyes],
  55       [AS_IF([test x"$enable_nls" = xyes],
  56              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  57              [AS_IF([test x"$enable_nls" != xno],
  58                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  59                      enable_nls=no])
  60              ])
  61       ])
  62
  63 AM_NLS
  64 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  65     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  66 IT_PROG_INTLTOOL([0.40.0])
  67 ])
  68
  69 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  70     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  71     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  72     AC_SUBST(INTLTOOL_POLICY_RULE)
  73 ])
  74
  75 GETTEXT_PACKAGE=elogind
  76 AC_SUBST(GETTEXT_PACKAGE)
  77 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [elogind])
  78
  79 AC_PROG_MKDIR_P
  80 AC_PROG_LN_S
  81 AC_PROG_SED
  82 AC_PROG_GREP
  83 AC_PROG_AWK
  84
  85 AC_PROG_CC_C99
  86
  87 AC_PATH_PROG([M4], [m4])
  88 AC_PATH_PROG([XSLTPROC], [xsltproc])
  89
  90 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
  91
  92 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
  93
  94 M4_DEFINES=
  95
  96 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  97 m4_ifdef([GTK_DOC_CHECK], [
  98 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  99          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
 100           enable_gtk_doc=no])
 101
 102 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
 103         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
 104 ])
 105
 106 AC_CHECK_TOOL(GPERF, gperf)
 107 if test -z "$GPERF" ; then
 108         AC_MSG_ERROR([*** gperf not found])
 109 fi
 110
 111 # ------------------------------------------------------------------------------
 112 address_sanitizer_cflags=
 113 address_sanitizer_cppflags=
 114 address_sanitizer_ldflags=
 115 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 116 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 117             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 118             AS_IF([test -z "$with_as_cflags"],
 119                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 120             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 121             address_sanitizer_cppflags="-DVALGRIND=1"
 122             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 123       ])
 124
 125 undefined_sanitizer_cflags=
 126 undefined_sanitizer_cppflags=
 127 undefined_sanitizer_ldflags=
 128 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 129 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 130             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 131             AS_IF([test -z "$with_us_cflags"],
 132                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 133             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 134             undefined_sanitizer_cppflags="-DVALGRIND=1"
 135             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 136       ])
 137
 138 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 139 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 140 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 141
 142 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 143         -pipe \
 144         -Wall \
 145         -Wextra \
 146         -Wno-inline \
 147         -Wundef \
 148         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 149         -Wlogical-op \
 150         -Wsign-compare \
 151         -Wmissing-include-dirs \
 152         -Wold-style-definition \
 153         -Wpointer-arith \
 154         -Winit-self \
 155         -Wdeclaration-after-statement \
 156         -Wfloat-equal \
 157         -Wsuggest-attribute=noreturn \
 158         -Wmissing-prototypes \
 159         -Wstrict-prototypes \
 160         -Wredundant-decls \
 161         -Wmissing-declarations \
 162         -Wmissing-noreturn \
 163         -Wshadow \
 164         -Wendif-labels \
 165         -Wstrict-aliasing=2 \
 166         -Wwrite-strings \
 167         -Wno-long-long \
 168         -Wno-overlength-strings \
 169         -Wno-unused-parameter \
 170         -Wno-missing-field-initializers \
 171         -Wno-unused-result \
 172         -Wno-format-signedness \
 173         -Werror=overflow \
 174         -Wdate-time \
 175         -Wnested-externs \
 176         -ffast-math \
 177         -fno-common \
 178         -fdiagnostics-show-option \
 179         -fno-strict-aliasing \
 180         -fvisibility=hidden \
 181         -ffunction-sections \
 182         -fdata-sections \
 183         -fstack-protector \
 184         -fstack-protector-strong \
 185         -fPIE \
 186         --param=ssp-buffer-size=4])
 187
 188 AS_CASE([$CC], [*clang*],
 189         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 190                -Wno-typedef-redefinition \
 191                -Wno-gnu-variable-sized-type-not-at-end \
 192         ])])
 193
 194 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 195         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 196                -flto -ffat-lto-objects])],
 197         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 198 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 199
 200 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 201         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 202                -Wp,-D_FORTIFY_SOURCE=2])],
 203         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 204 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 205
 206 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 207         -Wl,--as-needed \
 208         -Wl,--no-undefined \
 209         -Wl,--gc-sections \
 210         -Wl,-z,relro \
 211         -Wl,-z,now \
 212         -pie \
 213         -Wl,-fuse-ld=gold])
 214 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 215
 216 AC_CHECK_SIZEOF(pid_t)
 217 AC_CHECK_SIZEOF(uid_t)
 218 AC_CHECK_SIZEOF(gid_t)
 219 AC_CHECK_SIZEOF(time_t)
 220 AC_CHECK_SIZEOF(dev_t)
 221 AC_CHECK_SIZEOF(rlim_t,,[
 222        #include <sys/time.h>
 223        #include <sys/resource.h>
 224 ])
 225
 226 # ------------------------------------------------------------------------------
 227
 228 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 229 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 230 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 231
 232 # unconditionally pull-in librt with old glibc versions
 233 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 234
 235 save_LIBS="$LIBS"
 236 LIBS=
 237 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 238 CAP_LIBS="$LIBS"
 239 AC_SUBST(CAP_LIBS)
 240
 241 AC_CHECK_FUNCS([memfd_create])
 242 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 243 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns, getrandom, renameat2, kcmp, LO_FLAGS_PARTSCAN],
 244                [], [], [[
 245 #include <sys/types.h>
 246 #include <unistd.h>
 247 #include <sys/mount.h>
 248 #include <fcntl.h>
 249 #include <sched.h>
 250 #include <linux/loop.h>
 251 #include <linux/random.h>
 252 ]])
 253
 254 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 255                 IFLA_MACVLAN_FLAGS,
 256                 IFLA_IPVLAN_MODE,
 257                 IFLA_VTI_REMOTE,
 258                 IFLA_PHYS_PORT_ID,
 259                 IFLA_BOND_AD_INFO,
 260                 IFLA_VLAN_PROTOCOL,
 261                 IFLA_VXLAN_LOCAL6,
 262                 IFLA_IPTUN_6RD_RELAY_PREFIXLEN,
 263                 IFLA_BRIDGE_VLAN_INFO,
 264                 IFLA_BRPORT_UNICAST_FLOOD,
 265                 NDA_IFINDEX],
 266 [], [], [[
 267 #include <inttypes.h>
 268 #include <netinet/in.h>
 269 #include <netinet/ether.h>
 270 #include <linux/rtnetlink.h>
 271 #include <net/if.h>
 272 #include <linux/ip.h>
 273 #include <linux/if_tunnel.h>
 274 #include <linux/if_link.h>
 275 #include <linux/if_bridge.h>
 276 #include <linux/neighbour.h>
 277 ]])
 278
 279 # This makes sure pkg.m4 is available.
 280 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 281
 282 # ------------------------------------------------------------------------------
 283 have_dbus=no
 284 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 285 AS_IF([test "x$enable_dbus" != "xno"], [
 286         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 287                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 288                 [have_dbus=no])
 289         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 290                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 291 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 292
 293 # ------------------------------------------------------------------------------
 294 PKG_CHECK_MODULES(UDEV, [libudev])
 295
 296 # ------------------------------------------------------------------------------
 297 have_coverage=no
 298 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 299 if test "x$enable_coverage" = "xyes" ; then
 300         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 301         if test "x$lcov_found" = xno ; then
 302                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 303         else
 304                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 305                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 306                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 307                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 308                 else
 309                         have_coverage=yes
 310                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 311                         -fprofile-arcs \
 312                         -ftest-coverage])
 313                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 314                 fi
 315         fi
 316 fi
 317 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 318
 319 # ------------------------------------------------------------------------------
 320 have_blkid=no
 321 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 322 if test "x$enable_blkid" != "xno"; then
 323         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 324                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 325         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 326                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 327         fi
 328 fi
 329 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 330
 331 # ------------------------------------------------------------------------------
 332 have_seccomp=no
 333 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 334 if test "x$enable_seccomp" != "xno"; then
 335         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 336                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 337                 have_seccomp=yes
 338                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 339                [have_seccomp=no])
 340         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 341                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 342         fi
 343 fi
 344 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 345
 346 # ------------------------------------------------------------------------------
 347 have_selinux=no
 348 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 349 if test "x$enable_selinux" != "xno"; then
 350         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 351                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 352                  have_selinux=yes
 353                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 354                 [have_selinux=no])
 355         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 356                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 357         fi
 358 fi
 359 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 360
 361 have_apparmor=no
 362 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 363 if test "x$enable_apparmor" != "xno"; then
 364         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 365                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 366                  have_apparmor=yes
 367                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 368                 [have_apparmor=no])
 369         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 370                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 371         fi
 372 fi
 373 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 374
 375 # ------------------------------------------------------------------------------
 376 AC_ARG_ENABLE([pam],
 377         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 378                 [case "${enableval}" in
 379                         yes) have_pam=yes ;;
 380                         no) have_pam=no ;;
 381                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 382                 esac],
 383                 [have_pam=auto])
 384
 385 if test "x${have_pam}" != xno ; then
 386         AC_CHECK_HEADERS(
 387                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 388                 [have_pam=yes],
 389                 [if test "x$have_pam" = xyes ; then
 390                         AC_MSG_ERROR([*** PAM headers not found.])
 391                 fi])
 392
 393         AC_CHECK_LIB(
 394                 [pam],
 395                 [pam_syslog],
 396                 [have_pam=yes],
 397                 [if test "x$have_pam" = xyes ; then
 398                         AC_MSG_ERROR([*** libpam not found.])
 399                 fi])
 400
 401         if test "x$have_pam" = xyes ; then
 402                 PAM_LIBS="-lpam -lpam_misc"
 403                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 404                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 405         else
 406                 have_pam=no
 407         fi
 408 else
 409         PAM_LIBS=
 410 fi
 411 AC_SUBST(PAM_LIBS)
 412 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 413
 414 # ------------------------------------------------------------------------------
 415 AC_ARG_ENABLE([acl],
 416         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 417                 [case "${enableval}" in
 418                         yes) have_acl=yes ;;
 419                         no) have_acl=no ;;
 420                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 421                 esac],
 422                 [have_acl=auto])
 423
 424 if test "x${have_acl}" != xno ; then
 425         AC_CHECK_HEADERS(
 426                 [sys/acl.h acl/libacl.h],
 427                 [have_acl=yes],
 428                 [if test "x$have_acl" = xyes ; then
 429                         AC_MSG_ERROR([*** ACL headers not found.])
 430                 fi])
 431
 432         AC_CHECK_LIB(
 433                 [acl],
 434                 [acl_get_file],
 435                 [have_acl=yes],
 436                 [if test "x$have_acl" = xyes ; then
 437                         AC_MSG_ERROR([*** libacl not found.])
 438                 fi])
 439
 440         if test "x$have_acl" = xyes ; then
 441                 ACL_LIBS="-lacl"
 442                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 443                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 444         else
 445                 have_acl=no
 446         fi
 447 else
 448         ACL_LIBS=
 449 fi
 450 AC_SUBST(ACL_LIBS)
 451 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 452
 453 # ------------------------------------------------------------------------------
 454 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 455                 [case "${enableval}" in
 456                         yes) have_smack=yes ;;
 457                         no) have_smack=no ;;
 458                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 459                 esac],
 460                 [have_smack=auto])
 461
 462 if test "x${have_smack}" = xauto; then
 463         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 464         have_smack=yes
 465 fi
 466
 467 AC_ARG_WITH(smack-run-label,
 468 AS_HELP_STRING([--with-smack-run-label=STRING],
 469         [run systemd --system with a specific SMACK label]),
 470         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run with a smack label])],
 471         [])
 472
 473 if test "x${have_smack}" = xyes ; then
 474         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 475 fi
 476
 477 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 478
 479 # ------------------------------------------------------------------------------
 480 AC_ARG_WITH(system-uid-max,
 481         AS_HELP_STRING([--with-system-uid-max=UID]
 482                 [Maximum UID for system users]),
 483         [SYSTEM_UID_MAX="$withval"],
 484         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
 485
 486 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
 487 AC_SUBST(SYSTEM_UID_MAX)
 488
 489 # ------------------------------------------------------------------------------
 490 AC_ARG_WITH(system-gid-max,
 491         AS_HELP_STRING([--with-system-gid-max=GID]
 492                 [Maximum GID for system groups]),
 493         [SYSTEM_GID_MAX="$withval"],
 494         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
 495
 496 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
 497 AC_SUBST(SYSTEM_GID_MAX)
 498
 499 # ------------------------------------------------------------------------------
 500 have_polkit=no
 501 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 502 if test "x$enable_polkit" != "xno"; then
 503         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 504         have_polkit=yes
 505 fi
 506 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 507
 508 # ------------------------------------------------------------------------------
 509 have_kdbus=no
 510 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--enable-kdbus], [do connect to kdbus by default]))
 511 if test "x$enable_kdbus" = "xyes"; then
 512         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus support is to be enabled])
 513         have_kdbus=yes
 514         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
 515 fi
 516 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
 517
 518 # ------------------------------------------------------------------------------
 519 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
 520
 521 # ------------------------------------------------------------------------------
 522 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0],
 523                   [have_glib=yes], [have_glib=no])
 524 AS_IF([test "x$have_glib" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 525
 526 # ------------------------------------------------------------------------------
 527 have_manpages=no
 528 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 529 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
 530 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 531
 532 # ------------------------------------------------------------------------------
 533 AC_SUBST(M4_DEFINES)
 534
 535 AC_ARG_WITH([dbuspolicydir],
 536         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 537         [],
 538         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
 539
 540 AC_ARG_WITH([dbussessionservicedir],
 541         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 542         [],
 543         [with_dbussessionservicedir=${datadir}/dbus-1/services])
 544
 545 AC_ARG_WITH([dbussystemservicedir],
 546         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 547         [],
 548         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
 549
 550 AC_ARG_WITH([bashcompletiondir],
 551         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 552         [],
 553         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 554                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 555         ] , [
 556                 with_bashcompletiondir=${datadir}/bash-completion/completions
 557         ])])
 558
 559 AC_ARG_WITH([zshcompletiondir],
 560         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
 561         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
 562
 563 AC_ARG_WITH([rootprefix],
 564         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 565         [], [with_rootprefix=${ac_default_prefix}])
 566
 567 AC_ARG_WITH([rootlibdir],
 568         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 569         [],
 570         [with_rootlibdir=${libdir}])
 571
 572 AC_ARG_WITH([pamlibdir],
 573         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 574         [],
 575         [with_pamlibdir=${with_rootlibdir}/security])
 576
 577 AC_ARG_WITH([pamconfdir],
 578         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
 579         [],
 580         [with_pamconfdir=${sysconfdir}/pam.d])
 581
 582 AC_ARG_ENABLE([split-usr],
 583         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 584         [],
 585         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 586                 enable_split_usr=yes
 587         ], [
 588                 enable_split_usr=no
 589         ])])
 590
 591 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 592         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 593 ])
 594
 595 # Work around intltoolize and gtk-doc problems in VPATH builds
 596 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 597                                        [Define to do gtk-doc tests])
 598 AS_IF([test "x$0" != "x./configure"], [
 599         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
 600 ])
 601
 602 AC_ARG_ENABLE(tests,
 603         [AC_HELP_STRING([--disable-tests], [disable tests])],
 604         enable_tests=$enableval, enable_tests=yes)
 605 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 606
 607 AC_ARG_ENABLE(debug,
 608         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
 609         [if test "x$enableval" = "xyes"; then
 610                 enableval="hashmap,mmap-cache"
 611         fi
 612         saved_ifs="$IFS"
 613         IFS="$IFS$PATH_SEPARATOR,"
 614         for name in $enableval; do
 615                 case $name in
 616                 hashmap)
 617                         enable_debug_hashmap=yes
 618                         ;;
 619                 mmap-cache)
 620                         enable_debug_mmap_cache=yes
 621                         ;;
 622                 esac
 623         done
 624         IFS="$saved_ifs"],[])
 625
 626 enable_debug=""
 627 AS_IF([test x$enable_debug_hashmap = xyes], [
 628         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
 629         enable_debug="hashmap $enable_debug"
 630 ])
 631 AS_IF([test x$enable_debug_mmap_cache = xyes], [
 632         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
 633         enable_debug="mmap-cache $enable_debug"
 634 ])
 635 test -z "$enable_debug" && enable_debug="none"
 636
 637 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 638 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 639 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 640 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 641 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
 642 AC_SUBST([pamlibdir], [$with_pamlibdir])
 643 AC_SUBST([pamconfdir], [$with_pamconfdir])
 644 AC_SUBST([rootprefix], [$with_rootprefix])
 645 AC_SUBST([rootlibdir], [$with_rootlibdir])
 646
 647 AC_CONFIG_FILES([
 648         Makefile po/Makefile.in
 649 ])
 650
 651 AC_OUTPUT
 652 AC_MSG_RESULT([
 653         $PACKAGE_NAME $VERSION
 654
 655         PAM:                     ${have_pam}
 656         AppArmor:                ${have_apparmor}
 657         SELinux:                 ${have_selinux}
 658         SECCOMP:                 ${have_seccomp}
 659         SMACK:                   ${have_smack}
 660         ACL:                     ${have_acl}
 661         polkit:                  ${have_polkit}
 662         blkid:                   ${have_blkid}
 663         dbus:                    ${have_dbus}
 664         kdbus:                   ${have_kdbus}
 665         man pages:               ${have_manpages}
 666         gtk-doc:                 ${enable_gtk_doc}
 667         test coverage:           ${have_coverage}
 668         Split /usr:              ${enable_split_usr}
 669         extra debugging:         ${enable_debug}
 670
 671         prefix:                  ${prefix}
 672         rootprefix:              ${with_rootprefix}
 673         sysconf dir:             ${sysconfdir}
 674         datarootdir:             ${datarootdir}
 675         includedir:              ${includedir}
 676         lib dir:                 ${libdir}
 677         rootlib dir:             ${with_rootlibdir}
 678         PAM modules dir:         ${with_pamlibdir}
 679         PAM configuration dir:   ${with_pamconfdir}
 680         D-Bus policy dir:        ${with_dbuspolicydir}
 681         D-Bus session dir:       ${with_dbussessionservicedir}
 682         D-Bus system dir:        ${with_dbussystemservicedir}
 683         Bash completions dir:    ${with_bashcompletiondir}
 684         Zsh completions dir:     ${with_zshcompletiondir}
 685         Maximum System UID:      ${SYSTEM_UID_MAX}
 686         Maximum System GID:      ${SYSTEM_GID_MAX}
 687
 688         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 689         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
 690         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 691 ])