chiark / gitweb /
README: add /lib/udev/ is private
[elogind.git] / configure.ac
1 AC_INIT([udev], [143], [linux-hotplug@vger.kernel.org])
2 AC_PREREQ(2.60)
3 AM_INIT_AUTOMAKE([check-news foreign 1.9 dist-bzip2])
4 AC_DISABLE_STATIC
5 AC_USE_SYSTEM_EXTENSIONS
6 dnl AM_SILENT_RULES
7 AC_SYS_LARGEFILE
8 AC_CONFIG_MACRO_DIR([m4])
9 AC_PROG_LIBTOOL
10 AC_PROG_AWK
11 GTK_DOC_CHECK(1.10)
12 AC_PREFIX_DEFAULT([/usr])
13 AC_PATH_PROG([XSLTPROC], [xsltproc])
14
15 AC_ARG_WITH([rootlibdir],
16         AS_HELP_STRING([--with-rootlibdir=DIR], [rootfs directory to install shared libraries]),
17         [], [with_rootlibdir=$libdir])
18 AC_SUBST([rootlibdir], [$with_rootlibdir])
19
20 AC_ARG_WITH([selinux],
21         AS_HELP_STRING([--with-selinux], [enable SELinux support]),
22         [], [with_selinux=no])
23 if test "x$with_selinux" = xyes; then
24         LIBS_save=$LIBS
25         AC_CHECK_LIB(selinux, getprevcon,
26                 [],
27                 AC_MSG_ERROR([SELinux selected but libselinux not found]))
28         LIBS=$LIBS_save
29         SELINUX_LIBS="-lselinux -lsepol"
30         AC_DEFINE(WITH_SELINUX, [1] ,[SELinux support.])
31 fi
32 AC_SUBST([SELINUX_LIBS])
33 AM_CONDITIONAL(WITH_SELINUX, [test "x$with_selinux" = xyes])
34
35 AC_ARG_ENABLE([debug],
36         AS_HELP_STRING([--enable-debug], [enable debug messages]),
37         [], [enable_debug=no])
38 if test "x$enable_debug" = "xyes"; then
39         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
40 fi
41
42 AC_ARG_ENABLE([logging],
43         AS_HELP_STRING([--disable-logging], [disable system logging]),
44         [], enable_logging=yes)
45 if test "x$enable_logging" = "xyes"; then
46         AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
47 fi
48
49 AC_ARG_ENABLE([extras],
50         AS_HELP_STRING([--disable-extras], [disable extras with external dependencies]),
51         [], [enable_extras=yes])
52 if test "x$enable_extras" = xyes; then
53         AC_PATH_PROG([GPERF], [gperf])
54         if test -z "$GPERF"; then
55                 AC_MSG_ERROR([gperf is needed])
56         fi
57
58         PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.7.0 gobject-2.0 >= 2.7.0])
59         AC_SUBST([GLIB_CFLAGS])
60         AC_SUBST([GLIB_LIBS])
61
62         AC_CHECK_LIB([acl], [acl_init], [:], AC_MSG_ERROR([libacl not found]))
63         AC_CHECK_HEADER([acl/libacl.h], [:], AC_MSG_ERROR([libacl header not found]))
64
65         PKG_CHECK_MODULES(LIBUSB, libusb >= 0.1.12)
66         AC_SUBST(LIBUSB_CFLAGS)
67         AC_SUBST(LIBUSB_LIBS)
68
69         PKG_CHECK_MODULES(USBUTILS, usbutils >= 0.82)
70         AC_SUBST([USB_DATABASE], [$($PKG_CONFIG --variable=usbids usbutils)])
71
72         AC_CHECK_FILES([/usr/share/pci.ids], [pciids=/usr/share/pci.ids])
73         AC_CHECK_FILES([/usr/share/hwdata/pci.ids], [pciids=/usr/share/hwdata/pci.ids])
74         AC_CHECK_FILES([/usr/share/misc/pci.ids], [pciids=/usr/share/misc/pci.ids])
75         AC_ARG_WITH(pci-ids-path,
76                 AS_HELP_STRING([--pci-ids-path=DIR], [Path to pci.ids file]),
77                 [PCI_DATABASE=${withval}],
78                 [if test -n "$pciids" ; then
79                         PCI_DATABASE="$pciids"
80                 else
81                         AC_MSG_ERROR([pci.ids not found, try --with-pci-ids-path=])
82                 fi])
83         AC_SUBST(PCI_DATABASE)
84 fi
85 AM_CONDITIONAL([ENABLE_EXTRAS], [test "x$enable_extras" = xyes])
86
87 AC_ARG_ENABLE([introspection],
88         AS_HELP_STRING([--enable-introspection], [enable GObject introspection]),
89         [], [enable_introspection=no])
90 if test "x$enable_introspection" = xyes; then
91         PKG_CHECK_MODULES([INTROSPECTION], [gobject-introspection-1.0 >= 0.6.2])
92         AC_DEFINE([ENABLE_INTROSPECTION], [1], [enable GObject introspection support])
93         AC_SUBST([G_IR_SCANNER], [$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)])
94         AC_SUBST([G_IR_COMPILER], [$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)])
95         AC_SUBST([G_IR_GENERATE], [$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)])
96         AC_SUBST([GIRDIR], [$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)])
97         AC_SUBST([GIRTYPELIBDIR], [$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)])
98 fi
99 AM_CONDITIONAL([ENABLE_INTROSPECTION], [test "x$enable_introspection" = xyes])
100
101 AC_CONFIG_HEADERS(config.h)
102 AC_CONFIG_FILES([
103         Makefile
104         libudev/Makefile
105         libudev/libudev.pc
106         libudev/docs/Makefile
107         libudev/docs/version.xml
108         udev/Makefile
109         rules/Makefile
110         extras/Makefile
111         extras/ata_id/Makefile
112         extras/cdrom_id/Makefile
113         extras/edd_id/Makefile
114         extras/path_id/Makefile
115         extras/firmware/Makefile
116         extras/collect/Makefile
117         extras/floppy/Makefile
118         extras/fstab_import/Makefile
119         extras/rule_generator/Makefile
120         extras/scsi_id/Makefile
121         extras/usb_id/Makefile
122         extras/v4l_id/Makefile
123         extras/hid2hci/Makefile
124         extras/udev-acl/Makefile
125         extras/usb-db/Makefile
126         extras/gudev/Makefile
127         extras/gudev/gudev-1.0.pc
128         extras/gudev/docs/Makefile
129         extras/gudev/docs/version.xml
130         extras/keymap/Makefile
131         extras/modem-modeswitch/Makefile
132 ])
133
134 AC_OUTPUT
135 AC_MSG_RESULT([
136         udev $VERSION
137         ========
138
139         prefix:                 ${prefix}
140         sysconfdir:             ${sysconfdir}
141         sbindir:                ${sbindir}
142         libdir:                 ${libdir}
143         rootlibdir:             ${rootlibdir}
144         libexecdir:             ${libexecdir}
145
146         datarootdir:            ${datarootdir}
147         mandir:                 ${mandir}
148         includedir:             ${includedir}
149
150         logging:                ${enable_logging}
151         debug:                  ${enable_debug}
152         selinux:                ${with_selinux}
153
154         compiler:               ${CC}
155         cflags:                 ${CFLAGS}
156         ldflags:                ${LDFLAGS}
157
158         extras:                 ${enable_extras}
159         gintrospection:         ${enable_introspection}
160
161         usb.ids:                ${USB_DATABASE}
162         pci.ids:                ${PCI_DATABASE}
163
164         xsltproc:               ${XSLTPROC}
165         gperf:                  ${GPERF}
166 ])