configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [206],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT([disable-static])
  46
  47 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  48 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  49
  50 # i18n stuff for the PolicyKit policy files
  51 IT_PROG_INTLTOOL([0.40.0])
  52
  53 GETTEXT_PACKAGE=systemd
  54 AC_SUBST(GETTEXT_PACKAGE)
  55
  56 AC_PROG_MKDIR_P
  57 AC_PROG_LN_S
  58 AC_PROG_SED
  59 AC_PROG_GREP
  60 AC_PROG_AWK
  61
  62 AC_PROG_CC
  63 AC_PROG_CC_C99
  64 AM_PROG_CC_C_O
  65 AC_PROG_GCC_TRADITIONAL
  66
  67 AC_PATH_PROG([M4], [m4])
  68 AC_PATH_PROG([XSLTPROC], [xsltproc])
  69
  70 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  71 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  72
  73 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  74
  75 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  76
  77 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod])
  78
  79 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec])
  80
  81 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  82 m4_ifdef([GTK_DOC_CHECK], [
  83 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  84          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
  85           enable_gtk_doc=no])
  86
  87 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  88         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  89 ])
  90
  91 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  92 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  93 ], [
  94    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
  95    enable_introspection=no])
  96
  97 AC_CHECK_TOOL(OBJCOPY, objcopy)
  98 AC_CHECK_TOOL(STRINGS, strings)
  99 AC_CHECK_TOOL(GPERF, gperf)
 100 if test -z "$GPERF" ; then
 101         AC_MSG_ERROR([*** gperf not found])
 102 fi
 103
 104 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 105         -pipe \
 106         -Wall \
 107         -Wextra \
 108         -Wno-inline \
 109         -Wundef \
 110         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 111         -Wlogical-op \
 112         -Wsign-compare \
 113         -Wmissing-include-dirs \
 114         -Wold-style-definition \
 115         -Wpointer-arith \
 116         -Winit-self \
 117         -Wdeclaration-after-statement \
 118         -Wfloat-equal \
 119         -Wmissing-prototypes \
 120         -Wstrict-prototypes \
 121         -Wredundant-decls \
 122         -Wmissing-declarations \
 123         -Wmissing-noreturn \
 124         -Wshadow \
 125         -Wendif-labels \
 126         -Wcast-align \
 127         -Wstrict-aliasing=2 \
 128         -Wwrite-strings \
 129         -Wno-long-long \
 130         -Wno-overlength-strings \
 131         -Wno-unused-parameter \
 132         -Wno-missing-field-initializers \
 133         -Wno-unused-result \
 134         -Werror=overflow \
 135         -ffast-math \
 136         -fno-common \
 137         -fdiagnostics-show-option \
 138         -fdiagnostics-color \
 139         -fno-strict-aliasing \
 140         -fvisibility=hidden \
 141         -ffunction-sections \
 142         -fdata-sections \
 143         -fstack-protector \
 144         --param=ssp-buffer-size=4])
 145 AC_SUBST([OUR_CFLAGS], $with_cflags)
 146
 147 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*], [
 148         CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 149                -Wp,-D_FORTIFY_SOURCE=2])], [
 150         python_extra_cflags=-Wp,-U_FORTIFY_SOURCE
 151         AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 152 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 153
 154 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 155         -Wl,--as-needed \
 156         -Wl,--no-undefined \
 157         -Wl,--gc-sections \
 158         -Wl,-z,relro \
 159         -Wl,-z,now])
 160 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 161
 162 # ------------------------------------------------------------------------------
 163 # we use python to build the man page index, and for systemd-python
 164 have_python=no
 165 have_python_devel=no
 166
 167 AC_ARG_WITH([python],
 168         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 169
 170 AS_IF([test "x$with_python" != "xno"], [
 171         AM_PATH_PYTHON(,, [:])
 172         AS_IF([test "$PYTHON" != :], [have_python=yes])
 173 ])
 174 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 175 AS_IF([test "x$PYTHON_BINARY" = "x"],
 176       [AS_IF([test "x$have_python" = "xyes"],
 177              [PYTHON_BINARY="$(which "$PYTHON")"],
 178              [PYTHON_BINARY=/usr/bin/python])])
 179 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 180
 181 AS_IF([test "x$with_python" != "xno"], [
 182         AC_PATH_PROG(PYTHON_CONFIG, python${PYTHON_VERSION}-config)
 183         AS_IF([test -n "$PYTHON_CONFIG"], [
 184               have_python_devel=yes
 185               PYTHON_CFLAGS="$($PYTHON_CONFIG --cflags) $python_extra_cflags"
 186               PYTHON_LIBS="$($PYTHON_CONFIG --ldflags)"
 187               AC_SUBST(PYTHON_CFLAGS)
 188               AC_SUBST(PYTHON_LIBS)
 189               AC_PATH_PROGS(SPHINX_BUILD, sphinx-build-${PYTHON_VERSION} sphinx-build)
 190         ])
 191 ])
 192 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 193
 194 # ------------------------------------------------------------------------------
 195
 196 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 197 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 198
 199 save_LIBS="$LIBS"
 200 LIBS=
 201 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 202 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 203 CAP_LIBS="$LIBS"
 204 LIBS="$save_LIBS"
 205 AC_SUBST(CAP_LIBS)
 206
 207 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 208 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 209 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 210 #include <unistd.h>
 211 #include <sys/mount.h>
 212 #include <fcntl.h>]])
 213
 214 # This makes sure pkg.m4 is available.
 215 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 216
 217 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 218
 219 # ------------------------------------------------------------------------------
 220 have_coverage=no
 221 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 222 if test "x$enable_coverage" = "xyes" ; then
 223         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 224         if test "x$lcov_found" = xno ; then
 225                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 226         else
 227                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 228                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 229                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 230                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 231                 else
 232                         have_coverage=yes
 233                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 234                         -fprofile-arcs \
 235                         -ftest-coverage])
 236                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 237                 fi
 238         fi
 239 fi
 240 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 241
 242 # ------------------------------------------------------------------------------
 243 have_kmod=no
 244 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 245 if test "x$enable_kmod" != "xno"; then
 246         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 247         if test "x$have_kmod" = "xyes"; then
 248                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 14 ],
 249                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 250                         AC_MSG_ERROR([*** kmod version >= 14 not found]))
 251         fi
 252         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 253                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 254         fi
 255 fi
 256 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 257
 258 # ------------------------------------------------------------------------------
 259 have_blkid=no
 260 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 261 if test "x$enable_blkid" != "xno"; then
 262         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 263                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 264         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 265                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 266         fi
 267 fi
 268 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 269
 270 # ------------------------------------------------------------------------------
 271 have_ima=yes
 272 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 273                 [case "${enableval}" in
 274                         yes) have_ima=yes ;;
 275                         no) have_ima=no ;;
 276                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 277                 esac],
 278                 [have_ima=yes])
 279
 280 if test "x${have_ima}" != xno ; then
 281         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 282 fi
 283
 284 # ------------------------------------------------------------------------------
 285 have_chkconfig=yes
 286 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 287                 [case "${enableval}" in
 288                         yes) have_chkconfig=yes ;;
 289                         no) have_chkconfig=no ;;
 290                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 291                 esac],
 292                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 293                 if test -z "$CHKCONFIG"; then
 294                         have_chkconfig=no
 295                 else
 296                         have_chkconfig=yes
 297                 fi])
 298
 299 if test "x${have_chkconfig}" != xno ; then
 300         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 301 fi
 302
 303 # ------------------------------------------------------------------------------
 304 have_selinux=no
 305 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 306 if test "x$enable_selinux" != "xno"; then
 307         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 308                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 309         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 310                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 311         fi
 312 fi
 313 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 314
 315 AC_ARG_WITH(debug-shell,
 316         AS_HELP_STRING([--with-debug-shell=PATH],
 317                 [Path to debug shell binary]),
 318         [SUSHELL="$withval"],[
 319         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 320
 321 AC_SUBST(SUSHELL)
 322
 323 AC_ARG_WITH([debug-tty],
 324         AS_HELP_STRING([--with-debug-tty=PATH],
 325                 [Specify the tty device for debug shell]),
 326         [DEBUGTTY="$withval"],
 327         [DEBUGTTY=/dev/tty9])
 328
 329 AC_SUBST(DEBUGTTY)
 330
 331 # ------------------------------------------------------------------------------
 332 have_xz=no
 333 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 334 if test "x$enable_xz" != "xno"; then
 335         PKG_CHECK_MODULES(XZ, [ liblzma ],
 336                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 337         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 338                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 339         fi
 340 fi
 341 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 342
 343 # ------------------------------------------------------------------------------
 344 AC_ARG_ENABLE([tcpwrap],
 345         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 346                 [case "${enableval}" in
 347                         yes) have_tcpwrap=yes ;;
 348                         no) have_tcpwrap=no ;;
 349                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 350                 esac],
 351                 [have_tcpwrap=auto])
 352
 353 if test "x${have_tcpwrap}" != xno ; then
 354         ACX_LIBWRAP
 355         if test "x${LIBWRAP_LIBS}" = x ; then
 356                 if test "x$have_tcpwrap" = xyes ; then
 357                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 358                 fi
 359                 have_tcpwrap=no
 360         else
 361                 have_tcpwrap=yes
 362         fi
 363 else
 364         LIBWRAP_LIBS=
 365 fi
 366 AC_SUBST(LIBWRAP_LIBS)
 367
 368 # ------------------------------------------------------------------------------
 369 AC_ARG_ENABLE([pam],
 370         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 371                 [case "${enableval}" in
 372                         yes) have_pam=yes ;;
 373                         no) have_pam=no ;;
 374                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 375                 esac],
 376                 [have_pam=auto])
 377
 378 if test "x${have_pam}" != xno ; then
 379         AC_CHECK_HEADERS(
 380                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 381                 [have_pam=yes],
 382                 [if test "x$have_pam" = xyes ; then
 383                         AC_MSG_ERROR([*** PAM headers not found.])
 384                 fi])
 385
 386         AC_CHECK_LIB(
 387                 [pam],
 388                 [pam_syslog],
 389                 [have_pam=yes],
 390                 [if test "x$have_pam" = xyes ; then
 391                         AC_MSG_ERROR([*** libpam not found.])
 392                 fi])
 393
 394         if test "x$have_pam" = xyes ; then
 395                 PAM_LIBS="-lpam -lpam_misc"
 396                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 397         else
 398                 have_pam=no
 399         fi
 400 else
 401         PAM_LIBS=
 402 fi
 403 AC_SUBST(PAM_LIBS)
 404 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 405
 406 # ------------------------------------------------------------------------------
 407 AC_ARG_ENABLE([acl],
 408         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 409                 [case "${enableval}" in
 410                         yes) have_acl=yes ;;
 411                         no) have_acl=no ;;
 412                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 413                 esac],
 414                 [have_acl=auto])
 415
 416 if test "x${have_acl}" != xno ; then
 417         AC_CHECK_HEADERS(
 418                 [sys/acl.h acl/libacl.h],
 419                 [have_acl=yes],
 420                 [if test "x$have_acl" = xyes ; then
 421                         AC_MSG_ERROR([*** ACL headers not found.])
 422                 fi])
 423
 424         AC_CHECK_LIB(
 425                 [acl],
 426                 [acl_get_file],
 427                 [have_acl=yes],
 428                 [if test "x$have_acl" = xyes ; then
 429                         AC_MSG_ERROR([*** libacl not found.])
 430                 fi])
 431
 432         if test "x$have_acl" = xyes ; then
 433                 ACL_LIBS="-lacl"
 434                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 435         else
 436                 have_acl=no
 437         fi
 438 else
 439         ACL_LIBS=
 440 fi
 441 AC_SUBST(ACL_LIBS)
 442 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 443
 444 # ------------------------------------------------------------------------------
 445 AC_ARG_ENABLE([xattr],
 446         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 447                 [case "${enableval}" in
 448                         yes) have_xattr=yes ;;
 449                         no) have_xattr=no ;;
 450                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 451                 esac],
 452                 [have_xattr=auto])
 453
 454 if test "x${have_xattr}" != xno ; then
 455         AC_CHECK_HEADERS(
 456                 [attr/xattr.h],
 457                 [have_xattr=yes],
 458                 [if test "x$have_xattr" = xyes ; then
 459                         AC_MSG_ERROR([*** XATTR headers not found.])
 460                 fi])
 461
 462         AC_CHECK_LIB(
 463                 [attr],
 464                 [fsetxattr],
 465                 [have_xattr=yes],
 466                 [if test "x$have_xattr" = xyes ; then
 467                         AC_MSG_ERROR([*** libattr not found.])
 468                 fi])
 469
 470         if test "x$have_xattr" = xyes ; then
 471                 XATTR_LIBS="-lattr"
 472                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 473         else
 474                 have_xattr=no
 475         fi
 476 else
 477         XATTR_LIBS=
 478 fi
 479 AC_SUBST(XATTR_LIBS)
 480 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 481
 482 # ------------------------------------------------------------------------------
 483 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 484                 [case "${enableval}" in
 485                         yes) have_smack=yes ;;
 486                         no) have_smack=no ;;
 487                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 488                 esac],
 489                 [have_smack=auto])
 490
 491 if test "x${have_xattr}" = xno; then
 492         if test "x${have_smack}" = xyes; then
 493                 AC_MSG_ERROR(SMACK requires xattr support)
 494         else
 495                 have_smack=no
 496         fi
 497 else
 498         if test "x${have_smack}" = xauto; then
 499                 have_smack=yes
 500         fi
 501 fi
 502
 503 if test "x${have_smack}" = xyes ; then
 504         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 505 fi
 506
 507 # ------------------------------------------------------------------------------
 508 AC_ARG_ENABLE([gcrypt],
 509         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 510                 [case "${enableval}" in
 511                         yes) have_gcrypt=yes ;;
 512                         no) have_gcrypt=no ;;
 513                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 514                 esac],
 515                 [have_gcrypt=auto])
 516
 517 if test "x${have_gcrypt}" != xno ; then
 518         AM_PATH_LIBGCRYPT(
 519                 [1.4.5],
 520                 [have_gcrypt=yes],
 521                 [if test "x$have_gcrypt" = xyes ; then
 522                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 523                 fi])
 524
 525         if test "x$have_gcrypt" = xyes ; then
 526                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 527                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 528                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 529         else
 530                 have_gcrypt=no
 531         fi
 532 else
 533         GCRYPT_LIBS=
 534         GCRYPT_CFLAGS=
 535 fi
 536 AC_SUBST(GCRYPT_LIBS)
 537 AC_SUBST(GCRYPT_CFLAGS)
 538 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 539
 540 # ------------------------------------------------------------------------------
 541 AC_ARG_ENABLE([audit],
 542         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 543                 [case "${enableval}" in
 544                         yes) have_audit=yes ;;
 545                         no) have_audit=no ;;
 546                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 547                 esac],
 548                 [have_audit=auto])
 549
 550 if test "x${have_audit}" != xno ; then
 551         AC_CHECK_HEADERS(
 552                 [libaudit.h],
 553                 [have_audit=yes],
 554                 [if test "x$have_audit" = xyes ; then
 555                         AC_MSG_ERROR([*** AUDIT headers not found.])
 556                 fi])
 557
 558         AC_CHECK_LIB(
 559                 [audit],
 560                 [audit_open],
 561                 [have_audit=yes],
 562                 [if test "x$have_audit" = xyes ; then
 563                         AC_MSG_ERROR([*** libaudit not found.])
 564                 fi])
 565
 566         if test "x$have_audit" = xyes ; then
 567                 AUDIT_LIBS="-laudit"
 568                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 569         else
 570                 have_audit=no
 571         fi
 572 else
 573         AUDIT_LIBS=
 574 fi
 575 AC_SUBST(AUDIT_LIBS)
 576
 577 # ------------------------------------------------------------------------------
 578 have_libcryptsetup=no
 579 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 580 if test "x$enable_libcryptsetup" != "xno"; then
 581         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 582                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 583         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 584                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 585         fi
 586 fi
 587 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 588
 589 # ------------------------------------------------------------------------------
 590 have_qrencode=no
 591 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 592 if test "x$enable_qrencode" != "xno"; then
 593         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 594                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 595         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 596                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 597         fi
 598 fi
 599 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 600
 601 # ------------------------------------------------------------------------------
 602 have_microhttpd=no
 603 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 604 if test "x$enable_microhttpd" != "xno"; then
 605         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 606                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 607         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 608                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 609         fi
 610 fi
 611 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 612
 613 # ------------------------------------------------------------------------------
 614 have_binfmt=no
 615 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 616 if test "x$enable_binfmt" != "xno"; then
 617         have_binfmt=yes
 618 fi
 619 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 620
 621 # ------------------------------------------------------------------------------
 622 have_vconsole=no
 623 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 624 if test "x$enable_vconsole" != "xno"; then
 625         have_vconsole=yes
 626 fi
 627 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 628
 629 # ------------------------------------------------------------------------------
 630 have_readahead=no
 631 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 632 if test "x$enable_readahead" != "xno"; then
 633         have_readahead=yes
 634 fi
 635 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 636
 637 # ------------------------------------------------------------------------------
 638 have_bootchart=no
 639 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 640 if test "x$enable_bootchart" != "xno"; then
 641         have_bootchart=yes
 642 fi
 643 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 644
 645 # ------------------------------------------------------------------------------
 646 have_quotacheck=no
 647 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 648 if test "x$enable_quotacheck" != "xno"; then
 649         have_quotacheck=yes
 650 fi
 651 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 652
 653 # ------------------------------------------------------------------------------
 654 have_tmpfiles=no
 655 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 656 if test "x$enable_tmpfiles" != "xno"; then
 657         have_tmpfiles=yes
 658 fi
 659 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 660
 661 # ------------------------------------------------------------------------------
 662 have_randomseed=no
 663 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 664 if test "x$enable_randomseed" != "xno"; then
 665         have_randomseed=yes
 666 fi
 667 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 668
 669 # ------------------------------------------------------------------------------
 670 have_logind=no
 671 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 672 if test "x$enable_logind" != "xno"; then
 673         have_logind=yes
 674 fi
 675 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 676 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 677
 678 # ------------------------------------------------------------------------------
 679 have_machined=no
 680 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
 681 if test "x$enable_machined" != "xno"; then
 682         have_machined=yes
 683 fi
 684 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
 685 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
 686
 687 # ------------------------------------------------------------------------------
 688 have_hostnamed=no
 689 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 690 if test "x$enable_hostnamed" != "xno"; then
 691         have_hostnamed=yes
 692 fi
 693 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 694
 695 # ------------------------------------------------------------------------------
 696 have_timedated=no
 697 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 698 if test "x$enable_timedated" != "xno"; then
 699         have_timedated=yes
 700 fi
 701 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 702
 703 # ------------------------------------------------------------------------------
 704 have_localed=no
 705 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 706 if test "x$enable_localed" != "xno"; then
 707         have_localed=yes
 708 fi
 709 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 710
 711 # ------------------------------------------------------------------------------
 712 have_coredump=no
 713 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 714 if test "x$enable_coredump" != "xno"; then
 715         have_coredump=yes
 716 fi
 717 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 718
 719 # ------------------------------------------------------------------------------
 720 have_polkit=no
 721 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 722 if test "x$enable_polkit" != "xno"; then
 723         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 724         have_polkit=yes
 725 fi
 726 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 727
 728 # ------------------------------------------------------------------------------
 729 have_efi=no
 730 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 731 if test "x$enable_efi" != "xno"; then
 732         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 733         have_efi=yes
 734 fi
 735 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 736
 737 # ------------------------------------------------------------------------------
 738 AC_ARG_WITH(rc-local-script-path-start,
 739         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 740                 [Path to /etc/rc.local]),
 741         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 742         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 743
 744 AC_ARG_WITH(rc-local-script-path-stop,
 745         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 746                 [Path to /usr/sbin/halt.local]),
 747         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 748         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 749
 750 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 751 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 752
 753 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 754 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 755
 756 # ------------------------------------------------------------------------------
 757 AC_ARG_WITH(kbd-loadkeys,
 758         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 759                 [Path to loadkeys]),
 760         [KBD_LOADKEYS="$withval"],
 761         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 762
 763 AC_ARG_WITH(kbd-setfont,
 764         AS_HELP_STRING([--with-kbd-setfont=PATH],
 765                 [Path to setfont]),
 766         [KBD_SETFONT="$withval"],
 767         [KBD_SETFONT="/usr/bin/setfont"])
 768
 769 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 770 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 771
 772 AC_SUBST(KBD_LOADKEYS)
 773 AC_SUBST(KBD_SETFONT)
 774
 775 AC_ARG_WITH(telinit,
 776         AS_HELP_STRING([--with-telinit=PATH],
 777                 [Path to telinit]),
 778         [TELINIT="$withval"],
 779         [TELINIT="/lib/upstart/telinit"])
 780
 781 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
 782
 783 AC_SUBST(TELINIT)
 784
 785 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 786
 787 # ------------------------------------------------------------------------------
 788 have_myhostname=no
 789 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 790 if test "x$enable_myhostname" != "xno"; then
 791         AC_HEADER_STDC
 792         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h])
 793
 794         AC_C_CONST
 795         AC_TYPE_SIZE_T
 796         AC_HEADER_TIME
 797
 798         AC_FUNC_MALLOC
 799         AC_FUNC_SELECT_ARGTYPES
 800         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 801
 802         have_myhostname=yes
 803 fi
 804 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 805
 806 # ------------------------------------------------------------------------------
 807 AC_ARG_WITH(firmware-path,
 808        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 809           [Firmware search path (default="")]),
 810        [], [with_firmware_path=""])
 811 OLD_IFS=$IFS
 812 IFS=:
 813 for i in $with_firmware_path; do
 814        if test "x${FIRMWARE_PATH}" = "x"; then
 815               FIRMWARE_PATH="\\\"${i}/\\\""
 816        else
 817               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 818        fi
 819 done
 820 IFS=$OLD_IFS
 821 AC_SUBST(FIRMWARE_PATH)
 822 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
 823 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
 824
 825 # ------------------------------------------------------------------------------
 826 AC_ARG_ENABLE([gudev],
 827        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 828        [], [enable_gudev=yes])
 829 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
 830 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 831 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 832
 833 # ------------------------------------------------------------------------------
 834 have_manpages=no
 835 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 836 AS_IF([test "x$enable_manpages" != xno], [
 837         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 838                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 839         ])
 840         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 841 ])
 842 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 843
 844 # ------------------------------------------------------------------------------
 845
 846 # Location of the init scripts as mandated by LSB
 847 SYSTEM_SYSVINIT_PATH=/etc/init.d
 848 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 849 M4_DEFINES=
 850
 851 AC_ARG_WITH([sysvinit-path],
 852         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 853                 [Specify the path to where the SysV init scripts are located])],
 854         [SYSTEM_SYSVINIT_PATH="$withval"],
 855         [])
 856
 857 AC_ARG_WITH([sysvrcnd-path],
 858         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
 859                 [Specify the path to the base directory for the SysV rcN.d directories])],
 860         [SYSTEM_SYSVRCND_PATH="$withval"],
 861         [])
 862
 863 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 864         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 865         SYSTEM_SYSV_COMPAT="yes"
 866         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 867 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 868         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 869 else
 870         SYSTEM_SYSV_COMPAT="no"
 871 fi
 872
 873 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 874 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 875 AC_SUBST(M4_DEFINES)
 876
 877 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 878
 879 AC_ARG_WITH([tty-gid],
 880         [AS_HELP_STRING([--with-tty-gid=GID],
 881                 [Specify the numeric GID of the 'tty' group])],
 882         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 883         [])
 884
 885 AC_ARG_WITH([dbuspolicydir],
 886         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 887         [],
 888         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
 889
 890 AC_ARG_WITH([dbussessionservicedir],
 891         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 892         [],
 893         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
 894
 895 AC_ARG_WITH([dbussystemservicedir],
 896         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 897         [],
 898         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
 899
 900 AC_ARG_WITH([dbusinterfacedir],
 901         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 902         [],
 903         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
 904
 905 AC_ARG_WITH([bashcompletiondir],
 906         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 907         [],
 908         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 909                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 910         ] , [
 911                 with_bashcompletiondir=${datadir}/bash-completion/completions
 912         ])])
 913
 914 AC_ARG_WITH([rootprefix],
 915         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 916         [], [with_rootprefix=${ac_default_prefix}])
 917
 918 AC_ARG_WITH([rootlibdir],
 919         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 920         [],
 921         [with_rootlibdir=${libdir}])
 922
 923 AC_ARG_WITH([pamlibdir],
 924         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 925         [],
 926         [with_pamlibdir=${with_rootlibdir}/security])
 927
 928 AC_ARG_ENABLE([split-usr],
 929         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 930         [],
 931         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 932                 enable_split_usr=yes
 933         ], [
 934                 enable_split_usr=no
 935         ])])
 936
 937 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 938         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 939 ])
 940
 941 # Work around intltoolize and gtk-doc problems in VPATH builds
 942 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 943                                        [Define to do gtk-doc tests])
 944 AS_IF([test "x$0" != "x./configure"], [
 945         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
 946 ])
 947
 948 AC_ARG_ENABLE(tests,
 949        [AC_HELP_STRING([--disable-tests], [disable tests])],
 950        enable_tests=$enableval, enable_tests=yes)
 951 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 952
 953 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 954 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 955 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 956 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 957 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 958 AC_SUBST([pamlibdir], [$with_pamlibdir])
 959 AC_SUBST([rootprefix], [$with_rootprefix])
 960 AC_SUBST([rootlibdir], [$with_rootlibdir])
 961
 962 AC_CONFIG_FILES([
 963         Makefile po/Makefile.in
 964         docs/libudev/Makefile
 965         docs/libudev/version.xml
 966         docs/gudev/Makefile
 967         docs/gudev/version.xml
 968 ])
 969
 970 AC_OUTPUT
 971 AC_MSG_RESULT([
 972         $PACKAGE_NAME $VERSION
 973
 974         libcryptsetup:           ${have_libcryptsetup}
 975         tcpwrap:                 ${have_tcpwrap}
 976         PAM:                     ${have_pam}
 977         AUDIT:                   ${have_audit}
 978         IMA:                     ${have_ima}
 979         SELinux:                 ${have_selinux}
 980         SMACK:                   ${have_smack}
 981         XZ:                      ${have_xz}
 982         ACL:                     ${have_acl}
 983         XATTR:                   ${have_xattr}
 984         GCRYPT:                  ${have_gcrypt}
 985         QRENCODE:                ${have_qrencode}
 986         MICROHTTPD:              ${have_microhttpd}
 987         CHKCONFIG:               ${have_chkconfig}
 988         binfmt:                  ${have_binfmt}
 989         vconsole:                ${have_vconsole}
 990         readahead:               ${have_readahead}
 991         bootchart:               ${have_bootchart}
 992         quotacheck:              ${have_quotacheck}
 993         tmpfiles:                ${have_tmpfiles}
 994         randomseed:              ${have_randomseed}
 995         logind:                  ${have_logind}
 996         machined:                ${have_machined}
 997         hostnamed:               ${have_hostnamed}
 998         timedated:               ${have_timedated}
 999         localed:                 ${have_localed}
1000         coredump:                ${have_coredump}
1001         polkit:                  ${have_polkit}
1002         efi:                     ${have_efi}
1003         kmod:                    ${have_kmod}
1004         blkid:                   ${have_blkid}
1005         nss-myhostname:          ${have_myhostname}
1006         gudev:                   ${enable_gudev}
1007         gintrospection:          ${enable_introspection}
1008         Python:                  ${have_python}
1009         Python Headers:          ${have_python_devel}
1010         man pages:               ${have_manpages}
1011         gtk-doc:                 ${enable_gtk_doc}
1012         test coverage:           ${have_coverage}
1013         Split /usr:              ${enable_split_usr}
1014         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1015
1016         prefix:                  ${prefix}
1017         rootprefix:              ${with_rootprefix}
1018         sysconf dir:             ${sysconfdir}
1019         datarootdir:             ${datarootdir}
1020         includedir:              ${includedir}
1021         include_prefix:          ${INCLUDE_PREFIX}
1022         lib dir:                 ${libdir}
1023         rootlib dir:             ${with_rootlibdir}
1024         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1025         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1026         Build Python:            ${PYTHON}
1027         Installation Python:     ${PYTHON_BINARY}
1028         firmware path:           ${FIRMWARE_PATH}
1029         PAM modules dir:         ${with_pamlibdir}
1030         D-Bus policy dir:        ${with_dbuspolicydir}
1031         D-Bus session dir:       ${with_dbussessionservicedir}
1032         D-Bus system dir:        ${with_dbussystemservicedir}
1033         D-Bus interfaces dir:    ${with_dbusinterfacedir}
1034         Bash completions dir:    ${with_bashcompletiondir}
1035         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1036         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1037         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1038
1039         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1040         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1041         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1042         PYTHON_CFLAGS:           ${PYTHON_CFLAGS}
1043         PYTHON_LIBS:             ${PYTHON_LIBS}
1044 ])