configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010 Lennart Poettering
   4 #
   5 #  systemd is free software; you can redistribute it and/or modify it
   6 #  under the terms of the GNU General Public License as published by
   7 #  the Free Software Foundation; either version 2 of the License, or
   8 #  (at your option) any later version.
   9 #
  10 #  systemd is distributed in the hope that it will be useful, but
  11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 #  General Public License for more details.
  14 #
  15 #  You should have received a copy of the GNU General Public License
  16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ(2.63)
  19
  20 AC_INIT([systemd],[29],[systemd-devel@lists.freedesktop.org])
  21 AC_CONFIG_SRCDIR([src/main.c])
  22 AC_CONFIG_MACRO_DIR([m4])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_USE_SYSTEM_EXTENSIONS
  25 AC_SYS_LARGEFILE
  26
  27 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects dist-bzip2])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
  30
  31 AC_CANONICAL_HOST
  32 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  33 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  34        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  35       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  36
  37 AM_SILENT_RULES([yes])
  38
  39 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  40
  41 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  42         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  43         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  44 ])
  45
  46 AC_PROG_MKDIR_P
  47 AC_PROG_LN_S
  48 AC_PROG_SED
  49
  50 AC_PROG_CC
  51 AC_PROG_CC_C99
  52 AM_PROG_CC_C_O
  53 AC_PROG_GCC_TRADITIONAL
  54
  55 AC_CHECK_TOOL(OBJCOPY, objcopy)
  56 AC_CHECK_TOOL(STRINGS, strings)
  57
  58 CC_CHECK_CFLAGS_APPEND([ \
  59         -pipe \
  60         -Wall \
  61         -W \
  62         -Wextra \
  63         -Wno-inline \
  64         -Wvla \
  65         -Wundef \
  66         -Wformat=2 \
  67         -Wlogical-op \
  68         -Wsign-compare \
  69         -Wformat-security \
  70         -Wmissing-include-dirs \
  71         -Wformat-nonliteral \
  72         -Wold-style-definition \
  73         -Wpointer-arith \
  74         -Winit-self \
  75         -Wdeclaration-after-statement \
  76         -Wfloat-equal \
  77         -Wmissing-prototypes \
  78         -Wstrict-prototypes \
  79         -Wredundant-decls \
  80         -Wmissing-declarations \
  81         -Wmissing-noreturn \
  82         -Wshadow \
  83         -Wendif-labels \
  84         -Wcast-align \
  85         -Wstrict-aliasing=2 \
  86         -Wwrite-strings \
  87         -Wno-long-long \
  88         -Wno-overlength-strings \
  89         -Wno-unused-parameter \
  90         -Wno-missing-field-initializers \
  91         -Wno-unused-result \
  92         -Wp,-D_FORTIFY_SOURCE=2 \
  93         -ffast-math \
  94         -fno-common \
  95         -fdiagnostics-show-option \
  96         -fno-strict-aliasing \
  97         -fvisibility=hidden \
  98         -ffunction-sections \
  99         -fdata-sections \
 100         -Wl,--as-needed \
 101         -Wl,--gc-sections])
 102
 103 LT_PREREQ(2.2)
 104 LT_INIT
 105
 106 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 107 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 108 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 109 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 110
 111 # This makes sure pkg.m4 is available.
 112 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 113
 114 PKG_CHECK_MODULES(UDEV, [ libudev >= 160 ])
 115 AC_SUBST(UDEV_CFLAGS)
 116 AC_SUBST(UDEV_LIBS)
 117
 118 PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.2 ])
 119 AC_SUBST(DBUS_CFLAGS)
 120 AC_SUBST(DBUS_LIBS)
 121
 122 have_selinux=no
 123 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 124 if test "x$enable_selinux" != "xno"; then
 125         PKG_CHECK_MODULES(SELINUX, [ libselinux ],
 126                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 127         AC_SUBST(SELINUX_CFLAGS)
 128         AC_SUBST(SELINUX_LIBS)
 129         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 130                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 131         fi
 132 fi
 133 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 134
 135 AC_ARG_ENABLE([tcpwrap],
 136         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 137                 [case "${enableval}" in
 138                         yes) have_tcpwrap=yes ;;
 139                         no) have_tcpwrap=no ;;
 140                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 141                 esac],
 142                 [have_tcpwrap=auto])
 143
 144 if test "x${have_tcpwrap}" != xno ; then
 145         ACX_LIBWRAP
 146         if test "x${LIBWRAP_LIBS}" = x ; then
 147                 if test "x$have_tcpwrap" = xyes ; then
 148                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 149                 fi
 150                 have_tcpwrap=no
 151         else
 152                 have_tcpwrap=yes
 153         fi
 154 else
 155         LIBWRAP_LIBS=
 156 fi
 157 AC_SUBST(LIBWRAP_LIBS)
 158
 159 AC_ARG_ENABLE([pam],
 160         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 161                 [case "${enableval}" in
 162                         yes) have_pam=yes ;;
 163                         no) have_pam=no ;;
 164                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 165                 esac],
 166                 [have_pam=auto])
 167
 168 if test "x${have_pam}" != xno ; then
 169         AC_CHECK_HEADERS(
 170                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 171                 [have_pam=yes],
 172                 [if test "x$have_pam" = xyes ; then
 173                         AC_MSG_ERROR([*** PAM headers not found.])
 174                 fi])
 175
 176         AC_CHECK_LIB(
 177                 [pam],
 178                 [pam_syslog],
 179                 [have_pam=yes],
 180                 [if test "x$have_pam" = xyes ; then
 181                         AC_MSG_ERROR([*** libpam not found.])
 182                 fi])
 183
 184         if test "x$have_pam" = xyes ; then
 185                 PAM_LIBS="-lpam -lpam_misc"
 186                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 187         else
 188                 have_pam=no
 189         fi
 190 else
 191         PAM_LIBS=
 192 fi
 193 AC_SUBST(PAM_LIBS)
 194 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 195
 196 AC_ARG_ENABLE([acl],
 197         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 198                 [case "${enableval}" in
 199                         yes) have_acl=yes ;;
 200                         no) have_acl=no ;;
 201                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 202                 esac],
 203                 [have_acl=auto])
 204
 205 if test "x${have_acl}" != xno ; then
 206         AC_CHECK_HEADERS(
 207                 [sys/acl.h acl/libacl.h],
 208                 [have_acl=yes],
 209                 [if test "x$have_acl" = xyes ; then
 210                         AC_MSG_ERROR([*** ACL headers not found.])
 211                 fi])
 212
 213         AC_CHECK_LIB(
 214                 [acl],
 215                 [acl_get_file],
 216                 [have_acl=yes],
 217                 [if test "x$have_acl" = xyes ; then
 218                         AC_MSG_ERROR([*** libacl not found.])
 219                 fi])
 220
 221         if test "x$have_acl" = xyes ; then
 222                 ACL_LIBS="-lacl"
 223                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 224         else
 225                 have_acl=no
 226         fi
 227 else
 228         ACL_LIBS=
 229 fi
 230 AC_SUBST(ACL_LIBS)
 231 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 232
 233 AC_ARG_ENABLE([audit],
 234         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 235                 [case "${enableval}" in
 236                         yes) have_audit=yes ;;
 237                         no) have_audit=no ;;
 238                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 239                 esac],
 240                 [have_audit=auto])
 241
 242 if test "x${have_audit}" != xno ; then
 243         AC_CHECK_HEADERS(
 244                 [libaudit.h],
 245                 [have_audit=yes],
 246                 [if test "x$have_audit" = xyes ; then
 247                         AC_MSG_ERROR([*** AUDIT headers not found.])
 248                 fi])
 249
 250         AC_CHECK_LIB(
 251                 [audit],
 252                 [audit_open],
 253                 [have_audit=yes],
 254                 [if test "x$have_audit" = xyes ; then
 255                         AC_MSG_ERROR([*** libaudit not found.])
 256                 fi])
 257
 258         if test "x$have_audit" = xyes ; then
 259                 AUDIT_LIBS="-laudit"
 260                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 261         else
 262                 have_audit=no
 263         fi
 264 else
 265         AUDIT_LIBS=
 266 fi
 267 AC_SUBST(AUDIT_LIBS)
 268
 269 have_libcryptsetup=no
 270 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 271 if test "x$enable_libcryptsetup" != "xno"; then
 272         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup ],
 273                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 274         AC_SUBST(LIBCRYPTSETUP_CFLAGS)
 275         AC_SUBST(LIBCRYPTSETUP_LIBS)
 276         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 277                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 278         fi
 279 fi
 280 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 281
 282 have_binfmt=no
 283 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 284 if test "x$enable_binfmt" != "xno"; then
 285         have_binfmt=yes
 286 fi
 287 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 288
 289 have_gtk=no
 290 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
 291 if test "x$enable_gtk" != "xno"; then
 292         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 glib-2.0 > 2.26 gio-unix-2.0 ],
 293                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
 294         AC_SUBST(GTK_CFLAGS)
 295         AC_SUBST(GTK_LIBS)
 296         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
 297                 AC_MSG_ERROR([*** gtk support requested but libraries not found])
 298         fi
 299 fi
 300 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
 301
 302 if test "$have_gtk" = "yes"; then
 303         PKG_CHECK_MODULES(LIBNOTIFY, [ libnotify ])
 304         PKG_CHECK_EXISTS([ libnotify >= 0.7.0 ], [ libnotify07=yes ])
 305
 306         AC_SUBST(LIBNOTIFY_CFLAGS)
 307         AC_SUBST(LIBNOTIFY_LIBS)
 308 fi
 309 AM_CONDITIONAL(LIBNOTIFY07, [ test "$libnotify07" = "yes" ])
 310
 311 AM_PROG_VALAC([0.10])
 312 AC_SUBST(VAPIDIR)
 313 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
 314
 315 AC_PATH_PROG([XSLTPROC], [xsltproc])
 316 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 317
 318 AC_PATH_PROG([M4], [m4])
 319
 320 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux or other]))
 321 if test "z$with_distro" = "z"; then
 322         if test "$cross_compiling" = yes; then
 323                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 324         else
 325                 test -f "/etc/redhat-release" && with_distro="fedora"
 326                 test -f "/etc/SuSE-release" && with_distro="suse"
 327                 test -f "/etc/debian_version" &&  with_distro="debian"
 328                 test -f "/etc/arch-release" && with_distro="arch"
 329                 test -f "/etc/gentoo-release" && with_distro="gentoo"
 330                 test -f "/etc/slackware-version" && with_distro="slackware"
 331                 test -f "/etc/frugalware-release" && with_distro="frugalware"
 332                 test -f "/etc/altlinux-release" && with_distro="altlinux"
 333                 test -f "/etc/mandriva-release" && with_distro="mandriva"
 334                 test -f "/etc/meego-release" && with_distro="meego"
 335                 test -f "/etc/angstrom-version" && with_distro="angstrom"
 336                 if test "x`lsb_release -is 2>/dev/null`" = "xUbuntu"; then
 337                         with_distro="ubuntu"
 338                 fi
 339         fi
 340         if test "z$with_distro" = "z"; then
 341                 with_distro=`uname -s`
 342         fi
 343 fi
 344 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 345 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 346
 347 # Location of the init scripts as mandated by LSB
 348 SYSTEM_SYSVINIT_PATH=/etc/init.d
 349 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 350
 351 M4_DISTRO_FLAG=
 352 have_plymouth=no
 353
 354 case $with_distro in
 355         fedora)
 356                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 357                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 358                 M4_DISTRO_FLAG=-DTARGET_FEDORA=1
 359                 have_plymouth=yes
 360                 ;;
 361         suse)
 362                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 363                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 364                 M4_DISTRO_FLAG=-DTARGET_SUSE=1
 365                 have_plymouth=yes
 366                 ;;
 367         debian)
 368                 SYSTEM_SYSVRCND_PATH=/etc
 369                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 370                 M4_DISTRO_FLAG=-DTARGET_DEBIAN=1
 371                 ;;
 372         ubuntu)
 373                 SYSTEM_SYSVRCND_PATH=/etc
 374                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 375                 M4_DISTRO_FLAG=-DTARGET_UBUNTU=1
 376                 ;;
 377         arch)
 378                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 379                 SYSTEM_SYSVRCND_PATH=/etc
 380                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 381                 M4_DISTRO_FLAG=-DTARGET_ARCH=1
 382                 ;;
 383         gentoo)
 384                 SYSTEM_SYSVINIT_PATH=
 385                 SYSTEM_SYSVRCND_PATH=
 386                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 387                 M4_DISTRO_FLAG=-DTARGET_GENTOO=1
 388                 ;;
 389         slackware)
 390                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 391                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 392                 M4_DISTRO_FLAG=-DTARGET_SLACKWARE=1
 393                 ;;
 394         frugalware)
 395                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 396                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 397                 M4_DISTRO_FLAG=-DTARGET_FRUGALWARE=1
 398                 have_plymouth=yes
 399                 ;;
 400         altlinux)
 401                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 402                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
 403                 M4_DISTRO_FLAG=-DTARGET_ALTLINUX=1
 404                 have_plymouth=yes
 405                 ;;
 406         mandriva)
 407                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 408                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
 409                 M4_DISTRO_FLAG=-DTARGET_MANDRIVA=1
 410                 have_plymouth=yes
 411                 ;;
 412         meego)
 413                 SYSTEM_SYSVINIT_PATH=
 414                 SYSTEM_SYSVRCND_PATH=
 415                 AC_DEFINE(TARGET_MEEGO, [], [Target is MeeGo])
 416                 M4_DISTRO_FLAG=-DTARGET_MEEGO=1
 417                 ;;
 418         angstrom)
 419                 SYSTEM_SYSVRCND_PATH=/etc
 420                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
 421                 M4_DISTRO_FLAG=-DTARGET_ANGSTROM=1
 422                 ;;
 423         other)
 424                 ;;
 425         *)
 426                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 427                 ;;
 428 esac
 429
 430 AC_ARG_WITH([sysvinit-path],
 431         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 432                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 433         [SYSTEM_SYSVINIT_PATH="$withval"],
 434         [])
 435
 436 AC_ARG_WITH([sysvrcd-path],
 437         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 438                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 439         [SYSTEM_SYSVRCND_PATH="$withval"],
 440         [])
 441
 442 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 443 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 444 AC_SUBST(M4_DISTRO_FLAG)
 445
 446 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 447         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 448         SYSTEM_SYSV_COMPAT="yes"
 449 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 450         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 451 else
 452         SYSTEM_SYSV_COMPAT="no"
 453 fi
 454
 455 AC_ARG_WITH([tty-gid],
 456         [AS_HELP_STRING([--with-tty-gid=GID],
 457                 [Specify the numeric GID of the 'tty' group])],
 458         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 459         [])
 460
 461 AC_ARG_ENABLE(plymouth, AS_HELP_STRING([--enable-plymouth], [enable plymouth support]))
 462 if test -n "$enable_plymouth"; then
 463         have_plymouth="$enable_plymouth"
 464 fi
 465
 466 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 467 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 468 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 469 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 470 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 471 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 472 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 473 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 474 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 475 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
 476 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 477 AM_CONDITIONAL(TARGET_MEEGO, test x"$with_distro" = xmeego)
 478 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
 479
 480 AM_CONDITIONAL(HAVE_PLYMOUTH, test "$have_plymouth" = "yes")
 481 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 482
 483 AC_ARG_WITH([dbuspolicydir],
 484         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 485         [],
 486         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 487
 488 AC_ARG_WITH([dbussessionservicedir],
 489         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 490         [],
 491         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 492
 493 AC_ARG_WITH([dbussystemservicedir],
 494         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 495         [],
 496         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 497
 498 AC_ARG_WITH([dbusinterfacedir],
 499         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 500         [],
 501         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 502
 503 AC_ARG_WITH([udevrulesdir],
 504         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
 505         [],
 506         [with_udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d])
 507
 508 AC_ARG_WITH([pamlibdir],
 509         AS_HELP_STRING([--with-pamlibdir=DIR], [Diectory for PAM modules]),
 510         [],
 511         [with_pamlibdir=/lib/`$CC -print-multi-os-directory`/security])
 512
 513 AC_ARG_WITH([rootdir],
 514         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
 515         [],
 516         [with_rootdir=${ac_default_prefix}])
 517
 518 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 519 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 520 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 521 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 522 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 523 AC_SUBST([pamlibdir], [$with_pamlibdir])
 524 AC_SUBST([rootdir], [$with_rootdir])
 525
 526 AC_CONFIG_FILES([Makefile])
 527 AC_OUTPUT
 528
 529 echo "
 530         $PACKAGE_NAME $VERSION
 531
 532         Distribution:            ${with_distro}
 533         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 534         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 535         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 536         Gtk:                     ${have_gtk}
 537         libcryptsetup:           ${have_libcryptsetup}
 538         tcpwrap:                 ${have_tcpwrap}
 539         PAM:                     ${have_pam}
 540         AUDIT:                   ${have_audit}
 541         SELinux:                 ${have_selinux}
 542         ACL:                     ${have_acl}
 543         binfmt:                  ${have_binfmt}
 544         plymouth:                ${have_plymouth}
 545         prefix:                  ${prefix}
 546         root dir:                ${with_rootdir}
 547         udev rules dir:          ${with_udevrulesdir}
 548         pam modules dir:         ${with_pamlibdir}
 549         dbus policy dir:         ${with_dbuspolicydir}
 550         dbus session dir:        ${with_dbussessionservicedir}
 551         dbus system dir:         ${with_dbussystemservicedir}
 552         dbus interfaces dir:     ${with_dbusinterfacedir}
 553 "