configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 # FIXME: Update to proper web page
  23 AC_INIT([elogind],
  24         [219.6],
  25         [http://bugs.freedesktop.org/enter_bug.cgi?product=elogind],
  26         [elogind],
  27         [http://www.freedesktop.org/wiki/Software/elogind])
  28
  29 AC_CONFIG_SRCDIR([src/login/logind.c])
  30 AC_CONFIG_MACRO_DIR([m4])
  31 AC_CONFIG_HEADERS([config.h])
  32 AC_CONFIG_AUX_DIR([build-aux])
  33
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AC_SYS_LARGEFILE
  36 AC_PREFIX_DEFAULT([/usr])
  37 AM_MAINTAINER_MODE([enable])
  38 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  39 AM_SILENT_RULES([yes])
  40 AC_CANONICAL_HOST
  41 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  42 LT_PREREQ(2.2)
  43 LT_INIT([disable-static])
  44
  45 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by elogind])])
  46 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by elogind])])
  47
  48 SET_ARCH(X86_64, x86_64*)
  49 SET_ARCH(IA32, i*86*)
  50 SET_ARCH(MIPS, mips*)
  51
  52 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  53 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  54 AS_IF([test x"$intltool_found" != xyes],
  55       [AS_IF([test x"$enable_nls" = xyes],
  56              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  57              [AS_IF([test x"$enable_nls" != xno],
  58                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  59                      enable_nls=no])
  60              ])
  61       ])
  62
  63 AM_NLS
  64 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  65     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  66 IT_PROG_INTLTOOL([0.40.0])
  67 ])
  68
  69 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  70     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  71     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  72     AC_SUBST(INTLTOOL_POLICY_RULE)
  73 ])
  74
  75 GETTEXT_PACKAGE=elogind
  76 AC_SUBST(GETTEXT_PACKAGE)
  77 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [elogind])
  78
  79 AC_PROG_MKDIR_P
  80 AC_PROG_LN_S
  81 AC_PROG_SED
  82 AC_PROG_GREP
  83 AC_PROG_AWK
  84
  85 AC_PROG_CC_C99
  86
  87 AC_PATH_PROG([M4], [m4])
  88 AC_PATH_PROG([XSLTPROC], [xsltproc])
  89
  90 AC_PATH_PROG([HALT], [halt], [halt])
  91 AC_PATH_PROG([REBOOT], [reboot], [reboot])
  92 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
  93
  94 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
  95
  96 M4_DEFINES=
  97
  98 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  99 m4_ifdef([GTK_DOC_CHECK], [
 100 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
 101          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
 102           enable_gtk_doc=no])
 103
 104 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
 105         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
 106 ])
 107
 108 AC_CHECK_TOOL(GPERF, gperf)
 109 if test -z "$GPERF" ; then
 110         AC_MSG_ERROR([*** gperf not found])
 111 fi
 112
 113 # ------------------------------------------------------------------------------
 114 address_sanitizer_cflags=
 115 address_sanitizer_cppflags=
 116 address_sanitizer_ldflags=
 117 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 118 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 119             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 120             AS_IF([test -z "$with_as_cflags"],
 121                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 122             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 123             address_sanitizer_cppflags="-DVALGRIND=1"
 124             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 125       ])
 126
 127 undefined_sanitizer_cflags=
 128 undefined_sanitizer_cppflags=
 129 undefined_sanitizer_ldflags=
 130 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 131 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 132             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 133             AS_IF([test -z "$with_us_cflags"],
 134                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 135             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 136             undefined_sanitizer_cppflags="-DVALGRIND=1"
 137             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 138       ])
 139
 140 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 141 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 142 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 143
 144 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 145         -pipe \
 146         -Wall \
 147         -Wextra \
 148         -Wno-inline \
 149         -Wundef \
 150         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 151         -Wlogical-op \
 152         -Wsign-compare \
 153         -Wmissing-include-dirs \
 154         -Wold-style-definition \
 155         -Wpointer-arith \
 156         -Winit-self \
 157         -Wdeclaration-after-statement \
 158         -Wfloat-equal \
 159         -Wsuggest-attribute=noreturn \
 160         -Wmissing-prototypes \
 161         -Wstrict-prototypes \
 162         -Wredundant-decls \
 163         -Wmissing-declarations \
 164         -Wmissing-noreturn \
 165         -Wshadow \
 166         -Wendif-labels \
 167         -Wstrict-aliasing=2 \
 168         -Wwrite-strings \
 169         -Wno-long-long \
 170         -Wno-overlength-strings \
 171         -Wno-unused-parameter \
 172         -Wno-missing-field-initializers \
 173         -Wno-unused-result \
 174         -Wno-format-signedness \
 175         -Werror=overflow \
 176         -Wdate-time \
 177         -Wnested-externs \
 178         -ffast-math \
 179         -fno-common \
 180         -fdiagnostics-show-option \
 181         -fno-strict-aliasing \
 182         -fvisibility=hidden \
 183         -ffunction-sections \
 184         -fdata-sections \
 185         -fstack-protector \
 186         -fstack-protector-strong \
 187         -fPIE \
 188         --param=ssp-buffer-size=4])
 189
 190 AS_CASE([$CC], [*clang*],
 191         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 192                -Wno-typedef-redefinition \
 193                -Wno-gnu-variable-sized-type-not-at-end \
 194         ])])
 195
 196 dnl AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 197 dnl         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 198 dnl                -flto -ffat-lto-objects])],
 199 dnl         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 200 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 201
 202 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 203         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 204                -Wp,-D_FORTIFY_SOURCE=2])],
 205         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 206 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 207
 208 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 209         -Wl,--as-needed \
 210         -Wl,--no-undefined \
 211         -Wl,--gc-sections \
 212         -Wl,-z,relro \
 213         -Wl,-z,now \
 214         -pie \
 215         -Wl,-fuse-ld=gold])
 216 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 217
 218 AC_CHECK_SIZEOF(pid_t)
 219 AC_CHECK_SIZEOF(uid_t)
 220 AC_CHECK_SIZEOF(gid_t)
 221 AC_CHECK_SIZEOF(time_t)
 222 AC_CHECK_SIZEOF(dev_t)
 223 AC_CHECK_SIZEOF(rlim_t,,[
 224        #include <sys/time.h>
 225        #include <sys/resource.h>
 226 ])
 227
 228 # ------------------------------------------------------------------------------
 229
 230 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 231 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 232 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 233
 234 # unconditionally pull-in librt with old glibc versions
 235 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 236
 237 save_LIBS="$LIBS"
 238 LIBS=
 239 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 240 CAP_LIBS="$LIBS"
 241 AC_SUBST(CAP_LIBS)
 242
 243 AC_CHECK_FUNCS([memfd_create])
 244 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 245 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns, getrandom, renameat2, kcmp, LO_FLAGS_PARTSCAN],
 246                [], [], [[
 247 #include <sys/types.h>
 248 #include <unistd.h>
 249 #include <sys/mount.h>
 250 #include <fcntl.h>
 251 #include <sched.h>
 252 #include <linux/loop.h>
 253 #include <linux/random.h>
 254 ]])
 255
 256 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 257                 IFLA_MACVLAN_FLAGS,
 258                 IFLA_IPVLAN_MODE,
 259                 IFLA_VTI_REMOTE,
 260                 IFLA_PHYS_PORT_ID,
 261                 IFLA_BOND_AD_INFO,
 262                 IFLA_VLAN_PROTOCOL,
 263                 IFLA_VXLAN_LOCAL6,
 264                 IFLA_IPTUN_6RD_RELAY_PREFIXLEN,
 265                 IFLA_BRIDGE_VLAN_INFO,
 266                 IFLA_BRPORT_UNICAST_FLOOD,
 267                 NDA_IFINDEX],
 268 [], [], [[
 269 #include <inttypes.h>
 270 #include <netinet/in.h>
 271 #include <netinet/ether.h>
 272 #include <linux/rtnetlink.h>
 273 #include <net/if.h>
 274 #include <linux/ip.h>
 275 #include <linux/if_tunnel.h>
 276 #include <linux/if_link.h>
 277 #include <linux/if_bridge.h>
 278 #include <linux/neighbour.h>
 279 ]])
 280
 281 # This makes sure pkg.m4 is available.
 282 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 283
 284 # ------------------------------------------------------------------------------
 285 have_dbus=no
 286 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 287 AS_IF([test "x$enable_dbus" != "xno"], [
 288         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 289                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 290                 [have_dbus=no])
 291         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 292                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 293 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 294
 295 # ------------------------------------------------------------------------------
 296 PKG_CHECK_MODULES(UDEV, [libudev])
 297
 298 AC_ARG_WITH([udevrulesdir],
 299             AS_HELP_STRING([--with-udevrulesdir=DIR], [Directory for udev rules files]),
 300             [],
 301             [with_udevrulesdir=$($PKG_CONFIG --variable=udevdir udev)/rules.d])
 302 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 303 AC_SUBST([udevbindir], [$($PKG_CONFIG --variable=udevdir udev)/../bin])
 304
 305 # ------------------------------------------------------------------------------
 306 have_coverage=no
 307 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 308 if test "x$enable_coverage" = "xyes" ; then
 309         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 310         if test "x$lcov_found" = xno ; then
 311                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 312         else
 313                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 314                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 315                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 316                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 317                 else
 318                         have_coverage=yes
 319                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 320                         -fprofile-arcs \
 321                         -ftest-coverage])
 322                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 323                 fi
 324         fi
 325 fi
 326 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 327
 328 # ------------------------------------------------------------------------------
 329 have_blkid=no
 330 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 331 if test "x$enable_blkid" != "xno"; then
 332         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 333                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 334         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 335                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 336         fi
 337 fi
 338 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 339
 340 # ------------------------------------------------------------------------------
 341 have_seccomp=no
 342 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 343 if test "x$enable_seccomp" != "xno"; then
 344         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 345                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 346                 have_seccomp=yes
 347                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 348                [have_seccomp=no])
 349         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 350                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 351         fi
 352 fi
 353 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 354
 355 # ------------------------------------------------------------------------------
 356 have_selinux=no
 357 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 358 if test "x$enable_selinux" != "xno"; then
 359         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 360                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 361                  have_selinux=yes
 362                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 363                 [have_selinux=no])
 364         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 365                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 366         fi
 367 fi
 368 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 369
 370 have_apparmor=no
 371 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 372 if test "x$enable_apparmor" != "xno"; then
 373         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 374                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 375                  have_apparmor=yes
 376                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 377                 [have_apparmor=no])
 378         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 379                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 380         fi
 381 fi
 382 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 383
 384 # ------------------------------------------------------------------------------
 385 AC_ARG_ENABLE([pam],
 386         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 387                 [case "${enableval}" in
 388                         yes) have_pam=yes ;;
 389                         no) have_pam=no ;;
 390                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 391                 esac],
 392                 [have_pam=auto])
 393
 394 if test "x${have_pam}" != xno ; then
 395         AC_CHECK_HEADERS(
 396                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 397                 [have_pam=yes],
 398                 [if test "x$have_pam" = xyes ; then
 399                         AC_MSG_ERROR([*** PAM headers not found.])
 400                 fi])
 401
 402         AC_CHECK_LIB(
 403                 [pam],
 404                 [pam_syslog],
 405                 [have_pam=yes],
 406                 [if test "x$have_pam" = xyes ; then
 407                         AC_MSG_ERROR([*** libpam not found.])
 408                 fi])
 409
 410         if test "x$have_pam" = xyes ; then
 411                 PAM_LIBS="-lpam -lpam_misc"
 412                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 413                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 414         else
 415                 have_pam=no
 416         fi
 417 else
 418         PAM_LIBS=
 419 fi
 420 AC_SUBST(PAM_LIBS)
 421 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 422
 423 # ------------------------------------------------------------------------------
 424 AC_ARG_ENABLE([acl],
 425         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 426                 [case "${enableval}" in
 427                         yes) have_acl=yes ;;
 428                         no) have_acl=no ;;
 429                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 430                 esac],
 431                 [have_acl=auto])
 432
 433 if test "x${have_acl}" != xno ; then
 434         AC_CHECK_HEADERS(
 435                 [sys/acl.h acl/libacl.h],
 436                 [have_acl=yes],
 437                 [if test "x$have_acl" = xyes ; then
 438                         AC_MSG_ERROR([*** ACL headers not found.])
 439                 fi])
 440
 441         AC_CHECK_LIB(
 442                 [acl],
 443                 [acl_get_file],
 444                 [have_acl=yes],
 445                 [if test "x$have_acl" = xyes ; then
 446                         AC_MSG_ERROR([*** libacl not found.])
 447                 fi])
 448
 449         if test "x$have_acl" = xyes ; then
 450                 ACL_LIBS="-lacl"
 451                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 452                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 453         else
 454                 have_acl=no
 455         fi
 456 else
 457         ACL_LIBS=
 458 fi
 459 AC_SUBST(ACL_LIBS)
 460 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 461
 462 # ------------------------------------------------------------------------------
 463 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 464                 [case "${enableval}" in
 465                         yes) have_smack=yes ;;
 466                         no) have_smack=no ;;
 467                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 468                 esac],
 469                 [have_smack=auto])
 470
 471 if test "x${have_smack}" = xauto; then
 472         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 473         have_smack=yes
 474 fi
 475
 476 AC_ARG_WITH(smack-run-label,
 477 AS_HELP_STRING([--with-smack-run-label=STRING],
 478         [run systemd --system with a specific SMACK label]),
 479         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run with a smack label])],
 480         [])
 481
 482 if test "x${have_smack}" = xyes ; then
 483         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 484 fi
 485
 486 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 487
 488 # ------------------------------------------------------------------------------
 489 AC_ARG_WITH(system-uid-max,
 490         AS_HELP_STRING([--with-system-uid-max=UID]
 491                 [Maximum UID for system users]),
 492         [SYSTEM_UID_MAX="$withval"],
 493         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
 494
 495 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
 496 AC_SUBST(SYSTEM_UID_MAX)
 497
 498 # ------------------------------------------------------------------------------
 499 AC_ARG_WITH(system-gid-max,
 500         AS_HELP_STRING([--with-system-gid-max=GID]
 501                 [Maximum GID for system groups]),
 502         [SYSTEM_GID_MAX="$withval"],
 503         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
 504
 505 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
 506 AC_SUBST(SYSTEM_GID_MAX)
 507
 508 # ------------------------------------------------------------------------------
 509 have_polkit=no
 510 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 511 if test "x$enable_polkit" != "xno"; then
 512         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 513         have_polkit=yes
 514 fi
 515 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 516
 517 # ------------------------------------------------------------------------------
 518 have_kdbus=no
 519 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--enable-kdbus], [do connect to kdbus by default]))
 520 if test "x$enable_kdbus" = "xyes"; then
 521         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus support is to be enabled])
 522         have_kdbus=yes
 523         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
 524 fi
 525 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
 526
 527 # ------------------------------------------------------------------------------
 528 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
 529
 530 # ------------------------------------------------------------------------------
 531 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0],
 532                   [have_glib=yes], [have_glib=no])
 533 AS_IF([test "x$have_glib" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 534
 535 # ------------------------------------------------------------------------------
 536 have_manpages=no
 537 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 538 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
 539 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 540
 541 # ------------------------------------------------------------------------------
 542 AC_SUBST(M4_DEFINES)
 543
 544 AC_ARG_WITH([dbuspolicydir],
 545         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 546         [],
 547         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
 548
 549 AC_ARG_WITH([dbussessionservicedir],
 550         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 551         [],
 552         [with_dbussessionservicedir=${datadir}/dbus-1/services])
 553
 554 AC_ARG_WITH([dbussystemservicedir],
 555         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 556         [],
 557         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
 558
 559 AC_ARG_WITH([bashcompletiondir],
 560         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 561         [],
 562         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 563                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 564         ] , [
 565                 with_bashcompletiondir=${datadir}/bash-completion/completions
 566         ])])
 567
 568 AC_ARG_WITH([zshcompletiondir],
 569         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
 570         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
 571
 572 AC_ARG_WITH([rootlibdir],
 573         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 574         [],
 575         [with_rootlibdir=${libdir}])
 576
 577 AC_ARG_WITH([pamlibdir],
 578         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 579         [],
 580         [with_pamlibdir=${with_rootlibdir}/security])
 581
 582 AC_ARG_WITH([pamconfdir],
 583         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
 584         [],
 585         [with_pamconfdir=${sysconfdir}/pam.d])
 586
 587 AC_ARG_ENABLE([split-usr],
 588         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 589         [],
 590         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 591                 enable_split_usr=yes
 592         ], [
 593                 enable_split_usr=no
 594         ])])
 595
 596 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 597         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 598 ])
 599
 600 # Work around intltoolize and gtk-doc problems in VPATH builds
 601 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 602                                        [Define to do gtk-doc tests])
 603 AS_IF([test "x$0" != "x./configure"], [
 604         AC_SUBST([INTLTOOL_UPDATE], [/usr/bin/env true])
 605 ])
 606
 607 AC_ARG_ENABLE(tests,
 608         [AC_HELP_STRING([--disable-tests], [disable tests])],
 609         enable_tests=$enableval, enable_tests=yes)
 610 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 611
 612 AC_ARG_ENABLE(debug,
 613         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
 614         [if test "x$enableval" = "xyes"; then
 615                 enableval="hashmap,mmap-cache"
 616         fi
 617         saved_ifs="$IFS"
 618         IFS="$IFS$PATH_SEPARATOR,"
 619         for name in $enableval; do
 620                 case $name in
 621                 hashmap)
 622                         enable_debug_hashmap=yes
 623                         ;;
 624                 mmap-cache)
 625                         enable_debug_mmap_cache=yes
 626                         ;;
 627                 esac
 628         done
 629         IFS="$saved_ifs"],[])
 630
 631 enable_debug=""
 632 AS_IF([test x$enable_debug_hashmap = xyes], [
 633         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
 634         enable_debug="hashmap $enable_debug"
 635 ])
 636 AS_IF([test x$enable_debug_mmap_cache = xyes], [
 637         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
 638         enable_debug="mmap-cache $enable_debug"
 639 ])
 640 test -z "$enable_debug" && enable_debug="none"
 641
 642 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 643 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 644 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 645 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 646 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
 647 AC_SUBST([pamlibdir], [$with_pamlibdir])
 648 AC_SUBST([pamconfdir], [$with_pamconfdir])
 649 AC_SUBST([rootlibdir], [$with_rootlibdir])
 650
 651 AC_CONFIG_FILES([
 652         Makefile po/Makefile.in
 653 ])
 654
 655 AC_OUTPUT
 656 AC_MSG_RESULT([
 657         $PACKAGE_NAME $VERSION
 658
 659         PAM:                     ${have_pam}
 660         AppArmor:                ${have_apparmor}
 661         SELinux:                 ${have_selinux}
 662         SECCOMP:                 ${have_seccomp}
 663         SMACK:                   ${have_smack}
 664         ACL:                     ${have_acl}
 665         polkit:                  ${have_polkit}
 666         blkid:                   ${have_blkid}
 667         dbus:                    ${have_dbus}
 668         kdbus:                   ${have_kdbus}
 669         man pages:               ${have_manpages}
 670         gtk-doc:                 ${enable_gtk_doc}
 671         test coverage:           ${have_coverage}
 672         Split /usr:              ${enable_split_usr}
 673         extra debugging:         ${enable_debug}
 674
 675         prefix:                  ${prefix}
 676         sysconf dir:             ${sysconfdir}
 677         datarootdir:             ${datarootdir}
 678         includedir:              ${includedir}
 679         lib dir:                 ${libdir}
 680         rootlib dir:             ${with_rootlibdir}
 681         PAM modules dir:         ${with_pamlibdir}
 682         PAM configuration dir:   ${with_pamconfdir}
 683         D-Bus policy dir:        ${with_dbuspolicydir}
 684         D-Bus session dir:       ${with_dbussessionservicedir}
 685         D-Bus system dir:        ${with_dbussystemservicedir}
 686         Bash completions dir:    ${with_bashcompletiondir}
 687         Zsh completions dir:     ${with_zshcompletiondir}
 688         Maximum System UID:      ${SYSTEM_UID_MAX}
 689         Maximum System GID:      ${SYSTEM_GID_MAX}
 690
 691         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 692         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
 693         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 694 ])