configure.ac

   1 AC_INIT([udev], [170], [linux-hotplug@vger.kernel.org])
   2 AC_PREREQ(2.60)
   3 AM_INIT_AUTOMAKE([check-news foreign 1.10 dist-bzip2 subdir-objects])
   4 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
   5 AC_DISABLE_STATIC
   6 AC_USE_SYSTEM_EXTENSIONS
   7 AC_SYS_LARGEFILE
   8 AC_CONFIG_MACRO_DIR([m4])
   9 LT_INIT
  10 AC_PROG_AWK
  11 GTK_DOC_CHECK(1.10)
  12 AC_PREFIX_DEFAULT([/usr])
  13 AC_PATH_PROG([XSLTPROC], [xsltproc])
  14
  15 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([POSIX RT library not found])])
  16
  17 AC_ARG_WITH([rootlibdir],
  18         AS_HELP_STRING([--with-rootlibdir=DIR], [rootfs directory to install shared libraries]),
  19         [], [with_rootlibdir=$libdir])
  20 AC_SUBST([rootlib_execdir], [$with_rootlibdir])
  21
  22 AC_ARG_WITH([selinux],
  23         AS_HELP_STRING([--with-selinux], [enable SELinux support]),
  24         [], [with_selinux=no])
  25 if test "x$with_selinux" = xyes; then
  26         LIBS_save=$LIBS
  27         AC_CHECK_LIB(selinux, getprevcon,
  28                 [],
  29                 AC_MSG_ERROR([SELinux selected but libselinux not found]))
  30         LIBS=$LIBS_save
  31         SELINUX_LIBS="-lselinux -lsepol"
  32         AC_DEFINE(WITH_SELINUX, [1] ,[SELinux support.])
  33 fi
  34 AC_SUBST([SELINUX_LIBS])
  35 AM_CONDITIONAL(WITH_SELINUX, [test "x$with_selinux" = xyes])
  36
  37 AC_ARG_ENABLE([debug],
  38         AS_HELP_STRING([--enable-debug], [enable debug messages]),
  39         [], [enable_debug=no])
  40 if test "x$enable_debug" = "xyes"; then
  41         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  42 fi
  43
  44 AC_ARG_ENABLE([logging],
  45         AS_HELP_STRING([--disable-logging], [disable system logging]),
  46         [], enable_logging=yes)
  47 if test "x$enable_logging" = "xyes"; then
  48         AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
  49 fi
  50
  51 AC_ARG_WITH(firmware-path,
  52         AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
  53            [Firmware search path (default=/lib/firmware/updates:/lib/firmware)]),
  54         [], [with_firmware_path="/lib/firmware/updates:/lib/firmware"])
  55 OLD_IFS=$IFS
  56 IFS=:
  57 for i in $with_firmware_path; do
  58         if test "x${FIRMWARE_PATH}" = "x"; then
  59                 FIRMWARE_PATH="\\\"${i}/\\\""
  60         else
  61                 FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
  62         fi
  63 done
  64 IFS=$OLD_IFS
  65 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
  66
  67 AC_ARG_WITH([systemdsystemunitdir],
  68         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
  69         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
  70 if test "x$with_systemdsystemunitdir" != xno; then
  71         AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
  72 fi
  73 AM_CONDITIONAL(WITH_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
  74
  75 # ------------------------------------------------------------------------------
  76 # rule_generator - persistent network and optical device rule generator
  77 # ------------------------------------------------------------------------------
  78 AC_ARG_ENABLE([rule_generator],
  79         AS_HELP_STRING([--disable-rule_generator], [disable persistent network, cdrom support]),
  80         [], [enable_rule_generator=yes])
  81 AM_CONDITIONAL([ENABLE_RULE_GENERATOR], [test "x$enable_rule_generator" = xyes])
  82
  83 # ------------------------------------------------------------------------------
  84 # usb/pci-db - read vendor/device string database
  85 # ------------------------------------------------------------------------------
  86 AC_ARG_ENABLE([hwdb],
  87         AS_HELP_STRING([--disable-hwdb], [disable hardware database support]),
  88         [], [enable_hwdb=yes])
  89 if test "x$enable_hwdb" = xyes; then
  90         if test "x$cross_compiling" = "xno" ; then
  91                 AC_CHECK_FILES([/usr/share/pci.ids], [pciids=/usr/share/pci.ids])
  92                 AC_CHECK_FILES([/usr/share/hwdata/pci.ids], [pciids=/usr/share/hwdata/pci.ids])
  93                 AC_CHECK_FILES([/usr/share/misc/pci.ids], [pciids=/usr/share/misc/pci.ids])
  94         fi
  95
  96         PKG_CHECK_MODULES(USBUTILS, usbutils >= 0.82)
  97         AC_SUBST([USB_DATABASE], [$($PKG_CONFIG --variable=usbids usbutils)])
  98
  99         AC_ARG_WITH(pci-ids-path,
 100                 [AS_HELP_STRING([--with-pci-ids-path=DIR], [Path to pci.ids file])],
 101                 [PCI_DATABASE=${withval}],
 102                 [if test -n "$pciids" ; then
 103                         PCI_DATABASE="$pciids"
 104                 else
 105                         AC_MSG_ERROR([pci.ids not found, try --with-pci-ids-path=])
 106                 fi])
 107         AC_MSG_CHECKING([for PCI database location])
 108         AC_MSG_RESULT([$PCI_DATABASE])
 109         AC_SUBST(PCI_DATABASE)
 110 fi
 111 AM_CONDITIONAL([ENABLE_HWDB], [test "x$enable_hwdb" = xyes])
 112
 113 # ------------------------------------------------------------------------------
 114 # udev_acl - apply ACLs for users with local forground sessions
 115 # ------------------------------------------------------------------------------
 116 AC_ARG_ENABLE([udev_acl],
 117         AS_HELP_STRING([--disable-udev_acl], [disable local user acl permissions support]),
 118         [], [enable_udev_acl=yes])
 119 if test "x$enable_udev_acl" = xyes; then
 120         AC_CHECK_LIB([acl], [acl_init], [:], AC_MSG_ERROR([libacl not found]))
 121         AC_CHECK_HEADER([acl/libacl.h], [:], AC_MSG_ERROR([libacl header not found]))
 122
 123         PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0])
 124         AC_SUBST([GLIB_CFLAGS])
 125         AC_SUBST([GLIB_LIBS])
 126 fi
 127 AM_CONDITIONAL([ENABLE_UDEV_ACL], [test "x$enable_udev_acl" = xyes])
 128
 129 # ------------------------------------------------------------------------------
 130 # GUdev - libudev gobject interface
 131 # ------------------------------------------------------------------------------
 132 AC_ARG_ENABLE([gudev],
 133         AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support]),
 134         [], [enable_gudev=yes])
 135 if test "x$enable_gudev" = xyes; then
 136         PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0])
 137         AC_SUBST([GLIB_CFLAGS])
 138         AC_SUBST([GLIB_LIBS])
 139 fi
 140
 141 AC_ARG_ENABLE([introspection],
 142        AS_HELP_STRING([--disable-introspection], [disable GObject introspection]),
 143        [], [enable_introspection=yes])
 144 if test "x$enable_introspection" = xyes; then
 145         PKG_CHECK_MODULES([INTROSPECTION], [gobject-introspection-1.0 >= 0.6.2])
 146         AC_DEFINE([ENABLE_INTROSPECTION], [1], [enable GObject introspection support])
 147         AC_SUBST([G_IR_SCANNER], [$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)])
 148         AC_SUBST([G_IR_COMPILER], [$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)])
 149         AC_SUBST([G_IR_GENERATE], [$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)])
 150         AC_SUBST([GIRDIR], [$($PKG_CONFIG --define-variable=datadir=${datadir} --variable=girdir gobject-introspection-1.0)])
 151         AC_SUBST([GIRTYPELIBDIR], [$($PKG_CONFIG --define-variable=libdir=${libdir} --variable=typelibdir gobject-introspection-1.0)])
 152 fi
 153 AM_CONDITIONAL([ENABLE_INTROSPECTION], [test "x$enable_introspection" = xyes])
 154
 155 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = xyes])
 156
 157 # ------------------------------------------------------------------------------
 158 # keymap - map custom hardware's multimedia keys
 159 # ------------------------------------------------------------------------------
 160 AC_ARG_ENABLE([keymap],
 161         AS_HELP_STRING([--disable-keymap], [disable keymap fixup support]),
 162         [], [enable_keymap=yes])
 163 if test "x$enable_keymap" = xyes; then
 164         AC_PATH_PROG([GPERF], [gperf])
 165         if test -z "$GPERF"; then
 166                 AC_MSG_ERROR([gperf is needed])
 167         fi
 168
 169         AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 170         AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 171 fi
 172 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = xyes])
 173
 174 # ------------------------------------------------------------------------------
 175 # create_floppy_devices - historical floppy kernel device nodes (/dev/fd0h1440, ...)
 176 # ------------------------------------------------------------------------------
 177 AC_ARG_ENABLE([floppy],
 178         AS_HELP_STRING([--enable-floppy], [enable legacy floppy support]),
 179         [], [enable_floppy=no])
 180 AM_CONDITIONAL([ENABLE_FLOPPY], [test "x$enable_floppy" = xyes])
 181
 182 # ------------------------------------------------------------------------------
 183 # edd_id - create /dev/disk/by-id/edd-* links for BIOS EDD data
 184 # ------------------------------------------------------------------------------
 185 AC_ARG_ENABLE([edd],
 186         AS_HELP_STRING([--enable-edd], [enable disk edd support]),
 187         [], [enable_edd=no])
 188 AM_CONDITIONAL([ENABLE_EDD], [test "x$enable_edd" = xyes])
 189
 190 # ------------------------------------------------------------------------------
 191 # mobile-action-modeswitch - switch Mobile Action cables into serial mode
 192 # ------------------------------------------------------------------------------
 193 AC_ARG_ENABLE([action_modeswitch],
 194         AS_HELP_STRING([--enable-action_modeswitch], [enable action modeswitch support]),
 195         [], [enable_action_modeswitch=no])
 196 if test "x$enable_action_modeswitch" = xyes; then
 197         PKG_CHECK_MODULES(LIBUSB, libusb >= 0.1.12)
 198         AC_SUBST(LIBUSB_CFLAGS)
 199         AC_SUBST(LIBUSB_LIBS)
 200 fi
 201 AM_CONDITIONAL([ENABLE_ACTION_MODESWITCH], [test "x$enable_action_modeswitch" = xyes])
 202
 203 AC_CONFIG_HEADERS(config.h)
 204 AC_CONFIG_FILES([
 205         Makefile
 206         udev/udev.pc
 207         init/udev.service
 208         init/udev-trigger.service
 209         init/udev-settle.service
 210         libudev/libudev.pc
 211         libudev/docs/Makefile
 212         libudev/docs/version.xml
 213         extras/gudev/gudev-1.0.pc
 214         extras/gudev/docs/Makefile
 215         extras/gudev/docs/version.xml
 216 ])
 217
 218 AC_OUTPUT
 219 AC_MSG_RESULT([
 220         udev $VERSION
 221         ========
 222
 223         prefix:                 ${prefix}
 224         sysconfdir:             ${sysconfdir}
 225         sbindir:                ${sbindir}
 226         libdir:                 ${libdir}
 227         rootlibdir:             ${rootlib_execdir}
 228         libexecdir:             ${libexecdir}
 229
 230         datarootdir:            ${datarootdir}
 231         mandir:                 ${mandir}
 232         includedir:             ${includedir}
 233
 234         include_prefix:         ${INCLUDE_PREFIX}
 235
 236         systemdsystemunitdir:   ${systemdsystemunitdir}
 237
 238         logging:                ${enable_logging}
 239         debug:                  ${enable_debug}
 240         selinux:                ${with_selinux}
 241
 242         compiler:               ${CC}
 243         cflags:                 ${CFLAGS}
 244         ldflags:                ${LDFLAGS}
 245
 246         rule_generator:         ${enable_rule_generator}
 247         hwdb:                   ${enable_hwdb}
 248         udev_acl:               ${enable_udev_acl}
 249         gudev:                  ${enable_gudev}
 250         gintrospection:         ${enable_introspection}
 251         keymap:                 ${enable_keymap}
 252         floppy:                 ${enable_floppy}
 253         edd:                    ${enable_edd}
 254         action_modeswitch:      ${enable_action_modeswitch}
 255
 256         usb.ids:                ${USB_DATABASE}
 257         pci.ids:                ${PCI_DATABASE}
 258         firmware path:          ${FIRMWARE_PATH}
 259
 260         xsltproc:               ${XSLTPROC}
 261         gperf:                  ${GPERF}
 262 ])