configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010-2012 Lennart Poettering
   4 #  Copyright 2010-2012 Kay Sievers
   5 #
   6 #  systemd is free software; you can redistribute it and/or modify it
   7 #  under the terms of the GNU Lesser General Public License as published by
   8 #  the Free Software Foundation; either version 2.1 of the License, or
   9 #  (at your option) any later version.
  10 #
  11 #  systemd is distributed in the hope that it will be useful, but
  12 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  13 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  14 #  Lesser General Public License for more details.
  15 #
  16 #  You should have received a copy of the GNU Lesser General Public License
  17 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_PREREQ([2.64])
  20
  21 AC_INIT([systemd],
  22         [182],
  23         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  24         [systemd],
  25         [http://www.freedesktop.org/wiki/Software/systemd])
  26
  27 AC_CONFIG_SRCDIR([src/core/main.c])
  28 AC_CONFIG_MACRO_DIR([m4])
  29 AC_CONFIG_HEADERS([config.h])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 AC_SYS_LARGEFILE
  34 AC_PREFIX_DEFAULT([/usr])
  35 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  36 AM_SILENT_RULES([yes])
  37 AC_CANONICAL_HOST
  38 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  39 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  40        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  41       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  42
  43 LT_PREREQ(2.2)
  44 LT_INIT
  45
  46 # i18n stuff for the PolicyKit policy files
  47 IT_PROG_INTLTOOL([0.40.0])
  48
  49 GETTEXT_PACKAGE=systemd
  50 AC_SUBST(GETTEXT_PACKAGE)
  51
  52 AC_PROG_MKDIR_P
  53 AC_PROG_LN_S
  54 AC_PROG_SED
  55 AC_PROG_GREP
  56 AC_PROG_AWK
  57
  58 AC_PROG_CC
  59 AC_PROG_CC_C99
  60 AM_PROG_CC_C_O
  61 AC_PROG_GCC_TRADITIONAL
  62
  63 AC_PATH_PROG([M4], [m4])
  64 GTK_DOC_CHECK(1.10)
  65 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  66
  67 AC_CHECK_TOOL(OBJCOPY, objcopy)
  68 AC_CHECK_TOOL(STRINGS, strings)
  69 AC_CHECK_TOOL(GPERF, gperf)
  70 if test -z "$GPERF" ; then
  71         AC_MSG_ERROR([*** gperf not found])
  72 fi
  73
  74 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
  75         -pipe \
  76         -Wall \
  77         -W \
  78         -Wextra \
  79         -Wno-inline \
  80         -Wvla \
  81         -Wundef \
  82         -Wformat=2 \
  83         -Wlogical-op \
  84         -Wsign-compare \
  85         -Wformat-security \
  86         -Wmissing-include-dirs \
  87         -Wformat-nonliteral \
  88         -Wold-style-definition \
  89         -Wpointer-arith \
  90         -Winit-self \
  91         -Wdeclaration-after-statement \
  92         -Wfloat-equal \
  93         -Wmissing-prototypes \
  94         -Wstrict-prototypes \
  95         -Wredundant-decls \
  96         -Wmissing-declarations \
  97         -Wmissing-noreturn \
  98         -Wshadow \
  99         -Wendif-labels \
 100         -Wcast-align \
 101         -Wstrict-aliasing=2 \
 102         -Wwrite-strings \
 103         -Wno-long-long \
 104         -Wno-overlength-strings \
 105         -Wno-unused-parameter \
 106         -Wno-missing-field-initializers \
 107         -Wno-unused-result \
 108         -Werror=overflow \
 109         -Wp,-D_FORTIFY_SOURCE=2 \
 110         -ffast-math \
 111         -fno-common \
 112         -fdiagnostics-show-option \
 113         -fno-strict-aliasing \
 114         -fvisibility=hidden \
 115         -ffunction-sections \
 116         -fdata-sections])
 117 AC_SUBST([WARNINGFLAGS], $with_cflags)
 118
 119 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 120         -Wl,--as-needed \
 121         -Wl,--gc-sections])
 122 AC_SUBST([GCLDFLAGS], $with_ldflags)
 123
 124 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 125 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 126
 127 save_LIBS="$LIBS"
 128 LIBS=
 129 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 130 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 131 CAP_LIBS="$LIBS"
 132 LIBS="$save_LIBS"
 133 AC_SUBST(CAP_LIBS)
 134
 135 # This makes sure pkg.m4 is available.
 136 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 137
 138 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 139 PKG_CHECK_MODULES(KMOD, [libkmod >= 5])
 140 PKG_CHECK_MODULES(BLKID,[blkid >= 2.20])
 141
 142 # ------------------------------------------------------------------------------
 143 have_ima=yes
 144 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 145                 [case "${enableval}" in
 146                         yes) have_ima=yes ;;
 147                         no) have_ima=no ;;
 148                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 149                 esac],
 150                 [have_ima=yes])
 151
 152 if test "x${have_ima}" != xno ; then
 153         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 154 fi
 155
 156 # ------------------------------------------------------------------------------
 157 have_selinux=no
 158 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 159 if test "x$enable_selinux" != "xno"; then
 160         PKG_CHECK_MODULES(SELINUX, [ libselinux ],
 161                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 162         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 163                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 164         fi
 165 fi
 166 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 167
 168 # ------------------------------------------------------------------------------
 169 have_xz=no
 170 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 171 if test "x$enable_xz" != "xno"; then
 172         PKG_CHECK_MODULES(XZ, [ liblzma ],
 173                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 174         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 175                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 176         fi
 177 fi
 178 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 179
 180 # ------------------------------------------------------------------------------
 181 AC_ARG_ENABLE([tcpwrap],
 182         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 183                 [case "${enableval}" in
 184                         yes) have_tcpwrap=yes ;;
 185                         no) have_tcpwrap=no ;;
 186                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 187                 esac],
 188                 [have_tcpwrap=auto])
 189
 190 if test "x${have_tcpwrap}" != xno ; then
 191         ACX_LIBWRAP
 192         if test "x${LIBWRAP_LIBS}" = x ; then
 193                 if test "x$have_tcpwrap" = xyes ; then
 194                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 195                 fi
 196                 have_tcpwrap=no
 197         else
 198                 have_tcpwrap=yes
 199         fi
 200 else
 201         LIBWRAP_LIBS=
 202 fi
 203 AC_SUBST(LIBWRAP_LIBS)
 204
 205 # ------------------------------------------------------------------------------
 206 AC_ARG_ENABLE([pam],
 207         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 208                 [case "${enableval}" in
 209                         yes) have_pam=yes ;;
 210                         no) have_pam=no ;;
 211                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 212                 esac],
 213                 [have_pam=auto])
 214
 215 if test "x${have_pam}" != xno ; then
 216         AC_CHECK_HEADERS(
 217                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 218                 [have_pam=yes],
 219                 [if test "x$have_pam" = xyes ; then
 220                         AC_MSG_ERROR([*** PAM headers not found.])
 221                 fi])
 222
 223         AC_CHECK_LIB(
 224                 [pam],
 225                 [pam_syslog],
 226                 [have_pam=yes],
 227                 [if test "x$have_pam" = xyes ; then
 228                         AC_MSG_ERROR([*** libpam not found.])
 229                 fi])
 230
 231         if test "x$have_pam" = xyes ; then
 232                 PAM_LIBS="-lpam -lpam_misc"
 233                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 234         else
 235                 have_pam=no
 236         fi
 237 else
 238         PAM_LIBS=
 239 fi
 240 AC_SUBST(PAM_LIBS)
 241 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 242
 243 # ------------------------------------------------------------------------------
 244 AC_ARG_ENABLE([acl],
 245         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 246                 [case "${enableval}" in
 247                         yes) have_acl=yes ;;
 248                         no) have_acl=no ;;
 249                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 250                 esac],
 251                 [have_acl=auto])
 252
 253 if test "x${have_acl}" != xno ; then
 254         AC_CHECK_HEADERS(
 255                 [sys/acl.h acl/libacl.h],
 256                 [have_acl=yes],
 257                 [if test "x$have_acl" = xyes ; then
 258                         AC_MSG_ERROR([*** ACL headers not found.])
 259                 fi])
 260
 261         AC_CHECK_LIB(
 262                 [acl],
 263                 [acl_get_file],
 264                 [have_acl=yes],
 265                 [if test "x$have_acl" = xyes ; then
 266                         AC_MSG_ERROR([*** libacl not found.])
 267                 fi])
 268
 269         if test "x$have_acl" = xyes ; then
 270                 ACL_LIBS="-lacl"
 271                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 272         else
 273                 have_acl=no
 274         fi
 275 else
 276         ACL_LIBS=
 277 fi
 278 AC_SUBST(ACL_LIBS)
 279 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 280
 281 # ------------------------------------------------------------------------------
 282 AC_ARG_ENABLE([audit],
 283         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 284                 [case "${enableval}" in
 285                         yes) have_audit=yes ;;
 286                         no) have_audit=no ;;
 287                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 288                 esac],
 289                 [have_audit=auto])
 290
 291 if test "x${have_audit}" != xno ; then
 292         AC_CHECK_HEADERS(
 293                 [libaudit.h],
 294                 [have_audit=yes],
 295                 [if test "x$have_audit" = xyes ; then
 296                         AC_MSG_ERROR([*** AUDIT headers not found.])
 297                 fi])
 298
 299         AC_CHECK_LIB(
 300                 [audit],
 301                 [audit_open],
 302                 [have_audit=yes],
 303                 [if test "x$have_audit" = xyes ; then
 304                         AC_MSG_ERROR([*** libaudit not found.])
 305                 fi])
 306
 307         if test "x$have_audit" = xyes ; then
 308                 AUDIT_LIBS="-laudit"
 309                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 310         else
 311                 have_audit=no
 312         fi
 313 else
 314         AUDIT_LIBS=
 315 fi
 316 AC_SUBST(AUDIT_LIBS)
 317
 318 # ------------------------------------------------------------------------------
 319 have_libcryptsetup=no
 320 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 321 if test "x$enable_libcryptsetup" != "xno"; then
 322         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup ],
 323                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 324         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 325                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 326         fi
 327 fi
 328 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 329
 330 # ------------------------------------------------------------------------------
 331 have_binfmt=no
 332 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 333 if test "x$enable_binfmt" != "xno"; then
 334         have_binfmt=yes
 335 fi
 336 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 337
 338 # ------------------------------------------------------------------------------
 339 have_vconsole=no
 340 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 341 if test "x$enable_vconsole" != "xno"; then
 342         have_vconsole=yes
 343 fi
 344 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 345
 346 # ------------------------------------------------------------------------------
 347 have_readahead=no
 348 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 349 if test "x$enable_readahead" != "xno"; then
 350         have_readahead=yes
 351 fi
 352 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 353
 354 # ------------------------------------------------------------------------------
 355 have_quotacheck=no
 356 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 357 if test "x$enable_quotacheck" != "xno"; then
 358         have_quotacheck=yes
 359 fi
 360 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 361
 362 # ------------------------------------------------------------------------------
 363 have_randomseed=no
 364 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 365 if test "x$enable_randomseed" != "xno"; then
 366         have_randomseed=yes
 367 fi
 368 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 369
 370 # ------------------------------------------------------------------------------
 371 have_logind=no
 372 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 373 if test "x$enable_logind" != "xno"; then
 374         have_logind=yes
 375 fi
 376 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 377 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 378
 379 # ------------------------------------------------------------------------------
 380 have_hostnamed=no
 381 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 382 if test "x$enable_hostnamed" != "xno"; then
 383         have_hostnamed=yes
 384 fi
 385 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 386
 387 # ------------------------------------------------------------------------------
 388 have_timedated=no
 389 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 390 if test "x$enable_timedated" != "xno"; then
 391         have_timedated=yes
 392 fi
 393 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 394
 395 # ------------------------------------------------------------------------------
 396 have_localed=no
 397 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 398 if test "x$enable_localed" != "xno"; then
 399         have_localed=yes
 400 fi
 401 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 402
 403 # ------------------------------------------------------------------------------
 404 have_coredump=no
 405 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 406 if test "x$enable_coredump" != "xno"; then
 407         have_coredump=yes
 408 fi
 409 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 410
 411 # ------------------------------------------------------------------------------
 412 if test "x$cross_compiling" = "xno" ; then
 413        AC_CHECK_FILES([/usr/share/pci.ids], [pciids=/usr/share/pci.ids])
 414        AC_CHECK_FILES([/usr/share/hwdata/pci.ids], [pciids=/usr/share/hwdata/pci.ids])
 415        AC_CHECK_FILES([/usr/share/misc/pci.ids], [pciids=/usr/share/misc/pci.ids])
 416 fi
 417
 418 AC_ARG_WITH(usb-ids-path,
 419        [AS_HELP_STRING([--with-usb-ids-path=DIR], [Path to usb.ids file])],
 420        [USB_DATABASE=${withval}],
 421        [if test -n "$usbids" ; then
 422               USB_DATABASE="$usbids"
 423        else
 424               PKG_CHECK_MODULES(USBUTILS, usbutils >= 0.82)
 425               AC_SUBST([USB_DATABASE], [$($PKG_CONFIG --variable=usbids usbutils)])
 426        fi])
 427 AC_MSG_CHECKING([for USB database location])
 428 AC_MSG_RESULT([$USB_DATABASE])
 429 AC_SUBST(USB_DATABASE)
 430
 431 AC_ARG_WITH(pci-ids-path,
 432        [AS_HELP_STRING([--with-pci-ids-path=DIR], [Path to pci.ids file])],
 433        [PCI_DATABASE=${withval}],
 434        [if test -n "$pciids" ; then
 435               PCI_DATABASE="$pciids"
 436        else
 437               AC_MSG_ERROR([pci.ids not found, try --with-pci-ids-path=])
 438        fi])
 439 AC_MSG_CHECKING([for PCI database location])
 440 AC_MSG_RESULT([$PCI_DATABASE])
 441 AC_SUBST(PCI_DATABASE)
 442
 443 # ------------------------------------------------------------------------------
 444 AC_ARG_WITH(firmware-path,
 445        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 446           [Firmware search path (default=ROOTPREFIX/lib/firmware/updates:ROOTPREFIX/lib/firmware)]),
 447        [], [with_firmware_path="$rootprefix/lib/firmware/updates:$rootprefix/lib/firmware"])
 448 OLD_IFS=$IFS
 449 IFS=:
 450 for i in $with_firmware_path; do
 451        if test "x${FIRMWARE_PATH}" = "x"; then
 452               FIRMWARE_PATH="\\\"${i}/\\\""
 453        else
 454               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 455        fi
 456 done
 457 IFS=$OLD_IFS
 458 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
 459
 460 # ------------------------------------------------------------------------------
 461 AC_ARG_ENABLE([gudev],
 462        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 463        [], [enable_gudev=yes])
 464 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0]) ])
 465 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 466
 467 # ------------------------------------------------------------------------------
 468 AC_ARG_ENABLE([keymap],
 469        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 470        [], [enable_keymap=yes])
 471 AS_IF([test "x$enable_keymap" = "xyes"], [
 472        AC_PATH_PROG([GPERF], [gperf])
 473        if test -z "$GPERF"; then
 474               AC_MSG_ERROR([gperf is needed])
 475        fi
 476
 477        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 478        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 479 ])
 480 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 481
 482 # ------------------------------------------------------------------------------
 483 have_manpages=no
 484 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 485 if test "x$enable_manpages" != "xno"; then
 486         have_manpages=yes
 487 fi
 488 AM_CONDITIONAL(ENABLE_MANPAGES, [test "$have_manpages" = "yes"])
 489
 490 # ------------------------------------------------------------------------------
 491 AC_PATH_PROG([XSLTPROC], [xsltproc])
 492 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 493
 494 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux, mandriva, meego, mageia, angstrom or other]))
 495 if test "z$with_distro" = "z"; then
 496         if test "$cross_compiling" = yes; then
 497                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 498         else
 499                 with_distro=$($GREP '^ID=' /etc/os-release | $SED 's/ID=//');
 500         fi
 501         if test "z$with_distro" = "z"; then
 502                 with_distro=other
 503         fi
 504 fi
 505 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 506 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 507
 508 # Location of the init scripts as mandated by LSB
 509 SYSTEM_SYSVINIT_PATH=/etc/init.d
 510 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 511
 512 M4_DEFINES=
 513 have_plymouth=no
 514
 515 case $with_distro in
 516         fedora)
 517                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 518                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 519                 M4_DEFINES=-DTARGET_FEDORA=1
 520                 have_plymouth=yes
 521                 ;;
 522         opensuse|suse)
 523                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 524                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 525                 M4_DEFINES=-DTARGET_SUSE=1
 526                 have_plymouth=yes
 527                 ;;
 528         debian)
 529                 SYSTEM_SYSVRCND_PATH=/etc
 530                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 531                 M4_DEFINES=-DTARGET_DEBIAN=1
 532                 ;;
 533         ubuntu)
 534                 SYSTEM_SYSVRCND_PATH=/etc
 535                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 536                 M4_DEFINES=-DTARGET_UBUNTU=1
 537                 ;;
 538         arch)
 539                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 540                 SYSTEM_SYSVRCND_PATH=/etc
 541                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 542                 M4_DEFINES=-DTARGET_ARCH=1
 543                 ;;
 544         gentoo)
 545                 SYSTEM_SYSVINIT_PATH=
 546                 SYSTEM_SYSVRCND_PATH=
 547                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 548                 M4_DEFINES=-DTARGET_GENTOO=1
 549                 ;;
 550         slackware)
 551                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 552                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 553                 M4_DEFINES=-DTARGET_SLACKWARE=1
 554                 ;;
 555         frugalware)
 556                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 557                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 558                 M4_DEFINES=-DTARGET_FRUGALWARE=1
 559                 have_plymouth=yes
 560                 ;;
 561         altlinux)
 562                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 563                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
 564                 M4_DEFINES=-DTARGET_ALTLINUX=1
 565                 have_plymouth=yes
 566                 ;;
 567         mandriva)
 568                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 569                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
 570                 M4_DEFINES=-DTARGET_MANDRIVA=1
 571                 have_plymouth=yes
 572                 ;;
 573         meego)
 574                 SYSTEM_SYSVINIT_PATH=
 575                 SYSTEM_SYSVRCND_PATH=
 576                 AC_DEFINE(TARGET_MEEGO, [], [Target is MeeGo])
 577                 M4_DEFINES=-DTARGET_MEEGO=1
 578                 ;;
 579         angstrom)
 580                 SYSTEM_SYSVRCND_PATH=/etc
 581                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
 582                 M4_DEFINES=-DTARGET_ANGSTROM=1
 583                 ;;
 584         mageia)
 585                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 586                 AC_DEFINE(TARGET_MAGEIA, [], [Target is Mageia])
 587                 M4_DISTRO_FLAG=-DTARGET_MAGEIA=1
 588                 have_plymouth=yes
 589                 ;;
 590         other)
 591                 ;;
 592         *)
 593                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 594                 ;;
 595 esac
 596
 597 AC_ARG_WITH([sysvinit-path],
 598         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 599                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 600         [SYSTEM_SYSVINIT_PATH="$withval"],
 601         [])
 602
 603 AC_ARG_WITH([sysvrcd-path],
 604         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 605                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 606         [SYSTEM_SYSVRCND_PATH="$withval"],
 607         [])
 608
 609 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 610 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 611 AC_SUBST(M4_DEFINES)
 612
 613 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 614         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 615         SYSTEM_SYSV_COMPAT="yes"
 616         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 617 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 618         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 619 else
 620         SYSTEM_SYSV_COMPAT="no"
 621 fi
 622
 623 AC_ARG_WITH([tty-gid],
 624         [AS_HELP_STRING([--with-tty-gid=GID],
 625                 [Specify the numeric GID of the 'tty' group])],
 626         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 627         [])
 628
 629 AC_ARG_ENABLE(plymouth, AS_HELP_STRING([--enable-plymouth], [enable plymouth support]))
 630 if test -n "$enable_plymouth"; then
 631         have_plymouth="$enable_plymouth"
 632 fi
 633
 634 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 635 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 636 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 637 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 638 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 639 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 640 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 641 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 642 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 643 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
 644 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 645 AM_CONDITIONAL(TARGET_MEEGO, test x"$with_distro" = xmeego)
 646 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
 647 AM_CONDITIONAL(TARGET_MAGEIA, test x"$with_distro" = xmageia)
 648
 649 AM_CONDITIONAL(HAVE_PLYMOUTH, test "$have_plymouth" = "yes")
 650 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 651
 652 AC_ARG_WITH([dbuspolicydir],
 653         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 654         [],
 655         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 656
 657 AC_ARG_WITH([dbussessionservicedir],
 658         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 659         [],
 660         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 661
 662 AC_ARG_WITH([dbussystemservicedir],
 663         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 664         [],
 665         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 666
 667 AC_ARG_WITH([dbusinterfacedir],
 668         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 669         [],
 670         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 671
 672 AC_ARG_WITH([rootprefix],
 673         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 674         [], [with_rootprefix=${ac_default_prefix}])
 675
 676 AC_ARG_WITH([rootlibdir],
 677         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 678         [],
 679         [with_rootlibdir=${libdir}])
 680
 681 AC_ARG_WITH([pamlibdir],
 682         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 683         [],
 684         [with_pamlibdir=${with_rootlibdir}/security])
 685
 686 AC_ARG_ENABLE([split-usr],
 687         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 688         [],
 689         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 690                 enable_split_usr=yes
 691         ], [
 692                 enable_split_usr=no
 693         ])])
 694
 695 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 696         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 697 ])
 698
 699 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 700 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 701 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 702 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 703 AC_SUBST([pamlibdir], [$with_pamlibdir])
 704 AC_SUBST([rootprefix], [$with_rootprefix])
 705 AC_SUBST([rootlibdir], [$with_rootlibdir])
 706
 707 AC_CONFIG_FILES([
 708         Makefile po/Makefile.in
 709         docs/libudev/Makefile
 710         docs/libudev/version.xml
 711         docs/gudev/Makefile
 712         docs/gudev/version.xml
 713 ])
 714
 715 AC_OUTPUT
 716 AC_MSG_RESULT([
 717         $PACKAGE_NAME $VERSION
 718
 719         Distribution:            ${with_distro}
 720         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 721         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 722         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 723         libcryptsetup:           ${have_libcryptsetup}
 724         tcpwrap:                 ${have_tcpwrap}
 725         PAM:                     ${have_pam}
 726         AUDIT:                   ${have_audit}
 727         IMA:                     ${have_ima}
 728         SELinux:                 ${have_selinux}
 729         XZ:                      ${have_xz}
 730         ACL:                     ${have_acl}
 731         binfmt:                  ${have_binfmt}
 732         vconsole:                ${have_vconsole}
 733         readahead:               ${have_readahead}
 734         quotacheck:              ${have_quotacheck}
 735         randomseed:              ${have_randomseed}
 736         logind:                  ${have_logind}
 737         hostnamed:               ${have_hostnamed}
 738         timedated:               ${have_timedated}
 739         localed:                 ${have_localed}
 740         coredump:                ${have_coredump}
 741         plymouth:                ${have_plymouth}
 742         firmware path:           ${FIRMWARE_PATH}
 743         usb.ids:                 ${USB_DATABASE}
 744         pci.ids:                 ${PCI_DATABASE}
 745         gudev:                   ${enable_gudev}
 746         gintrospection:          ${enable_introspection}
 747         keymap:                  ${enable_keymap}
 748
 749         prefix:                  ${prefix}
 750         rootprefix:              ${with_rootprefix}
 751         sysconf dir:             ${sysconfdir}
 752         datarootdir:             ${datarootdir}
 753         includedir:              ${includedir}
 754         include_prefix:          ${INCLUDE_PREFIX}
 755         libexec dir:             ${libexecdir}
 756         lib dir:                 ${libdir}
 757         rootlib dir:             ${with_rootlibdir}
 758         PAM modules dir:         ${with_pamlibdir}
 759         D-Bus policy dir:        ${with_dbuspolicydir}
 760         D-Bus session dir:       ${with_dbussessionservicedir}
 761         D-Bus system dir:        ${with_dbussystemservicedir}
 762         D-Bus interfaces dir:    ${with_dbusinterfacedir}
 763         Split /usr:              ${enable_split_usr}
 764         man pages:               ${have_manpages}
 765 ])